এসকিউএল সার্ভারে স্ট্রিং থেকে সমস্ত অ-বর্ণমালা অক্ষর কেড়ে ফেলা যায়?

172

স্ট্রিং থেকে বর্ণমালা নয় এমন সমস্ত অক্ষর আপনি কীভাবে সরিয়ে ফেলতে পারেন?

অ-বর্ণমালা সম্পর্কে কি?

এটি কি একটি কাস্টম ফাংশন হতে হবে বা আরও সাধারণীকরণযোগ্য সমাধান রয়েছে?

sql-server  parsing  user-defined-functions  alphanumeric  alphabetic 
— এমনকি মিয়েন
সূত্র

উত্তর:

362

এই ফাংশনটি ব্যবহার করে দেখুন:

Create Function [dbo].[RemoveNonAlphaCharacters](@Temp VarChar(1000))
Returns VarChar(1000)
AS
Begin

    Declare @KeepValues as varchar(50)
    Set @KeepValues = '%[^a-z]%'
    While PatIndex(@KeepValues, @Temp) > 0
        Set @Temp = Stuff(@Temp, PatIndex(@KeepValues, @Temp), 1, '')

    Return @Temp
End

এটিকে কল করুন:

Select dbo.RemoveNonAlphaCharacters('abc1234def5678ghi90jkl')

আপনি একবার কোডটি বুঝতে পারলে আপনার দেখতে হবে যে অন্যান্য অক্ষরও সরিয়ে ফেলতে এটি পরিবর্তন করা তুলনামূলক সহজ। এমনকি আপনি আপনার অনুসন্ধানের প্যাটার্নে যাওয়ার জন্য এটিকে যথেষ্ট গতিশীল করতে পারেন।

আশা করি এটা সাহায্য করবে.

— জর্জ মাস্ত্রোস
সূত্র
9
এই কোডটি অ-আলফা অক্ষরগুলি সরিয়ে দেয় (সুতরাং সংখ্যাগুলিও সরানো হয়)। আপনি যদি নম্বরগুলি ছেড়ে যেতে চান (অ-আলফা সংখ্যাসূচক অক্ষরগুলি সরিয়ে ফেলুন), তবে ... ^ আজকে ^ আজ ^ 0-9 দিয়ে প্রতিস্থাপন করুন যে অনুসন্ধানের স্ট্রিংটি কোডটিতে দুটি ভিন্ন জায়গায় উপস্থিত হবে appears উভয় প্রতিস্থাপন করতে ভুলবেন না।
— জর্জ মাস্ত্রোস
26
জেফের মন্তব্য থেকে: আমি মনে করি যে সমস্ত নন-অক্ষর এবং অ-সংখ্যাগুলি সরিয়ে ফেলতে চাইলে আপনি '^ a-z0-9' (বনাম '^ আজ ^ 0-9' চাইবেন, যা স্ট্রিংয়ে ছেড়ে যাবে) ।
— এমনকি Mien,
1
+1 জর্জ এটি সেই জায়গাগুলির মধ্যে একটি যেখানে "সেট-ভিত্তিক" কোড এবং ইনলাইন স্কালার ফাংশনগুলির ব্যবহারের মাধ্যমে সারি-বাই-সারিটি মারতে দারুণ অসুবিধা হয়। সুন্দরভাবে সম্পন্ন. আমি আপনার "ইনিশিয়াল ক্যাপস" ফাংশনটিও ব্যবহার করছি, যা বেশ কয়েক বছর ধরে এখন একইরকম বেসিক ফর্ম রয়েছে।
— জেফ মোডেন
6
@ লিঞ্চি পরিবর্তন '% [^ এজে]%' থেকে '% [^ এজে]%' মূলত, z এর পরে একটি স্পেস অক্ষর রাখুন।
— জর্জ মাস্ত্রোস
8
পরিবর্তনশীল নাম কিপভ্যালিউস আসলে যা করা তা বোঝানো তার বিপরীত। কিপভ্যালুগুলি এমন অক্ষরগুলি তালিকাভুক্ত করে যা বাদ দেওয়া দরকার ..
— ne2121
167

এর স্থিতিমাপ সংস্করণ জি Mastros ' সন্ত্রস্ত উত্তর :

CREATE FUNCTION [dbo].[fn_StripCharacters]
(
    @String NVARCHAR(MAX), 
    @MatchExpression VARCHAR(255)
)
RETURNS NVARCHAR(MAX)
AS
BEGIN
    SET @MatchExpression =  '%['+@MatchExpression+']%'

    WHILE PatIndex(@MatchExpression, @String) > 0
        SET @String = Stuff(@String, PatIndex(@MatchExpression, @String), 1, '')

    RETURN @String

END

বর্ণমালা:

SELECT dbo.fn_StripCharacters('a1!s2@d3#f4$', '^a-z')

সাংখ্যিক শুধুমাত্র:

SELECT dbo.fn_StripCharacters('a1!s2@d3#f4$', '^0-9')

কেবলমাত্র বর্ণমালা:

SELECT dbo.fn_StripCharacters('a1!s2@d3#f4$', '^a-z0-9')

অ আলফানিউমেরিক:

