Org টেবিলের ক্ষেত্রগুলির পূর্বরূপ দেখুন

Question

কখনও কখনও org-মোডে একটি টেবিল তৈরি করার সময় ম্যানুয়াল কলামের প্রস্থ সেট করা সুবিধাজনক। এটি এটিকে এমন করে তোলে যাতে কলামগুলি তাদের দীর্ঘতম প্রবেশের আকারে বাড়তে না পারে। যখন org-মোড টেবিলটিতে কোনও এন্ট্রি পাওয়া যায় তার কলামের চেয়ে বেশি দীর্ঘ হয়, প্রবেশটি =>শেষে প্রতীক সহ দৃষ্টিভঙ্গি হয়ে যায়।

আমি জানি যে আমি C-c `ব্যবহার করতে পারি org-table-edit-field, তবে এর জন্য C-c C-cপূর্বরূপ উইন্ডোটি বন্ধ করতে এবং org- মোড বাফারে ফিরে আসতে টিপতে হবে। প্রিফিক্স আর্গুমেন্টের সাথে একই কমান্ডটি কল করা C-u C-c `পুরো ক্ষেত্রটিকে দৃশ্যমান করে তোলে যাতে এটি জায়গায় সম্পাদনা করা যায়, তবে আমি যদি দ্রুত ধারাবাহিকতায় 5-10 ক্ষেত্রের দ্রুত পূর্বরূপ দেখতে চাই তবে এটি ক্লান্তিকর।

LibreOffice ক্যালকের একটি স্প্রেডশিটের শীর্ষে একটি পূর্বরূপ ক্ষেত্র রয়েছে (এমএস এক্সেলও তাই) যা বর্তমানে নির্বাচিত ক্ষেত্রের মান দেখায়:

একটি org- মোড টেবিল সম্পাদনা করার সময় কি একই ধরণের প্রাকদর্শন পাওয়া সম্ভব? মিনিফারটি এটির জন্য একটি ভাল জায়গা বলে মনে হচ্ছে, যদিও এটি *Messages*দ্রুত বাফারটি পূরণ করার পার্শ্ব প্রতিক্রিয়া থাকতে পারে । বাফারের শীর্ষে বা নীচে একটি উত্সর্গীকৃত মিনি উইন্ডোও কাজ করবে।

Comments

এখানে বর্ণিত হিসাবে , আপনি কাটা ক্ষেত্রগুলির বিষয়বস্তুগুলি মাউসের সাহায্যে তাদের উপরে ঘোরাফেরা করে দেখতে পারেন (কোনও ক্লিকের প্রয়োজন নেই)। আপনি যদি tooltip-modeচালু করে থাকেন তবে সামগ্রীগুলি একটি সরঞ্জামদণ্ডে দেখানো হবে; অন্যথায় তারা প্রতিধ্বনি অঞ্চলে প্রদর্শিত হবে।

— itjeyd

যদি আমি মাউসটি ব্যবহার করতে পছন্দ করি তবে আমি আমার টেবিলগুলি এক্সেলের মধ্যে তৈরি করতাম ... ;-)

— নিসপিও

আপনি কেবল এই বিকল্পটি সম্পর্কে সচেতন তা নিশ্চিত করতে চেয়েছিলেন ...

— je ই

Answer 1

জুয়ানচোর উত্তরে অনুপ্রাণিত হয়ে আমি বর্তমান ক্ষেত্রের মানটি প্রদর্শন করতে শিরোনাম লাইনটি ব্যবহার করার সিদ্ধান্ত নিয়েছি। আমি যখন সেখানে ছিলাম তখন আমি স্থির করেছিলাম যে শিরোনামের সাথে ক্ষেত্রের অবস্থানটিও প্রদর্শন করা ভাল হবে:

এটি অর্জনের জন্য আমি এই কোডটি ব্যবহার করেছি:

(defun my-trim-string (arg) 
  "Simple function for trimming the whitespace from the ends of
 a string. Also removes any string properties such as font faces."
  (let ((str (substring-no-properties arg)))
    (when (string-match "^[ \t]+" str)
      (setq str (replace-match "" nil nil str)))
    (when (string-match "[ \t]+$" str)
      (setq str (replace-match "" nil nil str)))
    str))

