ব্যাচের চাকরিতে টাইমস্ট্যাম্প হিসাবে একটি ফাইলের নাম তৈরি করা

Question 1

আমাদের একটি ব্যাচের কাজ রয়েছে যা প্রতিদিন চলে এবং একটি ফাইল একটি পিকআপ ফোল্ডারে অনুলিপি করে। আমি সেই ফাইলটির একটি অনুলিপিও নিতে এবং ফাইলের নাম সহ একটি সংরক্ষণাগার ফোল্ডারে রেখে দিতে চাই

 yyyy-MM-dd.log

উইন্ডোজ ব্যাচের কাজটি করার সবচেয়ে সহজ উপায় কী?

আমি মূলত এই ইউনিক্স কমান্ডের সমতুল্য খুঁজছি:

cp source.log `date +%F`.log

Question 2

CP source.log %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%.log

তবে এটি লোকাল নির্ভর। আমি %DATE%স্থানীয় কিনা তা নিশ্চিত নই , বা উইন্ডোজের স্বল্প তারিখের জন্য নির্দিষ্ট করা ফর্ম্যাটের উপর নির্ভর করে।

এই উত্তর থেকে বর্তমান তারিখটি বের করার জন্য এখানে একটি স্থানীয়-স্বাধীন উপায় রয়েছে তবে এটি নির্ভর করে WMICএবং FOR /F:

FOR /F %%A IN ('WMIC OS GET LocalDateTime ^| FINDSTR \.') DO @SET B=%%A
CP source.log %B:~0,4%-%B:~4,2%-%B:~6,2%.log

Question 3

এটি আমার পক্ষে কাজ করেছে এবং এটি একটি ফাইল নাম-নিরাপদ সমাধান ছিল (যদিও এটি একটি এমএম-ডিডি-ওয়াইওয়াই ফর্ম্যাট উত্পন্ন করে):

C:\ set SAVESTAMP=%DATE:/=-%@%TIME::=-%
C:\ set SAVESTAMP=%SAVESTAMP: =%
C:\ set SAVESTAMP=%SAVESTAMP:,=.%.jpg
C:\ echo %SAVESTAMP%
11-04-2012@20-52-42.79.jpg

প্রথম কমান্ডটি একটি তারিখ নেয় এবং এর সাথে প্রতিস্থাপন /করে -, TIME নেয় এবং এর সাথে প্রতিস্থাপিত :হয় -এবং এগুলি DATE @ TIME ফর্ম্যাটে একত্রিত করে। দ্বিতীয় setবিবৃতি কোনো শূণ্যস্থান এবং তৃতীয় সরিয়ে ফেলা হবে setপ্রতিস্থাপিত ,সঙ্গে .এবং appends .jpgএক্সটেনশান।

উপরের কোডটি সামান্য স্ক্রিপ্টে ব্যবহৃত হয়েছে যা আরও প্রক্রিয়াকরণের জন্য সুরক্ষা আইপি ক্যামেরা থেকে চিত্রগুলি টানছে:

:while
set SAVESTAMP=%DATE:/=-%@%TIME::=-%
set SAVESTAMP=%SAVESTAMP: =%
set SAVESTAMP=%SAVESTAMP:,=.%.jpg
wget-1.10.2.exe --tries=0 -O %SAVESTAMP% http://admin:<password>@<ip address>:<port>/snapshot.cgi
timeout 1
GOTO while

Question 4

জন্য ফরাসি লোকেল (ফ্রান্স) শুধুমাত্র , সতর্কতা অবলম্বন করা আবশ্যক কারণ /তারিখ প্রদর্শিত হবে:

echo %DATE%
08/09/2013

লগ ফাইলের আমাদের সমস্যার জন্য, কেবলমাত্র ফরাসি লোকালের জন্য আমার প্রস্তাবটি এখানে রয়েছে :

SETLOCAL
set LOGFILE_DATE=%DATE:~6,4%.%DATE:~3,2%.%DATE:~0,2%
set LOGFILE_TIME=%TIME:~0,2%.%TIME:~3,2%
set LOGFILE=log-%LOGFILE_DATE%-%LOGFILE_TIME%.txt
rem log-2014.05.19-22.18.txt
command > %LOGFILE%

Question 5

এখানে একটি স্থানীয় স্বাধীন সমাধান রয়েছে (সেটডেটটাইমকম্পোনেন্টস.কম নামে একটি ফাইলের অনুলিপি করুন):

@echo off
REM This script taken from the following URL:
REM http://www.winnetmag.com/windowsscripting/article/articleid/9177/windowsscripting_9177.html

