এসকিউএল সার্ভার ২০০৮ সালে কে নির্দিষ্ট ক্রয় তৈরি করেছে তার তালিকা করার কোনও উপায় আছে?
ইন এই তাই লিংক সেখানে কিছু উত্তর কিন্তু হয় 6yrs থেকে আগে।
আমি জানি যে আপনার নাম এবং তারিখটি লেখার জন্য এটি সর্বোত্তম অভ্যাস এবং তারপরে প্রক্রিয়াটি তৈরি করা শুরু করুন, তবে আমি কোথায় কাজ করি তা এটি দেখতে পাচ্ছি না।
যদি এটি করার কোনও উপায় না থাকে তবে ট্রিগারগুলি দিয়ে এই কাজটি করা যায়?
এবং একটি বোনাস প্রশ্ন। এটি কি কোনও ডিবিএর কাজ? কে এটি তৈরি করেছে জানতে?
আপনাকে অনেক ধন্যবাদ.
উত্তর:
হ্যাঁ, একটি উপায় আছে
ট্রিগার ফলাফল সংরক্ষণ করার জন্য টেবিল
USE [SOME_DATABASE]
GO
CREATE TABLE [dbo].[ddl_objects_log](
[date] [datetime] NULL DEFAULT (getdate()),
[login_name] [nvarchar](128) NULL,
[nt_user_name] [nvarchar](128) NULL,
[program_name] [nvarchar](128) NULL,
[host_name] [nvarchar](128) NULL,
[text] [xml] NULL
) ON [PRIMARY] TEXTIMAGE_ON [PRIMARY]
GO
ট্রিগার
USE [SOME_DATABASE]
GO
/****** Object: DdlTrigger [ddl_db_trigger] Script Date: 22/01/2015 13:41:38 ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
CREATE TRIGGER [ddl_db_trigger]
ON DATABASE
FOR CREATE_FUNCTION,
CREATE_PROCEDURE,
CREATE_TABLE,
CREATE_TRIGGER,
CREATE_VIEW,
ALTER_FUNCTION,
ALTER_PROCEDURE,
ALTER_TABLE,
ALTER_TRIGGER,
ALTER_VIEW,
DROP_FUNCTION,
DROP_PROCEDURE,
DROP_TABLE,
DROP_TRIGGER,
DROP_VIEW,
CREATE_INDEX,
ALTER_INDEX,
DROP_INDEX
AS
BEGIN
set nocount ON
insert into ddl_objects_log(login_name, nt_user_name, program_name, host_name, text)
select login_name, nt_user_name, program_name, host_name, EVENTDATA() from sys.dm_exec_sessions WITH(NOLOCK) where session_id=@@SPID
set nocount OFF
END
GO
ENABLE TRIGGER [ddl_db_trigger] ON DATABASE
GO
ট্রিগার ফলাফল নিরীক্ষণের প্রশ্ন
USE [SOME_DATABASE]
GO
SELECT top 10
REPLACE(CONVERT(VARCHAR(250), text.query('data(/EVENT_INSTANCE/PostTime)')),'T', ' ') as modify_datetime,
CONVERT(VARCHAR(215), text.query('data(/EVENT_INSTANCE/EventType)')) as event_type,
CONVERT(VARCHAR(225), text.query('data(/EVENT_INSTANCE/ServerName)')) as server_name,
CONVERT(VARCHAR(225), text.query('data(/EVENT_INSTANCE/DatabaseName)')) as database_name,
CONVERT(VARCHAR(225), text.query('data(/EVENT_INSTANCE/ObjectType)')) as object_type,
CONVERT(VARCHAR(225), text.query('data(/EVENT_INSTANCE/ObjectName)')) as object_name,
CONVERT(VARCHAR(215), text.query('data(/EVENT_INSTANCE/UserName)')) as user_name,
Login_name,
CONVERT(VARCHAR(MAX), text.query('data(/EVENT_INSTANCE/TSQLCommand/CommandText)')) as command_text
FROM [SOME_DATABASE].[dbo].[ddl_objects_log]
where CONVERT(VARCHAR(225), text.query('data(/EVENT_INSTANCE/ObjectName)')) like '%SOME_STORED_PROCEDURE%'
order by date desc
GO
অন্য ডিবিএর ভিন্ন মতামত থাকতে পারে তবে আমি ডিবিএর জন্য এই তথ্যটি সহজেই উপলব্ধ হিসাবে বিবেচনা করি।
FROM [SOME_DATABASE].[dbo].[ddl_objects_log]টেবিলটি তৈরি করব?
আপনি যদি ডিফল্ট ট্রেস সক্ষম করে থাকেন এবং এটি ঘূর্ণায়িত না হয় তবে আপনি এসপি কে তৈরি করেছেন তা খুঁজে পেতে আপনি এটি ব্যবহার করতে পারেন
/*
Object Altered
Object Created
Object Deleted
*/
SELECT TE.name ,
v.subclass_name ,
DB_NAME(t.DatabaseId) AS DBName ,
T.NTDomainName ,
t.NTUserName ,
t.HostName ,
t.ApplicationName ,
t.LoginName ,
t.Duration ,
t.StartTime ,
t.ObjectName ,
CASE t.ObjectType
WHEN 8259 THEN 'Check Constraint'
WHEN 8260 THEN 'Default (constraint or standalone)'
WHEN 8262 THEN 'Foreign-key Constraint'
WHEN 8272 THEN 'Stored Procedure'
WHEN 8274 THEN 'Rule'
WHEN 8275 THEN 'System Table'
WHEN 8276 THEN 'Trigger on Server'
WHEN 8277 THEN '(User-defined) Table'
WHEN 8278 THEN 'View'
WHEN 8280 THEN 'Extended Stored Procedure'
WHEN 16724 THEN 'CLR Trigger'
WHEN 16964 THEN 'Database'
WHEN 16975 THEN 'Object'
WHEN 17222 THEN 'FullText Catalog'
WHEN 17232 THEN 'CLR Stored Procedure'
WHEN 17235 THEN 'Schema'
WHEN 17475 THEN 'Credential'
WHEN 17491 THEN 'DDL Event'
WHEN 17741 THEN 'Management Event'
WHEN 17747 THEN 'Security Event'
WHEN 17749 THEN 'User Event'
WHEN 17985 THEN 'CLR Aggregate Function'
WHEN 17993 THEN 'Inline Table-valued SQL Function'
WHEN 18000 THEN 'Partition Function'
WHEN 18002 THEN 'Replication Filter Procedure'
WHEN 18004 THEN 'Table-valued SQL Function'
WHEN 18259 THEN 'Server Role'
WHEN 18263 THEN 'Microsoft Windows Group'
WHEN 19265 THEN 'Asymmetric Key'
WHEN 19277 THEN 'Master Key'
WHEN 19280 THEN 'Primary Key'
WHEN 19283 THEN 'ObfusKey'
WHEN 19521 THEN 'Asymmetric Key Login'
WHEN 19523 THEN 'Certificate Login'
WHEN 19538 THEN 'Role'
WHEN 19539 THEN 'SQL Login'
WHEN 19543 THEN 'Windows Login'
WHEN 20034 THEN 'Remote Service Binding'
WHEN 20036 THEN 'Event Notification on Database'
WHEN 20037 THEN 'Event Notification'
WHEN 20038 THEN 'Scalar SQL Function'
WHEN 20047 THEN 'Event Notification on Object'
WHEN 20051 THEN 'Synonym'
WHEN 20549 THEN 'End Point'
WHEN 20801 THEN 'Adhoc Queries which may be cached'
WHEN 20816 THEN 'Prepared Queries which may be cached'
WHEN 20819 THEN 'Service Broker Service Queue'
WHEN 20821 THEN 'Unique Constraint'
WHEN 21057 THEN 'Application Role'
WHEN 21059 THEN 'Certificate'
WHEN 21075 THEN 'Server'
WHEN 21076 THEN 'Transact-SQL Trigger'
WHEN 21313 THEN 'Assembly'
WHEN 21318 THEN 'CLR Scalar Function'
WHEN 21321 THEN 'Inline scalar SQL Function'
WHEN 21328 THEN 'Partition Scheme'
WHEN 21333 THEN 'User'
WHEN 21571 THEN 'Service Broker Service Contract'
WHEN 21572 THEN 'Trigger on Database'
WHEN 21574 THEN 'CLR Table-valued Function'
WHEN 21577
THEN 'Internal Table (For example, XML Node Table, Queue Table.)'
WHEN 21581 THEN 'Service Broker Message Type'
WHEN 21586 THEN 'Service Broker Route'
WHEN 21587 THEN 'Statistics'
WHEN 21825 THEN 'User'
WHEN 21827 THEN 'User'
WHEN 21831 THEN 'User'
WHEN 21843 THEN 'User'
WHEN 21847 THEN 'User'
WHEN 22099 THEN 'Service Broker Service'
WHEN 22601 THEN 'Index'
WHEN 22604 THEN 'Certificate Login'
WHEN 22611 THEN 'XMLSchema'
WHEN 22868 THEN 'Type'
ELSE 'Hmmm???'
END AS ObjectType
FROM [fn_trace_gettable](CONVERT(VARCHAR(150), ( SELECT TOP 1
value
FROM [fn_trace_getinfo](NULL)
WHERE [property] = 2
)), DEFAULT) T
JOIN sys.trace_events TE ON T.EventClass = TE.trace_event_id
JOIN sys.trace_subclass_values v ON v.trace_event_id = TE.trace_event_id
AND v.subclass_value = t.EventSubClass
WHERE TE.name IN ( 'Object:Created', 'Object:Deleted', 'Object:Altered' )
-- filter statistics created by SQL server
AND t.ObjectType NOT IN ( 21587 )
-- filter tempdb objects
AND DatabaseID <> 2
-- get only events in the past 24 hours
AND StartTime > DATEADD(HH, -24, GETDATE())
ORDER BY t.StartTime DESC ;
সম্প্রসারিত করতে এখানে ক্লিক করুন
এটি কি কোনও ডিবিএর কাজ? স্কয়ার ভিতরে কি তৈরি হয়েছে জানতে?
এটি নির্ভর করে যে আপনি কীভাবে অবজেক্ট তৈরি / পরিবর্তন বা বাদ পড়েছেন তা জানতে চান। আপনি যদি মনে করেন যে কোনও অবৈধ ব্যবহারকারীর দ্বারা অবজেক্টগুলি তৈরি করা / নামানো হয়েছে বা পরিবর্তিত হয়েছে তবে আপনি লগইন করতে এবং আপনাকে বিজ্ঞপ্তি দিতে ইভেন্টের বিজ্ঞপ্তিটি ব্যবহার করতে পারেন । আপনার যথাযথ ফিল্টার অন্তর্ভুক্ত রয়েছে তা নিশ্চিত করুন।
এই উত্তরের সম্পূর্ণতার জন্য, আমি উল্লেখ করতে চাই - এসকিউএল সার্ভার থেকে আমি ডিফল্টরূপে কোন ইভেন্টের তথ্য পেতে পারি? হারুন বারট্রান্ড থেকে।
DATEADD(HH, -24, GETDATE())যদি 24 ঘন্টাের বেশি ফলাফল পেতে চান তবে আপনাকেও সংশোধন করতে হবে।
select * from sys.procedures where type = 'P' order by create_date desc
AND DatabaseID= 'the_Database_I_Wantএটি DATEADD(HH, -24, GETDATE())মন্তব্য সহ আমার কিছুই দেখায় না । আমি কি ভুল কিছু করছি?
আমি দেরিতে আসছি, তবে আমি সুরক্ষা এবং * প্রশাসনের জিনিসগুলি "করি"।
এটি কি কোনও ডিবিএর কাজ? স্কয়ার ভিতরে কি তৈরি হয়েছে জানতে?
হ্যাঁ । যেখানেই সম্ভব এই লগগুলি তৈরি করা বা তৈরি করা জরুরী। যাইহোক, এটিও আপনার দায়িত্ব, আমার মতে এটি গুরুত্বপূর্ণ হওয়া অবধি "এই বাক্সটি না খোলা"। অন্য কথায় - আবার, আমার দৃষ্টিতে - ডেটার জন্য রেপো সরবরাহ করা আপনার সুরক্ষার বিষয়টি নিশ্চিত করা, সুরক্ষিত করা নিশ্চিত করা ... এবং তারপরে আপনাকে বিশেষভাবে ডাকা না হলে ভিতরে থাকা তথ্য থেকে দূরে থাকুন আপনার লক্ষ্য অর্জনের প্রয়োজন না হলে এটি দেখুন বা না করুন।
আমার মতামত, এবং আমার দৃষ্টিভঙ্গি, তবে আমি বহু বছর ধরে সংবেদনশীল এবং গোপনীয় ডেটা নিয়ে কাজ করেছি এবং এটি প্রায় কোনও ক্ষেত্রেই পয়েন্ট করে তুলেছি [1] "বাক্সটি খুলবেন না", কারণ এটি ব্যবহারকারীদের উপর আস্থা হ্রাস করে।
এখন আমাকে একটি আলাদা পথ অবলম্বন করা যাক : কেউ যদি দ্রুত বুঝতে না পারে যে পদ্ধতিটি এজ-কেসে কীভাবে প্রতিক্রিয়া জানায়? আপনার বা আমার ধাঁধাতে এক ঘন্টা কী লাগতে পারে লেখককে কয়েক মিনিট সময় নিতে পারে: "আহ, ঠিক আছে, এই জিনিসটি ব্যর্থ হয় ..."