উইন্ডোতে কোনও চলকটিতে একটি কমান্ডের ফলাফল কীভাবে পাব?

Question

আমি একটি উইন্ডোজ ব্যাচের স্ক্রিপ্টে চলক হিসাবে একটি কমান্ডের ফলাফল পেতে খুঁজছি ( বাশ স্ক্রিপ্টিং সমতুল্যের জন্য বাশনে একটি কমান্ডের ফলাফল কীভাবে পাবেন ) দেখুন। একটি সমাধান যা .bat ফাইলে কাজ করবে সেটিকে অগ্রাধিকার দেওয়া হয় তবে অন্যান্য সাধারণ উইন্ডোজ স্ক্রিপ্টিং সমাধানগুলিও স্বাগত।

Comments

জন, এই খুব দরকারী প্রশ্নটি পাওয়া হাস্যকর বিষয় hard তোমার মত বিকল্প বাচনভঙ্গীর উপরে নির্ভর যোগ বিবেচনা করুন গেল কিভাবে ক্যাপচার আউটপুট এএ এর প্রোগ্রাম উইন্ডোজ ব্যাচ ফাইল একটি পরিবর্তনশীল মধ্যে?

— পাইওটার ডব্রোগস্ট

গুগল এই পৃষ্ঠাটি তৃতীয় স্থানে প্রদর্শিত করেছে।

— রেনে নিনফেনিগার

উইন্ডোজ ব্যাচের

— মাইকেল ফ্রেইজিম

@ মিশেলফ্রিজেম এই নকলটির আগে 2 বছর আগে এই প্রশ্নটি জিজ্ঞাসা করা হয়েছিল - তবে এই প্রশ্নের একাধিক নকল রয়েছে। মন্তব্যগুলি দেখুন stackoverflow.com/questions/6359820/...

— icc97

@ আইসিসি ৯7, "সম্ভাব্য নকল" পরিষ্কার করার একটি উপায় - অনুরূপ প্রশ্নগুলি বন্ধ করতে এবং সর্বোত্তম উত্তরের সাথে একটি রাখার জন্য। তারিখটি অত্যাবশ্যক নয়। মেটা.স্ট্যাকেক্সেঞ্জঞ্জ / প্রশ্নগুলি / ১৪76464৩/২ দেখুন। আপনি যদি একমত হন যে এটির স্পষ্টকরণ দরকার তবে দয়া করে মেটা.স্ট্যাকেক্সচেঞ্জ / সেকশনস / ২৮৯৯৮০ / এ ভোট দিন আপনি যদি একাধিক সদৃশ দেখতে পান তবে আপনার উচিত একটি পছন্দ হিসাবে বেছে নেওয়া এবং অন্যকে বন্ধ করার জন্য ভোট দেওয়া ।

— মাইকেল ফ্রেইজিম

Answer 1

আপনাকে যদি সমস্ত কমান্ড আউটপুট ক্যাপচার করতে হয় তবে আপনি এই জাতীয় ব্যাচ ব্যবহার করতে পারেন:

@ECHO OFF
IF NOT "%1"=="" GOTO ADDV
SET VAR=
FOR /F %%I IN ('DIR *.TXT /B /O:D') DO CALL %0 %%I
SET VAR
GOTO END

:ADDV
SET VAR=%VAR%!%1

:END

সমস্ত আউটপুট লাইনগুলি "!" দিয়ে আলাদা করে ভিএআর-এ সংরক্ষণ করা হয়।

@ জন: এর কোন ব্যবহারিক ব্যবহার আছে কি? আমি মনে করি আপনার পাওয়ারশেল বা স্ক্রিপ্টিংয়ের কাজগুলি সহজেই সম্পাদন করতে সক্ষম এমন কোনও প্রোগ্রামিং ভাষা দেখতে হবে (পাইথন, পার্ল, পিএইচপি, রুবি)

Comments

একক লাইন উত্তর আমার নির্দিষ্ট ক্ষেত্রে সমাধান করবে। আমি ঠিক বুঝতে পেরেছিলাম যে সেখানে একটি বহু-লাইন বিকল্প (বা একটি সহজ একক লাইন বিকল্প) রয়েছে। আমি অনুমান করি ব্যাট ফাইলগুলির ক্ষমতা কেবল দুর্দান্ত নয়। এটির জন্য প্রয়োজন জাভা অ্যাপ্লিকেশনগুলি মোড়ানো ব্যাটার স্ক্রিপ্টগুলির। মূলত শ্রেণিপথ নির্মাণ।

— জন মেঘের

এটির সাথে খুব সাবধানতা অবলম্বন করুন। জিডাব্লুটিটি নির্দিষ্ট ক্লাসপাথ দিয়ে জাভা শুরু করার জন্য ব্যাচ ফাইলগুলি ব্যবহার করার চেষ্টাও করেছিল, যা আপনি অ-এসসিআইআই অক্ষরগুলির সাথে ডিরেক্টরিতে যাওয়ার সাথে সাথে ভয়ঙ্কর ব্যর্থ হন (সে ক্ষেত্রে এটি আমার বাড়ি ছিল :))। যেহেতু তারা ভিবিএস দিয়ে এটি পুনরায় লিখেছেন।

— জোয়

এই জন্য কোন ব্যবহারিক ব্যবহার আছে? তুমি কি মজা করছ? এটি অন্যান্য শেলগুলিতে সর্বদা ব্যবহৃত হয় (সমস্ত জিএনইউ / লিনাক্স যা আমি অনুমান করি) এবং এটি খুব দরকারী।

— পাইওটর ডব্রোগোস্ট

@ পাইওটারডব্রোগোস্ট আমি মনে করি তিনি যা বলতে চেয়েছিলেন তা হ'ল বাশ স্ক্রিপ্টগুলি অতীতের এক ভয়াবহ অবশেষ ( কোনও প্রোগ্রামের আউটপুট ক্যাপচার করার জন্য আপনাকে লুপের জন্য ব্যবহার করতে হবে ? সিরিয়াসলি?), এবং আপনি যদি কখনও বক্তব্যটি পেতে পারেন যেখানে আপনি নিজেকে ভেরিয়েবলগুলি ব্যবহার করার প্রয়োজন মনে করেন, আপনার পাওয়ারশেলের মতো আরও আধুনিক কিছু ব্যবহার করা উচিত।

— Ajedi32

একটি ব্যবহারিক ব্যবহার আছে, আসলে ... কিন্ডা। আমি একটি নির্দিষ্ট ভিজ্যুয়াল স্টুডিও পাথটি পাওয়ার জন্য পাওয়ারশেল স্ক্রিপ্টটি ব্যবহার করতে চাই, তবে যে পথটি আমার দরকার তা হ'ল একটি ব্যাচ ফাইল যা এনভ ভার্সের একটি সেট সেট করে যাতে আমি এডিটবিনকে কল করতে পারি ... সুতরাং আমাকে পথটি খুঁজে বের করতে হবে এবং এটির কলিং ইনস্ট্যান্সে ফিরে আসুন cmdযাতে আমি এটি সেখানে চালাতে পারি। ... হ্যাঁ, এটি শব্দের মতোই ভয়ঙ্কর। ভিজ্যুয়াল স্টুডিও আমাকে মাঝে মাঝে কাঁদতে চায়। @ আজেদী 32 আমি মনে করি আপনি বলতে চেয়েছিলেন যে ব্যাচের স্ক্রিপ্টগুলি অতীতের এক ভয়াবহ অবশেষ। ;)

— jpmc26

Answer 2

কমান্ডের জন্য নম্রতা কয়েক বছর ধরে কিছু আকর্ষণীয় ক্ষমতা জমা করেছে:

D:\> FOR /F "delims=" %i IN ('date /t') DO set today=%i
D:\> echo %today%
Sat 20/09/2008

নোট করুন যে "delims="ডিফল্ট স্থান এবং ট্যাব ডিলিমিটারগুলিকে ওভাররাইট করে যাতে ডেট কমান্ডের আউটপুট একসাথে সমস্ত গাব্বল হয়ে যায়।

মাল্টি-লাইন আউটপুট ক্যাপচার করতে, এটি এখনও মূলত এক-লাইনার হতে পারে (পরিবর্তিত এলএফটিকে ফলাফলের পরিবর্তনশীল হিসাবে ডিলিমিটার হিসাবে ব্যবহার করে):

REM NB:in a batch file, need to use %%i not %i
setlocal EnableDelayedExpansion
SET lf=-
FOR /F "delims=" %%i IN ('dir \ /b') DO if ("!out!"=="") (set out=%%i) else (set out=!out!%lf%%%i)
ECHO %out%