(defun my-org-table-location (&optional arg)
  "Get the location of the current field in the table"
  (interactive "P")
  (when (eq 'org-mode major-mode)
    (org-table-get-specials)
    (let* ((row (org-table-current-dline))
           (col (org-table-current-column))
           (loc (if arg
                    (format "%c%02d" (+ 64 col) row)
                  (format "@%d$%d" row col))))
      (when (called-interactively-p 'any)
        (message "Field Location: %s" loc))
      loc)))

(defun my-org-table-field (&optional arg)
  "Get the value of the current field in the table"
  (interactive "P")
  (when (eq 'org-mode major-mode)
    (org-table-get-specials)
    (let* ((formula (org-table-current-field-formula))
           (value (my-trim-string (org-table-get-field)))
           (field (or (and arg formula) value)))
      (when (called-interactively-p 'any)
        (message "Field Value: %s" loc))
      field)))

;; Define the format for the header line in Org mode
(setq my-org-table-header
      (list '(:eval (let ((loc (my-org-table-location))
                          (field (my-org-table-field)))
                      (format " %s: %s" loc field)))))

(defun my-org-mode-setup ()
  "Apply custom setup to org-mode buffers"
  (setq-local header-line-format my-org-table-header))
(add-hook 'org-mode-hook 'my-org-mode-setup)

এটি কয়েক দিনের (সর্বনিম্ন) পরীক্ষার সহ্য করেছে, তাই আমি এগিয়ে গিয়ে ভাগ করে নেওয়ার সিদ্ধান্ত নিয়েছি। অন্য কারও যদি এটির ব্যবহার শেষ হয় তবে আপনার যদি এটির সাথে কোনও সমস্যা দেখা দেয় তবে দয়া করে আমাকে জানান।

Answer 2

শেঠের উত্তরে অনুপ্রাণিত হয়ে, আপনি সর্বদা হেডার লাইনে (যা উইন্ডোটির শীর্ষে একটি সামান্য পরিচিত মোড লাইন) এ সরঞ্জামটিপ পাঠ্যটি প্রদর্শন করতে পারেন।

নিম্নলিখিতটি কার্যকর করুন:

(setq-default header-line-format (list '(:eval (help-at-pt-kbd-string))))

এখন, প্রতিবার পয়েন্টের নীচে পাঠ্যের একটি টুলটিপ বৈশিষ্ট্য রয়েছে, এটি শিরোলেখ লাইনে প্রদর্শিত হবে।

প্রকৃতপক্ষে, org- টেবিলের সরঞ্জামদ্বারগুলিতে নির্দেশাবলী সহ একটি বিরক্তিকর উপসর্গ থাকে তবে এটি আপনার সমস্যার একটি অনুমান।

Comments

ধন্যবাদ! আমি এই ধারণাটি প্রসারিত করে এমন একটি সমাধান নিয়ে এসেছি যাতে যে কোনও ক্ষেত্রের মান (কেবলমাত্র সরঞ্জামদণ্ডের সাথে নয়) প্রদর্শিত হয়।

— নিস্পিও

Answer 3

যদি আপনি আপনার কার্সারটি ঘরে রাখেন এবং C-h .এটি আঘাত করেন তবে প্রতিধ্বনি অঞ্চলে সেই ঘরের জন্য সহায়তা পাঠ্যটি প্রদর্শিত হবে। সহায়তা পাঠ্যে সম্পূর্ণ মান পাশাপাশি অন্যান্য সহায়তা পাঠ্য থাকে। ধরণের গোলমাল কিন্তু এটি মানটি দেখায়।

ইকো দেখুন display-local-helpএবং সহায়তা করুন ।

Answer 4

এটি একটি পুরানো প্রশ্ন, তবে আমাকে এটি যুক্ত করতে দিন।

(add-hook 'org-mode-hook
          '(lambda ()
             (setq-local header-line-format (list '(:eval (substring-no-properties (org-table-get-field)))))
           ))

আমি মনে করি @ স্নিপিও'র সমাধানটি কার্যকর করার এটি আরও প্রত্যক্ষ উপায়।

Answer 5

M-x org-table-follow-field-mode আপনার ফাইলের org- মোডে থাকাকালীন কেবল রিমোট-সম্পাদনা দেখার অনুমতি দেওয়া উচিত নয়। সুতরাং আপনি ঘর-সম্পাদনাটি দৃষ্টিতে না রেখেই সহজেই টেবিল এবং ঘরগুলি যেমন অদলবদ কলামগুলির মতো সহজেই বিভিন্ন জিনিস করতে পারেন।

কী-বাইন্ডিং সহ, আমি যখনই টেবিলের ভিতরে থাকি তখন আমি এই কীটি টিপুন এবং এই মোডটি সক্রিয় করতে চাই। এখন কেবলমাত্র, আমি যখনই টেবিলে থাকি তবে এটি স্বয়ংক্রিয়ভাবে সক্রিয় করার কোনও উপায় খুঁজে পেতে পারি find