REM Create the date and time elements.
for /f "tokens=1-7 delims=:/-, " %%i in ('echo exit^|cmd /q /k"prompt $d $t"') do (
   for /f "tokens=2-4 delims=/-,() skip=1" %%a in ('echo.^|date') do (
      set dow=%%i
      set %%a=%%j
      set %%b=%%k
      set %%c=%%l
      set hh=%%m
      set min=%%n
      set ss=%%o
   )
)

REM Let's see the result.
echo %dow% %yy%-%mm%-%dd% @ %hh%:%min%:%ss%

আমি আমার সমস্ত। সিএমডি স্ক্রিপ্টগুলি একই ফোল্ডারে রেখেছি (% ScriptTROOT%); যে কোনও স্ক্রিপ্টের জন্য তারিখ / সময় মানগুলি প্রয়োজন সেটিকে নীচের উদাহরণ হিসাবে সেটডেটটাইমকোম্পোনসিটিএমডি কল করবে:

setlocal

@echo Initializing...
set SCRIPTROOT=%~dp0
set ERRLOG=C:\Oopsies.err

:: Log start time
call "%SCRIPTROOT%\SetDateTimeComponents.cmd" >nul
@echo === %dow% %yy%-%mm%-%dd% @ %hh%:%min%:%ss% : Start === >> %ERRLOG%

:: Perform some long running action and log errors to ERRLOG.

:: Log end time
call "%SCRIPTROOT%\SetDateTimeComponents.cmd" >nul
@echo === %dow% %yy%-%mm%-%dd% @ %hh%:%min%:%ss% : End === >> %ERRLOG%

উদাহরণটি দেখায়, আপনি যখনই তারিখ / সময় মান আপডেট করার প্রয়োজন হয় তখনই আপনি সেটডেটটাইমকোম্পোনসিটিএমডি কল করতে পারেন। টাইপ পার্সিং স্ক্রিপ্টটি তার নিজস্ব সেটডেটটাইমকম্পোনেন্টস.এমডি ফাইলে লুকিয়ে রাখা কুৎসিত বিবরণগুলি আড়াল করার একটি দুর্দান্ত উপায় এবং আরও গুরুত্বপূর্ণ, টাইপগুলি এড়ানো উচিত।

Question 6

যেহেতু তাদের ছিঁড়ে ফেলা %DATE%এবং %TIME%পৃথক করে জড়িত করার ধারণাটি একেবারে ভঙ্গুর বলে মনে হচ্ছে, এখানে একটি বিকল্প যা পাওয়ারশেল অনেলাইনার ব্যবহার করে:

for /f %i in ('powershell -c "get-date -format yyyy-MM-dd--HH-mm-ss"') do @set DATETIME=%i
set LOGFILE=my-script-%DATETIME%.txt

রেফারেন্স get-dateহয় এখানে উভয় .NET-শৈলী এবং ইউনিক্স-শৈলী জন্য বিন্যাস বিকল্প সহ।

Question 7

আমি প্রায়শই এটি ব্যবহার করি এবং সমস্ত কিছুকে একটি একক অনুলিপি কমান্ডে রাখি। নীচের অনুলিপিগুলি উদাহরণ। টেক্সট হিসাবে উদাহরণ_YYYYMMDD_HHMMSS.txt এবং অবশ্যই আপনি এটি আপনার পছন্দসই বিন্যাস অনুসারে পরিবর্তন করতে পারেন। যদি ফাইলস্পেকের কোনও ফাঁক থাকে তবে কোটগুলি কেবল প্রয়োজনীয়। আপনি যদি একই একই তারিখ / টাইমস্ট্যাম্পটি পুনরায় ব্যবহার করতে চান তবে আপনাকে এটি একটি ভেরিয়েবলে সঞ্চয় করতে হবে।

copy "{path}\example.txt" "{path}\_%date:~10,4%%date:~4,2%%date:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.txt"

Question 8

এটি আউটপুটটি 2-সংখ্যার মান হ'ল তা নিশ্চিত করবে ... আপনি ডায়াগোনস্টিকস বিভাগে কোনও মন্তব্য না করে আউটপুটটিকে আপনার পছন্দ অনুযায়ী পরীক্ষা করতে পারেন এবং পরীক্ষা করতে পারেন। উপভোগ করুন!

(আমি এটি অন্যান্য ফোরামে থেকে প্রচুর ধার নিয়েছি ...)

:: ------------------ Date and Time Modifier ------------------------

@echo off
setlocal

:: THIS CODE WILL DISPLAY A 2-DIGIT TIMESTAMP FOR USE IN APPENDING FILENAMES

:: CREATE VARIABLE %TIMESTAMP%