SELECT dbo.fn_StripCharacters('a1!s2@d3#f4$', 'a-z0-9')
— এমনকি মিয়েন
সূত্র
3
আমি এই সংস্করণটিকে প্রাধান্য দিয়েছি এবং ভোট দেওয়ার জন্য স্ক্রোলিংয়ের আগে জি মাস্ত্রোসের উত্তরটির আমার অভিযোজনটি তৈরি করেছি!
— আর্সেনাভিয়ান
রেজেক্স প্যাটার্নটি সমস্ত সাদা স্থানের সাথে কাজ করছে বলে মনে হয় না। আমি যদি আলফানিউমেরিক অক্ষর এবং সাদা স্থান বাদে সমস্ত বিশেষ অক্ষরগুলি ছাঁটাই করতে চাই তবে আমি SELECT dbo.fn_StripCharacters('a1!s2 spaces @d3# f4$', '^a-z0-9\s')এখনও হোয়াইটস্পেসের স্ট্রিপগুলি ব্যবহার করব বলে আশা করব । আমিও ব্যবহার করার চেষ্টা করেছি [[:blank:]]কিন্তু এটি ফাংশনটি ভেঙে দেয় এবং স্ট্রিং থেকে কিছুই সরানো হয় না। নিকটতম Ive পেয়েছেন হ'ল: SELECT dbo.fn_StripCharacters('a1!s2 spaces @d3# f4$', '^a-z0-9 ')(রেজেক্স প্যাটার্নে একটি স্থান হার্ড-কোডিং)। তবে এটি লাইন ব্রেকগুলি সরাবে না।
— বিলি ম্যাককি
2
@ বিলিএমকিকি নিয়মিত প্রকাশের শেষে এটি যুক্ত করার পরিবর্তে শুরুতে স্থান যুক্ত করুন। SELECT dbo.fn_StripCharacters('a1!s2 spaces @d3# f4$', '^ a-z0-9')
— মাইক
8

বিশ্বাস করুন বা না করুন, আমার সিস্টেমে এই কুরুচিপূর্ণ ফাংশনটি জি মাস্ট্রোস মার্জিতের চেয়ে ভাল অভিনয় করে।

CREATE FUNCTION dbo.RemoveSpecialChar (@s VARCHAR(256)) 
RETURNS VARCHAR(256) 
WITH SCHEMABINDING
    BEGIN
        IF @s IS NULL
            RETURN NULL
        DECLARE @s2 VARCHAR(256) = '',
                @l INT = LEN(@s),
                @p INT = 1

        WHILE @p <= @l
            BEGIN
                DECLARE @c INT
                SET @c = ASCII(SUBSTRING(@s, @p, 1))
                IF @c BETWEEN 48 AND 57
                   OR  @c BETWEEN 65 AND 90
                   OR  @c BETWEEN 97 AND 122
                    SET @s2 = @s2 + CHAR(@c)
                SET @p = @p + 1
            END

        IF LEN(@s2) = 0
            RETURN NULL

        RETURN @s2
— জে ব্রুনে
সূত্র
সাধারণ কমা, পিরিয়ড, স্পেস ইত্যাদি সম্পর্কে কী?
— sojim
আপনি যদি ASCIIএখানে পূর্ণসংখ্যার ব্যবহার না করেন এবং SUBSTRINGকিছু অক্ষরের সাথে সরাসরি আউটপুট তুলনা করেন তবে কতটা পার্থক্য রয়েছে : যেমন: SET @ch=SUBSTRING(@s, @p, 1)এবংIF @ch BETWEEN '0' AND '9' OR @ch BETWEEN 'a' AND 'z' OR @ch BETWEEN 'A' AND 'Z' ...
— এস। স্পর্শান
আপনার ফাংশন যেমন রয়েছে তেমন ফাংশনে তার সাথে স্ক্যামিনেন্ডিং যুক্ত করুন। আপনি ভিচারার ব্যবহার করছেন, তার ফাংশন এনভিচারার ব্যবহার করছে। আপনি যদি তার ফাংশনে যে প্যারামিটারগুলি দিয়ে যাচ্ছেন সেগুলি যদি ভর্চার হয় তবে আপনি তার ফাংশনটির মধ্যে এনভিচারারের পরিবর্তে ভ্রচারার ব্যবহার করা উচিত অন্যথায়, আপনার সিস্টেমে স্ট্রিংয়ের মানগুলি ভার্চর থেকে এনভিচারচারে নিক্ষেপ করা দরকার যা এটি আরও ব্যয়বহুল perform এমনকি এই পরিবর্তনগুলির সাথে আপনার ক্রিয়াকলাপটি এখনও দ্রুত হতে পারে তবে সেগুলির কয়েকটি উদাহরণ আমি দেখতে পাচ্ছি যেখানে আপনার পরিস্থিতিতে আপনার জন্য ধীরে ধীরে তার কার্যকারিতা সম্পাদন করতে পারে।
— এরিক
1
তার ফাংশনটি এনভিচারার (ম্যাক্স )ও ব্যবহার করছে এবং আপনার ফাংশনটি ভর্চার (256) ব্যবহার করছে। যদি 256 আপনার প্রয়োজন হয় তবে তার ফাংশনটিও VARCHAR (256) ব্যবহার করতে পরিবর্তন করুন এবং তার ফাংশনটি আপনার জন্য দ্রুত কাজ করবে।
— এরিকআই
5

