সংজ্ঞায়িত পরিমাণের সাথে পরিচিতি তালিকা তৈরি করার কোনও উপায় কি কেউ জানেন? এগুলি ছদ্মবেশী এন্ট্রি হতে পারে, তবে আমার কেবল> 2000 এন্ট্রি সহ একটি ঠিকানা বই তৈরি করা দরকার। একটি অটোমেটর স্ক্রিপ্ট হ'ল আমার মনে যা আছে তবে আমি কীভাবে এটি করব তা নিশ্চিত নই।
যদি এটি ভুল জায়গায় থাকে তবে আমি ক্ষমা চাই। এসই বা এসই বিবেচনা করছিল তবে অনুভব করেছি যে আমি এখানেই শুরু করব।
উত্তর:
একটি অ্যাপলজিপ্ট ওএস এক্স অ্যাড্রেস বুক এন্ট্রিগুলি বাল্ক-তৈরি করতে পারে, যা আপনি আপনার আইফোনটিতে আমদানি করতে পারবেন। আমি আপনার জন্য একটি বেসিক তৈরি করেছি:
-- Change these to your desired data
set firstName to "Test"
set lastName to "User"
set numberOfEntries to "5" as integer
set counter to "1" as integer
tell application "Address Book"
repeat numberOfEntries times
set thePerson to make new person with properties {first name:firstName, last name:lastName & " " & counter}
make new email at end of emails of thePerson with properties {label:"Work", value:"test" & counter & "@example.com"}
make new address at end of addresses of thePerson with properties {label:"Home", city:"Fakeville", street:(counter as string) & " Some St."}
set counter to counter + 1
end repeat
save
end tell
অ্যাপলস্ক্রিপ্ট সম্পাদক খুলুন (আপনার Applications/Utilities/ফোল্ডারে) এবং এটি একটি নতুন স্ক্রিপ্টে আটকান। যেমনটি, এটি আপনাকে এর মতো 5 নম্বরযুক্ত যোগাযোগ করবে:
আপনি set numberOfEntries to "5" as integerলাইনের নম্বরটি আপনার প্রয়োজনীয় অনেকগুলিতে পরিবর্তন করতে পারেন, এবং আপনি ইচ্ছা করলে ডেটা পরিবর্তন করতে পারেন। আপনার যদি অন্যান্য ক্ষেত্রগুলির প্রয়োজন হয় (যেমন ফোন নম্বর), জিজ্ঞাসা করুন এবং আমি আপনাকে কীভাবে তা দেখাতে পারি।
আমি কিছুটা ওভারবোর্ডে গিয়েছিলাম এবং এমন একটি সংস্করণ তৈরি করেছি যা সুন্দর নাম নিয়ে আসে। আমি ২০ টি সর্বাধিক জনপ্রিয় পুরুষ ও মহিলা নাম নিলাম, ৪০ টি সর্বাধিক জনপ্রিয় সর্বশেষ নাম এবং একটি মধ্যম প্রাথমিক যুক্ত করেছি, সুতরাং আপনি আমার গণিত দ্বারা ডুপ্লিকেটগুলির (কমপক্ষে ৫০% এর নিচে কিছুটা) পাবেন বোকা খুঁজছেন নম্বরযুক্ত পরিচিতি।
এটি একটি গোষ্ঠীতে ("টেস্ট গ্রুপ") এর সাথে সমস্ত পরিচিতি যুক্ত করে যাতে আপনি কোনও বিদ্যমান ঠিকানা পুস্তকে যুক্ত করে থাকেন এবং পরে এটি পরিষ্কার করতে চান তবে আপনি সহজেই সমস্ত ডামিগুলি চয়ন করতে পারেন।
সম্পাদনা: কয়টি আইটেম তৈরি করতে হবে তার প্রম্পটেও আমি এটি পরিবর্তন করেছি, সুতরাং কোড সম্পাদনা করার প্রয়োজন নেই।
-- name lists: 20 most popular (US) male and female first names, 40 most popular last names
set firstNameList to {"Mary", "Patricia", "Linda", "Barbara", "Elizabeth", "Jennifer", "Maria", "Susan", "Margaret", "Dorothy", "Lisa", "Nancy", "Karen", "Betty", "Helen", "Sandra", "Donna", "Carol", "Ruth", "Sharon", "James", "John", "Robert", "Michael", "William", "David", "Richard", "Charles", "Joseph", "Thomas", "Christopher", "Daniel", "Paul", "Mark", "Donald", "George", "Kenneth", "Steven", "Edward", "Brian"}
set lastNameList to {"Smith", "Johnson", "Williams", "Jones", "Brown", "Davis", "Miller", "Wilson", "Moore", "Taylor", "Anderson", "Thomas", "Jackson", "White", "Harris", "Martin", "Thompson", "Garcia", "Martinez", "Robinson", "Clark", "Rodriguez", "Lewis", "Lee", "Walker", "Hall", "Allen", "Young", "Hernandez", "King", "Wright", "Lopez", "Hill", "Scott", "Green", "Adams", "Baker", "Gonzalez", "Nelson", "Carter"}
set initialList to "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
set counter to "1" as integer
-- prompt for how many contacts to create
set dialogText to "Number of contacts to create?"
repeat
display dialog dialogText default answer ""
set numberOfEntries to text returned of result
try
if numberOfEntries = "" then error
set numberOfEntries to numberOfEntries as number
exit repeat
on error
end try
end repeat
-- populate the address book
tell application "Address Book"
set theGroup to make new group with properties {name:"Test Group"}
repeat numberOfEntries times
set firstName to some item of firstNameList
set lastName to some item of lastNameList
set middleInitial to some item of initialList & "."
set thePerson to make new person with properties {first name:firstName, middle name:middleInitial, last name:lastName}
make new email at end of emails of thePerson with properties {label:"Work", value:firstName & middleInitial & lastName & "@example.com"}
make new address at end of addresses of thePerson with properties {label:"Home", city:"Fakeville", street:(counter as string) & " Some St."}
add thePerson to theGroup
set counter to counter + 1
end repeat
save
end tell
এটি যা উত্পন্ন করে তা এখানে:
