ডানের পরিবর্তে বামদিকে ডেস্কটপ আইকন স্থাপন করা

15

অ্যাপল ডেস্কটপের বাম দিকে স্বয়ংক্রিয়ভাবে উলাম বা আইকন তৈরির যে কোনও উপায়। ডিফল্টরূপে তারা ডানদিকে যায়।

macos desktop

— user59793
সূত্র

— 0942v8653

এটি ম্যাকওএসের সমাধানগুলির মধ্যে একটি যা আমি বুঝতে পারি না। অ্যাপল ব্যবহারকারীদের ডানদিকে আইকন রাখতে বাধ্য করে কেন? আপনি এগুলি বাম দিকে টেনে আনতে পারেন, তবে এটি বিন্দু নয়। আপনি যখন তাদের নাম অনুসারে বাছাই করেন তখন সমস্ত কিছু ডানদিকে ফিরে যায়। এমনকি আপনি যখন Desktopফাইন্ডারে ডিরেক্টরি খুলেন , আইকনগুলি বামদিকে প্রান্তিক হয়! এটি বেমানান। আমার সিস্টেমের ভাষাটি বাম থেকে ডান স্ক্রিপ্টের জন্য সেট করা আছে, আরবী বা হিব্রু নয় ... এটিই কি অ্যাপলের বিখ্যাত অভিজ্ঞতা?

— vtvs

7

আইকনগুলিকে স্বয়ংক্রিয়ভাবে বামে যেতে বাধ্য করার কোনও উপায় নেই (এবং আপনি যে মানদণ্ডটি চয়ন করেন তার দ্বারা সাজিয়ে রাখুন)।

কোনও কার্যকারণ হিসাবে, আপনি কোনও মানদণ্ডের দ্বারা আইটেমগুলি সজ্জিত না করতে এবং বামদিকে ম্যানুয়ালি আইকন স্থাপন না করে আপনি ফাইন্ডারে ভিউ অপশনগুলি পরিবর্তন করতে পারেন ।

ডেস্কটপে একটি ফাঁকা জায়গায় ক্লিক করুন।
ফাইন্ডারের ভিউ> শো ভিউ অপশন মেনুতে যেতে Cmd+ টিপুন Jবা মাউসটি ব্যবহার করুন ।
ইন সাজানোর ক্রম: ডায়ালগে ড্রপডাউন, নয়তো চয়ন কোনটি বা স্ন্যাপ গ্রিডে ।
আপনি আপনার ডেস্কটপে যে কোনও জায়গায় ফাইল ফেলে দিতে সক্ষম হবেন এবং তারা সেখানেই থাকবেন।

ম্যাক বেসিকগুলি দেখুন : আরও তথ্যের জন্য আপনার উইন্ডোগুলিকে সংশোধন করুন।

এছাড়াও মধ্য দিয়ে যেতে ম্যাক বুনিয়াদি Mac ব্যবহার সম্পর্কে আরও জানতে পেজ।

— এম কে
সূত্র

1

কিউ স্বয়ংক্রিয়ভাবে ক্লিন আপ বাই এবং বাছাই অনুসারে বাছাইয়ের বিষয়ে জিজ্ঞাসা করছে, আমি বিশ্বাস করি, ফাইন্ডার ভিউ মেনুতে - এবং এটি এক ধরণের দুর্দান্ত। কেন শুধু ডানদিকে ব্যবস্থা?

— জো 219

ধন্যবাদ। আমি স্বয়ংক্রিয় অংশটি মিস করেছি এবং উত্তরটি সংশোধন করেছি।

— এমকে

2

এটি সেরা সমাধান নয় তবে অন্য কিছু না করলে এটি কাজ করতে পারে ...

ডেস্কটপের সাথে যুক্ত একটি অটোমেটর ফোল্ডার অ্যাকশন তৈরি করুন।
আইটেমটি জুড়ুন: "অ্যাপলস্ক্রিপ্ট চালান"

অ্যাপলস্ক্রিপ্ট পাঠ্য বাক্সে নিম্নলিখিত কোডটি আটকান:

-- https://gist.github.com/mrienstra/8330528
-- Based on http://www.tuaw.com/2012/12/24/applescript-desktop-icon-race/
-- Inspired by http://namesakecomic.com/comic/happy-new-year-from-namesake/#comment-1182035013

-- Rearranges Desktop icons to flow from left to right, top to bottom.