for /f "tokens=1-8 delims=.:/-, " %%i in ('echo exit^|cmd /q /k"prompt $D $T"') do (
   for /f "tokens=2-4 skip=1 delims=/-,()" %%a in ('echo.^|date') do (
set dow=%%i
set %%a=%%j
set %%b=%%k
set %%c=%%l
set hh=%%m
set min=%%n
set sec=%%o
set hsec=%%p
)
)

:: ensure that hour is always 2 digits

if %hh%==0 set hh=00
if %hh%==1 set hh=01
if %hh%==2 set hh=02
if %hh%==3 set hh=03
if %hh%==4 set hh=04
if %hh%==5 set hh=05
if %hh%==6 set hh=06
if %hh%==7 set hh=07
if %hh%==8 set hh=08
if %hh%==9 set hh=09


:: --------- TIME STAMP DIAGNOSTICS -------------------------

:: Un-comment these lines to test output

:: echo dayOfWeek = %dow%
:: echo year = %yy%
:: echo month = %mm%
:: echo day = %dd%
:: echo hour = %hh%
:: echo minute = %min%
:: echo second = %sec%
:: echo hundredthsSecond = %hsec%
:: echo.
:: echo Hello! 
:: echo Today is %dow%, %mm%/%dd%. 
:: echo.
:: echo. 
:: echo.
:: echo.
:: pause

:: --------- END TIME STAMP DIAGNOSTICS ----------------------

:: assign timeStamp:
:: Add the date and time parameters as necessary - " yy-mm-dd-dow-min-sec-hsec "

endlocal & set timeStamp=%yy%%mm%%dd%_%hh%-%min%-%sec%
echo %timeStamp%

Question 9

ফাইলের নাম হিসাবে বর্তমান তারিখ সহ একটি ফাইল তৈরি করুন (উদাঃ ২০০৮-১০-০৮.ড্যাট)

echo hello > %date%.dat

বর্তমান তারিখ সহ তবে "-" ছাড়াই (উদাঃ ২০০১১০৮.ডাট)

echo hello > %date:-=%.dat

Question 10

হতে পারে এটি সাহায্য করতে পারে:

echo off
@prompt set date=$d$_ set time=$t$h$h$h
echo some log >> %date% %time%.log
exit

বা

echo off
set v=%date%.log
echo some log >> %v%

Question 11

আমি বর্তমান টাইমস্ট্যাম্প মুদ্রণ করার জন্য একটি সামান্য সি প্রোগ্রাম একসাথে রেখেছি (লোকেল-নিরাপদ, কোনও খারাপ চরিত্র নেই ...)। তারপরে, পরিবেশের পরিবর্তনশীলে ফলটি সংরক্ষণ করতে আমি ফর কমান্ডটি ব্যবহার করি:

:: Get the timestamp
for /f %%x in ('@timestamp') do set TIMESTAMP=%%x

:: Use it to generate a filename
for /r %%x in (.\processed\*) do move "%%~x" ".\archived\%%~nx-%TIMESTAMP%%%~xx"

এখানে একটি লিঙ্ক:

https://github.com/HarryPehkonen/dos-timestamp

Question 12

আমি জানি যে এই থ্রেডটি পুরানো তবে আমি এখানে এটি যুক্ত করতে চাই কারণ এটি আমাকে এটিকে সমস্ত কিছু পরিষ্কার করার চেষ্টা করেছিল এবং এটি পরিষ্কার। এটি সম্পর্কে সুন্দর জিনিসটি আপনি এটি সর্বদা চলমান ব্যাচ ফাইলের জন্য একটি লুপে রাখতে পারেন। সার্ভার আপ-টাইম লগ বা কিছু। যাইহোক আমি এটি যাইহোক জন্য ব্যবহার করি। আমি আশা করি এটি কোনও দিন কাউকে সহায়তা করবে।

@setlocal enableextensions enabledelayedexpansion
@echo off

call :timestamp freshtime freshdate
echo %freshdate% - %freshtime% - Some data >> "%freshdate - Somelog.log"

:timestamp
set hour=%time:~0,2%
if "%hour:~0,1%" == " " set hour=0%hour:~1,1%
set min=%time:~3,2%
if "%min:~0,1%" == " " set min=0%min:~1,1%
set secs=%time:~6,2%
if "%secs:~0,1%" == " " set secs=0%secs:~1,1%
set FreshTime=%hour%:%min%:%secs%

set year=%date:~-4%
set month=%date:~4,2%
if "%month:~0,1%" == " " set month=0%month:~1,1%
set day=%date:~7,2%
if "%day:~0,1%" == " " set day=0%day:~1,1%
set FreshDate=%month%.%day%.%year%

Question 13

