কিউবাসিক, 309 বাইট
সতর্কতা: গল্ফযুক্ত সংস্করণটি ব্যবহারকারী-বান্ধব নয়: এর একটি অদ্ভুত ইনপুট পদ্ধতি রয়েছে, অসীম লুপ হিসাবে চালায় এবং এর কোনও বিলম্ব হয় না (এইভাবে কিছু সিস্টেমে খুব দ্রুত চলে)। আপনার কিউবাসিক পরিবেশে কোনও প্রোগ্রামটি কীভাবে শেষ করতে হয় তা যদি আপনি জানেন তবেই এটি চালান। অব্যক্ত সংস্করণটি সুপারিশ করা হয়েছে (নীচে দেখুন)।
INPUT w,h
SCREEN 9
FOR y=1TO h
FOR x=1TO w
PSET(x,y),VAL(INPUT$(1))
NEXT
NEXT
DO
FOR y=1TO h
FOR x=1TO w
SCREEN,,0
c=POINT(x,y)
d=c
IF c=7THEN d=1
IF c=1THEN d=6
IF c=6THEN
n=0
FOR v=y-1TO y+1
FOR u=x-1TO x+1
n=n-(POINT(u,v)=7)
NEXT
NEXT
d=7+(n=0OR n>2)
END IF
SCREEN,,1,0
PSET(x,y),d
NEXT
NEXT
PCOPY 1,0
LOOP
চালানোর জন্য, প্রম্পট আপনার কনফিগারেশন এর প্রস্থ ইনপুট এ উল্লেখ wএবং উচ্চতা h। 1 তারপরে w*hকক্ষের জন্য একক-অঙ্কের কোডগুলি টাইপ করুন (বাম থেকে ডানদিকে সরানো হচ্ছে, তারপরে উপরে থেকে নীচে), সহ
0 = খালি6 = তারে7 = সিগন্যাল মাথা1 সিগন্যাল লেজ
একবার আপনি সমস্ত কক্ষে প্রবেশ করে নিলে সিমুলেশনটি শুরু হবে (এবং আপনি প্রোগ্রামটিকে হত্যা না করা অবধি চিরকাল অবিরত)।
Ungolfed
আরও ব্যবহারকারী-বান্ধব সংস্করণ। বিন্যাসটি সংশোধন করতে DATA, শেষে বিবৃতিগুলি সংশোধন করুন ।
কোডটি POINTফাংশনটির সুবিধা গ্রহণ করে যা স্ক্রিন থেকে একটি পিক্সেলের রঙের মান পড়ে। এর অর্থ আমাদের কোষগুলিকে আলাদাভাবে অ্যারে হিসাবে সংরক্ষণ করতে হবে না। সমস্ত ঘর এক সাথে আপডেট হয় তা নিশ্চিত করার জন্য, আমরা দ্বিতীয় "পৃষ্ঠায়" আপডেটগুলি সম্পাদন করি। আমরা SCREENবিবৃতিটির একটি সংস্করণ ব্যবহার করে সক্রিয় পৃষ্ঠা টগল করতে পারি , এবং বিবৃতিটি ব্যবহার করে একটি পৃষ্ঠার বিষয়বস্তু অন্যটিতে অনুলিপি করতে পারি PCOPY।
SCREEN 9
EMPTY = 0 ' Black
HEAD = 7 ' Light gray
TAIL = 1 ' Blue
WIRE = 6 ' Brown/orange
' First two data values are the width and height
READ w, h
' The rest are the initial configuration, row by row
' Read them and plot the appropriately colored pixels
FOR y = 1 TO h
FOR x = 1 TO w
READ state$
IF state$ = "" THEN value = EMPTY
IF state$ = "H" THEN value = HEAD
IF state$ = "T" THEN value = TAIL
IF state$ = "W" THEN value = WIRE
PSET (x, y), value
NEXT x
NEXT y
' Loop the simulation until user presses a key
DO UNTIL INKEY$ <> ""
' Store current time for delay purposes
t# = TIMER
FOR y = 1 TO h
FOR x = 1 TO w
' Active page = display page = 0
SCREEN , , 0
' Get the color value of the pixel at x,y
oldVal = POINT(x, y)
IF oldVal = EMPTY THEN
newVal = EMPTY
ELSEIF oldVal = HEAD THEN
newVal = TAIL
ELSEIF oldVal = TAIL THEN
newVal = WIRE
ELSEIF oldVal = WIRE THEN
neighbors = 0
FOR ny = y - 1 TO y + 1
FOR nx = x - 1 TO x + 1
IF POINT(nx, ny) = HEAD THEN neighbors = neighbors + 1
NEXT nx
NEXT ny
IF neighbors = 1 OR neighbors = 2 THEN
newVal = HEAD
ELSE
newVal = WIRE
END IF
END IF
' Active page = 1, display page = 0
SCREEN , , 1, 0
' Plot the new value on page 1
PSET (x, y), newVal
NEXT x
NEXT y
' Copy page 1 to page 0
PCOPY 1, 0
' Delay
WHILE TIMER >= t# AND t# + 0.2 > TIMER
WEND
LOOP
DATA 8,5
DATA T,H,W,W,W,W,W,W
DATA W, , , ,W, , ,
DATA , , ,W,W,W, ,
DATA W, , , ,W, , ,
DATA H,T,W,W, ,W,W,W
1 প্রস্থ এবং উচ্চতার জন্য সর্বোচ্চ মানগুলি কোন স্ক্রিন মোড ব্যবহৃত হয় তার উপর নির্ভর করে। ইন SCREEN 9, প্রস্থটি 638 এবং উচ্চতা 348 পর্যন্ত হতে পারে SCREEN 7a একটি ছোট উইন্ডো দেয়)।
উদাহরণ রান
স্ক্রিন মোড 7 সহ আর্কাইভ.আর.জে অবরুদ্ধ সংস্করণ :
