কক প্রুফের মধ্যে কফিক্স নির্মূল করা

Question

কক-তে সংক্রামক ধরনের ব্যবহার করে কিছু মৌলিক বৈশিষ্ট্য প্রমাণ করার চেষ্টা করার সময়, আমি নিম্নলিখিত সমস্যাটি চালিয়ে যাচ্ছি এবং আমি এটি পেতে পারি না। সমস্যাটি আমি নিম্নরূপে একটি সাধারণ কক স্ক্রিপ্টে নিঃশেষিত করেছি।

টাইপ গাছটি সম্ভবত অসীম গাছগুলিকে সংজ্ঞা দেয় যাতে শাখাগুলি এ টাইপের এগুলির উপাদান সহ লেবেলযুক্ত থাকে । ডালে সমস্ত উপাদানের জন্য সংজ্ঞায়িত করা প্রয়োজন নেই একজন । মান ইউনিভ সর্বদা সংজ্ঞায়িত সমস্ত এ শাখা সহ অসীম গাছ । isUniv পরীক্ষার কিনা একটি প্রদত্ত গাছ সমান ইউনিভার্সিটি । লেমাতে বলা হয়েছে যে ইউনিভ প্রকৃতপক্ষে ইস্রাivকে সন্তুষ্ট করে ।

Parameter A : Set.

CoInductive Tree: Set := Node : (A -> option Tree) -> Tree.

Definition derv (a : A) (t: Tree): option Tree :=
  match t with Node f => f a end.

CoFixpoint Univ : Tree := Node (fun _ => Some Univ).

CoInductive isUniv : Tree -> Prop :=
  isuniv : forall (nf : A -> option Tree) (a : A) (t : Tree), 
    nf a = Some t -> 
    isUniv t -> 
    isUniv (Node nf).

Lemma UnivIsUniv : isUniv Univ.
Proof.
  cofix CH.    (* this application of cofix is fine *)
  unfold Univ. 

Admitted.

এই মুহুর্তে আমি প্রমাণটি ছেড়ে দিই। বর্তমান লক্ষ্যটি হ'ল:

CH : isUniv Univ
============================
isUniv (cofix Univ  : Tree := Node (fun _ : A => Some Univ))

আমি জানি না যে কফিক্সটি উত্পাদনের লক্ষ্যে (নোড কিছু) উত্পাদনের লক্ষ্যে প্রয়োগ করতে হবে যাতে আমি ইসুনিভ প্রয়োগ করতে পারি ।

কেউ কি এই লেমা প্রমাণ করতে সহায়তা করতে পারে? এমন পরিস্থিতিতে কফিক্স
নির্মূল করার মানক উপায়গুলি কী কী ?

Comments

ট্যাগ "ইন্টারেক্টিভ-প্রমাণগুলি" পর্যাপ্ত নয়, কারণ এটি সাধারণত তাদের জটিলতা-তাত্ত্বিক অর্থে ইন্টারেক্টিভ প্রুফ সিস্টেমগুলিকে বোঝায়। আমি মনে করি সঠিক শব্দটি হ'ল "ইন্টারেক্টিভ-উপপাদ্য-প্রমাণকারী", বা "উপপাদ্য-প্রমাণকারী"।

— ইড্ডো টাজামেরেট

স্থির হয়েছে, "প্রুফ-অ্যাসিস্ট্যান্টস" ব্যবহার করে

— ডেভ ক্লার্ক

Answer 1

আপনি কাঠের সাথে মেলে এমন একটি সহায়ক ফাংশন ব্যবহার করে কফিক্সটি নির্মূল করতে পারেন।

Definition TT (t:Tree) :=
  match t with
    | Node o => Node o
  end.

Lemma TTid : forall t: Tree, t = TT t.
  intro t.
  destruct t.
  reflexivity.
  Qed.

Lemma UnivIsUniv : isUniv Univ.
Proof.
  cofix.
  rewrite TTid.
  unfold TT.
  unfold Univ.

আপনি এই লক্ষ্যটি অর্জন করতে পারবেন যা একটি অনাবশ্যক পদক্ষেপ।

  UnivIsUniv : isUniv Univ
  ============================
   isUniv
     (Node
        (fun _ : A =>
         Some (cofix Univ  : Tree := Node (fun _ : A => Some Univ))))

আমি http://adam.chlipala.net/cpdt/html/Coinductive.html থেকে এই কৌশলটি গ্রহণ করেছি

Comments

এর জন্য ধন্যবাদ. আমি সেই পৃষ্ঠাটির দিকে তাকিয়ে ছিলাম ঠিক তখনই আপনার উত্তরটি এসেছিল Cra

— ডেভ ক্লার্ক 15

Answer 2

(* I post my answer as a Coq file. In it I show that supercoooldave's
   definition of a universal tree is not what he intended. His isUniv
   means "the tree has an infinite branch". I provide the correct
   definition, show that the universal tree is universal according to
   the new definition, and I provide counter-examples to
   supercooldave's definition. I also point out that the universal
   tree of branching type A has an infinite path iff A is inhabited.
   *)

