এক্সেল থেকে ইউআরএল অনুলিপি করুন

Question

আমি আমার প্রথম আপেলস্ক্রিপ্ট করছি। আমি এক্সেল থেকে পিংডম সরঞ্জামের গতি পরীক্ষায় একটি সংক্ষিপ্ত পাঠ্য (এটি একটি ওয়েবসাইট) অনুলিপি করতে চাই। দীর্ঘ সময়ে আমি এটি বিভিন্ন পাঠ্যের সাথে এটি করতে চাই - তবে প্রথমে আমি একটি দিয়ে শুরু করতে চাই।

আমি এক্সেল এবং তারপরে ডকুমেন্টটি খুলতে সক্ষম হয়েছি। তবে তারপরে আমাকে ক্ষেত্র বি 1 এর জন্য কপি করতে হবে। আমি 'Goo' বি 1 তে পরিচালিত হয়েছি, তবে তারপরে আমাকে এটি অনুলিপি করতে হবে, এবং আমি কীভাবে তা বুঝতে পারি না।

পরবর্তী স্টেড হ'ল ক্রোম সক্রিয় করা এবং তারপরে টুলস.পটিম.কম - আমি এটি করতে সক্ষম হয়েছি। তবে আমি কীভাবে পিংডোমে বি 1 এর মান ফিল্ডে আটকে দিতে পারি?

আশা করি কেউ আমাকে সাহায্য করবে. যদি এটি যথেষ্ট ভাল ব্যাখ্যা না করা থাকে তবে আমাকে জানান।

সেরা, সোরেন

Comments

আপনি কি করছেন তা দয়া করে পরিষ্কার করতে পারেন? আপনার অর্থ কী তা বোঝা শক্ত।

— আইপোগ্রাম

ভিন্ন জিজ্ঞাসা স্বাগতম। আপনি লিখেন I want to copy a short text (that's a website).. যখন আপনি ওয়েবসাইট লিখবেন, আপনার কি ইউআরএল বোঝাচ্ছে (এরকম কিছু https://apple.stackexchange.com)

— জৌমে

Answer 1

আমার কাছে মাইক্রোসফ্ট এক্সেল নেই তাই আমি ফিল্ড বি 1 এর তথ্য দিয়ে অ্যাপলস্ক্রিপ্টে একটি পরিবর্তনশীল সেট করতে সত্যিই সহায়তা করতে পারি না। এই নিম্নলিখিত কোডটি আপনাকে কিছুটা সহায়তা করতে পারে এবং আপনাকে সঠিক ট্র্যাকে সেট করতে পারে।

property theURL : "https://tools.pingdom.com/"
-- change the URL in the following variable to the URL from field B1 from Excel
set urlFromExcel to "https://apple.stackexchange.com/questions/338936/copy-from-excel-to-url"

if application "Google Chrome" is not running then
    tell application "Google Chrome"
        activate
        repeat while not (exists of window 1)
            delay 0.1
        end repeat
        tell its window 1
            set URL of (make new tab) to theURL
        end tell
    end tell
else if application "Google Chrome" is running then
    tell application "Google Chrome"
        if not (exists of (tabs of window 1 whose URL contains "pingdom")) then
            tell its window 1
                set URL of (make new tab) to theURL
            end tell
        end if
    end tell
end if

tell application "Google Chrome" to tell active tab of window 1
    repeat while loading is true
        delay 0.1
    end repeat
end tell

inputByID("urlInput", urlFromExcel)

to inputByID(theId, theValue)
    tell application "Google Chrome" to (tabs of window 1 whose URL contains "pingdom")
    set pingdomTabs to item 1 of the result
    tell application "Google Chrome"
        execute pingdomTabs javascript "document.getElementById('" & theId & "').value ='" & theValue & "';"
    end tell
end inputByID