আমি বেশিরভাগই এই ফাংশনটি ব্যবহার করি:
cf() {
cd "$(osascript -e 'tell app "Finder" to POSIX path of (insertion location as alias)')"
}
আপনি নীচের মতো একটি স্ক্রিপ্টকেও একটি শর্টকাট বরাদ্দ করতে পারেন।
একটি বিদ্যমান ট্যাব পুনরায় ব্যবহার করুন বা একটি নতুন উইন্ডো তৈরি করুন (টার্মিনাল):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if (exists window 1) and not busy of window 1 then
do script "cd " & quoted form of p in window 1
else
do script "cd " & quoted form of p
end if
activate
end tell
একটি বিদ্যমান ট্যাব পুনরায় ব্যবহার করুন বা একটি নতুন ট্যাব তৈরি করুন (টার্মিনাল):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if not (exists window 1) then reopen
activate
if busy of window 1 then
tell application "System Events" to keystroke "t" using command down
end if
do script "cd " & quoted form of p in window 1
end tell
সর্বদা একটি নতুন ট্যাব তৈরি করুন (আইটার্ম 2):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "iTerm"
if exists current terminal then
current terminal
else
make new terminal
end if
tell (launch session "Default") of result to write text "cd " & quoted form of p
activate
end tell
প্রথম দুটি স্ক্রিপ্টে 10.7-এ যুক্ত পরিষেবাদির তুলনায় কয়েকটি সুবিধা রয়েছে:
- ১০.৯-তে, একটি বাগ রয়েছে যেখানে সার্ভিসগুলি যেগুলি ইনপুট হিসাবে ফোল্ডারগুলি গ্রহণ করে সেগুলি কলাম ভিউতে পরিষেবা মেনুতে কখনই তালিকাভুক্ত হয় না। আপনি যদি ফোল্ডার পরিষেবাতে নতুন টার্মিনাল ট্যাব কোনও কীবোর্ড শর্টকাট বরাদ্দ করেন তবে এটি কলাম ভিউতে কাজ করে না।
- আপনাকে প্রথমে কোনও ফোল্ডার নির্বাচন করার প্রয়োজনের পরিবর্তে তারা শিরোনাম বারে ফোল্ডারটি ব্যবহার করে।
- ব্যস্ত না হলে তারা সম্মুখতম ট্যাবটি পুনরায় ব্যবহার করে, যেমন একটি কমান্ড চালানো, ম্যান পৃষ্ঠা প্রদর্শন করা বা ইম্যাক চালানো।
আপনি যদি 10.7 বা 10.8 ব্যবহার করেন তবে এতে পরিবর্তন tell application "Finder" to set p to POSIX path of (insertion location as alias)করুন:
tell application "Finder"
if exists Finder window 1 then
set p to POSIX path of (target of Finder window 1 as alias)
else
set p to POSIX path of (path to desktop)
end if
end tell
10.7 এবং 10.8 (তবে 10.9 বা 10.6 এ নয়) -তে একটি বাগ রয়েছে যেখানে insertion locationসম্পত্তি পাওয়ার সময় ফাইন্ডার শেষবারের ফোকাসের পরে অন্য অ্যাপ্লিকেশনটিতে ফিরে আসার পরে তৈরি উইন্ডোগুলি উপেক্ষা করে ।
