কমান্ড লাইনটি ব্যবহার করে আমি কীভাবে ব্লুটুথ টিথারিং শুরু করতে পারি?

Question

আমি আশা করি কেবল কীবোর্ডটি ব্যবহার করে আমার আইফোনটি ব্যবহার করে টিথারিং শুরু করার একটি দ্রুত উপায় চাই। ব্লুটুথ মেনুটি ব্যবহার করে, আমি আমার ডিভাইসের জন্য সাবমেনুতে নেটওয়ার্ক থেকে সংযোগের বিকল্পটি চয়ন করতে পারি, তবে এটি কী স্বয়ংক্রিয়ভাবে চালানো সম্ভব?

শেষ পর্যন্ত আমি এটিকে (খুব ভয়ঙ্কর) আলফ্রেড.এপ-এ একটি শর্টকাটে বরাদ্দ করতে চাই, তবে কমান্ড লাইন বা অ্যাপলস্ক্রিপ্ট ব্যবহার করে যে কোনও কিছুই কাজ করবে।

এটা কি সম্ভব? ধন্যবাদ !!

Answer 1

দেখে মনে হচ্ছে না এইভাবে ব্লুটুথের সাথে কাজ করার জন্য সরাসরি অ্যাপলস্ক্রিপ্ট অভিধান রয়েছে।

আপনি যদিও জিইউআই স্ক্রিপ্টিং ব্যবহার করতে পারেন, যা ম্যাক ওএসের অ্যাক্সেসযোগ্যতা বৈশিষ্ট্যটি মেনু আইটেমগুলি ইত্যাদি নির্বাচন করতে ব্যবহার করে

জিইউআই অ্যাপলস্ক্রিপ্ট দিয়ে কীভাবে শুরু করবেন সে সম্পর্কে একটি দুর্দান্ত লিখনআপ ম্যাকোসআউটোমেশন ডটকম এ উপলব্ধ ।

আপনার যদি ক্রমাগত পরিবর্তিত জিনিসের তালিকা থাকে তবে জিইউআই অটোমেশনটি কঠিন হতে পারে, তবে আপনার যদি সাধারণত ব্লুটুথ আইটেমগুলির সাথে সংযুক্ত থাকে যা একই থাকে তবে আপনার ঠিক থাকা উচিত।

তারপরে আপনি আলফ্রেডের মাধ্যমে এই অ্যাপলস্ক্রিপ্টটি কল করতে পারেন।

Answer 2

http://macscripter.net/viewtopic.php?id=38559

উপরের লিঙ্কটিতে একটি খুব সুন্দর স্ক্রিপ্ট আমি কিছুটা আপডেট করেছি। মনে রাখবেন যে এটিতে ব্লুটুইল [ গিট রেপো ] [ ওয়েবসাইট / বাইনারি ] ব্যবহার করা হয়েছে।

ব্লুটুথ সক্ষম করুন:

-- Enable Bluetooth and Connect to iPhone

property blueutilPath : "/opt/local/bin/blueutil"

-- Turn on bluetooth.
if execBlueutil("status") contains "Status: off" then
    execBlueutil("on")

    connectDevice()

    doGrowl()

end if

on execBlueutil(command)
    set res to do shell script blueutilPath & " " & command
    if res contains "Error" then
        display dialog res
        quit
    end if
    return res
end execBlueutil

-- Connect Device
on connectDevice()
    tell application "System Preferences"
        activate
        set AppleScript's text item delimiters to "."
        set current pane to pane "com.apple.preference.network"
        set winNetwork to "Network"
        set btooth to "Bluetooth"

        tell application "System Events" to tell process "System Preferences"
            set theRow to row 1 of table 1 of scroll area 1 of window winNetwork whose value of static text 1 contains btooth
            select theRow --clicks the bluetooth row
            --If Bluetooth is already connected, the button will say Disconnect, so we don't want to turn it off:
            try
                click (button 1 of group 1 of window winNetwork whose title is "Connect")
            end try
        end tell
        tell application "System Preferences"
            quit
        end tell
    end tell
end connectDevice

on doGrowl()
    tell application "System Events"
        set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
    end tell
    if isRunning then
        tell application id "com.Growl.GrowlHelperApp"
            set the allNotificationsList to ¬
                {"Bluetooth Setting"}
            set the enabledNotificationsList to ¬
                {"Bluetooth Setting"}
            register as application ¬
                "AppleScript - Bluetooth" all notifications allNotificationsList ¬
                default notifications enabledNotificationsList

            notify with name ¬
                "Bluetooth Setting" title ¬
                "Bluetooth is On & iPhone Connected" description ¬
                "Bluetooth has been enabled with iPhone tethered." application name "AppleScript - Bluetooth" icon of file (path to me)
        end tell
    end if
end doGrowl

ব্লুটুথ অক্ষম করুন:

property blueutilPath : "/opt/local/bin/blueutil"

-- Turn off Bluetooth.
if execBlueutil("status") contains "Status: on" then
    execBlueutil("off")

    doGrowl()
end if
on execBlueutil(command)
    set res to do shell script blueutilPath & " " & command
    if res contains "Error" then
        display dialog res
        quit
    end if
    return res
end execBlueutil

on doGrowl()
    tell application "System Events"
        set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
    end tell
    if isRunning then
        tell application id "com.Growl.GrowlHelperApp"
            set the allNotificationsList to ¬
                {"Bluetooth Setting"}
            set the enabledNotificationsList to ¬
                {"Bluetooth Setting"}
            register as application ¬
                "AppleScript - Bluetooth" all notifications allNotificationsList ¬
                default notifications enabledNotificationsList

            notify with name ¬
                "Bluetooth Setting" title ¬
                "Bluetooth Off" description ¬
                "Bluetooth has been disabled." application name "AppleScript - Bluetooth" icon of file (path to me)
        end tell
    end if
end doGrowl

Answer 3

আমি এর জন্য অটোমেটার ব্যবহার করার পরামর্শ দেব, আপনি এটিকে সহজ করার জন্য আলফ্রেড থেকে কল করতে পারেন :)

আমার বর্তমান অটোমেটরের ওয়ার্কফ্লো এটি করে:

Click the "bluetooth" menu bar item.
Connect to Network

এই পদ্ধতিটি ব্যবহার করে আপনি এক মিনিটের মধ্যে প্রায় কোনও কিছু স্বয়ংক্রিয় করতে পারেন