x86 32-বিট মেশিন কোড ফাংশন, 21 বাইট
x86-64 মেশিন কোড ফাংশন, 22 বাইট
32 বিট মোডে 1 বি সংরক্ষণের জন্য বিভাজক = ফিলার -1 ব্যবহার করা দরকার, যেমন fill=0এবং sep=/। 22-বাইট সংস্করণ বিভাজক এবং ফিলার একটি স্বেচ্ছাসেবী পছন্দ ব্যবহার করতে পারে।
এটি ইনপুট-বিভাজক = \n(0xa), আউটপুট-ফিলার = 0, আউটপুট-বিভাজক = /= ফিলার -1 সহ 21-বাইট সংস্করণ । এই ধ্রুবকগুলি সহজেই পরিবর্তন করা যায়।
; see the source for more comments
; RDI points to the output buffer, RSI points to the src string
; EDX holds the base
; This is the 32-bit version.
; The 64-bit version is the same, but the DEC is one byte longer (or we can just mov al,output_separator)
08048080 <str_exp>:
8048080: 6a 01 push 0x1
8048082: 59 pop ecx ; ecx = 1 = base**0
8048083: ac lods al,BYTE PTR ds:[esi] ; skip the first char so we don't do too many multiplies
; read an input row and accumulate base**n as we go.
08048084 <str_exp.read_bar>:
8048084: 0f af ca imul ecx,edx ; accumulate the exponential
8048087: ac lods al,BYTE PTR ds:[esi]
8048088: 3c 0a cmp al,0xa ; input_separator = newline
804808a: 77 f8 ja 8048084 <str_exp.read_bar>
; AL = separator or terminator
; flags = below (CF=1) or equal (ZF=1). Equal also implies CF=0 in this case.
; store the output row
804808c: b0 30 mov al,0x30 ; output_filler
804808e: f3 aa rep stos BYTE PTR es:[edi],al ; ecx bytes of filler
8048090: 48 dec eax ; mov al,output_separator
8048091: aa stos BYTE PTR es:[edi],al ;append delim
; CF still set from the inner loop, even after DEC clobbers the other flags
8048092: 73 ec jnc 8048080 <str_exp> ; new row if this is a separator, not terminator
8048094: c3 ret
08048095 <end_of_function>
; 0x95 - 0x80 = 0x15 = 21 bytes
64-বিট সংস্করণটি 1 বাইট দীর্ঘ, 2-বাইট ডিইসি বা এ ব্যবহার করে mov al, output_separator। অন্য যে, মেশিন-কোড উভয় সংস্করণের জন্য একই, কিন্তু কিছু রেজিস্টার নাম পরিবর্তন (যেমন rcxপরিবর্তে ecxমধ্যে pop)।
পরীক্ষা প্রোগ্রাম চালানো থেকে নমুনা আউটপুট (বেস 3):
$ ./string-exponential $'.\n..\n...\n....' $(seq 3);echo
000/000000000/000000000000000000000000000/000000000000000000000000000000000000000000000000000000000000000000000000000000000/
অ্যালগরিদম :
exp *= baseপ্রতিটি ফিলার চরের জন্য করে ইনপুটটি লুপ করুন । ডিলিমিটার এবং সমাপ্ত শূন্য বাইটে, expফিলার বাইটগুলি সংযোজন করুন এবং তারপরে আউটপুট স্ট্রিংয়ের জন্য পৃথক করুন এবং এতে পুনরায় সেট করুন exp=1। এটি অত্যন্ত সুবিধাজনক যে ইনপুটটি কোনও নতুন লাইন এবং একটি টার্মিনেটর উভয় দিয়েই শেষ না হওয়ার গ্যারান্টিযুক্ত ।
ইনপুট-এ, বিভাজকের উপরে থাকা কোনও বাইট মান (স্বাক্ষরবিহীন তুলনা) ফিলার হিসাবে গণ্য করা হয়, এবং বিভাজকের নীচে থাকা কোনও বাইট মানকে একটি স্ট্রিং-মার্কার হিসাবে বিবেচনা করা হয়। (একটি শূন্য-বাইটের জন্য সুস্পষ্টভাবে চেক test al,alকরতে অভ্যন্তরীণ লুপ দ্বারা নির্ধারিত পতাকাগুলিতে অতিরিক্ত বনাম ব্রাঞ্চিং লাগবে )।
নিয়মগুলি কেবল একটি ট্রেলিং বিভাজককে অনুমতি দেয় যখন এটি পিছনের নতুন লাইনে থাকে। আমার বাস্তবায়ন সর্বদা বিভাজককে সংযোজন করে। ৩ বিট মোডে 1 বি সঞ্চয় পেতে, এই নিয়মের জন্য বিভাজক = 0xa ( '\n'এএসসিআইআই এলএফ = লাইনফিড), ফিলার = 0 এক্সবি ( '\v'এএসসিআইআই ভিটি = উল্লম্ব ট্যাব) প্রয়োজন। এটি খুব মানব-বান্ধব নয়, তবে আইনটির চিঠিটি সন্তুষ্ট করে। (আপনি হেক্সডাম্প বা
tr $'\v' xআউটপুটটি এটি কাজ করে যাচাই করতে, বা ধ্রুবকটি পরিবর্তন করতে পারেন যাতে আউটপুট বিভাজক এবং ফিলার মুদ্রণযোগ্য হয় I আমি আরও লক্ষ্য করেছি যে বিধিগুলি মনে করে যে এটি আউটপুট হিসাবে একই ফিল / সিপ ব্যবহার করে একই ইনপুট গ্রহণ করতে পারে , তবে আমি সেই নিয়ম ভঙ্গ করে কোনও লাভ করতে দেখছি না))।
NASM / YASM উত্স। %ifপরীক্ষা প্রোগ্রামের সাথে অন্তর্ভুক্ত স্টাফগুলি ব্যবহার করে 32 বা 64-বিট কোড হিসাবে তৈরি করুন বা আরসিএক্সকে এক্সে পরিবর্তন করুন।
input_separator equ 0xa ; `\n` in NASM syntax, but YASM doesn't do C-style escapes
output_filler equ '0' ; For strict rules-compliance, needs to be input_separator+1
output_separator equ output_filler-1 ; saves 1B in 32-bit vs. an arbitrary choice
;; Using output_filler+1 is also possible, but isn't compatible with using the same filler and separator for input and output.
global str_exp
str_exp: ; void str_exp(char *out /*rdi*/, const char *src /*rsi*/,
; unsigned base /*edx*/);
.new_row:
push 1
pop rcx ; ecx=1 = base**0
lodsb ; Skip the first char, since we multiply for the separator
.read_bar:
imul ecx, edx ; accumulate the exponential
lodsb
cmp al, input_separator
ja .read_bar ; anything > separator is treated as filler
; AL = separator or terminator
; flags = below (CF=1) or equal (ZF=1). Equal also implies CF=0, since x-x doesn't produce carry.
mov al, output_filler
rep stosb ; append ecx bytes of filler to the output string
%if output_separator == output_filler-1
dec eax ; saves 1B in the 32-bit version. Use dec even in 64-bit for easier testing
%else
mov al, output_separator
%endif
stosb ; append the delimiter
; CF is still set from the .read_bar loop, even if DEC clobbered the other flags
; JNC/JNB here is equivalent to JE on the original flags, because we can only be here if the char was below-or-equal the separator
jnc .new_row ; separator means more rows, else it's a terminator
; (f+s)+f+ full-match guarantees that the input doesn't end with separator + terminator
ret
ফাংশনটি স্বাক্ষর সহ x86-64 SystemV ABI অনুসরণ করে,
void str_exp(char *out /*rdi*/, const char *src /*rsi*/, unsigned base /*edx*/);
এটি কেবলমাত্র আউটপুট স্ট্রিংয়ের দৈর্ঘ্যের কলারটিকে এটিতে একটি অতীত-শেষের পয়েন্টার রেখে অবহিত করে rdi, যাতে আপনি এটির কোনও ফেরতের মান বিবেচনা করতে পারেন স্ট্যান্ডার্ড কলিং কনভেনশন।
xchg eax,ediইক্স বা র্যাক্সের শেষ-পয়েন্টারটি ফিরে আসতে 1 বা 2 বাইট ( ) লাগবে। (যদি x32 এবিআই ব্যবহার করা হয় তবে পয়েন্টারগুলি কেবলমাত্র 32 বিট হওয়ার গ্যারান্টিযুক্ত, অন্যথায় xchg rax,rdiযদি কলার কম 32 বিটের বাইরে একটি বাফারে একটি পয়েন্টার দেয় তবে আমাদের ব্যবহার করতে হবে )) আমি এই সংস্করণটিতে আমি অন্তর্ভুক্ত করি না পোস্ট করা হচ্ছে কারণ কলার কলকারীর কাছ থেকে মান না পেয়ে ব্যবহার করতে পারে এমন কোনও কর্মক্ষেত্র রয়েছে rdi, তাই আপনি কোনও রেপার ছাড়াই সি থেকে এই কল করতে পারেন।
আমরা আউটপুট স্ট্রিং বা যেকোন কিছুই বাতিলও করি না, সুতরাং এটি কেবলমাত্র নতুন লাইন-টার্মিনেটেড। এটি ঠিক করতে 2 বাইট লাগবে: xchg eax,ecx / stosb (আরসিএক্স শূন্য থেকে rep stosb।)
আউটপুট-স্ট্রিংয়ের দৈর্ঘ্য বের করার উপায়গুলি হ'ল:
- আরডিআই ফিরতি স্ট্রিংয়ের এক অতীত-শেষের দিকে নির্দেশ করে (যাতে কলার লেন = শেষ-শুরু করতে পারে)
- কলকারী কেবলমাত্র ইনপুটটিতে কত সারি ছিল তা জানতে এবং নিউলাইনগুলি গণনা করতে পারে
- কলার একটি বড় শূন্য বাফার এবং
strlen()তারপরে ব্যবহার করতে পারে ।
এগুলি সুন্দর বা দক্ষ নয় (কোনও এসএম কলারের কাছ থেকে আরডিআইর রিটার্ন মান ব্যবহার করা বাদে) তবে আপনি যদি এটি চান তবে সি থেকে গল্ফড অ্যাসেম ফাংশনগুলি কল করবেন না: পি
আকার / ব্যাপ্তির সীমাবদ্ধতা
সর্বাধিক আউটপুট স্ট্রিং আকারটি ভার্চুয়াল মেমরি ঠিকানা-স্পেস সীমাবদ্ধতার দ্বারা সীমাবদ্ধ। (মূলত এটি যে বর্তমান x86-64 হার্ডওয়্যার কেবল ভার্চুয়াল ঠিকানায় 48 টি গুরুত্বপূর্ণ বিটকে সমর্থন করে, অর্ধেকভাগে বিভক্ত হয় কারণ তারা শূন্য-প্রসারণের পরিবর্তে সাইন-এক্সটেন্ড করে। লিঙ্কিত উত্তরে ডায়াগ্রামটি দেখুন ))
প্রতিটি সারিতে সর্বাধিক 2 ** 32 - 1 ফিলার বাইট থাকতে পারে, যেহেতু আমি 32-বিট রেজিস্টারে ঘনিষ্ঠভাবে জমা করি।
ফাংশনটি 0 থেকে 2 ** 32 - 1 পর্যন্ত ঘাঁটিগুলির জন্য সঠিকভাবে কাজ করে Cor প্রতি লাইনে 1 ফিলার।)
এটি ইন্টেল আইভিব্রিজে এবং পরবর্তীকালেও স্পষ্টতই দ্রুতগতির, বিশেষত বৃহত্তর সারিগুলি সারিবদ্ধ মেমরিটিতে লেখা হওয়ার জন্য। ERMSB বৈশিষ্ট্য সহ সিপিইউগুলিতে প্রান্তিক পয়েন্টার সহ বৃহত গণনাগুলির জন্য rep stosbসর্বোত্তম বাস্তবায়নmemset() । উদাহরণস্বরূপ 180 ** 4টি 0.97 গিগাবাইট, এবং আমার i7-6700k স্কাইলেকে (~ 256k নরম পৃষ্ঠা-ত্রুটি সহ) / dev / নালটিতে লিখতে 0.27 সেকেন্ড সময় নেয়। (লিনাক্সের উপর ডিভাইস-চালক, / dev / নাল জন্য তথ্য যে কোন জায়গায় কপি করে না, এটা ঠিক আয়। সুতরাং সব সময় হয় rep stosbএবং নরম পৃষ্ঠা-ফল্ট যে ট্রিগার যখন প্রথমবারের মত মেমরি স্পর্শ। এটা দুর্ভাগ্যক্রমে বিএসএসে অ্যারের জন্য স্বচ্ছ হিটপেজগুলি ব্যবহার না করা। সম্ভবত কোনও madvise()সিস্টেম কল এটির গতি বাড়িয়ে দেবে))
পরীক্ষা প্রোগ্রাম :
একটি স্ট্যাটিক বাইনারি তৈরি করুন এবং ./string-exponential $'#\n##\n###' $(seq 2)বেস 2 হিসাবে চালান an একটি বাস্তবায়ন এড়ানোর জন্য atoi, এটি ব্যবহার করে base = argc-2। (কমান্ড-লাইন দৈর্ঘ্যের সীমা হাস্যকরভাবে বড় ঘাঁটিগুলি পরীক্ষা করতে বাধা দেয়))
এই মোড়ক 1 জিবি পর্যন্ত আউটপুট স্ট্রিংয়ের জন্য কাজ করে। (এটি কেবলমাত্র একক রাইটিং () সিস্টেমকে কল দেয় এমনকি বিশালাকার স্ট্রিংয়ের জন্য, তবে লিনাক্স এমনকি পাইপগুলিতে লেখার জন্য এটি সমর্থন করে)। অক্ষর গণনা করার জন্য পাইপটি প্রবেশ করুন wc -cবা strace ./foo ... > /dev/nullরাইটিং সিস্কেলে আর্গ দেখতে ব্যবহার করুন।
এটির জন্য আরজি হিসাবে রিটার্ন-মানটি আর্গ হিসাবে স্ট্রিংয়ের দৈর্ঘ্য গণনা করে নেয় write()।
;;; Test program that calls it
;;; Assembles correctly for either x86-64 or i386, using the following %if stuff.
;;; This block of macro-stuff also lets us build the function itself as 32 or 64-bit with no source changes.
%ifidn __OUTPUT_FORMAT__, elf64
%define CPUMODE 64
%define STACKWIDTH 8 ; push / pop 8 bytes
%define PTRWIDTH 8
%elifidn __OUTPUT_FORMAT__, elfx32
%define CPUMODE 64
%define STACKWIDTH 8 ; push / pop 8 bytes
%define PTRWIDTH 4
%else
%define CPUMODE 32
%define STACKWIDTH 4 ; push / pop 4 bytes
%define PTRWIDTH 4
%define rcx ecx ; Use the 32-bit names everywhere, even in addressing modes and push/pop, for 32-bit code
%define rsi esi
%define rdi edi
%define rsp esp
%endif
global _start
_start:
mov rsi, [rsp+PTRWIDTH + PTRWIDTH*1] ; rsi = argv[1]
mov edx, [rsp] ; base = argc
sub edx, 2 ; base = argc-2 (so it's possible to test base=0 and base=1, and so ./foo $'xxx\nxx\nx' $(seq 2) has the actual base in the arg to seq)
mov edi, outbuf ; output buffer. static data is in the low 2G of address space, so 32-bit mov is fine. This part isn't golfed, though
call str_exp ; str_exp(outbuf, argv[1], argc-2)
; leaves RDI pointing to one-past-the-end of the string
mov esi, outbuf
mov edx, edi
sub edx, esi ; length = end - start
%if CPUMODE == 64 ; use the x86-64 ABI
mov edi, 1 ; fd=1 (stdout)
mov eax, 1 ; SYS_write (Linux x86-64 ABI, from /usr/include/asm/unistd_64.h)
syscall ; write(1, outbuf, length);
xor edi,edi
mov eax,231 ; exit_group(0)
syscall
%else ; Use the i386 32-bit ABI (with legacy int 0x80 instead of sysenter for convenience)
mov ebx, 1
mov eax, 4 ; SYS_write (Linux i386 ABI, from /usr/include/asm/unistd_32.h)
mov ecx, esi ; outbuf
; 3rd arg goes in edx for both ABIs, conveniently enough
int 0x80 ; write(1, outbuf, length)
xor ebx,ebx
mov eax, 1
int 0x80 ; 32-bit ABI _exit(0)
%endif
section .bss
align 2*1024*1024 ; hugepage alignment (32-bit uses 4M hugepages, but whatever)
outbuf: resb 1024*1024*1024 * 1
; 2GB of code+data is the limit for the default 64-bit code model.
; But with -m32, a 2GB bss doesn't get mapped, so we segfault. 1GB is plenty anyway.
এটি মজাদার চ্যালেঞ্জ ছিল যা নিজেকে খুব ভালভাবে asm, বিশেষত x86 স্ট্রিং অপ্সকে ধার দেয় । ইনপুট স্ট্রিংয়ের শেষে কোনও নিউলাইন এবং তারপরে কোনও টার্মিনেটর পরিচালনা করা এড়াতে নিয়মগুলি সুন্দরভাবে ডিজাইন করা হয়েছে।
পুনরাবৃত্তিবৃদ্ধির সাথে ঘনিষ্ঠভাবে ঘন ঘন একই সাথে পুনরাবৃত্ত সংযোজনের সাথে গুণণের মতো এবং যাইহোক আমার প্রতিটি ইনপুট সারিতে অক্ষরগুলি গণনা করার জন্য লুপ করা দরকার।
আমি ওয়ান-অপরেন্ড mulবা imulতার পরিবর্তে দীর্ঘতর ব্যবহারের বিষয়টি বিবেচনা করেছি imul r,r, তবে এর EAX এর অন্তর্নিহিত ব্যবহারটি LODSB এর সাথে বিরোধ করবে would
আমি লোড এবং তুলনা করার পরিবর্তে এসসিএএসবি চেষ্টাও করেছি , তবে xchg esi,ediঅভ্যন্তরীণ লুপের আগে এবং পরে আমার দরকার ছিল , কারণ এসসিএএসবি এবং স্টোসবি উভয়ই ইডিআই ব্যবহার করে। (সুতরাং 64৪-বিট সংস্করণে 32৪-বিট পয়েন্টার কেটে এড়াতে x32 এবিআই ব্যবহার করতে হবে)।
STOSB এড়ানো কোনও বিকল্প নয়; আর কিছুই কোথাও সংক্ষেপে কাছে নেই। এবং এসসিএএসবি ব্যবহারের অর্ধেক সুবিধা হ'ল অভ্যন্তরীণ লুপটি ছেড়ে যাওয়ার পরে AL = ফিলার, সুতরাং আমাদের আরইপি স্টসবির কোনও সেটআপের প্রয়োজন নেই।
এসসিএএসবি আমার যা করা ছিল তার থেকে অন্য দিকের সাথে তুলনা করে, তাই আমার তুলনাগুলি উল্টে দেওয়া দরকার।
এক্সএইচজি এবং স্ক্যাসবি দিয়ে আমার সেরা চেষ্টা। কাজ করে, তবে কম নয় isn't ( 32-বিট কোড, ফিলারকে বিভাজক হিসাবে পরিবর্তন করতে inc/ decট্রিক ব্যবহার করে )।
; SCASB version, 24 bytes. Also experimenting with a different loop structure for the inner loop, but all these ideas are break-even at best
; Using separator = filler+1 instead of filler-1 was necessary to distinguish separator from terminator from just CF.
input_filler equ '.' ; bytes below this -> terminator. Bytes above this -> separator
output_filler equ input_filler ; implicit
output_separator equ input_filler+1 ; ('/') implicit
8048080: 89 d1 mov ecx,edx ; ecx=base**1
8048082: b0 2e mov al,0x2e ; input_filler= .
8048084: 87 fe xchg esi,edi
8048086: ae scas al,BYTE PTR es:[edi]
08048087 <str_exp.read_bar>:
8048087: ae scas al,BYTE PTR es:[edi]
8048088: 75 05 jne 804808f <str_exp.bar_end>
804808a: 0f af ca imul ecx,edx ; exit the loop before multiplying for non-filler
804808d: eb f8 jmp 8048087 <str_exp.read_bar> ; The other loop structure (ending with the conditional) would work with SCASB, too. Just showing this for variety.
0804808f <str_exp.bar_end>:
; flags = below if CF=1 (filler<separator), above if CF=0 (filler<terminator)
; (CF=0 is the AE condition, but we can't be here on equal)
; So CF is enough info to distinguish separator from terminator if we clobber ZF with INC
; AL = input_filler = output_filler
804808f: 87 fe xchg esi,edi
8048091: f3 aa rep stos BYTE PTR es:[edi],al
8048093: 40 inc eax ; output_separator
8048094: aa stos BYTE PTR es:[edi],al
8048095: 72 e9 jc 8048080 <str_exp> ; CF is still set from the inner loop
8048097: c3 ret
একটি ইনপুট জন্য ../.../., উত্পাদন ..../......../../। আমি বিভাজক = নিউলাইন সহ সংস্করণটির একটি হ্যাক্সডাম্প দেখানো বিরক্ত করব না।
"" <> "#"~Table~#3 বাইটের চেয়ে কম"#"~StringRepeat~#, সম্ভবত আরও গল্ফযোগ্য।