ভিবিএ ব্যবহার করে কোনও ফোল্ডারে ফাইল লুপ করবেন?

Question

আমি ডিরেক্টরি ব্যবহার করে একটি ডিরেক্টরি ফাইল লুপ করতে চাই VBA এক্সেল 2010 এ।

লুপে, আমার প্রয়োজন হবে:

• ফাইলের নাম, এবং
• যে তারিখে ফাইলটি ফর্ম্যাট করা হয়েছিল

আমি নীচের কোডিং করেছি যা ফোল্ডারে আর 50 টি ফাইল না থাকলে তা সূক্ষ্মভাবে কাজ করে, অন্যথায় এটি হাস্যকরভাবে ধীর হয় (আমার> 10000 ফাইলযুক্ত ফোল্ডারগুলির সাথে কাজ করা দরকার)। এই কোডের একমাত্র সমস্যাটি হ'ল এটি দেখার জন্য অপারেশনটি file.nameখুব বেশি সময় নেয়।

কোড যা কাজ করে তবে ওয়ায়আআআআআই খুব ধীর (100 ফাইলের মধ্যে 15 সেকেন্ড):

Sub LoopThroughFiles()
   Dim MyObj As Object, MySource As Object, file As Variant
   Set MySource = MyObj.GetFolder("c:\testfolder\")
   For Each file In MySource.Files
      If InStr(file.name, "test") > 0 Then
         MsgBox "found"
         Exit Sub
      End If
   Next file
End Sub

---

সমস্যা সমাধান:

1. আমার সমস্যাটি Dirএকটি নির্দিষ্ট উপায়ে (15000 ফাইলের জন্য 20 সেকেন্ড) এবং কমান্ডটি ব্যবহার করে টাইম স্ট্যাম্প পরীক্ষা করার জন্য নীচের সমাধানের মাধ্যমে সমাধান করা হয়েছে FileDateTime।
2. ২০ সেকেন্ডের নীচে থেকে অন্য উত্তর গ্রহণ করা হ্রাস করে ১ সেকেন্ডেরও কম হয়।

Comments

আপনার প্রাথমিক সময়টি এখনও ভিবিএর জন্য ধীর বলে মনে হচ্ছে। আপনি কি অ্যাপ্লিকেশন.স্ক্রিনআপডিটিং = মিথ্যা ব্যবহার করছেন?

— মিশিয়েল ভ্যান ডার ব্লঙ্ক

আপনি নিখোঁজ মনে করছেন codeসেট MyObj = নতুন

— ফাইলসিসটেমবজেক্ট

আমি এটি বরং দুঃখজনক বলে মনে করি যে লোকেরা দ্রুত এফএসওকে "ধীর" বলে ডাকে, তবে আপনি যে পারফরম্যান্স পেনাল্টির কথা উল্লেখ করেন তা হ'ল দেরিতে আবদ্ধ কলগুলির পরিবর্তে প্রারম্ভিক বাইন্ডিং ব্যবহার করে আপনি এড়াতে পারেন Object।

— ম্যাথিউ গুইনন

Answer 1

পরিবর্তে একটি কার্য হিসাবে আমার ব্যাখ্যা এখানে:

'#######################################################################
'# LoopThroughFiles
'# Function to Loop through files in current directory and return filenames
'# Usage: LoopThroughFiles ActiveWorkbook.Path, "txt" 'inputDirectoryToScanForFile
'# /programming/10380312/loop-through-files-in-a-folder-using-vba
'#######################################################################
Function LoopThroughFiles(inputDirectoryToScanForFile, filenameCriteria) As String

    Dim StrFile As String
    'Debug.Print "in LoopThroughFiles. inputDirectoryToScanForFile: ", inputDirectoryToScanForFile

    StrFile = Dir(inputDirectoryToScanForFile & "\*" & filenameCriteria)
    Do While Len(StrFile) > 0
        Debug.Print StrFile
        StrFile = Dir

    Loop

End Function

Comments

কেন কিছুই ফিরিয়ে দেওয়া হচ্ছে না? এটি কোনও ফাংশনে আবদ্ধ না করে ব্রেইটটিজ-এর দেওয়া উত্তরের মত নয়

— শফীক

Answer 2

Dirওয়াইল্ড কার্ড গ্রহণ করে যাতে আপনি testসামনের দিকে ফিল্টার যুক্ত করতে এবং প্রতিটি ফাইলের পরীক্ষা এড়ানো এড়াতে পারেন

Sub LoopThroughFiles()
    Dim StrFile As String
    StrFile = Dir("c:\testfolder\*test*")
    Do While Len(StrFile) > 0
        Debug.Print StrFile
        StrFile = Dir
    Loop
End Sub

Comments

গ্রেট। এটি কেবল রানটাইমটিকে 20 সেকেন্ড থেকে <1 সেকেন্ডে উন্নত করেছে। এটি একটি বড় উন্নতি, যেহেতু কোডটি প্রায়শই চালিত হবে। ধন্যবাদ!!

— tyrex

এটি কারণ হতে পারে কারণ যখন করবেন ... লুপটি তখন ... উইন্ডের চেয়ে ভাল। আরও তথ্য এখানে stackoverflow.com/questions/32728334/…

— হিলা ডিজি

আমি সেই উন্নতির স্তর দ্বারা ভাবি না (20 - এক্সএক্সএক্সএক্স সময়) - আমি মনে করি এটি ওয়াইল্ডকার্ড একটি পার্থক্য আনছে।

— brettdj

ডিআইআর () লুকিয়ে থাকা ফাইলগুলি ফিরবে বলে মনে হয় না।

— হামিশ

@ হ্যামিশ, আপনি বিভিন্ন ধরণের ফাইল (লুকানো, সিস্টেম ইত্যাদি) ফেরত দেওয়ার পক্ষে তার যুক্তিটি পরিবর্তন করতে পারেন - এমএস ডকুমেন্টেশন দেখুন: ডকস.মাইক্রোসফটকম

— ভিনসেন্ট

Answer 3

দির খুব দ্রুত বলে মনে হচ্ছে।

Sub LoopThroughFiles()
    Dim MyObj As Object, MySource As Object, file As Variant
   file = Dir("c:\testfolder\")
   While (file <> "")
      If InStr(file, "test") > 0 Then
         MsgBox "found " & file
         Exit Sub
      End If
     file = Dir
  Wend
End Sub

Comments

গ্রেট, আপনাকে অনেক ধন্যবাদ. আমি দির ব্যবহার করি তবে আমি জানতাম না যে আপনি এটিও সেভাবে ব্যবহার করতে পারেন। কমান্ডের পাশাপাশি FileDateTimeআমার সমস্যাও সমাধান হয়ে গেছে।

— tyrex

এখনও একটি প্রশ্ন। আমি ডিআইআর সর্বাধিক সাম্প্রতিক ফাইলগুলি দিয়ে শুরু হওয়া লুপটি বাড়িয়ে দিলে আমি গতিতে গুরুতর উন্নতি করতে পারি। আপনি এটি করার কোনও উপায় দেখতে পাচ্ছেন?

— tyrex

আমার উত্তরোত্তর প্রশ্নটি Brettdj এর নীচের মন্তব্যে নিষ্পত্তি হয়েছে।

— tyrex

দির notতবে traverse the whole directory tree। প্রয়োজনের ক্ষেত্রে: বিশ্লেষকক্যাভিও

— ডির-

দির অন্যান্য ডিআইআর কমান্ড দ্বারা বাধাগ্রস্ত হবে, সুতরাং আপনি যদি ডিয়ার সমন্বিত একটি সাবরুটিন চালান তবে এটি এটি আপনার মূল সাবতে "রিসেট" করতে পারে। মূল প্রশ্ন অনুসারে এফএসও ব্যবহার করা এই সমস্যাটি মুছে ফেলে। সম্পাদনা: স্রেফ নীচে @ লিমানাটহকের পোস্টটি দেখেছি, একই জিনিস

— বাল্ডমোশার

Answer 4

এর Dir ফাংশন যেতে উপায় কিন্তু সমস্যা হল আপনি ব্যবহার করতে পারবেন না হয় Dirযাও recursively ফাংশন যেমন বলেছেন, এখানে, নীচে প্রতি ।

আমি যেভাবে এটি পরিচালনা করেছি তা হ'ল Dirলক্ষ্য ফোল্ডারের জন্য সমস্ত সাব-ফোল্ডার পেতে ফাংশনটি ব্যবহার করা এবং সেগুলি একটি অ্যারেতে লোড করা, তারপরে অ্যারেটিকে পুনরাবৃত্তি করে এমন একটি ফাংশনে পাস করুন।

এখানে একটি ক্লাস যা আমি লিখেছিলাম যা এটি সম্পাদন করে, এটিতে ফিল্টারগুলি অনুসন্ধান করার ক্ষমতা অন্তর্ভুক্ত রয়েছে। ( আপনাকে হাঙ্গেরিয়ান স্বরলিপিটি ক্ষমা করতে হবে, এটি যখন সমস্ত ক্রোধ ছিল তখনই এটি লেখা হয়েছিল ))

Private m_asFilters() As String
Private m_asFiles As Variant
Private m_lNext As Long
Private m_lMax As Long

Public Function GetFileList(ByVal ParentDir As String, Optional ByVal sSearch As String, Optional ByVal Deep As Boolean = True) As Variant
    m_lNext = 0
    m_lMax = 0

    ReDim m_asFiles(0)
    If Len(sSearch) Then
        m_asFilters() = Split(sSearch, "|")
    Else
        ReDim m_asFilters(0)
    End If

    If Deep Then
        Call RecursiveAddFiles(ParentDir)
    Else
        Call AddFiles(ParentDir)
    End If

    If m_lNext Then
        ReDim Preserve m_asFiles(m_lNext - 1)
        GetFileList = m_asFiles
    End If

End Function

Private Sub RecursiveAddFiles(ByVal ParentDir As String)
    Dim asDirs() As String
    Dim l As Long
    On Error GoTo ErrRecursiveAddFiles
    'Add the files in 'this' directory!


    Call AddFiles(ParentDir)

    ReDim asDirs(-1 To -1)
    asDirs = GetDirList(ParentDir)
    For l = 0 To UBound(asDirs)
        Call RecursiveAddFiles(asDirs(l))
    Next l
    On Error GoTo 0
Exit Sub
ErrRecursiveAddFiles:
End Sub
Private Function GetDirList(ByVal ParentDir As String) As String()
    Dim sDir As String
    Dim asRet() As String
    Dim l As Long
    Dim lMax As Long

    If Right(ParentDir, 1) <> "\" Then
        ParentDir = ParentDir & "\"
    End If
    sDir = Dir(ParentDir, vbDirectory Or vbHidden Or vbSystem)
    Do While Len(sDir)
        If GetAttr(ParentDir & sDir) And vbDirectory Then
            If Not (sDir = "." Or sDir = "..") Then
                If l >= lMax Then
                    lMax = lMax + 10
                    ReDim Preserve asRet(lMax)
                End If
                asRet(l) = ParentDir & sDir
                l = l + 1
            End If
        End If
        sDir = Dir
    Loop
    If l Then
        ReDim Preserve asRet(l - 1)
        GetDirList = asRet()
    End If
End Function
Private Sub AddFiles(ByVal ParentDir As String)
    Dim sFile As String
    Dim l As Long

    If Right(ParentDir, 1) <> "\" Then
        ParentDir = ParentDir & "\"
    End If

    For l = 0 To UBound(m_asFilters)
        sFile = Dir(ParentDir & "\" & m_asFilters(l), vbArchive Or vbHidden Or vbNormal Or vbReadOnly Or vbSystem)
        Do While Len(sFile)
            If Not (sFile = "." Or sFile = "..") Then
                If m_lNext >= m_lMax Then
                    m_lMax = m_lMax + 100
                    ReDim Preserve m_asFiles(m_lMax)
                End If
                m_asFiles(m_lNext) = ParentDir & sFile
                m_lNext = m_lNext + 1
            End If
            sFile = Dir
        Loop
    Next l
End Sub

Comments

আমি কলামে পাওয়া ফাইলগুলি তালিকাবদ্ধ করতে চাইলে এর বাস্তবায়ন কী হতে পারে?

— জেকাভিজ

@ জাচাভিজ গেটফিললিস্ট পদ্ধতিটি স্ট্রিংয়ের একটি অ্যারে প্রদান করে। আপনি সম্ভবত অ্যারের মাধ্যমে পুনরাবৃত্তি করতে এবং আইটেমগুলিকে একটি তালিকাভিউতে যুক্ত করুন বা এর মতো কিছু করতে পারেন। তালিকাভিউতে কীভাবে আইটেমগুলি দেখাতে হবে সে সম্পর্কে বিশদগুলি সম্ভবত এই পোস্টের আওতার বাইরে।

— লাইমানাথহক

Answer 5

Dir আমি যখন অন্য ফোল্ডারগুলি থেকে ফাইলগুলি পরিচালনা করি এবং প্রসেস করি তখন ফাংশনটি সহজেই ফোকাস হারাতে থাকে।

আমি উপাদানটির সাথে আরও ভাল ফলাফল পেয়েছি FileSystemObject।

পুরো উদাহরণ এখানে দেওয়া হল:

http://www.xl-central.com/list-files-fso.html

মাইক্রোসফ্ট স্ক্রিপ্টিং রানটাইম (সরঞ্জামসমূহ> রেফারেন্স ব্যবহার করে) ভিজ্যুয়াল বেসিক সম্পাদকটিতে একটি রেফারেন্স সেট করতে ভুলবেন না

একবার চেষ্টা করে দেখো!

Comments

প্রযুক্তিগতভাবে এটি সেই পদ্ধতি যা প্রশ্নকর্তা ব্যবহার করছেন, তাদের কাছে কেবল তাদের উল্লেখগুলি অন্তর্ভুক্ত নেই যা এই পদ্ধতিটি ধীর করে দেবে।

— মার্কুচিবিয় 2

Answer 6

আর একবার চেষ্টা কর. ( লিঙ্ক )

Private Sub CommandButton3_Click()

Dim FileExtStr As String
Dim FileFormatNum As Long
Dim xWs As Worksheet
Dim xWb As Workbook
Dim FolderName As String
Application.ScreenUpdating = False
Set xWb = Application.ThisWorkbook
DateString = Format(Now, "yyyy-mm-dd hh-mm-ss")
FolderName = xWb.Path & "\" & xWb.Name & " " & DateString
MkDir FolderName
For Each xWs In xWb.Worksheets
    xWs.Copy
    If Val(Application.Version) < 12 Then
        FileExtStr = ".xls": FileFormatNum = -4143
    Else
        Select Case xWb.FileFormat
            Case 51:
                FileExtStr = ".xlsx": FileFormatNum = 51
            Case 52:
                If Application.ActiveWorkbook.HasVBProject Then
                    FileExtStr = ".xlsm": FileFormatNum = 52
                Else
                    FileExtStr = ".xlsx": FileFormatNum = 51
                End If
            Case 56:
                FileExtStr = ".xls": FileFormatNum = 56
            Case Else:
                FileExtStr = ".xlsb": FileFormatNum = 50
        End Select
    End If
    xFile = FolderName & "\" & Application.ActiveWorkbook.Sheets(1).Name & FileExtStr
    Application.ActiveWorkbook.SaveAs xFile, FileFormat:=FileFormatNum
    Application.ActiveWorkbook.Close False
Next
MsgBox "You can find the files in " & FolderName
Application.ScreenUpdating = True

End Sub