আমি জানতাম যে এসকিউএল স্ট্রিং ম্যানিপুলেশনে খারাপ ছিল, তবে আমি ভাবিনি যে এটি এতটা কঠিন হবে। একটি স্ট্রিং থেকে সমস্ত সংখ্যা বের করে ফেলার জন্য এখানে একটি সাধারণ ফাংশন। এটি করার আরও ভাল উপায় হতে পারে তবে এটি একটি শুরু।

CREATE FUNCTION dbo.AlphaOnly (
    @String varchar(100)
)
RETURNS varchar(100)
AS BEGIN
  RETURN (
    REPLACE(
      REPLACE(
        REPLACE(
          REPLACE(
            REPLACE(
              REPLACE(
                REPLACE(
                  REPLACE(
                    REPLACE(
                      REPLACE(
                        @String,
                      '9', ''),
                    '8', ''),
                  '7', ''),
                '6', ''),
              '5', ''),
            '4', ''),
          '3', ''),
        '2', ''),
      '1', ''),
    '0', '')
  )
END
GO

-- ==================
DECLARE @t TABLE (
    ColID       int,
    ColString   varchar(50)
)

INSERT INTO @t VALUES (1, 'abc1234567890')

SELECT ColID, ColString, dbo.AlphaOnly(ColString)
FROM @t

আউটপুট

ColID ColString
----- ------------- ---
    1 abc1234567890 abc

রাউন্ড 2 - ডেটা চালিত ব্ল্যাকলিস্ট

-- ============================================
-- Create a table of blacklist characters
-- ============================================
IF EXISTS (SELECT * FROM sys.tables WHERE [object_id] = OBJECT_ID('dbo.CharacterBlacklist'))
  DROP TABLE dbo.CharacterBlacklist
GO
CREATE TABLE dbo.CharacterBlacklist (
    CharID              int         IDENTITY,
    DisallowedCharacter nchar(1)    NOT NULL
)
GO
INSERT INTO dbo.CharacterBlacklist (DisallowedCharacter) VALUES (N'0')
INSERT INTO dbo.CharacterBlacklist (DisallowedCharacter) VALUES (N'1')
INSERT INTO dbo.CharacterBlacklist (DisallowedCharacter) VALUES (N'2')
INSERT INTO dbo.CharacterBlacklist (DisallowedCharacter) VALUES (N'3')
INSERT INTO dbo.CharacterBlacklist (DisallowedCharacter) VALUES (N'4')
INSERT INTO dbo.CharacterBlacklist (DisallowedCharacter) VALUES (N'5')
INSERT INTO dbo.CharacterBlacklist (DisallowedCharacter) VALUES (N'6')
INSERT INTO dbo.CharacterBlacklist (DisallowedCharacter) VALUES (N'7')
INSERT INTO dbo.CharacterBlacklist (DisallowedCharacter) VALUES (N'8')
INSERT INTO dbo.CharacterBlacklist (DisallowedCharacter) VALUES (N'9')
GO

-- ====================================
IF EXISTS (SELECT * FROM sys.objects WHERE [object_id] = OBJECT_ID('dbo.StripBlacklistCharacters'))
  DROP FUNCTION dbo.StripBlacklistCharacters
GO
CREATE FUNCTION dbo.StripBlacklistCharacters (
    @String nvarchar(100)
)
RETURNS varchar(100)
AS BEGIN
  DECLARE @blacklistCt  int
  DECLARE @ct           int
  DECLARE @c            nchar(1)

  SELECT @blacklistCt = COUNT(*) FROM dbo.CharacterBlacklist

  SET @ct = 0
  WHILE @ct < @blacklistCt BEGIN
    SET @ct = @ct + 1

    SELECT @String = REPLACE(@String, DisallowedCharacter, N'')
    FROM dbo.CharacterBlacklist
    WHERE CharID = @ct
  END

  RETURN (@String)
END
GO

-- ====================================
DECLARE @s  nvarchar(24)
SET @s = N'abc1234def5678ghi90jkl'

SELECT
    @s                  AS OriginalString,
    dbo.StripBlacklistCharacters(@s)   AS ResultString

আউটপুট

OriginalString           ResultString
------------------------ ------------
abc1234def5678ghi90jkl   abcdefghijkl

পাঠকদের কাছে আমার চ্যালেঞ্জ: আপনি কি আরও দক্ষ করে তুলতে পারেন? পুনরাবৃত্তি ব্যবহার সম্পর্কে কী?

— রব গ্যারিসন
সূত্র
আপনি সম্ভবত আরও ভাল একটি ডিবো লিখতে পারেন rip স্ট্রিপ ব্ল্যাকলিস্টচার্যাকারস () sommarskog.se/arrays-in-sql-2005.html#tblnum টেবিলটি আপনার কালো তালিকার তালিকায় যোগ দিয়েছিলেন, তবে আজ চেষ্টা করার জন্য আমি খুব অলস নিজে ....
— কেএম।
4

আপনি যদি আমার মতো হন এবং আপনার উত্পাদন ডেটাতে কেবল ফাংশন যুক্ত করার অ্যাক্সেস না রাখেন তবে এখনও এই ধরণের ফিল্টারিং করতে চান তবে ফিল্টারযুক্ত টুকরোগুলি আবার একসাথে রাখার জন্য একটি পিভট টেবিল ব্যবহার করে একটি খাঁটি এসকিউএল সমাধান দিন।

