ওরাকলের কোনও টেবিলে সূচীগুলি ব্যবহার করে আসল স্থানটি কীভাবে খুঁজে পাবেন?

Question

আমি ওরাকল 10 জি-তে একটি টেবিলের সূচীগুলির দ্বারা প্রকৃত স্থানটি গ্রাস করা সন্ধান করতে চাই। ভবিষ্যতের ব্যবহারের জন্য ওরাকল দ্বারা সংরক্ষিত স্থানটি অন্তর্ভুক্ত করার জন্য আমার ইচ্ছা নেই। (ওরাকল দ্বারা ওভারহেড বিবেচনা করা উচিত নয়।) আমি ব্যবহৃত বাইট চাই বরাদ্দ বাইট না।

আপনি কি আমাকে এগিয়ে যেতে সাহায্য করতে পারেন?

এছাড়াও, কোনও টেবিলে দীর্ঘ ক্ষেত্রের আসল আকার খুঁজে পাওয়ার কোনও উপায় আছে কি?

PS: vsize () এবং dbms_lob.getleth () কাজ করে না।

Comments

আপনি কি ভাগ করে নিতে পারেন কেন এই দুটি পদ্ধতি আপনার পক্ষে কার্যকর হয়নি?

— jcolebrand

আপনার দ্বিতীয় প্রশ্নটি আলাদাভাবে জিজ্ঞাসা করা উচিত।

— লেইফ রিফেল

@ ভালো কথা বলুন। আসুন দেখুন কি ব্যবহারকারী বুঝতে পারেন যে তারা স্থানান্তরিত হয়েছে এবং এখানে উত্তর পেতে সমস্ত পদক্ষেপের মধ্য দিয়ে যায়। তাদের পক্ষে আমার আঙ্গুলগুলি পেরিয়ে।

— jcolebrand

এছাড়াও stackoverflow.com/a/16661034/603516 দেখুন ।

— ভাদজিম

Answer 1

SELECT idx.index_name, SUM(bytes)
  FROM dba_segments seg,
       dba_indexes  idx
 WHERE idx.table_owner = <<owner of table>>
   AND idx.table_name  = <<name of table>>
   AND idx.owner       = seg.owner
   AND idx.index_name  = seg.segment_name
 GROUP BY idx.index_name

প্রতিটি সূচক দ্বারা প্রকৃতপক্ষে কত পরিমাণে স্থান ব্যয় করা হবে তা আপনাকে প্রদর্শন করবে। আপনি কীভাবে ওভারহেডের জন্য অ্যাকাউন্ট করতে চাইছেন এবং কীভাবে আপনি কোনও সূচকের প্রসঙ্গে "ব্যবহৃত" এবং "বরাদ্দ" পার্থক্য করছেন তা আমি পরিষ্কার নই। আপনি যদি সূচকে ফাঁকা জায়গার জন্য অ্যাকাউন্ট করতে চান তবে সূচীতে আংশিকভাবে কতগুলি খালি ব্লক রয়েছে তা নির্ধারণ করতে আপনি DBMS_SPACE.SPACE_USAGE পদ্ধতিটি ব্যবহার করতে পারেন ।

Comments

আমি বিশ্বাস করি যে ওপিকে আপনার ক্যোয়ারী কী প্রত্যাবর্তন করবে তা বরাদ্দকৃত বোঝায় (এবং এটি কোনও পরে স্বয়ংক্রিয়ভাবে সঙ্কুচিত হয় না delete <<name of table>>) ব্যবহৃত আকারের বিপরীতে যা সূচকে প্রবেশের সংখ্যার সাথে পৃথক হবে।

— রেনি নাইফেনিগার

ডিবিএ টেবিলগুলি অ্যাক্সেস না করেই এই আদেশটি সম্ভব: SELECT idx.index_name, SUM(bytes) FROM user_segments seg, user_indexes idx WHERE idx.table_name = 'EMERGE_REPORTING_DETAIL' AND idx.index_name = seg.segment_name GROUP BY idx.index_name

— রিচার্ড ডিঙ্গওয়াল

