মেশিন কোডে কেবল প্রিন্টযোগ্য দৃশ্যমান ASCII অক্ষর ব্যবহার করে x86 / x86-64 এ আলাদাভাবে শাখা

Question

টাস্কটি সহজ: মেশিন কোডে কেবল প্রিন্টযোগ্য দৃশ্যমান ASCII অক্ষর 0x21 ... 0x7e (0x7e (স্পেস এবং ডেল অনুমোদিত নয়) ব্যবহার করে x86 (32-বিট) এবং x86-64 (64-বিট) তে আলাদা আলাদা একটি শাখাগুলি লিখুন) ।

• শর্তাধীন সমাবেশের অনুমতি নেই।
• এপিআই কলগুলি ব্যবহারের অনুমতি নেই।
• কার্নেল-মোড (রিং 0) কোড ব্যবহারের অনুমতি নেই।
• কোডটি অবশ্যই লিনাক্সে বা অন্য কোনও সুরক্ষিত মোড ওএসে আইএ -32 এবং x86-64 উভয় ক্ষেত্রেই ব্যতিক্রম ঘটানো ছাড়া চলবে।
• ক্রিয়াকলাপ অবশ্যই কমান্ড লাইন প্যারামিটারের উপর নির্ভর করবে না।
• 0x21 ... 0x7e (33 ... 126 দশমিক) ব্যাপ্তিতে কেবলমাত্র ASCII অক্ষর ব্যবহার করে সমস্ত নির্দেশাবলী মেশিন কোডে এনকোড করা উচিত। সুতরাং যেমন। আপনি স্ব-সংশোধনকারী কোড ব্যবহার না করা cpuidসীমা ছাড়াই (এটি 0f a2))
• একই বাইনারি কোডটি অবশ্যই x86 এবং x86-64 এ চলতে হবে তবে ফাইল শিরোনাম (ELF / ELF64 / ইত্যাদি) আলাদা হতে পারে, আপনাকে আবার একত্রিত হতে হবে এবং আবার এটি লিঙ্ক করতে হবে। তবে, বাইনারি কোড অবশ্যই পরিবর্তন করা উচিত নয়।
• I386 ... কোর আই 7 এর মধ্যে থাকা সমস্ত প্রসেসরের উপর সমাধানগুলি সমাধান করা উচিত তবে আমি আরও সীমিত সমাধানেও আগ্রহী।
• কোডটি অবশ্যই 32-বিট x86 তে শাখা করা উচিত তবে x86-64 বা তার বিপরীতে নয়, তবে শর্তযুক্ত জাম্প ব্যবহারের প্রয়োজন নেই (পরোক্ষ লাফ বা কলটিও গ্রহণযোগ্য)। শাখার টার্গেটের ঠিকানাটি অবশ্যই এমন হতে হবে যে কোনও কোডের জন্য স্থান রয়েছে, কমপক্ষে 2 বাইট স্পেস যাতে একটি সংক্ষিপ্ত লাফ ( jmp rel8) ফিট করে।

বিজয়ী উত্তরটি হ'ল মেশিন কোডের সর্বনিম্ন বাইট ব্যবহার করে। ফাইল শিরোনামের বাইটগুলি (ELF / ELF64 উদাহরণস্বরূপ) গণনা করা হয় না, এবং শাখার পরে কোনও কোড বাইট (পরীক্ষার উদ্দেশ্যে ইত্যাদি) গণনা করা হয় না।

আপনার উত্তরটি ASCII হিসাবে, হেক্সাডেসিমাল বাইট হিসাবে এবং মন্তব্য কোড হিসাবে উপস্থাপন করুন।

আমার সমাধান, 39 বাইট:

হওয়া ASCII: fhotfhatfhitfhutfhotfhatfhitfhut_H3<$t!

হেক্সাডেসিমেল: 66 68 6F 74 66 68 61 74 66 68 69 74 66 68 75 74 66 68 6F 74 66 68 61 74 66 68 69 74 66 68 75 74 5F 48 33 3C 24 74 21।

কোড:

; can be compiled eg. with yasm.
; yasm & ld:
; yasm -f elf64 -m amd64 -g dwarf2 x86_x86_64_branch.asm -o x86_x86_64_branch.o; ld x86_x86_64_branch.o -o x86_x86_64_branch
; yasm & gcc:
; yasm -f elf64 -m amd64 -g dwarf2 x86_x86_64_branch.asm -o x86_x86_64_branch.o; gcc -o x86_x86_64_branch x86_x86_64_branch.o

section .text
global main
extern printf

main:
    push    word 0x746f     ; 66 68 6f 74 (x86, x86-64)
    push    word 0x7461     ; 66 68 61 74 (x86, x86-64)
    push    word 0x7469     ; 66 68 69 74 (x86, x86-64)
    push    word 0x7475     ; 66 68 75 74 (x86, x86-64)

    push    word 0x746f     ; 66 68 6f 74 (x86, x86-64)
    push    word 0x7461     ; 66 68 61 74 (x86, x86-64)
    push    word 0x7469     ; 66 68 69 74 (x86, x86-64)
    push    word 0x7475     ; 66 68 75 74 (x86, x86-64)

    db      0x5f            ; x86:    pop edi
                            ; x86-64: pop rdi

    db      0x48, 0x33, 0x3c, 0x24
                            ; x86:
                            ; 48          dec eax
                            ; 33 3c 24    xor edi,[esp]

                            ; x86-64:
                            ; 48 33 3c 24 xor rdi,[rsp]

    jz      @bits_64        ; 0x74 0x21
                            ; branch only if running in 64-bit mode.

; the code golf part ends here, 39 bytes so far.

; the rest is for testing only, and does not affect the answer.

    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop
    nop

    jmp     @bits_32

@bits_64:
    db      0x55                    ; push rbp

    db      0x48, 0x89, 0xe5        ; mov rbp,rsp
    db      0x48, 0x8d, 0x3c, 0x25  ; lea rdi,
    dd      printf_msg              ; [printf_msg]
    xor     eax,eax
    mov     esi,64

    call    printf
    db      0x5d                    ; pop rbp

    NR_exit equ 60

    xor     edi,edi
    mov     eax,NR_exit     ; number of syscall (60)
    syscall

@bits_32:
    lea     edi,[printf_msg]
    mov     esi,32
    call    printf

    mov     eax,NR_exit
    int     0x80

section .data

printf_msg: db "running in %d-bit system", 0x0a, 0

Comments

আপনি সত্যিই কুঁড়েঘরে গরম টুপি

— মারছেন

খুশী হলাম। অদ্ভুত, তবে দুর্দান্ত। যেহেতু আপনি বিজয়ী শর্তটি "সংক্ষিপ্ততম" হিসাবে সেট করছেন আমি ট্যাগটি [কোড-গল্ফ] এ পরিবর্তন করতে যাচ্ছি এবং একটি নতুন বর্ণনামূলক ট্যাগ যুক্ত করব। আপনি যদি তাদের পছন্দ না করেন তবে আমাকে জানান।

— dmckee --- প্রাক্তন-মডারেটর বিড়ালছানা

Answer 1

7 বাইট

0000000: 6641 2521 2173 21                        fA%!!s!

32 বিট হিসাবে

00000000  6641              inc cx
00000002  2521217321        and eax,0x21732121

হিসাবে 64 বিট

00000000  6641252121        and ax,0x2121
00000005  7321              jnc 0x28

andক্যারি পতাকা সাফ করে তাই bit৪ বিট সংস্করণ সর্বদা ঝাঁপিয়ে পড়ে। -৪-বিটের জন্য 6641অপারেন্ড আকারের ওভাররাইড হয় তারপরে rex.bঅপারেন্ডের আকারটি and16 বিট হিসাবে আসে। 32-বিটে এটি 6641একটি সম্পূর্ণ নির্দেশনা তাই andএর কোনও উপসর্গ নেই এবং 32-বিটের অপারেন্ড আকার রয়েছে। এটি andকেবলমাত্র 64৪-বিট মোডে কার্যকর করা দুটি নির্দেশের বাইট দিলে তাত্ক্ষণিকভাবে বাইটগুলি ব্যবহার করে ।