এনবি আমি 40 টি অক্ষর পর্যন্ত টেবিলটিকে হার্ডকোড করেছি, আপনার যদি ফিল্টার করার জন্য আরও দীর্ঘ স্ট্রিং থাকে তবে আপনাকে আরও যুক্ত করতে হবে।

SET CONCAT_NULL_YIELDS_NULL OFF;

with 
    ToBeScrubbed
as (
    select 1 as id, '*SOME 222@ !@* #* BOGUS !@*&! DATA' as ColumnToScrub
),

Scrubbed as (
    select 
        P.Number as ValueOrder,
        isnull ( substring ( t.ColumnToScrub , number , 1 ) , '' ) as ScrubbedValue,
        t.id
    from
        ToBeScrubbed t
        left join master..spt_values P
            on P.number between 1 and len(t.ColumnToScrub)
            and type ='P'
    where
        PatIndex('%[^a-z]%', substring(t.ColumnToScrub,P.number,1) ) = 0
)

SELECT
    id, 
    [1]+ [2]+ [3]+ [4]+ [5]+ [6]+ [7]+ [8] +[9] +[10]
    +  [11]+ [12]+ [13]+ [14]+ [15]+ [16]+ [17]+ [18] +[19] +[20]
    +  [21]+ [22]+ [23]+ [24]+ [25]+ [26]+ [27]+ [28] +[29] +[30]
    +  [31]+ [32]+ [33]+ [34]+ [35]+ [36]+ [37]+ [38] +[39] +[40] as ScrubbedData
FROM (
    select 
        *
    from 
        Scrubbed
    ) 
    src
    PIVOT (
        MAX(ScrubbedValue) FOR ValueOrder IN (
        [1], [2], [3], [4], [5], [6], [7], [8], [9], [10],
        [11], [12], [13], [14], [15], [16], [17], [18], [19], [20],
        [21], [22], [23], [24], [25], [26], [27], [28], [29], [30],
        [31], [32], [33], [34], [35], [36], [37], [38], [39], [40]
        )
    ) pvt
— কাইল হালে
সূত্র
এই সমাধানটি আমার কাছে 235 কে সারির একটি সেটটিতে কোনও ফাংশন ব্যবহারের চেয়ে 2.3x দ্রুত ছিল। আমাকে 2x প্রতিস্থাপনও করতে হয়েছিল এবং মোট চারটি সিটিই ব্যবহার করেছি। চ্যাম্পের মতো কাজ করেছেন।
— জেজেএস
4

প্রদত্ত সমস্ত সমাধানগুলি দেখে আমি ভেবেছিলাম যে একটি খাঁটি এসকিউএল পদ্ধতি থাকতে হবে যার জন্য কোনও ফাংশন বা সিটিই / এক্সএমএল কোয়ের প্রয়োজন নেই এবং নেস্টেড রিপ্লেস বিবৃতি বজায় রাখতে অসুবিধা নেই। এখানে আমার সমাধান:

SELECT 
  x
  ,CASE WHEN a NOT LIKE '%' + SUBSTRING(x, 1, 1) + '%' THEN '' ELSE SUBSTRING(x, 1, 1) END
    + CASE WHEN a NOT LIKE '%' + SUBSTRING(x, 2, 1) + '%' THEN '' ELSE SUBSTRING(x, 2, 1) END
    + CASE WHEN a NOT LIKE '%' + SUBSTRING(x, 3, 1) + '%' THEN '' ELSE SUBSTRING(x, 3, 1) END
    + CASE WHEN a NOT LIKE '%' + SUBSTRING(x, 4, 1) + '%' THEN '' ELSE SUBSTRING(x, 4, 1) END
    + CASE WHEN a NOT LIKE '%' + SUBSTRING(x, 5, 1) + '%' THEN '' ELSE SUBSTRING(x, 5, 1) END
    + CASE WHEN a NOT LIKE '%' + SUBSTRING(x, 6, 1) + '%' THEN '' ELSE SUBSTRING(x, 6, 1) END
-- Keep adding rows until you reach the column size 
    AS stripped_column
FROM (SELECT 
        column_to_strip AS x
        ,'ABCDEFGHIJKLMNOPQRSTUVWXYZ' AS a 
      FROM my_table) a

এইভাবে করার সুবিধাটি হ'ল বৈধ অক্ষরগুলি সাব ক্যোয়ারির একটি স্ট্রিংয়ে অক্ষরের আলাদা আলাদা সেটগুলির জন্য পুনরায় কনফিগার করা সহজ করে contained

খারাপ দিকটি হ'ল আপনার কলামের আকার পর্যন্ত প্রতিটি অক্ষরের জন্য আপনাকে এসকিউএল সারি যুক্ত করতে হবে। সেই কাজটি আরও সহজ করার জন্য আমি নীচের পাওয়ারশেল স্ক্রিপ্টটি কেবল ব্যবহার করেছি, উদাহরণস্বরূপ যদি কোনও ভিচারার ()৪):

1..64 | % {
  "    + CASE WHEN a NOT LIKE '%' + SUBSTRING(x, {0}, 1) + '%' THEN '' ELSE SUBSTRING(x, {0}, 1) END" -f $_
} | clip.exe
— ডেভ সেক্সটন
সূত্র
3
সাধারণ ক্ষেত্রে বিশ্রী, তবে সংকীর্ণ কলামের সাহায্যে একবারে জিজ্ঞাসার জন্য সহজ এবং দরকারী।
— এরিক জে।
3

অ-বর্ণমালা অক্ষর মুছে ফেলার আরও একটি উপায় এখানে iTVF। প্রথমত, আপনার প্যাটার্ন-ভিত্তিক স্ট্রিং স্প্লিটার দরকার। ডওয়াইন ক্যাম্পের নিবন্ধ থেকে নেওয়া একটি এখানে :

-- PatternSplitCM will split a string based on a pattern of the form 
-- supported by LIKE and PATINDEX 
-- 
-- Created by: Chris Morris 12-Oct-2012 
CREATE FUNCTION [dbo].[PatternSplitCM]
(
       @List                VARCHAR(8000) = NULL
       ,@Pattern            VARCHAR(50)
) RETURNS TABLE WITH SCHEMABINDING 
AS 

RETURN
    WITH numbers AS (
        SELECT TOP(ISNULL(DATALENGTH(@List), 0))
            n = ROW_NUMBER() OVER(ORDER BY (SELECT NULL))
        FROM
        (VALUES (0),(0),(0),(0),(0),(0),(0),(0),(0),(0)) d (n),
        (VALUES (0),(0),(0),(0),(0),(0),(0),(0),(0),(0)) e (n),
        (VALUES (0),(0),(0),(0),(0),(0),(0),(0),(0),(0)) f (n),
        (VALUES (0),(0),(0),(0),(0),(0),(0),(0),(0),(0)) g (n)
    )

    SELECT
        ItemNumber = ROW_NUMBER() OVER(ORDER BY MIN(n)),
        Item = SUBSTRING(@List,MIN(n),1+MAX(n)-MIN(n)),
        [Matched]
    FROM (
        SELECT n, y.[Matched], Grouper = n - ROW_NUMBER() OVER(ORDER BY y.[Matched],n)
        FROM numbers
        CROSS APPLY (
            SELECT [Matched] = CASE WHEN SUBSTRING(@List,n,1) LIKE @Pattern THEN 1 ELSE 0 END
        ) y
    ) d
    GROUP BY [Matched], Grouper

এখন আপনার প্যাটার্ন-ভিত্তিক বিভাজক রয়েছে, আপনার প্যাটার্নের সাথে মেলে এমন স্ট্রিংগুলি বিভক্ত করতে হবে:

[a-z]

এবং তারপরে কাঙ্ক্ষিত ফলাফল পেতে তাদেরকে সম্মতি জানাতে:

SELECT *
FROM tbl t
CROSS APPLY(
    SELECT Item + ''
    FROM dbo.PatternSplitCM(t.str, '[a-z]')
    WHERE Matched = 1
    ORDER BY ItemNumber
    FOR XML PATH('')
) x (a)

নমুনা

ফলাফল:

| Id |              str |              a |
|----|------------------|----------------|
|  1 |    test“te d'abc |     testtedabc |
|  2 |            anr¤a |           anra |
|  3 |  gs-re-C“te d'ab |     gsreCtedab |
|  4 |         M‚fe, DF |          MfeDF |
|  5 |           R™temd |          Rtemd |
|  6 |          ™jad”ji |          jadji |
|  7 |      Cje y ret¢n |       Cjeyretn |
|  8 |        J™kl™balu |        Jklbalu |
|  9 |       le“ne-iokd |       leneiokd |
| 10 |   liode-Pyr‚n‚ie |    liodePyrnie |
| 11 |         V„s G”ta |          VsGta |
| 12 |        Sƒo Paulo |        SoPaulo |
| 13 |  vAstra gAtaland | vAstragAtaland |
| 14 |  ¥uble / Bio-Bio |     ubleBioBio |
| 15 | U“pl™n/ds VAsb-y |    UplndsVAsby |
— ফেলিক্স প্যামিতান
সূত্র
অন্যান্য উত্তরের উপর এটি ব্যবহার করার কোনও সুবিধা আছে?
— এস। সরপুশন
2

মিঃ অ্যালেনের সমাধান থেকে অনুপ্রাণিত এই সমাধানটির জন্য একটি Numbersটেবিলের পূর্ণসংখ্যার প্রয়োজন (যা আপনি যদি ভাল পারফরম্যান্স সহ গুরুতর কোয়েরি ক্রিয়াকলাপ করতে চান তবে আপনার হাতে থাকা উচিত)। এটির জন্য কোনও সিটিই লাগবে না। আপনি NOT IN (...)নির্দিষ্ট অক্ষরগুলি বাদ দিতে অভিব্যক্তি পরিবর্তন করতে পারেন , বা কেবল নির্দিষ্ট অক্ষর ধরে রাখতে এটি একটি IN (...)ওআরপ্রেশনে পরিবর্তন করতে পারেন LIKE।

SELECT (
    SELECT  SUBSTRING([YourString], N, 1)
    FROM    dbo.Numbers
    WHERE   N > 0 AND N <= CONVERT(INT, LEN([YourString]))
        AND SUBSTRING([YourString], N, 1) NOT IN ('(',')',',','.')
    FOR XML PATH('')
) AS [YourStringTransformed]
FROM ...
— জে বিয়েনভেনু
সূত্র
কোনও সম্পর্কযুক্ত সমস্যার আকর্ষণীয় সমাধান।
— টেটারজুইস
2