Set Implicit Arguments.

CoInductive Tree (A : Set): Set := Node : (A -> option (Tree A)) -> Tree A.

Definition child (A : Set) (t : Tree A) (a : A) :=
  match t with
    Node f => f a
  end.

(* We consider two trees, one is the universal tree on A (always
   branches out fully), and the other is a binary tree which always
   branches to one side and not to the other, so it is like an
   infinite path with branches of length 1 shooting off at each node.  *)

CoFixpoint Univ (A : Set) : Tree A := Node (fun _ => Some (Univ A)).

CoFixpoint Thread : Tree (bool) :=
  Node (fun (b : bool) => if b then Some Thread else None).

(* The original definition of supercooldave should be called "has an
   infinite path", so we rename it to "hasInfinitePath". *)
CoInductive hasInfinitePath (A : Set) : Tree A -> Prop :=
  haspath : forall (f : A -> option (Tree A)) (a : A) (t : Tree A),
    f a = Some t ->
    hasInfinitePath t -> 
    hasInfinitePath (Node f).

(* The correct definition of universal tree. *)
CoInductive isUniv (A : Set) : Tree A -> Prop :=
  isuniv : forall (f : A -> option (Tree A)),
    (forall  a, exists t, f a = Some t /\ isUniv t) -> 
    isUniv (Node f).

(* Technicalities that allow us to get coinductive proofs done. *)
Definition TT (A : Set) (t : Tree A) :=
  match t with
    | Node o => Node o
  end.

Lemma TTid (A : Set) : forall t: Tree A, t = TT t.
  intros A t.
  destruct t.
  reflexivity.
  Qed.

(* Thread has an infinite path. *)
Lemma ThreadHasInfinitePath : hasInfinitePath Thread.
Proof.
  cofix H.
  rewrite TTid.
  unfold TT.
  unfold Thread.
  (* there is a path down the "true" branch leading to Thread. *)
  apply haspath with (a := true) (t := Thread).
  auto.
  auto.
Qed.

(* Auxiliary lemma *)
Lemma univChildNotNone (A : Set) (t : Tree A) (a : A):
  isUniv t -> (child t a <> None).
Proof.
  intros A t a [f H].
  destruct (H a) as [u [G _]].
  unfold child.
  rewrite G.
  discriminate.
Qed.

(* Thread is not universal. *)
Lemma ThreadNotUniversal: ~ (isUniv Thread).
Proof.
  unfold not.
  intro H.
  eapply univChildNotNone with (t := Thread) (a := false).
  auto.
  unfold Thread, child.
  auto.
Qed.

(* Now let us show that Univ is universal. *)
Lemma univIsuniv (A : Set): isUniv (Univ A).
Proof.
  intro A.
  cofix H.
  rewrite TTid.
  unfold TT.
  unfold Univ.
  apply isuniv.
  intro a.
  exists (Univ A).
  auto.
Qed.

(* By the way, it need not be the case that a universal tree has
   an infinite path! In fact, the universal tree of branching type
   A has an infinite path iff A is inhabited. *)

Lemma whenUnivHasInfiniteBranch (A : Set):
  hasInfinitePath (Univ A) <-> exists a : A, True.
Proof.
  intro A.
  split.
  intro H.
  destruct H as [f a t _].
  exists a.
  trivial.
  intros [a _].
  cofix H.
  rewrite TTid.
  unfold TT.
  unfold Univ.
  apply haspath with (t := Univ A); auto.
Qed.

Comments

এই কিছুটা বিব্রতকর প্রতিক্রিয়ার জন্য ধন্যবাদ। আমি জনগোষ্ঠীর সাথে আছি সমস্যাটি ছড়িয়ে দিয়েছি, তবে আমার চারপাশে এটি জরিমানা করতে পেরেছি। আশ্চর্যজনকভাবে, মহাবিশ্বটি উদ্ভাসিত হয়নি।

— ডেভ ক্লার্ক

ভাল, আমি আমার প্রতিক্রিয়া দেখে বিব্রত হই না :-) আমি ভেবেছিলাম আমিও যদি একটি উত্তর দেয় তবে আমিও একটি ব্যাপক প্রতিক্রিয়া জানাতে পারি।

— আন্দ্রেজ বাউয়ার

আপনার প্রতিক্রিয়া আমার জন্য বিব্রতকর ছিল। তবে অবশ্যই খুব প্রশংসিত

— ডেভ ক্লার্ক

আমি মজা করছিলাম ... যাইহোক, এতে বিব্রত হওয়ার কিছু নেই। আমি আরও খারাপ ভুল করেছি। এছাড়াও, ওয়েব লোকেরা চিন্তা করার আগে তাদের পোস্ট করার জন্য আমন্ত্রণ জানিয়েছে। আমি নিজেই এখানে আপনার সংজ্ঞাটির একটি ভুল সমাধান পোস্ট করেছি, তবে ভাগ্যক্রমে আমি এটি লক্ষ্য করেছিলাম আপনি করার আগে।

— আন্দ্রেজ বাউয়ার