পাইপযুক্ত এক্সপ্রেশন ক্যাপচার করতে, ব্যবহার করুন ^|:

FOR /F "delims=" %%i IN ('svn info . ^| findstr "Root:"') DO set "URL=%%i"

Comments

@ পাবলোগের উত্তর হিসাবে, এটি কেবল এই ক্ষেত্রে "তারিখ / t" কমান্ড থেকে আউটপুটটির শেষ লাইনটি পেতে কাজ করবে।

— জন মেঘের

আমি যখন ডাবল শতাংশের চিহ্নগুলি ব্যবহার করেছি, তখনই আপনার কাজের উত্তরটি পেয়েছি, যেমনFOR /F "delims=" %%i IN ('date /t') DO set today=%%i

— রাব্রেডিসি

@ র্যাবডিশনকি: আপনি যদি forসরাসরি কমান্ড লাইনে একটি কমান্ড টাইপ করেন তবে আপনি একটি একক ব্যবহার করেন %। আপনি যদি এটি ব্যাচ ফাইলে ব্যবহার করেন তবে আপনি ব্যবহার করুন %%।

— indiv

@ টারডেট: আপনি দয়া করে বলতে পারেন যে স্ক্রিপ্টটি কেমন হবে, যদি কমান্ডটি দিয়ে %for /f "delims=" %%i in ('date +%F_%H-%M-%S') do set now=%%i

— তর্কটি

@ ডিজেনারেট কমান্ডটি বৈধ হয় যদি dateব্যবহৃত কমান্ডটি সাইগউইন থেকে আসে। আমি এটা উল্লেখ করা উচিত ছিল আমি সম্মত।

— dma_k

Answer 3

বর্তমান ডিরেক্টরিটি পেতে, আপনি এটি ব্যবহার করতে পারেন:

CD > tmpFile
SET /p myvar= < tmpFile
DEL tmpFile
echo test: %myvar%

এটি যদিও একটি টেম্প-ফাইল ব্যবহার করছে, তাই এটি সবচেয়ে সুন্দর নয়, তবে এটি অবশ্যই কার্যকর হয়! 'সিডি' বর্তমান ডিরেক্টরিটিকে 'টিএমপিফাইলে' রাখে, 'এসইটি' টিএমপিফায়ালের সামগ্রী লোড করে।

"অ্যারে'র সাথে একাধিক লাইনের সমাধান এখানে রয়েছে:

@echo off

rem ---------
rem Obtain line numbers from the file
rem ---------

rem This is the file that is being read: You can replace this with %1 for dynamic behaviour or replace it with some command like the first example i gave with the 'CD' command.
set _readfile=test.txt

for /f "usebackq tokens=2 delims=:" %%a in (`find /c /v "" %_readfile%`) do set _max=%%a
set /a _max+=1
set _i=0
set _filename=temp.dat

rem ---------
rem Make the list
rem ---------

:makeList
find /n /v "" %_readfile% >%_filename%

rem ---------
rem Read the list
rem ---------

:readList
if %_i%==%_max% goto printList

rem ---------
rem Read the lines into the array
rem ---------
for /f "usebackq delims=] tokens=2" %%a in (`findstr /r "\[%_i%]" %_filename%`) do set _data%_i%=%%a
set /a _i+=1
goto readList

:printList
del %_filename%
set _i=1
:printMore
if %_i%==%_max% goto finished
set _data%_i%
set /a _i+=1
goto printMore

:finished

তবে আপনি অন্য একটি শক্তিশালী শেল থেকে যাওয়ার বিষয়ে বিবেচনা করতে পারেন বা এই স্টাফের জন্য একটি অ্যাপ্লিকেশন তৈরি করতে পারেন। এটি ব্যাচ ফাইলগুলির সম্ভাবনাগুলি বেশ খানিকটা প্রসারিত করছে।

Comments

কমান্ড থেকে একাধিক লাইন ক্যাপচার কাজ করবে কি একটি প্রকরণ আছে?

— জন মেঘার

বর্তমান ডিরেক্টরি পেতে আপনি ইকো% সিডি% ব্যবহার করতে পারেন

— জো

Answer 4