এখানে এমন একটি সমাধান রয়েছে যার জন্য কোনও ফাংশন তৈরি করা বা প্রতিস্থাপনের জন্য অক্ষরগুলির সমস্ত দৃষ্টিকোণ তালিকাভুক্ত করা দরকার না। এটি অবাঞ্ছিত অক্ষরগুলি খুঁজতে একটি প্যাটিনডেক্সের সাথে একত্রে পুনরাবৃত্ত বিবরণ ব্যবহার করে। এটি একটি কলামে সমস্ত অযাচিত অক্ষর প্রতিস্থাপন করবে - যে কোনও স্ট্রিংয়ে অন্তত 100 টি অনন্য বাজে অক্ষর রয়েছে। (EG "ABC123DEF234" তে 4 টি খারাপ অক্ষর থাকবে 1, 2, 3 এবং 4) 100 সীমাটি একটি WITH বিবৃতিতে অনুমোদিত পুনরাবৃত্তির সর্বাধিক সংখ্যা, তবে এটি প্রক্রিয়া করার জন্য সারিগুলির সংখ্যার উপর সীমাবদ্ধতা আরোপ করে না, যা উপলব্ধ মেমরি দ্বারা শুধুমাত্র সীমাবদ্ধ।
আপনি যদি DISTINCT ফলাফল না চান, আপনি কোড থেকে দুটি বিকল্প অপসারণ করতে পারেন।

-- Create some test data:
SELECT * INTO #testData 
FROM (VALUES ('ABC DEF,K.l(p)'),('123H,J,234'),('ABCD EFG')) as t(TXT)

-- Actual query:
-- Remove non-alpha chars: '%[^A-Z]%'
-- Remove non-alphanumeric chars: '%[^A-Z0-9]%'
DECLARE @BadCharacterPattern VARCHAR(250) = '%[^A-Z]%';

WITH recurMain as (
    SELECT DISTINCT CAST(TXT AS VARCHAR(250)) AS TXT, PATINDEX(@BadCharacterPattern, TXT) AS BadCharIndex
    FROM #testData
    UNION ALL
    SELECT CAST(TXT AS VARCHAR(250)) AS TXT, PATINDEX(@BadCharacterPattern, TXT) AS BadCharIndex
    FROM (
        SELECT 
            CASE WHEN BadCharIndex > 0 
                THEN REPLACE(TXT, SUBSTRING(TXT, BadCharIndex, 1), '')
                ELSE TXT 
            END AS TXT
        FROM recurMain
        WHERE BadCharIndex > 0
    ) badCharFinder
)
SELECT DISTINCT TXT
FROM recurMain
WHERE BadCharIndex = 0;
— গ্রেম জব
সূত্র
1

আমি এটি উভয় জায়গায় রেখেছি যেখানে প্যাট ইন্ডেক্স বলা হয়।

PatIndex('%[^A-Za-z0-9]%', @Temp)

উপরের কাস্টম ফাংশনের জন্য সরানননাল্ফাচার্যাক্টর এবং এর নামকরণ করুন সরানননাল্ফা নিউমারিকচারারস

— user381460
সূত্র
1

- প্রথম একটি ফাংশন তৈরি

CREATE FUNCTION [dbo].[GetNumericonly]
(@strAlphaNumeric VARCHAR(256))
RETURNS VARCHAR(256)
AS
BEGIN
     DECLARE @intAlpha INT
     SET @intAlpha = PATINDEX('%[^0-9]%', @strAlphaNumeric)
BEGIN
     WHILE @intAlpha > 0
   BEGIN
          SET @strAlphaNumeric = STUFF(@strAlphaNumeric, @intAlpha, 1, '' )
          SET @intAlpha = PATINDEX('%[^0-9]%', @strAlphaNumeric )
   END
END
RETURN ISNULL(@strAlphaNumeric,0)
END

এখন এই ফাংশন কল

select [dbo].[GetNumericonly]('Abhi12shek23jaiswal')

এর ফলাফল মত

1223
— অভিষেক জয়সওয়াল
সূত্র
1

পারফরম্যান্স দৃষ্টিকোণ থেকে আমি ইনলাইন ফাংশনটি ব্যবহার করব:

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
CREATE FUNCTION [dbo].[udf_RemoveNumericCharsFromString]
(
@List NVARCHAR(4000)
)
RETURNS TABLE 
AS RETURN

    WITH GetNums AS (
       SELECT TOP(ISNULL(DATALENGTH(@List), 0))
        n = ROW_NUMBER() OVER(ORDER BY (SELECT NULL))
        FROM
          (VALUES (0),(0),(0),(0)) d (n),
          (VALUES (0),(0),(0),(0),(0),(0),(0),(0),(0),(0)) e (n),
          (VALUES (0),(0),(0),(0),(0),(0),(0),(0),(0),(0)) f (n),
          (VALUES (0),(0),(0),(0),(0),(0),(0),(0),(0),(0)) g (n)
            )

    SELECT StrOut = ''+
        (SELECT Chr
         FROM GetNums
            CROSS APPLY (SELECT SUBSTRING(@List , n,1)) X(Chr)
         WHERE Chr LIKE '%[^0-9]%' 
         ORDER BY N
         FOR XML PATH (''),TYPE).value('.','NVARCHAR(MAX)')


   /*How to Use
   SELECT StrOut FROM dbo.udf_RemoveNumericCharsFromString ('vv45--9gut')
   Result: vv--gut
   */
