টি এসকিউএল সারণী কমাগুলিতে একটি কলাম বিভক্ত করার জন্য মূল্যবান ফাংশন

Question

মাইক্রোসফ্ট এসকিউএল সার্ভার ২০০৮ সালে প্রতিটি মানের জন্য পৃথক সারি ছড়িয়ে দিতে একটি ডাটাবেজে কমা বিস্মৃত কলাম নিতে একটি টেবিলের মূল্যবান ফাংশন লিখেছিলাম।

উদাহরণস্বরূপ: "এক, দুই, তিন, চার" নিম্নলিখিত মানগুলি সহ কেবল একটি কলাম সহ একটি নতুন টেবিল ফেরত আসবে:

one
two
three
four

এই কোডটি কি আপনাকে ত্রুটিযুক্ত বলে মনে হচ্ছে? আমি এটি দিয়ে পরীক্ষা যখন

SELECT * FROM utvf_Split('one,two,three,four',',') 

এটি কেবল চিরকাল চলে এবং কখনই কোনও কিছুই ফেরায় না। এটি সত্যিই হতাশাব্যঞ্জক হয়ে উঠছে বিশেষত যেহেতু এমএসএসকিউএল সার্ভারে বিভক্ত ফাংশনগুলিতে কোনও বিল্ড নেই (কেন কেন ?!) এবং ওয়েবে আমি যে সমস্ত অনুরূপ ফাংশন পেয়েছি সেগুলি হ'ল পরম ট্র্যাশ বা কেবল যা করার চেষ্টা করছি তার থেকে অপ্রাসঙ্গিক are ।

ফাংশনটি এখানে:

USE *myDBname*
GO
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
ALTER FUNCTION [dbo].[utvf_SPlit] (@String VARCHAR(MAX), @delimiter CHAR)

RETURNS @SplitValues TABLE
(
    Asset_ID VARCHAR(MAX) NOT NULL
)

AS
BEGIN
            DECLARE @FoundIndex INT
            DECLARE @ReturnValue VARCHAR(MAX)

            SET @FoundIndex = CHARINDEX(@delimiter, @String)

            WHILE (@FoundIndex <> 0)
            BEGIN
                  DECLARE @NextFoundIndex INT
                  SET @NextFoundIndex = CHARINDEX(@delimiter, @String, @FoundIndex+1)
                  SET @ReturnValue = SUBSTRING(@String, @FoundIndex,@NextFoundIndex-@FoundIndex)
                  SET @FoundIndex = CHARINDEX(@delimiter, @String)
                  INSERT @SplitValues (Asset_ID) VALUES (@ReturnValue)
            END

            RETURN
END

Answer 1

এটি সামান্য কাজ করে ...

DECLARE @FoundIndex INT
DECLARE @ReturnValue VARCHAR(MAX)

SET @FoundIndex = CHARINDEX(@delimiter, @String)

WHILE (@FoundIndex <> 0)
BEGIN
      SET @ReturnValue = SUBSTRING(@String, 0, @FoundIndex)
      INSERT @SplitValues (Asset_ID) VALUES (@ReturnValue)
      SET @String = SUBSTRING(@String, @FoundIndex + 1, len(@String) - @FoundIndex)
      SET @FoundIndex = CHARINDEX(@delimiter, @String)
END

INSERT @SplitValues (Asset_ID) VALUES (@String)

RETURN

Answer 2

আমি লুপ দিয়ে এটি করব না; আরও অনেক ভাল বিকল্প আছে। দ্বারা পর্যন্ত সবচেয়ে ভাল, আপনি যখন আছে বিভক্ত করা, CLR, এবং আদম Machanic এর পদক্ষেপ দ্রুততম আমি পরীক্ষিত করেছি ।

পরবর্তী সেরা পদ্ধতির আইএমএইচও, আপনি সিএলআর বাস্তবায়ন করতে না পারলে একটি নম্বর সারণি:

SET NOCOUNT ON;

DECLARE @UpperLimit INT = 1000000;

WITH n AS
(
    SELECT
        x = ROW_NUMBER() OVER (ORDER BY s1.[object_id])
    FROM       sys.all_objects AS s1
    CROSS JOIN sys.all_objects AS s2
    CROSS JOIN sys.all_objects AS s3
)
SELECT Number = x
  INTO dbo.Numbers
  FROM n
  WHERE x BETWEEN 1 AND @UpperLimit
  OPTION (MAXDOP 1); -- protecting from Paul White's observation