আপনাকে SETপ্যারামিটার সহ কমান্ডটি ব্যবহার করতে হবে /Pএবং এতে আপনার আউটপুট পরিচালনা করতে হবে। উদাহরণস্বরূপ http://www.ss64.com/nt/set.html দেখুন । সিএমডির পক্ষে কাজ করবে, .BAT ফাইল সম্পর্কে নিশ্চিত নয়

এই পোস্টে একটি মন্তব্য থেকে:

এই লিঙ্কটি কমান্ড "আছে Set /P _MyVar=<MyFilename.txt" যা এটি সেট হবে বলে _MyVarথেকে প্রথম লাইন MyFilename.txt। এটি " myCmd > tmp.txt" সাথে " set /P myVar=<tmp.txt" হিসাবে ব্যবহার করা যেতে পারে । তবে এটি কেবল আউটপুটটির প্রথম লাইন পাবে, সমস্ত আউটপুট নয়

Comments

এই লিঙ্কটিতে "সেট / পি _মাইভায়ার = <মাইফিলনাম.টিএসটিএক্স" কমান্ড রয়েছে যা বলে যে এটি মাইফাইলেম.টিএসটিএসটি থেকে প্রথম লাইনে _ মাইভার সেট করবে। এটি "myCmd> tmp.txt" হিসাবে "সেট / পি myVar = <tmp.txt" ব্যবহার করা যেতে পারে। তবে এটি কেবল আউটপুটটির প্রথম লাইন পাবে, সমস্ত আউটপুট নয়।

— জন মেঘের

এই উত্তরটি আমার মতো

Answer 5

"ভি" এনভায়রনমেন্ট ভেরিয়েবল সর্বাধিক সাম্প্রতিক ফাইল সেট করার উদাহরণ

FOR /F %I IN ('DIR *.* /O:D /B') DO SET V=%I

ব্যাচ ফাইলে আপনাকে লুপ ভেরিয়েবলের দ্বৈত উপসর্গ ব্যবহার করতে হবে:

FOR /F %%I IN ('DIR *.* /O:D /B') DO SET V=%%I

Comments

আমি এই পদ্ধতির আগে দেখেছি, তবে এটি সত্যই হ্যাকি বলে মনে হচ্ছে। এটিরও সমস্যা রয়েছে যে এটি কেবল ভেরিয়েবলের কমান্ড থেকে আউটপুটের শেষ লাইনটি ক্যাপচার করবে।

— জন মেঘার

Answer 6

FORকমান্ড থেকে ফলাফলটি ব্যবহার করুন । উদাহরণস্বরূপ (একটি ব্যাচের ফাইলের অভ্যন্তরে):

for /F "delims=" %%I in ('dir /b /a-d /od FILESA*') do (echo %%I)

আপনি %%Iযে মানটি চান তা ব্যবহার করতে পারেন। শুধু ভালো: %%I।

এবং আগাম %%Iকোনও স্পেস বা সিআর অক্ষর নেই এবং তুলনার জন্য ব্যবহার করা যেতে পারে !!

Answer 7

আপনি যদি কমান্ডের ফলাফলটিকে ব্যাশে আর্গুমেন্ট হিসাবে ব্যবহার করে প্রদত্ত সমাধানটি সন্ধান করছেন ?

তারপরে কোডটি এখানে:

@echo off
if not "%1"=="" goto get_basename_pwd
for /f "delims=X" %%i in ('cd') do call %0 %%i
for /f "delims=X" %%i in ('dir /o:d /b') do echo %%i>>%filename%.txt
goto end

:get_basename_pwd
set filename=%~n1

:end

• এটি পিডাব্লুডির মতো সিডি কমান্ডের ফলাফলের সাথে নিজেকে কল করবে।
• প্যারামিটারগুলিতে স্ট্রিং এক্সট্রাকশন ফাইলের নাম / ফোল্ডারটি ফিরিয়ে দেবে।
• এই ফোল্ডারটির সামগ্রীগুলি পান এবং filename.txt এ যুক্ত হন

[ক্রেডিট] : অন্যান্য সমস্ত উত্তর এবং উইন্ডোজ এক্সপি কমান্ড পৃষ্ঠাগুলিতে কিছু খনন করার জন্য ধন্যবাদ ।

Answer 8

@echo off

ver | find "6.1." > nul
if %ERRORLEVEL% == 0 (
echo Win7
for /f "delims=" %%a in ('DIR "C:\Program Files\Microsoft Office\*Outlook.EXE" /B /P /S') do call set findoutlook=%%a
%findoutlook%
)