-- To have this run automatically every time files are added or removed from the Desktop, set this script to run as a Desktop "Folder Action". (See https://developer.apple.com/library/mac/documentation/applescript/conceptual/applescriptlangguide/reference/ASLR_folder_actions.html )

-- This is currently a rough proof-of-concept. It has only been tested with OS X 10.8.5 (Mountain Lion).

-- Current known limitations: Does not work with "Label position" set to "Right" (specifically, icons will overlap).



-- Adjust these for different spacing
property theSpacingFactor : 1.0
property theGutterXFactor : 0.57
property theGutterYFactor : 0.57



on rearrangeDesktopIcons()
    tell application "Finder"
        tell icon view options of window of desktop
            set theArrangement to arrangement
            set theArrangementString to theArrangement as string
            if {"not arranged", "«constant ****narr»", "snap to grid", "«constant ****grda»"} does not contain theArrangementString then
                display alert "\"Rearrange Desktop Icons\" AppleScript says:" message "Cannot rearrange Desktop items, please change Desktop \"Sort by\" to \"None\" or \"Snap to Grid\"." giving up after 10
                return
            end if
            set theIconSize to icon size
            set theLabelSize to text size
        end tell

        set theDesktopBounds to bounds of window of desktop
        set theDesktopWidth to item 3 of theDesktopBounds
        set theDesktopHeight to item 4 of theDesktopBounds

        -- Retrieve a list of items on the desktop
        set theDesktopItems to every item of desktop
        set theContestantOffset to theIconSize / 2

        set theSpacing to (theIconSize + theLabelSize + theContestantOffset) * theSpacingFactor
        set theGuttersX to theSpacing * theGutterXFactor
        set theGuttersY to theSpacing * theGutterYFactor
        set theMaxColumns to ((theDesktopWidth - theGuttersX * 2) / theSpacing) as integer
        set theMaxRows to ((theDesktopHeight - theGuttersY * 2) / theSpacing) as integer
        set theMaxLocations to theMaxRows * theMaxColumns

        set y to 1
        repeat with a from 1 to length of theDesktopItems
            set x to a mod theMaxColumns
            if x is 0 then
                set x to theMaxColumns
            end if

            if a is greater than theMaxLocations then
                set desktop position of item a of theDesktopItems to {theGuttersX, theGuttersY}
            else
                set desktop position of item a of theDesktopItems to {theGuttersX + (x - 1) * theSpacing, theGuttersY + (y - 1) * theSpacing}
            end if

            if a mod theMaxColumns is 0 then
                set y to y + 1
            end if
        end repeat
    end tell
end rearrangeDesktopIcons



on adding folder items to alias after receiving listOfAlias
    rearrangeDesktopIcons()
end adding folder items to

on removing folder items from alias after losing listOfAliasOrText
    rearrangeDesktopIcons()
end removing folder items from

rearrangeDesktopIcons()

সুতরাং যখনই আপনার ডেস্কটপে কোনও ফাইল যুক্ত করা হবে তখন সমস্ত ফাইল বর্ণানুক্রমিকভাবে পুনরায় সাজানো হবে ...

— বেনজামিন চৌসে
সূত্র

0

আপনি যে ফোল্ডারগুলি চান সেভাবে সাজান। তারপরে ভিউ'র আওতায় 'পরিষ্কার করুন' hit এটি সবকিছু সুন্দরভাবে সারিবদ্ধ করবে। তারপরে আপনি কেবল সমস্ত ফোল্ডার হাইলাইট করতে পারেন এবং ঠিক যেখানে আপনি চান সেখানে সেগুলি ঠিক রাখতে পারেন। ম্যাকগুলি বাম দিকে, কেবল ডানদিকে ফোল্ডারগুলি সংগঠিত করে না, তবে কয়েকটি সহজ পদক্ষেপের সাহায্যে আপনি সমস্ত কিছু বামে ঝরঝরে করে সাজিয়ে রাখতে পারেন।

— MikeZ
সূত্র

এটি 'উইন্ডো' এর পরিবর্তে 'ভিউ' পড়তে হবে দুঃখিত, এটি আমার খারাপ ছিল।

— মাইকজেড

উত্তরের নীচে একটি সম্পাদনা লিঙ্ক রয়েছে যা পাঠ্যটি সরাসরি সম্পাদনা করতে দেয় :-)

— নোহাইসাইড

0

আমি ডান হাত থেকে সমস্ত ফোল্ডারটি হাইলাইট করেছি, তারপরে সেগুলি সবগুলি ধরে ধরে বাম দিকে আটকে দিলাম।

— জন
সূত্র