GO
CREATE UNIQUE CLUSTERED INDEX n ON dbo.Numbers(Number) 
    --WITH (DATA_COMPRESSION = PAGE);
GO

... যা এই ফাংশনটিকে অনুমতি দেয়:

CREATE FUNCTION dbo.SplitStrings_Numbers
(
   @List       NVARCHAR(MAX),
   @Delimiter  NVARCHAR(255)
)
RETURNS TABLE
WITH SCHEMABINDING
AS
   RETURN
   (
       SELECT Item = SUBSTRING(@List, Number, 
         CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)
       FROM dbo.Numbers
       WHERE Number <= CONVERT(INT, LEN(@List))
         AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
   );
GO

আমি বিশ্বাস করি যে আপনি যখন এটির কাজ করবেন তখন এই সমস্তগুলি আপনার ফাংশনটির চেয়ে আরও ভাল অভিনয় করবে , বিশেষত যেহেতু তারা মাল্টি-স্টেটমেন্টের পরিবর্তে ইনলাইন are আপনার কাজ কেন হচ্ছে না তা আমি তদন্ত করে দেখিনি, কারণ আমার মনে হয় না যে এই ফাংশনটি কাজ করা উপযুক্ত নয়।

কিন্তু সব বলেছে ...

যেহেতু আপনি এসকিউএল সার্ভার ২০০৮ ব্যবহার করছেন, তাই এমন কোনও কারণ কি আপনার প্রথম স্থানে বিভক্ত হওয়ার দরকার আছে? আমি বরং এটির জন্য একটি টিভিপি ব্যবহার করব:

CREATE TYPE dbo.strings AS TABLE
(
  string NVARCHAR(4000)
);

এখন আপনি এটিকে আপনার সঞ্চিত পদ্ধতিগুলির পরামিতি হিসাবে গ্রহণ করতে পারেন এবং সামগ্রীগুলি যেমন আপনি টিভিএফ ব্যবহার করতে চান তেমন ব্যবহার করতে পারেন:

CREATE PROCEDURE dbo.foo
  @strings dbo.strings READONLY
AS
BEGIN
  SET NOCOUNT ON;

  SELECT Asset_ID = string FROM @strings;
  -- SELECT Asset_ID FROM dbo.utvf_split(@other_param, ',');
END

এবং আপনি সরাসরি সি # ইত্যাদি থেকে একটি টিভিপি ডেটা টেবিল হিসাবে পাস করতে পারেন। এটি অবশ্যই উপরের যে কোনও সমাধানের বাইরে চলে যাবে, বিশেষত যদি আপনি বিশেষভাবে আপনার অ্যাপ্লিকেশনটিতে কমা-বিচ্ছিন্ন স্ট্রিং তৈরি করে থাকেন যাতে আপনার সঞ্চিত পদ্ধতিটি আবার টিভিতে আলাদা করার জন্য একটি টিভিপিকে কল করতে পারে। টিভিপিগুলিতে আরও অনেক তথ্যের জন্য এরল্যান্ড سومমারস্কোগের দুর্দান্ত নিবন্ধটি দেখুন ।

সাম্প্রতিককালে, আমি বিভাজন স্ট্রিংয়ের উপর একটি সিরিজ লিখেছি:

• http://sqlperformance.com/2012/07/t-sql-queries/split-strings
• http://sqlperformance.com/2012/08/t-sql-queries/splitting-strings-follow-up
• http://sqlperformance.com/2012/08/t-sql-queries/splitting-strings-now-with-less-t-sql

এবং যদি আপনি এসকিউএল সার্ভার 2016 বা আরও নতুন (বা অ্যাজুরি এসকিউএল ডেটাবেস) ব্যবহার করেন তবে এখানে একটি নতুন STRING_SPLITফাংশন রয়েছে যা আমি এখানে ব্লগ করেছি:

• পারফরম্যান্স আশ্চর্য এবং অনুমান: STRING_SPLIT ()
• এসকিউএল সার্ভার ২০১ STRING-এ STRING_SPLIT (): ফলো-আপ # 1
• এসকিউএল সার্ভার ২০১ STRING-এ STRING_SPLIT (): ফলো-আপ # 2