ver | find "5.1." > nul
if %ERRORLEVEL% == 0 (
echo WinXP
for /f "delims=" %%a in ('DIR "C:\Program Files\Microsoft Office\*Outlook.EXE" /B /P /S') do call set findoutlook=%%a
%findoutlook%
)
echo Outlook dir:  %findoutlook%
"%findoutlook%"

Comments

একটি উত্তর পোস্ট করার জন্য ধন্যবাদ! একটি কোড স্নিপেট এই প্রশ্নের উত্তর দিতে পারে, তবে আরও কিছু তথ্য প্রায় যেমন যুক্ত করা ইত্যাদি ব্যাখ্যা করা এখনও দুর্দান্ত

— j0k

Answer 9

আমি উপরের সমাধানগুলিতে একটি মন্তব্য যোগ করতে চাই:

এই সমস্ত বাক্যবিন্যাস পুরোপুরি ঠিকঠাকভাবে কাজ করে যদি আপনার আদেশটি পথের সাথে দেখা হয় বা যদি স্থানটি স্পেস বা বিশেষ বর্ণনাকারী ব্যতীত কোনও সেমিডপথ থাকে।

তবে যদি আপনি কোনও ফোল্ডারে কোনও এক্সিকিউটেবল কমান্ডটি ব্যবহার করার চেষ্টা করেন যা কোন পাথে বিশেষ অক্ষর রয়েছে তবে আপনার কমান্ডের পথটি ডাবল কোট (") এ আবদ্ধ করতে হবে এবং তারপরে ফর / এফ সিন্ট্যাক্স কাজ করবে না।

উদাহরণ:

$ for /f "tokens=* USEBACKQ" %f in (
    `""F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" Hello '"F:\GLW7\Distrib\System\Shells and scripting"'`
) do echo %f
The filename, directory name, or volume label syntax is incorrect.

অথবা

$ for /f "tokens=* USEBACKQ" %f in (
      `"F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe" "Hello World" "F:\GLW7\Distrib\System\Shells and scripting"`
) do echo %f
'F:\GLW7\Distrib\System\Shells' is not recognized as an internal or external command, operable program or batch file.

অথবা

`$ for /f "tokens=* USEBACKQ" %f in (
     `""F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" "Hello World" "F:\GLW7\Distrib\System\Shells and scripting"`
) do echo %f
'"F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" "Hello' is not recognized as an internal or external command, operable program or batch file.

সেক্ষেত্রে, কমান্ডটি ব্যবহার করতে এবং এর ফলাফলটি একটি ভেরিয়েবলের মধ্যে সঞ্চয় করার একমাত্র সমাধান হ'ল কমান্ডের মধ্যে একটিতে অস্থায়ীভাবে ডিফল্ট ডিরেক্টরি সেট করা:

pushd "%~d0%~p0"
FOR /F "tokens=* USEBACKQ" %%F IN (
    `FOLDERBROWSE "Hello world!" "F:\GLW7\Distrib\System\Layouts (print,display...)"`
) DO (SET MyFolder=%%F)
popd
echo My selected folder: %MyFolder%

ফলাফলটি তখন সঠিক:

My selected folder: F:\GLW7\Distrib\System\OS install, recovery, VM\
Press any key to continue . . .

অবশ্যই উপরের উদাহরণে, আমি ধরে নিয়েছি যে আমার ব্যাচ স্ক্রিপ্টটি আমার নির্বাহযোগ্য কমান্ডের মধ্যে একটির মতো একই ফোল্ডারে রয়েছে যাতে আমি "% ~ d0% ~ p0" সিনট্যাক্সটি ব্যবহার করতে পারি। যদি এটি আপনার ক্ষেত্রে না হয় তবে আপনার কমান্ডের পথটি সনাক্ত করতে এবং ডিফল্ট ডিরেক্টরিটিকে তার পথে পরিবর্তন করতে হবে।

নোট: যারা অবাক করে তাদের জন্য, এখানে ব্যবহৃত স্যাম্পল কমান্ডটি (একটি ফোল্ডার নির্বাচন করতে) হ'ল FOLDERBROWSE.EXE। আমি এটি ওয়েবসাইটে f2ko.de ( http://f2ko.de/en/cmd.php ) এ পেয়েছি ।