— hkravitz
সূত্র
আমি জানি যে এই থ্রেডটি পুরানো তবে, একটি ইনলাইন টেবিলের মূল্যবান ফাংশন হ'ল উপায়। আপনার সমাধান সঙ্গে সমস্যা, কারণ আপনি শুধুমাত্র সংখ্যা ফেরার করছি, এই কোড:), টাইপ) .value (, 'NVARCHAR (MAX টি)') প্রয়োজন হয় না এবং ফাংশন ~ 50% মন্দীভূত হবে '।'
— অ্যালান বুর্স্টেইন
1

এখানে আরো একটি পুনরাবৃত্ত সিটিই দ্রষ্টব্য, @ জারহার্ড ওয়েইসের উত্তরের উপর ভিত্তি করে এখানে । আপনার পুরো কোড ব্লকটি এসএসএমএসে অনুলিপি করতে এবং এটির সাথে খেলতে সক্ষম হওয়া উচিত। কী চলছে তা বুঝতে সহায়তা করতে ফলাফলগুলিতে কয়েকটি অতিরিক্ত কলাম অন্তর্ভুক্ত। PATINDEX (RegEx) এবং রিকার্সিভ সিটিই উভয়ের সাথে যা চলছে তা সমস্ত বুঝতে না হওয়া পর্যন্ত আমার কিছুটা সময় লেগেছে।

DECLARE @DefineBadCharPattern varchar(30)
SET @DefineBadCharPattern = '%[^A-z]%'  --Means anything NOT between A and z characters (according to ascii char value) is "bad"
SET @DefineBadCharPattern = '%[^a-z0-9]%'  --Means anything NOT between a and z characters or numbers 0 through 9 (according to ascii char value) are "bad"
SET @DefineBadCharPattern = '%[^ -~]%'  --Means anything NOT between space and ~ characters (all non-printable characters) is "bad"
--Change @ReplaceBadCharWith to '' to strip "bad" characters from string
--Change to some character if you want to 'see' what's being replaced. NOTE: It must be allowed accoring to @DefineBadCharPattern above
DECLARE @ReplaceBadCharWith varchar(1) = '#'  --Change this to whatever you want to replace non-printable chars with 
IF patindex(@DefineBadCharPattern COLLATE Latin1_General_BIN, @ReplaceBadCharWith) > 0
    BEGIN
        RAISERROR('@ReplaceBadCharWith value (%s) must be a character allowed by PATINDEX pattern of %s',16,1,@ReplaceBadCharWith, @DefineBadCharPattern)
        RETURN
    END
--A table of values to play with:
DECLARE @temp TABLE (OriginalString varchar(100))
INSERT @temp SELECT ' 1hello' + char(13) + char(10) + 'there' + char(30) + char(9) + char(13) + char(10)
INSERT @temp SELECT '2hello' + char(30) + 'there' + char(30)
INSERT @temp SELECT ' 3hello there'
INSERT @temp SELECT ' tab' + char(9) + ' character'
INSERT @temp SELECT 'good bye'

--Let the magic begin:
;WITH recurse AS (
    select
    OriginalString,
    OriginalString as CleanString,
    patindex(@DefineBadCharPattern COLLATE Latin1_General_BIN, OriginalString) as [Position],
    substring(OriginalString,patindex(@DefineBadCharPattern COLLATE Latin1_General_BIN, OriginalString),1) as [InvalidCharacter],
    ascii(substring(OriginalString,patindex(@DefineBadCharPattern COLLATE Latin1_General_BIN, OriginalString),1)) as [ASCIICode]
    from @temp
   UNION ALL
    select
    OriginalString,
    CONVERT(varchar(100),REPLACE(CleanString,InvalidCharacter,@ReplaceBadCharWith)),
    patindex(@DefineBadCharPattern COLLATE Latin1_General_BIN,CleanString) as [Position],
    substring(CleanString,patindex(@DefineBadCharPattern COLLATE Latin1_General_BIN,CleanString),1),
    ascii(substring(CleanString,patindex(@DefineBadCharPattern COLLATE Latin1_General_BIN,CleanString),1))
    from recurse
    where patindex(@DefineBadCharPattern COLLATE Latin1_General_BIN,CleanString) > 0
)
SELECT * FROM recurse
--optionally comment out this last WHERE clause to see more of what the recursion is doing:
WHERE patindex(@DefineBadCharPattern COLLATE Latin1_General_BIN,CleanString) = 0
— Baodad
সূত্র
0

প্রতিটি চরিত্র পরীক্ষা করার জন্য সিটিই জেনারেটেড নম্বরের সারণিটি ব্যবহার করে, তারপর এক্সএমএল এর জন্য রক্ষিত মানগুলির একটি স্ট্রিংকে সম্মতি জানাতে ...

CREATE FUNCTION [dbo].[PatRemove](
    @pattern varchar(50),
    @expression varchar(8000) 
    )