@ রিচার্ডডিংওয়াল - ধরে নিচ্ছেন যে আপনি ওরাকল ব্যবহারকারী হিসাবে লগ ইন করেছেন যা সূচকটির মালিক, এটি কার্যকর হবে। আপনি যদি ডিবিএর আগ্রহী হন তবে কতটা জায়গা ব্যবহার করা হচ্ছে তাতে আগ্রহী, আপনি সাধারণত টেবিলের মালিক ছাড়া অন্য কোনও ব্যবহারকারী হিসাবে লগ ইন করবেন।

— জাস্টিন গুহ

Answer 2

সূচকের বরাদ্দ এবং ব্যবহৃত আকারটি (যা আমি বিশ্বাস করি এটি আপনার বোঝার বিষয়ে বোঝার জন্য) আমি সম্ভবত ব্যবহার করব dbms_space

create or replace procedure tq84_index_size_proc 
as

  OBJECT_OWNER_in         varchar2(30) :=  user;
  OBJECT_NAME_in          varchar2(30) := 'TQ84_SIZE_IX';
  OBJECT_TYPE_in          varchar2(30) := 'INDEX';
  SAMPLE_CONTROL_in       number       :=  null;
  SPACE_USED_out          number;
  SPACE_ALLOCATED_out     number;
  CHAIN_PCENT_out         number;

  SUM_SEGMENT             number;

begin

  dbms_space.object_space_usage (
    OBJECT_OWNER           => OBJECT_OWNER_in        ,
    OBJECT_NAME            => OBJECT_NAME_in         ,
    OBJECT_TYPE            => OBJECT_TYPE_in         ,
    SAMPLE_CONTROL         => SAMPLE_CONTROL_in      ,
    SPACE_USED             => SPACE_USED_out         ,
    SPACE_ALLOCATED        => SPACE_ALLOCATED_out    ,
    CHAIN_PCENT            => CHAIN_PCENT_out
  );

  select sum(bytes) into SUM_SEGMENT 
    from user_segments
   where segment_name = OBJECT_NAME_in;


  dbms_output.put_line('Space Used:      ' || SPACE_USED_out);
  dbms_output.put_line('Space Allocated: ' || SPACE_ALLOCATED_out);
  dbms_output.put_line('Segment:         ' || SUM_SEGMENT);

end;
/

এই পদ্ধতিটি * TQ84_SIZE_IX * নামের একটি সূচকের বরাদ্দ এবং ব্যবহৃত আকারের পরিমাপ করে। সম্পূর্ণতার জন্য, আমি রিপোর্ট অনুসারে বাইটগুলির গণনাও যুক্ত করেছি user_segments।

এখন, এই পদ্ধতিটি কার্যত দেখা যায়:

create table tq84_size (
  col_1 varchar2(40),
  col_2 number
);

create index tq84_size_ix on tq84_size(col_1);

insert into tq84_size values ('*', 0);
commit;
exec tq84_index_size_proc;

সূচকে একটি প্রবেশের সাথে, নিম্নলিখিত পরিসংখ্যানগুলি ফিরে আসে:

Space Used:      1078
Space Allocated: 65536
Segment:         65536

সূচক পূরণ করা হচ্ছে ...

insert into tq84_size 
select substr(object_name || object_type, 1, 40),
       rownum
  from dba_objects,
       dba_types
 where rownum < 500000;
commit;

... এবং আবার পরিসংখ্যান পেয়ে ...

exec tq84_index_size_proc;

... রিপোর্ট:

Space Used:      25579796
Space Allocated: 32505856
Segment:         32505856

তারপরে, যদি সূচকটি "খালি করা হয়":

delete from tq84_size;
commit;
exec tq84_index_size_proc;

এটা দেখায়:

Space Used:      4052714
Space Allocated: 32505856
Segment:         32505856

যা দেখায় যে ব্যবহৃত আকারটি বরাদ্দ করা আকারটি সঙ্কুচিত হয় না।

Answer 3

যদি কেউ এখানে আসে একটি দীর্ঘ ক্ষেত্রের আকার খুঁজে বের করার জন্য উপায় খুঁজছেন, নীচে এটি করার একটি উপায়। প্রশ্নটি আলাদা করা হলে আমি এই উত্তরটি সরিয়ে ফেলব।