জটিল পথ দিয়ে অ্যাক্সেসযোগ্য এই জাতীয় নির্দেশের জন্য কারও কাছে যদি আরও ভাল সমাধান থাকে তবে আমি এটি শুনে খুব আনন্দিত হব।

গিলেজ

Comments

আপনি আপনার কমান্ডটির সাথে উপসর্গ করতে পারেন CALL। পথের ফাঁকা জায়গা থাকলে ফর / এফ কাজ করে না

— jeb

@ জেব: আপনাকে অনেক ধন্যবাদ! এখন আমার কোড < CALL "%SOURCEDIR%\FOLDERBROWSE" ... "quoted parameters"> নিখুঁতভাবে কাজ করে।

— গিলস মাইসনিউভে

Answer 10

আপনি সমস্ত আউটপুটকে একটি ভেরিয়েবলে ক্যাপচার করতে পারেন, তবে লাইনগুলি আপনার পছন্দসই একটি অক্ষর দ্বারা পৃথক করা হবে (নীচের উদাহরণে # প্রকৃত সিআর-এলএফের পরিবর্তে)।

@echo off
setlocal EnableDelayedExpansion
for /f "delims=" %%i in ('dir /b') do (
    if "!DIR!"=="" (set DIR=%%i) else (set DIR=!DIR!#%%i)
)
echo directory contains:
echo %DIR%

দ্বিতীয় সংস্করণ, যদি আপনার সামগ্রীতে লাইন-বাই-লাইনে প্রিন্ট করতে হয়। এটি "dir / b" থেকে আউটপুট সদৃশ লাইন থাকবে না এই সত্যটি অগ্রসর হয় তাই সাধারণ ক্ষেত্রে এটি কাজ নাও করতে পারে।

@echo off
setlocal EnableDelayedExpansion
set count=0
for /f "delims=" %%i in ('dir /b') do (
    if "!DIR!"=="" (set DIR=%%i) else (set DIR=!DIR!#%%i)
    set /a count = !count! + 1
)

echo directory contains:
echo %DIR%

for /l %%c in (1,1,%count%) do (
    for /f "delims=#" %%i in ("!DIR!") do (
        echo %%i
        set DIR=!DIR:%%i=!
    )
)

Answer 11

@echo off
setlocal EnableDelayedExpansion
FOR /F "tokens=1 delims= " %%i IN ('echo hola') DO (
    set TXT=%%i
)
echo 'TXT: %TXT%'

ফলাফলটি 'টিএক্সটি: হোলা'

Answer 12

আপনার forকমান্ডটি ব্যবহার করা উচিত , এখানে একটি উদাহরণ রয়েছে:

@echo off
rem Commands go here
exit /b
:output
for /f "tokens=* useback" %%a in (`%~1`) do set "output=%%a"

এবং আপনি ব্যবহার করতে পারেন call :output "Command goes here"তবে আউটপুটটি %output%ভেরিয়েবলের মধ্যে থাকবে।

দ্রষ্টব্য: যদি আপনার কাছে কোনও কমান্ড আউটপুট থাকে যা মাল্টলাইন থাকে তবে এই সরঞ্জামটি setআপনার মাল্টলাইনাল কমান্ডের শেষ লাইনে আউটপুট দেবে।

Answer 13

দয়া করে এই http://technet.microsoft.com/en-us/library/bb490982.aspx দেখুন যা আপনাকে কমান্ড আউটপুট দিয়ে কী করতে পারে তা ব্যাখ্যা করে।

Comments

এই নিবন্ধটি পুনঃনির্দেশ এবং সম্পর্কিত বিষয়গুলি কভার করে। এটি কীভাবে একটি কমান্ডের আউটপুট নেবে এবং এটিকে ভেরিয়েবলে নিয়ে যায় সে প্রশ্নের উত্তর দেয় না।

— জন মেঘার

তার উত্তরটি ব্যবহার করে আমি এগুলি নিয়ে এসেছি: git pull>0 set /P RESULTVAR=<0 সম্পাদনা: আমার ধারণা, এখানে লাইন ব্রেকগুলি কীভাবে ব্যবহার করতে হয় তা আমি জানি না ... প্রতিটি কমান্ড তার নিজস্ব লাইনে রয়েছে।

— রিবেইরোব্রেনো