RETURNS varchar(8000)
AS
BEGIN
    WITH 
        d(d) AS (SELECT d FROM (VALUES (0),(1),(2),(3),(4),(5),(6),(7),(8),(9)) digits(d)),
        nums(n) AS (SELECT ROW_NUMBER() OVER (ORDER BY (SELECT NULL)) FROM d d1, d d2, d d3, d d4),
        chars(c) AS (SELECT SUBSTRING(@expression, n, 1) FROM nums WHERE n <= LEN(@expression))
    SELECT 
        @expression = (SELECT c AS [text()] FROM chars WHERE c NOT LIKE @pattern FOR XML PATH(''));

    RETURN @expression;
END
— ডেনিস অ্যালেন
সূত্র
0 
DECLARE @vchVAlue NVARCHAR(255) = 'SWP, Lettering Position 1: 4 Ω, 2: 8 Ω, 3: 16 Ω, 4:  , 5:  , 6:  , Voltage Selector, Solder, 6, Step switch, : w/o fuseholder '


WHILE PATINDEX('%?%' , CAST(@vchVAlue AS VARCHAR(255))) > 0
  BEGIN
    SELECT @vchVAlue = STUFF(@vchVAlue,PATINDEX('%?%' , CAST(@vchVAlue AS VARCHAR(255))),1,' ')
  END 

SELECT @vchVAlue
— মোহননাদ কত্তশ
সূত্র
0

এইভাবে আমার পক্ষে কাজ হয়নি কারণ আমি নিয়মিত প্রকাশটি প্রতিস্থাপনের চেষ্টা করেছিলাম এমন আরবী বর্ণগুলি রাখার চেষ্টা করেছি কিন্তু এটিও কার্যকর হয়নি। আমি ASCII স্তরে কাজ করার জন্য অন্য পদ্ধতি লিখেছিলাম কারণ এটি আমার একমাত্র পছন্দ ছিল এবং এটি কাজ করেছিল।

 Create function [dbo].[RemoveNonAlphaCharacters] (@s varchar(4000)) returns varchar(4000)
   with schemabinding
begin
   if @s is null
      return null
   declare @s2 varchar(4000)
   set @s2 = ''
   declare @l int
   set @l = len(@s)
   declare @p int
   set @p = 1
   while @p <= @l begin
      declare @c int
      set @c = ascii(substring(@s, @p, 1))
      if @c between 48 and 57 or @c between 65 and 90 or @c between 97 and 122 or @c between 165 and 253 or @c between 32 and 33
         set @s2 = @s2 + char(@c)
      set @p = @p + 1
      end
   if len(@s2) = 0
      return null
   return @s2
   end

যাওয়া

— AGOMAA
সূত্র
-1

পোস্টটি কিছুটা পুরানো হলেও আমি নিম্নলিখিতটি বলতে চাই। উপরের সমাধান সহ আমার যে সমস্যাটি ছিল তা হ'ল এটি it, ë, ï ইত্যাদির মতো চরিত্রগুলি ফিল্টার করে না আমি নীচে একটি ফাংশন মানিয়ে নিয়েছি (স্মৃতি সংরক্ষণের জন্য আমি কেবল একটি 80 বার্চার স্ট্রিং ব্যবহার করেছি):

create FUNCTION dbo.udf_Cleanchars (@InputString varchar(80)) 
RETURNS varchar(80) 
AS 

BEGIN 
declare @return varchar(80) , @length int , @counter int , @cur_char char(1) 
SET @return = '' 
SET @length = 0 
SET @counter = 1 
SET @length = LEN(@InputString) 
IF @length > 0 
BEGIN WHILE @counter <= @length 

BEGIN SET @cur_char = SUBSTRING(@InputString, @counter, 1) IF ((ascii(@cur_char) in (32,44,46)) or (ascii(@cur_char) between 48 and 57) or (ascii(@cur_char) between 65 and 90) or (ascii(@cur_char) between 97 and 122))
BEGIN SET @return = @return + @cur_char END 
SET @counter = @counter + 1 
END END 

RETURN @return END
— এরিক
সূত্র
এরিক, এর জন্য আপনাকে ধন্যবাদ। আপনি যেমনটি বলেছেন, পোস্ট চিহ্নিত করা উত্তরটি খুব ভাল, তবে এটি like এর মতো বোকা "সংখ্যাসূচক" অক্ষরগুলি ছাঁটাই করে না ½
— ট্রয়
-3

আপনি কেবল এটিই ব্যবহার করছেন যদি আমি কেবল এটি ওরাকল 10 জি তে অন্তর্নির্মিত পেয়েছি। ফোন নম্বর তুলনা করার জন্য আমাকে সমস্ত বিশেষ অক্ষরগুলি ছড়িয়ে দিতে হয়েছিল।

regexp_replace(c.phone, '[^0-9]', '')
— লু Bu
সূত্র
5
"এসকিউএল সার্ভার" বিশেষত মাইক্রোসফ্টের পণ্যগুলিকে বোঝায়।
— কেউ নেই
আমাদের সাইট ব্যবহার করে, আপনি স্বীকার করেছেন যে আপনি আমাদের কুকি নীতি এবং গোপনীয়তা নীতিটি পড়েছেন এবং বুঝতে পেরেছেন ।
Licensed under cc by-sa 3.0 with attribution required.