ব্রেনফাক - 617 616 604 বাইট
+>>>>,[>++++[<-------->-]<[>>>>],]<<<<[>+<<+<+>>-]<[>+<-]+<+<<[>+>-<<-]>[<+>-]>[,+++++[>+++++<-]>>[<->-]<[>>>>>[>>>>]+[<<<<]<-]>>[<+>-]<<<]>[>>[,<]<<+++++++++<]<<<[-[+>>-<]>[>>[<+<+>>-]<<<<[>+>-<<-]>[<+>-]>[<<[<<<<]>>>>[[<<<<+>>>>-]>>>>]<<<<+>>-]>[>+<-]]<<<[-[+>]+<<<<]>>>>-<<<<<]>>>>>+++++[>----<-]>->[<+>>+<-]<[<<<[<<<<]+[>>>>]<-]>>[<+>-]<[<<<<]>>>++++[<-------->-]>[-[,+++>]+>>>[<<<->>]>]<<<<<[>-]>[>>]>>+[<++++[<++++++++>-]<]>>[+++++++++++++>>>>]<<<<----<+++[<<+<<[<<+<<]+[>>>>]<<<<-]<<<<[-<<<<]>[.,>>]<<<<<[<<<<]<++++++++++<<.<+<<+<<+<<+<<+<[.,>>]<<<<<[<<]>++++++++++<+<<+<<+<..<+<[.,>>]<[<<]<...<<.
এটি আমার দু'দিনের ভাল অংশে নিয়েছে। আমি মনে করি এটি মূল্য ছিল। সম্ভবত এমন কিছু অংশ রয়েছে যা কোন কোষে বা যেকোনো কিছুতে সঞ্চিত রয়েছে তা পরিবর্তন করে আরও গল্ফ করা যেতে পারে তবে এখনই আমি খুশী আমি এটি কাজ করে চলেছি।
এই প্রোগ্রামটি সম্পূর্ণ আলাদা হতে হবে যদি প্রশ্নটি নির্দিষ্ট করে না যে ইনপুটটি বাছাই করা হবে। যেভাবে কাজ করে তা হ'ল ইনপুটযুক্তগুলির প্রায় 10 টি পিনের একটি তালিকা তৈরি করে। এ ধরণের বিভ্রান্তিকর তবে সম্ভবত এটি আরও ভাল ব্যাখ্যা করবে:
If you input these pins: [2, 3, 6, 8, 9]
First, the program does this: [2, 3, 6, 8, 9] + [10]
Then this: [2, 3, 6] + [7] + [8, 9, 10]
Then this: [2, 3] + [4, 5] + [6, 7, 8, 9, 10]
Finally, this: [1] + [2, 3, 4, 5, 6, 7, 8, 9, 10]
To build this: [1, 2, 3, 4, 5, 6, 7, 8, 9, 10]
এটি করার সময় এটি মনে রাখে যে ব্যবহারকারীরা সেখানে কোন পিন রেখেছিল এবং কোনটি সেখানে রেখেছিল। ইনপুটটি বাছাই না করা থাকলে এই কৌশলটি ব্যবহার করা খুব কঠিন difficult
বাছাইয়ের কাজটি আরও সহজ করে দেয় 10 নম্বরটি সনাক্তকরণ, যেহেতু ব্রেনফাক ব্যক্তিগত বাইটগুলি নিয়ে কাজ করে, প্রতি সেপরে "সংখ্যা" নয়, এটি পাছায় ব্যথা হতে পারে, তবে সাজানো ইনপুটটি আমার পক্ষে কাজ করা আরও সহজ করে তুলেছে সঙ্গে. এর কারণটি কীভাবে আমি প্রোগ্রামে ডেটা সঞ্চয় করেছিলাম তার সাথে সম্পর্কিত। আমি সময় মতো ইনপুটতে একটি অক্ষর নিই এবং ফলাফলটি থেকে 32 বিয়োগ করি। এর পরে যদি ঘরটি শূন্য হয় না তবে আমি 4 টি ঘর এগিয়ে চলেছি। পুনরাবৃত্তি করার আগে। এর অর্থ হ'ল আমি প্রতি 4 টি কোষে ইনপুটসের একটি ফাঁকা স্থান বাইট পাই এবং আমি পিনগুলি তাদের 16+ সংখ্যা হিসাবে কার্যকরভাবে সঞ্চয় করি However তবে, 10 টাইপ করতে দুটি বাইট নেয়, তাই আমাকে এটির বিশেষ কেস করতে হয়েছিল। যদি ইনপুটটি বাছাই না করা হত, আমাকে পিনগুলি সন্ধান করতে হবে তবে এটি বাছাই করার পরে এটি উপস্থিত থাকলে সর্বদা সর্বশেষ পিন হবে। আমি পরীক্ষা করেছি (ইনপুট +1 এর শেষ বাইট) == (ইনপুটটির দ্বিতীয় শেষ বাইট) এবং যদি তা হয় তবে এটি অবশ্যই 10 হওয়া উচিত I আমি শেষ বাইট থেকে মুক্তি পেয়েছি এবং আমার সিস্টেমটি যা বোঝে তাতে দ্বিতীয় শেষটিকে সেট করেছি "10"। চরিত্রটি'1'এবং '0'একটি বাইটে ফিট না, তবে 26 সংখ্যাটি নিশ্চিত!
এ কৌশলটি ব্যবহার করার জন্য কিছু কাজ করার জন্য কৌশলগুলি নিয়ে আসা আমার প্রিয় অংশ। :)
আপনি যদি এই প্রোগ্রামটি আরও বিশদে কাজ করে সে বিষয়ে আগ্রহী হন, আপনি যা কিছু করেছেন তা মনে আছে তা নিশ্চিত করার জন্য আপনি এটি লেখার সময় আমি যে মন্তব্যগুলি ব্যবহার করেছি সেগুলি দেখতে পারা যায়। এমনকি মস্তিষ্কে মন্তব্য লেখাও শক্ত, কারণ কোনও মন্তব্য বাক্য গঠন নেই। পরিবর্তে, চরিত্রগুলি বাদে প্রতিটি চরিত্রের <[+.,-]>কোনও বিকল্প নেই। দুর্ঘটনাক্রমে .বা ,আপনার মন্তব্যে বাগগুলি প্রবর্তন করা সহজ ! সে কারণেই ব্যাকরণটি এতটাই উইঙ্কি এবং সেমিকোলনগুলি সর্বত্র রয়েছে।
সম্পাদনা: এটিকে স্ক্রু করা কতটা সহজ তার উদাহরণ হিসাবে: আমি একটি মন্তব্যে "অ-স্পেস" ব্যবহার করেছি! আমি যখন উত্স থেকে সমস্ত অ-বিএফ অক্ষর কেড়ে নিয়েছি, তখন প্রোগ্রামটি যেটি আমি রেখে দিয়েছিলাম -। ভাগ্যক্রমে এটি কিছুই ভাঙ্গেনি, তবে এখন আমি এটি একটি বাইট সংরক্ষণ করার জন্য সরিয়েছি। :)
দ্বিতীয় সম্পাদনা: আমি যখন এটিকে ছুঁয়েছি তখন কিছুক্ষণ হয়ে গেছে, হাহা। এই সাইটে অন্য একটি ব্রেইনফাক উত্তরে আমি লক্ষ্য করেছি যে আমি ঘটনাক্রমে মন্তব্য করা সংস্করণে একটি কমা ব্যবহার করেছি। যেহেতু ইনপুটটি ইতিমধ্যে শেষ হয়ে গেছে, এটি বর্তমান কক্ষকে 0 এ সেট করেছে (এটি বাস্তবায়ন নির্ভর, তবে আমার অভিজ্ঞতায় এটি সবচেয়ে সাধারণ আচরণ)। আমি বাগটি ঠিক করেছি, তবে এটি আমার চিন্তাভাবনা করে। 0 তে কোনও ঘর নির্ধারণ করার অলঙ্কৃত উপায়টি হল [-](মোটামুটি while (*p) { *p--; }), যা দুটি বাইট দীর্ঘ। যে কোনও সময় সমস্ত ইনপুট পড়েছে, আমি ,পরিবর্তে ব্যবহার করতে পারি । এটি আমাকে উত্তরে 2 বাইট এবং এই 12 টিতে বাঁচিয়েছে!
one flag at the very left; will be important later
+>>>>
all nonspace bytes of input separated by 3 empty cells; pin number `n` stored with value `n` plus 16
,[>++++[<-------->-]<[>>>>],]<<<<
test if last pin is 10
[>+<<+<+>>-]<[>+<-]+<+<<[>+>-<<-]>[<+>-]>
[
if not: find 10 minus the number it is; put that many placeholder pins (cells with value 1) at the end
,+++++[>+++++<-]>>[<->-]<[>>>>>[>>>>]+[<<<<]<-]>>[<+>-]<<<
]>
[
if so: get rid of '0' byte; convert '1' byte to 26 (10 plus 16)
>>[,<]<<+++++++++<
]<<<
pointer now sitting on the cell with the second greatest pin that was inputted (ie not a placeholder)
;;;;;;;
[
check for flag placed at the very beginning of the program; if present: break
-[+>>-<]>
[
find ((pin to our right) minus 1) minus pin to our left
move all pins left of us 4*(that value) cells and insert placeholder pins
>>[<+<+>>-]<<<<[>+>-<<-]>[<+>-]>[<<[<<<<]>>>>[[<<<<+>>>>-]>>>>]<<<<+>>-]>[>+<-]
]
find first non placeholder pin to our left
there has to be one because we haven't hit the flag yet
<<<[-[+>]+<<<<]>>>>-<<<<<
]>>>>>+
we have now added placeholder pins at the end and in the middle; all that's left is the beginning
subtract 17 from lowest pin and put that many placeholders to the left
++++[>----<-]>->[<+>>+<-]<[<<<[<<<<]+[>>>>]<-]>>[<+>-]
subtract 32 from an empty cell 2 to the left of the lowest pin; will be useful later
<[<<<<]>>>++++[<-------->-]>
placeholder pins have the value 1; real pins have a value somewhere between 17 and 26
normalize it by stepping through and setting every pin with value != 1 to 3 (0's ascii code is 2 higher than period so this will make it easier to print later)
[-[,+++>]+>>>[<<<->>]>]<<<<<[>-]>[>>]>>
start writing 32s across the board; hitting every second cell
that's every pin and the cell 2 to the right of each pin
this is done in such a way that it will only halt if adding 32 to a cell sets it to 0; which is why we subtracted 0 from an empty cell earlier
it will catch us and prevent an infinite loop
+[<++++[<++++++++>-]<]
now write 13 to each pin; this adds up to 46 or 48; which are exactly the ascii values we want
>>[+++++++++++++>>>>]
we happen to have made a 14; turn it into a 10 for a newline
<<<<----
we're so close now; i can taste it
we have a list of 10 pins; each one with the ascii value that needs to be written
we have 32 everywhere because we'll need spaces
we even have a newline
the only problem now is that our list looks like this:
;;;;;;;;;;;;;;;;;;;;;;;;
;;1 2 3 4 5 6 7 8 9 10;;
;;;;;;;;;;;;;;;;;;;;;;;;
and we need to print in this order:
;;;;;;;;;;;;;;;;;;;;;;;;
;;7 8 9 10 4 5 6 2 3 1;;
;;;;;;;;;;;;;;;;;;;;;;;;
it's a pretty simple fix
once we print a pin we obviously don't need to remember it any more
so we simply print the last 4 pins on the list; destroying them on the way
then we print the last 3; which have become the ones we want
then two; then one
<+++[<<+<<[<<+<<]+[>>>>]<<<<-]<<<<[-<<<<]
print pins 7 8 9 10
>[.,>>]
print pins 4 5 6
<<<<<[<<<<]<++++++++++<<.<+<<+<<+<<+<<+<[.,>>]
print pins 3 2
<<<<<[<<]>++++++++++<+<<+<<+<..<+<[.,>>]
print the final pin!! :)
<[<<]<...<<.