Answer 3

এসকিউএল সার্ভার 2016 টি STRING_SPLIT () ফাংশনটি প্রবর্তন করেছে । এর দুটি প্যারামিটার রয়েছে - স্ট্রিংটি কাটা হবে এবং বিভাজক। ফলাফল অনুসারে আউটপুট এক সারি হয়।

প্রদত্ত উদাহরণের জন্য

SELECT * FROM string_split('one,two,three,four', ',');

ফিরে আসবে

value
------------------
one
two
three
four

Answer 4

আমি জেফ মোডেনের স্ট্রিং স্প্লিটারটি প্রকাশিত হওয়ার প্রায় সময় থেকেই ব্যবহার এবং ভালবাসি।

ট্যালি ওহ! একটি উন্নত এসকিউএল 8 কে "সিএসভি বিভাজন" ফাংশন

CREATE FUNCTION [dbo].[DelimitedSplit8K]
--===== Define I/O parameters
        (@pString VARCHAR(8000), @pDelimiter CHAR(1))
--WARNING!!! DO NOT USE MAX DATA-TYPES HERE!  IT WILL KILL PERFORMANCE!
RETURNS TABLE WITH SCHEMABINDING AS
 RETURN
--===== "Inline" CTE Driven "Tally Table" produces values from 1 up to 10,000...
     -- enough to cover VARCHAR(8000)
  WITH E1(N) AS (
                 SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL
                 SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL
                 SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1
                ),                          --10E+1 or 10 rows
       E2(N) AS (SELECT 1 FROM E1 a, E1 b), --10E+2 or 100 rows
       E4(N) AS (SELECT 1 FROM E2 a, E2 b), --10E+4 or 10,000 rows max
 cteTally(N) AS (--==== This provides the "base" CTE and limits the number of rows right up front
                     -- for both a performance gain and prevention of accidental "overruns"
                 SELECT TOP (ISNULL(DATALENGTH(@pString),0)) ROW_NUMBER() OVER (ORDER BY (SELECT NULL)) FROM E4
                ),
cteStart(N1) AS (--==== This returns N+1 (starting position of each "element" just once for each delimiter)
                 SELECT 1 UNION ALL
                 SELECT t.N+1 FROM cteTally t WHERE SUBSTRING(@pString,t.N,1) = @pDelimiter
                ),
cteLen(N1,L1) AS(--==== Return start and length (for use in substring)
                 SELECT s.N1,
                        ISNULL(NULLIF(CHARINDEX(@pDelimiter,@pString,s.N1),0)-s.N1,8000)
                   FROM cteStart s
                )
--===== Do the actual split. The ISNULL/NULLIF combo handles the length for the final element when no delimiter is found.
 SELECT ItemNumber = ROW_NUMBER() OVER(ORDER BY l.N1),
        Item       = SUBSTRING(@pString, l.N1, l.L1)
   FROM cteLen l
;

Answer 5

CREATE FUNCTION [dbo].[fnSplit]
(

    @sInputList VARCHAR(8000),         -- List of delimited items

    @sDelimiter VARCHAR(8000) = ','    -- delimiter that separates items

)
RETURNS @List TABLE (colData VARCHAR(8000))

BEGIN

DECLARE @sItem VARCHAR(8000)

    WHILE CHARINDEX(@sDelimiter,@sInputList,0) <> 0

    BEGIN

        SELECT @sItem=RTRIM(LTRIM(SUBSTRING(@sInputList,1,CHARINDEX
(@sDelimiter,@sInputList,0)-1))),

        @sInputList=RTRIM(LTRIM(SUBSTRING(@sInputList,CHARINDEX(@sDelimiter,@sInputList,0)
+LEN(@sDelimiter),LEN(@sInputList))))

        IF LEN(@sItem) > 0
            INSERT INTO @List SELECT @sItem
        END

        IF LEN(@sInputList) > 0
            INSERT INTO @List SELECT @sInputList -- Put the last item in
        RETURN
    END

--TEST

--Example 1: select * from fnSplit('1,22,333,444,,5555,666', ',')

--Example 2: select * from fnSplit('1##22#333##444','##')  --note second colData has embedded #

--Example 3: select * from fnSplit('1 22 333 444  5555 666', ' ')