সাফারি ওয়েবপেজ হিসাবে অ্যাপলস্ক্রিপ্ট অ্যাপ্লিকেশন

Question

আমি বর্তমানে একটি অ্যাপলস্ক্রিপ্ট অ্যাপ্লিকেশন ব্যবহার করছি যা সাফারিতে একটি ওয়েবসাইট (পিএইচপিএমআইএডমিন) চালু করে। আমি সহজেই অ্যাক্সেসের জন্য এটিকে আমার ডকে রাখি।

আমি যা খুঁজছি

• এএসএ (অ্যাপলস্ক্রিপ্ট অ্যাপ্লিকেশন) এ ক্লিক করার পরে এটি সাফারি পৃষ্ঠাতে খোলে
• আমি যখন অন্য একটি উইন্ডোতে চলে যাই এবং আবার এএসএতে ক্লিক করি তখন এটি একটি নতুন উইন্ডো / ট্যাবে পুনরায় খোলার পরিবর্তে সাফারি উইন্ডোটিকে সামনে আনবে
• আমি এএসএ ছেড়ে দিলে সাফারি পৃষ্ঠা বন্ধ হয়ে যাবে
• ওয়েবসাইটটি যেখানে রয়েছে সেই ট্যাবটি যদি IX আউট করেন তবে এএসএটি প্রস্থান করবে

এটি করার জন্য কারও যদি ধারণা থাকে তবে এটি দুর্দান্ত হবে!

Comments

চারটি বুলেট পয়েন্ট বিবেচনায় নিয়ে, আমি বিশ্বাস করি না যে এটি সাধারণ বেসিক সাধারণ অ্যাপলস্ক্রিপ্টের সাথে যুক্তিসঙ্গতভাবে কার্যকরযোগ্য, আপনাকে সম্ভবত অ্যাপলস্ক্রিপ্টবিজেসিতে যেতে হবে। আইএমও কেবলমাত্র প্রথম দুটি বুলেট পয়েন্টে ফোকাস করা আরও সহজ হবে। আমি এটি তখনই লিখতাম যখন অ্যাপটি চালানো হয়, এটি লক্ষ্যযুক্ত ট্যাবটি উপস্থিত রয়েছে কিনা তা পরীক্ষা করে দেখায় এবং তা না হলে এটিটি না খোলে, অন্যথায় এটি সামনে আনুন এবং প্রস্থান করুন। আমি সত্যিই শেষ দুটি বুলেট পয়েন্টের প্রয়োজন দেখছি না, আপনি যখন এটি সম্পন্ন করেছেন তখন পৃষ্ঠাটি বন্ধ করুন এবং অ্যাপটি ইতিমধ্যে যেভাবেই বন্ধ হয়ে গেছে।

— ব্যবহারকারী 3439894

@ ব্যবহারকারী 3439894 তথ্যের জন্য ধন্যবাদ। আমি সম্মত আমি প্রস্তাবিত উপায় এটি করব। শেষ দুটি গুলি হ'ল কেউ রান হ্যান্ডলারটি ওপেন রাখতে ব্যবহার করে।

— জবিস

আইএমও রান হ্যান্ডলারের পরে বাঁচার দরকার নেই, এবং আপনি যদি এটি খোলা রাখেন তবে কোডটি লুপ করতে হবে এবং এটি কেবল প্রথম দুটি বুলেট পয়েন্টকে কেন্দ্র করে একটি যুক্তিসঙ্গত কাজের সমাধান অর্জন করতে ব্যবহারিক নয়।

— ব্যবহারকারীর 3439894

আপনি কি এমন কোনও সমাধানে আগ্রহী হবেন যা phpMyAdmin কে তার নিজস্ব "অ্যাপ" এ দেবে? যদি তা হয় তবে ফ্লুইডআপ ডট কমের মতো কিছু আদর্শ পছন্দ বলে মনে হচ্ছে।

— টিজে লুওমা

আমি মনে করি ইলেকট্রনের ভিত্তিতে @ টিজে লুওমা থ্যাটস। সম্ভবত ভাল ধারণা।

— জবিস

Answer 1

অন্য ব্যবহারকারীরা যেমন উল্লেখ করেছেন, তৃতীয় এবং চতুর্থ বুলেট পয়েন্টগুলি সম্ভবত ধরে রাখা উপযুক্ত নয়, কারণ এটি প্রথম দুটি কার্যকর করা কঠিন করে তোলে:

use S : application "Safari"
property PHPMyAdminURL : "http://xxxxx/ppmya"


on run
    if S is not running then return openPHPMyAdmin()

    set _T to a reference to (every tab of every window of S whose ¬
        name contains "PHPMyAdmin" and ¬
        URL contains "/ppmya")

    if (count _T) > 0 then return viewPHPMyAdmin(_T)

    openPHPMyAdmin()
end run


to openPHPMyAdmin()
    tell S
        if (count windows) = 0 then
            make new document with properties ¬
                {URL:PHPMyAdminURL}
        else
            make new tab at end of tabs of S's window 1 ¬
                with properties ¬
                {URL:PHPMyAdminURL}
            set current tab of S's window 1 to the result
        end if

        activate
    end tell
end openPHPMyAdmin


to viewPHPMyAdmin(T)
    set [T] to T
    set W to the first window of S whose tabs contains T

    set current tab of W to T
    activate S
    set the index of W to 1
end viewPHPMyAdmin

@ ব্যবহারকারী 3439894 এর কিছু প্রাথমিক প্রতিক্রিয়ার পরে, আমি স্ট্যান্ড on quit-ওপেন অ্যাপ্লিকেশন হিসাবে আইটেম 2 কার্যকরভাবে কার্যকর হতে বাধা দেয় বলে স্ক্রিপ্টটি ব্যবহার করার চেষ্টা করায় হ্যান্ডলারটি সরিয়েছি ।

Comments

আমি তবে আপনার কোডটি পরীক্ষা করে নিই না, প্রথম নজরে এই তৃতীয় বুলেট পয়েন্টটি সন্তুষ্ট করার জন্য রান হ্যান্ডলারের পরে খোলা থাকার জন্য লেখা আছে, তাই না? ঠিক আছে আমি অ্যাপটি চালুর পরে এবং খোলা থাকার পরে দ্বিতীয় বুলেট পয়েন্টটি কীভাবে এটি পরিচালনা করবে তা দেখতে আমি ব্যর্থ। খোলা অ্যাপলস্ক্রিপ্ট অ্যাপের ডক টাইল ক্লিক করে আবারও লক্ষ্য ট্যাবে ফোকাস সেট করতে কোনও অতিরিক্ত কোড চালানো যাচ্ছে না।

— ব্যবহারকারী 3439894

@ ব্যবহারকারী 3439894 হ্যাঁ আপনি ঠিক বলেছেন। ওপির প্রশ্নের বিপরীতে আমার আপনার প্রাথমিক মন্তব্যগুলি আরও সূক্ষ্মভাবে পড়া উচিত ছিল, কারণ এটিই প্রথম থেকেই আপনি সতর্ক করেছিলেন warning

— সিজেকে

ভাল স্ক্রিপ্ট। অন ​​প্রস্থান হ্যান্ডলারের সাহায্যে সমস্যা সমাধানের কোনও উপায় আমি খুঁজে পাচ্ছি কিনা তা দেখতে পাবেন onna ধন্যবাদ.

— জবিস