Comments

1 কে পৌঁছেছে অভিনন্দন।

— ডেভিডসি

এই আচরণটি সিপিইউ নির্দিষ্ট। কিছু 64৪-বিট সিস্টেম-64-বিট মোডে pre 66 উপসর্গটিকে উপেক্ষা করবে।

— পিটার ফেরি

@ পেটারফেরি কি আপনার কাছে এর জন্য কোনও রেফারেন্স রয়েছে? আমার পঠনটি হল যে REX.W সেট করা থাকলে একটি 66 ঘন্টা উপসর্গ উপেক্ষা করা হয় তবে এটি কেবল REX.B রয়েছে

— জেফ রেডি

মাফ করবেন, আমি ভুল এটি কেবল স্থানান্তর-অফ-কন্ট্রোল যা সেভাবে প্রভাবিত হয় (উদাঃ 66 ই 8 ইন্টেলের 16-বিট আইপি তে স্যুইচ করে না)।

— পিটার ফেরি

Answer 2

11 বাইট

ascii: j6Xj3AX,3t!
hex: 6a 36 58 6a 33 41 58 2c 33 74 21

32-বিট-এ 0x41 ঠিক আছে এমন সত্যটি ব্যবহার করে inc %ecx, যখন 64৪ -বিটে এটি এমন raxউপসর্গ যা নিম্নলিখিত popনির্দেশাবলীর টার্গেট রেজিস্টারকে পরিবর্তন করে ।

        .globl _check64
_check64:
        .byte   0x6a, 0x36      # push $0x36
        .byte   0x58            # pop %rax
        .byte   0x6a, 0x33      # push $0x33

        # this is either "inc %ecx; pop %eax" in 32-bit, or "pop %r8" in 64-bit.
        # so in 32-bit it sets eax to 0x33, in 64-bit it leaves rax unchanged at 0x36.
        .byte   0x41            # 32: "inc %ecx", 64: "rax prefix"
        .byte   0x58            # 32: "pop %eax", 64: "pop %r8"

        .byte   0x2c, 0x33      # sub $0x33,%al
        .byte   0x74, 0x21      # je (branches if 32 bit)

        mov     $1,%eax
        ret

        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        mov     $0,%eax
        ret

এটি ওএসএক্সে লিখেছেন, আপনার এসেম্বলার আলাদা হতে পারে।

এটি দিয়ে কল করুন:

#include <stdio.h>
extern int check64(void);
int main(int argc, char *argv[]) {
  if (check64()) {
    printf("64-bit\n");
  } else {
    printf("32-bit\n");
  }
  return 0;
}

Answer 3

7 বাইট

66 উপসর্গ উপর নির্ভর করে না।

$$@$Au!

32 বিট:

00000000 24 24 and al,24h
00000002 40    inc eax
00000003 24 41 and al,41h
00000005 75 21 jne 00000028h

AL এর INC এর পরে বিট 0 সেট থাকবে, দ্বিতীয় এবং এটি সংরক্ষণ করবে, শাখা নেওয়া হবে।

64-বিট:

00000000 24 24    and al,24h
00000002 40 24 41 and al,41h
00000005 75 21    jne 00000028h

প্রথম এবং এর পরে AL এর বিট 0 পরিষ্কার হবে, শাখা নেওয়া হবে না।

Answer 4

যদি কেবল সি 9 এইচ মুদ্রণযোগ্য হয় ...

32 বিট:

00000000 33 C9 xor  ecx, ecx
00000002 63 C9 arpl ecx, ecx
00000004 74 21 je   00000027h

এআরপিএল জেড পতাকা সাফ করবে, যার ফলে শাখাটি নেওয়া হবে।

64-বিট:

00000000 33 C9 xor    ecx, ecx
00000002 63 C9 movsxd ecx, ecx
00000004 74 21 je     00000027h

এক্সওআর জেড পতাকা সেট করবে, এমওভিএসএক্সডি এটি পরিবর্তন করবে না, শাখা নেওয়া হবে না।