আমি পাইপলাইনযুক্ত টেবিল ফাংশনটি ব্যবহার করে একটি ভিন্ন পদ্ধতির প্রস্তাব করতে চাই। এটি কিছুটা XMLTABLE এর কৌশলটির সাথে সমান, আপনি অক্ষরের স্ট্রিংকে বিভক্ত করার জন্য নিজস্ব কাস্টম ফাংশন সরবরাহ করছেন তা বাদ দিয়ে:
-- Create a collection type to hold the results
CREATE OR REPLACE TYPE typ_str2tbl_nst AS TABLE OF VARCHAR2(30);
/
-- Split the string according to the specified delimiter
CREATE OR REPLACE FUNCTION str2tbl (
p_string VARCHAR2,
p_delimiter CHAR DEFAULT ','
)
RETURN typ_str2tbl_nst PIPELINED
AS
l_tmp VARCHAR2(32000) := p_string || p_delimiter;
l_pos NUMBER;
BEGIN
LOOP
l_pos := INSTR( l_tmp, p_delimiter );
EXIT WHEN NVL( l_pos, 0 ) = 0;
PIPE ROW ( RTRIM( LTRIM( SUBSTR( l_tmp, 1, l_pos-1) ) ) );
l_tmp := SUBSTR( l_tmp, l_pos+1 );
END LOOP;
END str2tbl;
/
-- The problem solution
SELECT name,
project,
TRIM(COLUMN_VALUE) error
FROM t, TABLE(str2tbl(error));
ফলাফল:
NAME PROJECT ERROR
---------- ---------- --------------------
108 test Err1
108 test Err2
108 test Err3
109 test2 Err1
এই ধরণের পদ্ধতির সমস্যাটি হ'ল প্রায়শই অপ্টিমাইজার টেবিলের ক্রিয়াকলাপের কার্ডিনালিটিটি জানতে পারে না এবং এটি অনুমান করতে হবে। এটি আপনার কার্যকরকরণ পরিকল্পনার পক্ষে ক্ষতিকারক ক্ষতিকারক হতে পারে, সুতরাং এই সমাধানটি অপ্টিমাইজারের জন্য কার্যকরকরণের পরিসংখ্যান সরবরাহ করতে বাড়ানো যেতে পারে।
আপনি উপরের ক্যোয়ারিতে একটি এক্সপ্ল্যান প্ল্যান চালিয়ে এই অপ্টিমাইজারের প্রাক্কলনটি দেখতে পারেন:
Execution Plan
----------------------------------------------------------
Plan hash value: 2402555806
----------------------------------------------------------------------------------------------
| Id | Operation | Name | Rows | Bytes | Cost (%CPU)| Time |
----------------------------------------------------------------------------------------------
| 0 | SELECT STATEMENT | | 16336 | 366K| 59 (0)| 00:00:01 |
| 1 | NESTED LOOPS | | 16336 | 366K| 59 (0)| 00:00:01 |
| 2 | TABLE ACCESS FULL | T | 2 | 42 | 3 (0)| 00:00:01 |
| 3 | COLLECTION ITERATOR PICKLER FETCH| STR2TBL | 8168 | 16336 | 28 (0)| 00:00:01 |
----------------------------------------------------------------------------------------------
যদিও সংগ্রহের কেবল 3 টি মান রয়েছে, অপ্টিমাইজারটির পক্ষে 8168 সারি অনুমান করা হয়েছে (ডিফল্ট মান)। এটি প্রথমে অপ্রাসঙ্গিক বলে মনে হতে পারে, তবে উপ-অনুকূল পরিকল্পনার সিদ্ধান্ত নেওয়ার জন্য এটি অপ্টিমাইজারের পক্ষে যথেষ্ট।
সমাধানটি সংগ্রহের পরিসংখ্যান সরবরাহ করার জন্য অপ্টিমাইজার এক্সটেনশানগুলি ব্যবহার করা হয়:
-- Create the optimizer interface to the str2tbl function
CREATE OR REPLACE TYPE typ_str2tbl_stats AS OBJECT (
dummy NUMBER,
STATIC FUNCTION ODCIGetInterfaces ( p_interfaces OUT SYS.ODCIObjectList )
RETURN NUMBER,
STATIC FUNCTION ODCIStatsTableFunction ( p_function IN SYS.ODCIFuncInfo,
p_stats OUT SYS.ODCITabFuncStats,
p_args IN SYS.ODCIArgDescList,
p_string IN VARCHAR2,
p_delimiter IN CHAR DEFAULT ',' )
RETURN NUMBER
);
/
-- Optimizer interface implementation
CREATE OR REPLACE TYPE BODY typ_str2tbl_stats
AS
STATIC FUNCTION ODCIGetInterfaces ( p_interfaces OUT SYS.ODCIObjectList )
RETURN NUMBER
AS
BEGIN
p_interfaces := SYS.ODCIObjectList ( SYS.ODCIObject ('SYS', 'ODCISTATS2') );
RETURN ODCIConst.SUCCESS;
END ODCIGetInterfaces;
-- This function is responsible for returning the cardinality estimate
STATIC FUNCTION ODCIStatsTableFunction ( p_function IN SYS.ODCIFuncInfo,
p_stats OUT SYS.ODCITabFuncStats,
p_args IN SYS.ODCIArgDescList,
p_string IN VARCHAR2,
p_delimiter IN CHAR DEFAULT ',' )
RETURN NUMBER
AS
BEGIN
-- I'm using basically half the string lenght as an estimator for its cardinality
p_stats := SYS.ODCITabFuncStats( CEIL( LENGTH( p_string ) / 2 ) );
RETURN ODCIConst.SUCCESS;
END ODCIStatsTableFunction;
END;
/
-- Associate our optimizer extension with the PIPELINED function
ASSOCIATE STATISTICS WITH FUNCTIONS str2tbl USING typ_str2tbl_stats;
ফলাফল কার্যকরকরণ পরিকল্পনা পরীক্ষা করা:
Execution Plan
----------------------------------------------------------
Plan hash value: 2402555806
----------------------------------------------------------------------------------------------
| Id | Operation | Name | Rows | Bytes | Cost (%CPU)| Time |
----------------------------------------------------------------------------------------------
| 0 | SELECT STATEMENT | | 1 | 23 | 59 (0)| 00:00:01 |
| 1 | NESTED LOOPS | | 1 | 23 | 59 (0)| 00:00:01 |
| 2 | TABLE ACCESS FULL | T | 2 | 42 | 3 (0)| 00:00:01 |
| 3 | COLLECTION ITERATOR PICKLER FETCH| STR2TBL | 1 | 2 | 28 (0)| 00:00:01 |
----------------------------------------------------------------------------------------------
আপনি দেখতে পাচ্ছেন যে উপরের পরিকল্পনায় কার্ডিনালিটিটি 8196 অনুমান করা মান নয়। এটি এখনও সঠিক নয় কারণ আমরা ফাংশনে স্ট্রিংয়ের পরিবর্তে একটি কলামটি পাস করছি।
এই বিশেষ ক্ষেত্রে একটি ঘনিষ্ঠ প্রাক্কলন দেওয়ার জন্য ফাংশন কোডটিতে কিছু টুইট করা প্রয়োজন, তবে আমি মনে করি সামগ্রিক ধারণাটি এখানে বেশ সুন্দরভাবে ব্যাখ্যা করা হয়েছে।
এই উত্তরে ব্যবহৃত str2tbl ফাংশনটি মূলত টম কিট দ্বারা বিকাশ করা হয়েছিল:
https
অবজেক্টের ধরণের সাথে পরিসংখ্যানকে যুক্ত করার ধারণাটি এই নিবন্ধটি পড়ে আরও অনুসন্ধান করা যেতে পারে:
http://www.oracle-developer.net/display.php?id=427
এখানে বর্ণিত কৌশলটি 10 গ্রাম + এ কাজ করে।
REGEXP, ওরাকল এসকিউএল ব্যবহার করে একটি টেবিলের মধ্যে স্প্লিট কমা সীমানাঙ্কিত স্ট্রিং দেখুনXMLTABLEMODEL