আপনি কেবলমাত্র স্থানীয় স্থানীয় ফর্ম্যাটটি সনাক্ত করতে পারেন এবং আপনার ফর্ম্যাটে তারিখটি পেতে পারেন, উদাহরণস্বরূপ:

::for 30.10.2016 dd.MM.yyyy
if %date:~2,1%==. set d=%date:~-4%%date:~3,2%%date:~,2%
::for 10/30/2016 MM/dd/yyyy
if %date:~2,1%==/ set d=%date:~-4%%date:~,2%%date:~3,2%
::for 2016-10-30 yyyy-MM-dd
if %date:~4,1%==- set d=%date:~,4%%date:~5,2%%date:~-2%
::variable %d% have now value: 2016103 (yyyyMMdd)
set t=%time::=%
set t=%t:,=%
::variable %t% have now time without delimiters
cp source.log %d%_%t%.log

Question 14

আমি জানি এটি একটি পুরানো পোস্ট, তবে একটি সহজ সরল উত্তর রয়েছে (যদিও এটি কেবল উইন্ডোজের নতুন সংস্করণে কাজ করে)। কেবলমাত্র তারিখ বা সময় দেখানোর জন্য এবং আপনাকে সেট করার অনুরোধ না করার জন্য কেবলমাত্র তারিখ এবং TIME ডস কমান্ডের জন্য / টি প্যারামিটারটি ব্যবহার করুন:

@echo off
echo Starting test batch file > testlog.txt
date /t >> testlog.txt
time /t >> testlog.txt

Question 15

1) আপনি জিএনইউ কোর্টিলগুলি ডাউনলোড করতে পারেন যা জিএনইউ তারিখের সাথে আসে

2) আপনি ভিবিএস স্ক্রিপ্ট ব্যবহার করতে পারেন যা উইন্ডোতে তারিখের ম্যানিপুলেশনকে আরও সহজ করে তোলে:

Set objFS = CreateObject("Scripting.FileSystemObject")
strFolder = "c:\test"
Set objFolder = objFS.GetFolder(strFolder)
current = Now
mth = Month(current)
d = Day(current)
yr = Year(current)
If Len(mth) <2 Then
    mth="0"&mth
End If
If Len(d) < 2 Then
    d = "0"&d
End If
timestamp=yr & "-" & mth &"-"& d
For Each strFile In objFolder.Files
    strFileName = strFile.Name
    If InStr(strFileName,"file_name_here") > 0 Then
        BaseName = objFS.GetBaseName(strFileName)
        Extension = objFS.GetExtensionName(strFileName)
        NewName = BaseName & "-" & timestamp & "." & Extension
        strFile.Name = NewName
    End If
Next

স্ক্রিপ্টটি চালান:

c:\test> cscript /nologo myscript.vbs

Question 16

এটি (আমার) জার্মান স্থানীয় সাথে ভাল কাজ করে, এটি আপনার প্রয়োজনের সাথে সামঞ্জস্য করা সম্ভব হওয়া উচিত ...

forfiles /p *PATH* /m *filepattern* /c "cmd /c ren @file 
%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%_@file"

Question 17

মোতায়েনের জন্য বড় জিপ ফাইলগুলির জন্য, আমি কোয়ার্টার ঘন্টা ব্যবহার করি। এই পৃষ্ঠার অন্য কেউ এর আগে এটি উল্লেখ করেনি, তাই আমি আমার ছোট স্ক্রিপ্টটি এখানে রাখব:

set /a "quarter_hours=%time:~0,2%*4 + %time:~3,2% / 15"
set "zip_file=release_%DATE:~-4%.%DATE:~4,2%.%DATE:~7,2%.%quarter_hours%.zip"

এটি মধ্যরাত থেকে সকাল 5 টা পর্যন্ত শূন্য প্যাড কোয়ার্টার ঘন্টা নয়, তবে এটি এখনও এটি করে তোলে যাতে আপনি কয়েকটি সংঘর্ষের সাথে দিনে একাধিকবার স্ট্যাম্পড রিলিজ পেতে পারেন।

আশা করি এইটি কাজ করবে.

Question 18

ফাইলের নামটিতে সময় স্ট্যাম্প যুক্ত করতে মার্টিনের পরামর্শটি সামান্য টুইটের সাথে ব্যবহার করেছেন:

forfiles /p [foldername] /m rsync2.log /c "cmd /c ren @file %DATE:~6,4%%DATE:~3,2%%DATE:~0,2%_%time:~-11,2%-%time:~-8,2%-%time:~-5,2%-@file

10:17:21 23/10/2019 এর জন্য ফলাফল:

20191023_10-17-21-rsync2.log