নমুনা তথ্য...

CREATE TABLE TLONG 
(
  C1 Number(3),
  C2 LONG 
);

INSERT INTO TLONG VALUES (1,'abcd');
INSERT INTO TLONG VALUES (2,'abc');
INSERT INTO TLONG VALUES (3,'ab');
INSERT INTO TLONG VALUES (4,'1234567890');

কাজটি করার কাজ ... (উত্পাদনের জন্য এটি কোনও প্যাকেজে থাকা উচিত)

CREATE OR REPLACE FUNCTION GetLongLength (pKey Number) RETURN Number Is
   vLong Long;
BEGIN
   SELECT C2 INTO vLong FROM TLONG WHERE C1 = pKey;
   Return Length(vLong);
END;
/

SHOW ERRORS;

ফাংশনটি পরীক্ষা করুন ...

SELECT rownum, GetLongLength(rownum) FROM dual CONNECT BY rownum<=4;

ROWNUM                 GETLONGLENGTH(ROWNUM)  
---------------------- ---------------------- 
1                      4                      
2                      3                      
3                      2                      
4                      10                   

Answer 4

স্কিমায় সমস্ত সূচকের জন্য স্থানের ব্যবহার আরও জেনেরিক এবং সহজ করার জন্য আমাকে রেনা নিফেনিগার এর উত্তরটি পরিবর্তন করতে হয়েছিল।

ভেবেছিলাম যে আমি অন্য কেউ যদি এটির কাজে লাগে সে ক্ষেত্রে পরিবর্তিত কোডটি এখানে ভাগ করব:

--==========================================
-- Show space usage by all indexes in schema
--==========================================
-- Required to show output in SQLDeveloper, which would supress it otherwise.
SET SERVEROUTPUT ON;
-- Calculates size for given index
CREATE OR REPLACE PROCEDURE calc_index_size(
    index_name IN VARCHAR2)
AS
  OBJECT_OWNER_in     VARCHAR2(30) := USER;
  OBJECT_NAME_in      VARCHAR2(30) := index_name;
  OBJECT_TYPE_in      VARCHAR2(30) := 'INDEX';
  SAMPLE_CONTROL_in   NUMBER       := NULL;
  SPACE_USED_out      NUMBER;
  SPACE_ALLOCATED_out NUMBER;
  CHAIN_PCENT_out     NUMBER;
  SUM_SEGMENT         NUMBER;
BEGIN
  dbms_space.object_space_usage ( OBJECT_OWNER => OBJECT_OWNER_in , OBJECT_NAME => OBJECT_NAME_in , OBJECT_TYPE => OBJECT_TYPE_in , SAMPLE_CONTROL => SAMPLE_CONTROL_in , SPACE_USED => SPACE_USED_out , SPACE_ALLOCATED => SPACE_ALLOCATED_out , CHAIN_PCENT => CHAIN_PCENT_out );
  SELECT SUM(bytes)
  INTO SUM_SEGMENT
  FROM user_segments
  WHERE segment_name = OBJECT_NAME_in;
  dbms_output.put_line('Space Used:      ' || ROUND(SPACE_USED_out     /1024/1024, 2) || 'MB');
  dbms_output.put_line('Space Allocated: ' || ROUND(SPACE_ALLOCATED_out/1024/1024) || 'MB');
  dbms_output.put_line('Segment:         ' || ROUND(SUM_SEGMENT        /1024/1024) || 'MB');
END;
/
-- Shows index size for all indexes in a schema
DECLARE
BEGIN
  FOR user_indexes_sorted_by_size IN
  (SELECT idx.index_name,
    SUM(bytes)/1024/1024 AS "Size(MB)"
  FROM user_segments seg,
    user_indexes idx
  WHERE idx.index_name = seg.segment_name
  GROUP BY idx.index_name
  ORDER BY "Size(MB)" DESC
  )
  LOOP
    dbms_output.put_line( user_indexes_sorted_by_size.index_name );
    dbms_output.put_line( '-------------------------------------' );
    calc_index_size(user_indexes_sorted_by_size.index_name);
    dbms_output.put_line( '' );
  END LOOP;
END;
--==========================================
--==========================================