এসকিউএল সার্ভার ম্যানেজমেন্ট স্টুডিও ২০০৮-এর সমস্ত সারণী অনুসন্ধান করে একটি স্ট্রিং সন্ধান করুন

Question

এসকিউএল সার্ভার ম্যানেজমেন্ট স্টুডিও ২০০৮-তে কোনও ডাটাবেসের সমস্ত টেবিলের স্ট্রিং অনুসন্ধানের কোনও উপায় আছে কি?

আমি স্ট্রিং বলতে অনুসন্ধান করতে চাই john। ফলাফলটি এতে থাকা সারণী এবং তাদের নিজ নিজ সারিতে প্রদর্শিত হবে john।

Comments

সমস্ত টেবিল অনুসন্ধানের

— মাহমুদ গামাল

এসকিউএল সার্ভার ডেটাবেস-এর যে কোনও জায়গায় আমি কোনও মান খুঁজে

— জোনাথন লেফলার

phpmyadmin এটিকে খুব সহজভাবে অনুমতি দেয়

— Matoeil

Answer 1

আপনি যদি আমার মতো হন এবং একটি উত্পাদন পরিবেশে কিছু নির্দিষ্ট বিধিনিষেধ থাকে তবে আপনি টেম্প টেবিলের পরিবর্তে একটি টেবিল পরিবর্তনশীল এবং কোনও তৈরি প্রক্রিয়া না করে অ্যাড-হক ক্যোয়ারী ব্যবহার করতে চাইতে পারেন।

অবশ্যই আপনার এসকিউএল সার্ভারের উদাহরণের উপর নির্ভর করে এটি অবশ্যই সারণী ভেরিয়েবলগুলিকে সমর্থন করবে।

আমি অনুসন্ধানের সুযোগকে সংকুচিত করতে একটি ইউএসই বিবৃতি যুক্ত করেছি

USE DATABASE_NAME
DECLARE @SearchStr nvarchar(100) = 'SEARCH_TEXT'
DECLARE @Results TABLE (ColumnName nvarchar(370), ColumnValue nvarchar(3630))

SET NOCOUNT ON

DECLARE @TableName nvarchar(256), @ColumnName nvarchar(128), @SearchStr2 nvarchar(110)
SET  @TableName = ''
SET @SearchStr2 = QUOTENAME('%' + @SearchStr + '%','''')

WHILE @TableName IS NOT NULL

BEGIN
    SET @ColumnName = ''
    SET @TableName = 
    (
        SELECT MIN(QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME))
        FROM     INFORMATION_SCHEMA.TABLES
        WHERE         TABLE_TYPE = 'BASE TABLE'
            AND    QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME) > @TableName
            AND    OBJECTPROPERTY(
                    OBJECT_ID(
                        QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME)
                         ), 'IsMSShipped'
                           ) = 0
    )

    WHILE (@TableName IS NOT NULL) AND (@ColumnName IS NOT NULL)

    BEGIN
        SET @ColumnName =
        (
            SELECT MIN(QUOTENAME(COLUMN_NAME))
            FROM     INFORMATION_SCHEMA.COLUMNS
            WHERE         TABLE_SCHEMA    = PARSENAME(@TableName, 2)
                AND    TABLE_NAME    = PARSENAME(@TableName, 1)
                AND    DATA_TYPE IN ('char', 'varchar', 'nchar', 'nvarchar', 'int', 'decimal')
                AND    QUOTENAME(COLUMN_NAME) > @ColumnName
        )

        IF @ColumnName IS NOT NULL

        BEGIN
            INSERT INTO @Results
            EXEC
            (
                'SELECT ''' + @TableName + '.' + @ColumnName + ''', LEFT(' + @ColumnName + ', 3630) 
                FROM ' + @TableName + ' (NOLOCK) ' +
                ' WHERE ' + @ColumnName + ' LIKE ' + @SearchStr2
            )
        END
    END    
END

SELECT ColumnName, ColumnValue FROM @Results

Comments

অসাধারণ. আমি "PRINT @ টেবিলনাম + '' যুক্ত করেছি। ' 53 @ লাইনে + @ কলমনাম ", যাতে এটি আমার বড় ডাটাবেসের মাধ্যমে কাজ করার কারণে আমি কিছু স্থিতি পেতে পারি। তবে এটি খুব সহায়ক।

— প্রোভেগা

ধন্যবাদ! একটি পুরানো আইন অনুসন্ধান করেছেন! সিআরএম ডাটাবেস সহজ, যেখানে ফিল্ডন স্ক্রিনটি ছিল "কোম্পানী রেজি" এবং ডাটাবেস ক্ষেত্রটি ছিল "টিক্সারসিম্বল" তবে যে আগমন ঘটেছিল! লোল

— লিয়াম হিল্ডন

আমি কীভাবে ফলাফলের সাথে প্রাথমিক কীগুলি আনতে পারি? কোনও সহায়তা

— দুপিন্দর সিং

Answer 2

কিছুটা দেরি হলেও আশা করি দরকারী।

তৃতীয় পক্ষের কিছু সরঞ্জাম কেন চেষ্টা করবেন না যা এসএসএমএসে সংহত করা যায়।

আমি সঙ্গে কাজ করেছি ApexSQL অনুসন্ধান উভয় স্কিমা এবং তথ্য অনুসন্ধান ও সেখানে জন্য ভাল সাফল্যের সঙ্গে (100 বিনামূল্যে%) SSMS সরঞ্জাম প্যাক যে এই বৈশিষ্ট্যটি (এসকিউএল 2012 জন্য বিনামূল্যে কিন্তু বেশ সাশ্রয়ী) আছে।

উপরের সঞ্চিত পদ্ধতিটি সত্যিই দুর্দান্ত; এটা ঠিক যে এটি আমার মতে আরও সুবিধাজনক। এছাড়াও, যদি আপনি ডেটটাইম কলাম বা জিইউইডি কলাম এবং এর জন্য অনুসন্ধান করতে চান তবে কিছুটা সামান্য পরিবর্তন প্রয়োজন require

Answer 3

এসকিউএল সার্ভার ২০১২-এর জন্য টেকডোর জবাব আপডেট করতে । আপনাকে পরিবর্তন করতে হবে: 'FROM ' + @TableName + ' (NOLOCK) ' থেকে FROM ' + @TableName + 'WITH (NOLOCK) ' +

অন্যান্য জ্ঞানী আপনি নিম্নলিখিত ত্রুটি পাবেন: Deprecated feature 'Table hint without WITH' is not supported in this version of SQL Server.

নীচে সম্পূর্ণ আপডেট হওয়া সঞ্চিত প্রক্রিয়াটি রয়েছে:

CREATE PROC SearchAllTables
(
@SearchStr nvarchar(100)
)
AS
BEGIN

    CREATE TABLE #Results (ColumnName nvarchar(370), ColumnValue nvarchar(3630))

    SET NOCOUNT ON

    DECLARE @TableName nvarchar(256), @ColumnName nvarchar(128), @SearchStr2 nvarchar(110)
    SET  @TableName = ''
    SET @SearchStr2 = QUOTENAME('%' + @SearchStr + '%','''')

    WHILE @TableName IS NOT NULL

    BEGIN
        SET @ColumnName = ''
        SET @TableName = 
        (
            SELECT MIN(QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME))
            FROM     INFORMATION_SCHEMA.TABLES
            WHERE         TABLE_TYPE = 'BASE TABLE'
                AND    QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME) > @TableName
                AND    OBJECTPROPERTY(
                        OBJECT_ID(
                            QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME)
                             ), 'IsMSShipped'
                               ) = 0
        )

        WHILE (@TableName IS NOT NULL) AND (@ColumnName IS NOT NULL)

        BEGIN
            SET @ColumnName =
            (
                SELECT MIN(QUOTENAME(COLUMN_NAME))
                FROM     INFORMATION_SCHEMA.COLUMNS
                WHERE         TABLE_SCHEMA    = PARSENAME(@TableName, 2)
                    AND    TABLE_NAME    = PARSENAME(@TableName, 1)
                    AND    DATA_TYPE IN ('char', 'varchar', 'nchar', 'nvarchar', 'int', 'decimal')
                    AND    QUOTENAME(COLUMN_NAME) > @ColumnName
            )

            IF @ColumnName IS NOT NULL

            BEGIN
                INSERT INTO #Results
                EXEC
                (
                    'SELECT ''' + @TableName + '.' + @ColumnName + ''', LEFT(' + @ColumnName + ', 3630) 
                    FROM ' + @TableName + 'WITH (NOLOCK) ' +
                    ' WHERE ' + @ColumnName + ' LIKE ' + @SearchStr2
                )
            END
        END    
    END

    SELECT ColumnName, ColumnValue FROM #Results
END

Answer 4

কিছুটা দেরি হলেও আপনি সহজেই এই ক্যোয়ারির সাথে একটি স্ট্রিং খুঁজে পেতে পারেন

DECLARE
@search_string  VARCHAR(100),
@table_name     SYSNAME,
@table_id       INT,
@column_name    SYSNAME,
@sql_string     VARCHAR(2000)

SET @search_string = 'StringtoSearch'

DECLARE tables_cur CURSOR FOR SELECT ss.name +'.'+ so.name [name], object_id FROM sys.objects so INNER JOIN sys.schemas ss ON so.schema_id = ss.schema_id WHERE  type = 'U'

OPEN tables_cur

FETCH NEXT FROM tables_cur INTO @table_name, @table_id

WHILE (@@FETCH_STATUS = 0)
BEGIN
    DECLARE columns_cur CURSOR FOR SELECT name FROM sys.columns WHERE object_id = @table_id 
        AND system_type_id IN (167, 175, 231, 239)

    OPEN columns_cur

    FETCH NEXT FROM columns_cur INTO @column_name
        WHILE (@@FETCH_STATUS = 0)
        BEGIN
            SET @sql_string = 'IF EXISTS (SELECT * FROM ' + @table_name + ' WHERE [' + @column_name + '] 
            LIKE ''%' + @search_string + '%'') PRINT ''' + @table_name + ', ' + @column_name + ''''

            EXECUTE(@sql_string)

        FETCH NEXT FROM columns_cur INTO @column_name
        END

    CLOSE columns_cur

DEALLOCATE columns_cur

FETCH NEXT FROM tables_cur INTO @table_name, @table_id
END

CLOSE tables_cur
DEALLOCATE tables_cur

Comments

এই স্ক্রিপ্টটি ব্যর্থ হয় যখন কোনও টেবিলের স্কিমা "ডিবিও" না হয় দুর্ভাগ্যবশত ডিবিতে থাকা বেশিরভাগ টেবিলের আলাদা আলাদা স্কিমা থাকে। "ডিবিও" দম্পতির জন্য ভাল কাজ করে।

— রব

স্কিমাস টেবিলটিতে সবেমাত্র প্রাথমিক কার্সারটি INNER JOIN এ সম্পাদিত হয়েছে তাই এখন এটি ব্যবহারের ক্ষেত্রে টেবিলে স্কিমাটি নেই to

— ছিনতাই করুন

আমি বর্তমানে সমস্ত xML ক্ষেত্রকে উপেক্ষা করে অনুসন্ধান করার জন্য সিস্টেম_প্রকারের তালিকায় 99 (ntext) যুক্ত করেছি। `এবং system_type_id ইন (167, 175, 231, 239, 99)`

— ডাকাতি

Answer 5

আমি এর জন্য একটি এসপি লিখেছি যা সারণীর নাম, কলামের নামগুলিতে সন্ধানের কীওয়ার্ড স্ট্রিংয়ের সন্ধানের পাশাপাশি নীচের স্ক্রিন শটটিতে বর্ণিত অনুরূপ সারিগুলি অনুসন্ধান করে সন্ধানের ফলাফলগুলি ফর্ম ফেরত দেয় returns

এটি সবচেয়ে কার্যকর সমাধান নাও হতে পারে তবে আপনি সর্বদা এটি আপনার প্রয়োজন অনুসারে সংশোধন করতে এবং ব্যবহার করতে পারেন।

IF OBJECT_ID('sp_KeywordSearch', 'P') IS NOT NULL
    DROP PROC sp_KeywordSearch
GO

CREATE PROCEDURE sp_KeywordSearch @KeyWord NVARCHAR(100)
AS
BEGIN
    DECLARE @Result TABLE
        (TableName NVARCHAR(300),
         ColumnName NVARCHAR(MAX))

    DECLARE @Sql NVARCHAR(MAX),
        @TableName NVARCHAR(300),
        @ColumnName NVARCHAR(300),
        @Count INT

    DECLARE @tableCursor CURSOR

    SET @tableCursor = CURSOR LOCAL SCROLL FOR
    SELECT  N'SELECT @Count = COUNT(1) FROM [dbo].[' + T.TABLE_NAME + '] WITH (NOLOCK) WHERE CAST([' + C.COLUMN_NAME +
            '] AS NVARCHAR(MAX)) LIKE ''%' + @KeyWord + N'%''',
            T.TABLE_NAME,
            C.COLUMN_NAME
    FROM    INFORMATION_SCHEMA.TABLES AS T WITH (NOLOCK)
    INNER JOIN INFORMATION_SCHEMA.COLUMNS AS C WITH (NOLOCK)
    ON      T.TABLE_SCHEMA = C.TABLE_SCHEMA AND
            T.TABLE_NAME = C.TABLE_NAME
    WHERE   T.TABLE_TYPE = 'BASE TABLE' AND
            C.TABLE_SCHEMA = 'dbo' AND
            C.DATA_TYPE NOT IN ('image', 'timestamp')

    OPEN @tableCursor
    FETCH NEXT FROM @tableCursor INTO @Sql, @TableName, @ColumnName

    WHILE (@@FETCH_STATUS = 0)
    BEGIN
        SET @Count = 0

        EXEC sys.sp_executesql
            @Sql,
            N'@Count INT OUTPUT',
            @Count OUTPUT

        IF @Count > 0
        BEGIN
            INSERT  INTO @Result
                    (TableName, ColumnName)
            VALUES  (@TableName, @ColumnName)
        END

        FETCH NEXT FROM @tableCursor INTO @Sql, @TableName, @ColumnName
    END

    CLOSE @tableCursor
    DEALLOCATE @tableCursor

    SET @tableCursor = CURSOR LOCAL SCROLL FOR
    SELECT  SUBSTRING(TB.Sql, 1, LEN(TB.Sql) - 3) AS Sql, TB.TableName, SUBSTRING(TB.Columns, 1, LEN(TB.Columns) - 1) AS Columns
    FROM    (SELECT R.TableName, (SELECT R2.ColumnName + ', ' FROM @Result AS R2 WHERE R.TableName = R2.TableName FOR XML PATH('')) AS Columns,
                    'SELECT * FROM ' + R.TableName + ' WITH (NOLOCK) WHERE ' +
                    (SELECT 'CAST(' + R2.ColumnName + ' AS NVARCHAR(MAX)) LIKE ''%' + @KeyWord + '%'' OR '
                     FROM   @Result AS R2
                     WHERE  R.TableName = R2.TableName
                    FOR
                     XML PATH('')) AS Sql
             FROM   @Result AS R
             GROUP BY R.TableName) TB
    ORDER BY TB.Sql

    OPEN @tableCursor
    FETCH NEXT FROM @tableCursor INTO @Sql, @TableName, @ColumnName

    WHILE (@@FETCH_STATUS = 0)
    BEGIN
        PRINT @Sql
        SELECT  @TableName AS [Table],
                @ColumnName AS Columns
        EXEC(@Sql)

        FETCH NEXT FROM @tableCursor INTO @Sql, @TableName, @ColumnName
    END

    CLOSE @tableCursor
    DEALLOCATE @tableCursor

END

Comments

আমাদের অনুসন্ধানের স্ট্রিং কোথায় সংজ্ঞায়িত করবেন?

— দুপিন্দর সিং

Answer 6

নেস্টেড লুপিংয়ের দরকার নেই (সমস্ত টেবিল কলামের মাধ্যমে টেবিলগুলির মাধ্যমে বাইরের লুপিং এবং অভ্যন্তরীণ লুপিং)। যে কোনও একটি থেকে সমস্ত (বা নির্বিচারে নির্বাচিত / ফিল্টার করা) সারণী-কলামের সংমিশ্রণগুলি পুনরুদ্ধার করতে পারে INFORMATION_SCHEMA.COLUMNSএবং একটি লুপে কেবল সেগুলির মধ্য দিয়ে যায় (অনুসন্ধান):

DECLARE @search VARCHAR(100), @table SYSNAME, @column SYSNAME

DECLARE curTabCol CURSOR FOR
    SELECT c.TABLE_SCHEMA + '.' + c.TABLE_NAME, c.COLUMN_NAME
    FROM INFORMATION_SCHEMA.COLUMNS c
    JOIN INFORMATION_SCHEMA.TABLES t 
      ON t.TABLE_NAME=c.TABLE_NAME AND t.TABLE_TYPE='BASE TABLE' -- avoid views
    WHERE c.DATA_TYPE IN ('varchar','nvarchar') -- searching only in these column types
    --AND c.COLUMN_NAME IN ('NAME','DESCRIPTION') -- searching only in these column names

SET @search='john'

OPEN curTabCol
FETCH NEXT FROM curTabCol INTO @table, @column

WHILE (@@FETCH_STATUS = 0)
BEGIN
    EXECUTE('IF EXISTS 
             (SELECT * FROM ' + @table + ' WHERE ' + @column + ' = ''' + @search + ''') 
             PRINT ''' + @table + '.' + @column + '''')
    FETCH NEXT FROM curTabCol INTO @table, @column
END

CLOSE curTabCol
DEALLOCATE curTabCol

Comments

আপনি কী বলতে চাইছেন তা আমি জানি না, তবে এই ক্যোয়ারীটি ভাল কাজ করে। কার্সারটি curTabColসমস্ত টেবিলের জন্য পছন্দ করে তোলে ol তারপরে ভেরিয়েবল @ সন্ধানে স্ট্রিংয়ের জন্য এই সমস্ত কলাম অনুসন্ধান করে। যদি এই এসকিউএল ক্যোয়ারীতে যেমন একটি স্ট্রিং (সঠিক) উপস্থিত থাকে (অন্যথায় '% ...%' পছন্দ করুন), সারণী এবং কলামের নাম সংমিশ্রণটি মুদ্রিত হবে।

— sbrbot

Answer 7

এটি খুব সহায়ক ছিল। আমি এই পোস্টটি একটি পোস্টগ্রি এসকিউএল ডাটাবেসে আমদানি করতে চেয়েছিলাম। ভেবেছিলাম আমি আগ্রহী যে কারও সাথে এটি ভাগ করব। তাদের কয়েক ঘন্টা থাকবে। দ্রষ্টব্য: এই ফাংশনটি এসকিউএল স্টেটমেন্টগুলির একটি তালিকা তৈরি করে যা পোস্টগ্রি ডাটাবেসে অনুলিপি এবং সম্পাদন করা যায়। সম্ভবত কেউ স্মার্ট তখন আমার পোস্টগ্র্রে পেতে সমস্ত ফাংশনে স্টেটমেন্টগুলি তৈরি এবং কার্যকর করতে পারে।

CREATE OR REPLACE FUNCTION SearchAllTables(_search text) RETURNS TABLE( txt text ) as $funct$
    DECLARE __COUNT int;
    __SQL text;
BEGIN
    EXECUTE 'SELECT COUNT(0) FROM INFORMATION_SCHEMA.COLUMNS
                    WHERE    DATA_TYPE = ''text'' 
                    AND          table_schema = ''public'' ' INTO __COUNT;

    RETURN QUERY 
        SELECT CASE WHEN ROW_NUMBER() OVER (ORDER BY table_name) < __COUNT THEN 
            'SELECT ''' || table_name ||'.'|| column_name || ''' AS tbl, "'  || column_name || '" AS col FROM "public"."' || "table_name" || '" WHERE "'|| "column_name" || '" ILIKE ''%' || _search  || '%'' UNION ALL' 
            ELSE 
            'SELECT ''' || table_name ||'.'|| column_name || ''' AS tbl, "'  || column_name || '" AS col FROM "public"."' || "table_name" || '" WHERE "'|| "column_name" || '" ILIKE ''%' || _search  || '%'''
        END AS txt

                    FROM     INFORMATION_SCHEMA.COLUMNS
                    WHERE    DATA_TYPE = 'text' 
                    AND          table_schema = 'public';
END
$funct$ LANGUAGE plpgsql;

Answer 8

এই পোস্টে ইতিমধ্যে বেশ কয়েকবার যে উত্তরটি উল্লেখ করা হয়েছিল আমি কিছুটা গ্রহণ করেছি কারণ আমার কেবল একটি টেবিলে অনুসন্ধান করার দরকার ছিল:

(এবং টেবিলের নামের জন্য কিছুটা আরও সহজ ইনপুট তৈরি করা হয়েছে)

ALTER PROC dbo.db_compare_SearchAllTables_sp
(
    @SearchStr nvarchar(100),
    @TableName nvarchar(256) = ''
)
AS
BEGIN
        if PARSENAME(@TableName, 2) is null
            set @TableName = 'dbo.' + QUOTENAME(@TableName, '"')

    declare @results TABLE(ColumnName nvarchar(370), ColumnValue nvarchar(3630))

    SET NOCOUNT ON

    DECLARE @ColumnName nvarchar(128) = '', @SearchStr2 nvarchar(110)
    SET @SearchStr2 = QUOTENAME('%' + @SearchStr + '%','''')
        IF @TableName <> ''
        WHILE (@TableName IS NOT NULL) AND (@ColumnName IS NOT NULL)
        BEGIN
            SET @ColumnName =
            (
                SELECT MIN(QUOTENAME(COLUMN_NAME))
                FROM     INFORMATION_SCHEMA.COLUMNS
                WHERE         TABLE_SCHEMA    = PARSENAME(@TableName, 2)
                    AND    TABLE_NAME    = PARSENAME(@TableName, 1)
                    AND    DATA_TYPE IN ('char', 'varchar', 'nchar', 'nvarchar')
                    AND    QUOTENAME(COLUMN_NAME) > @ColumnName
            )

            IF @ColumnName IS NOT NULL
            BEGIN
                INSERT INTO @results
                EXEC
                (
                    'SELECT ''' + @TableName + '.' + @ColumnName + ''', LEFT(' + @ColumnName + ', 3630) 
                    FROM ' + @TableName + ' WITH (NOLOCK) ' +
                    ' WHERE ' + @ColumnName + ' LIKE ' + @SearchStr2
                )
            END
        END    
        ELSE
    WHILE @TableName IS NOT NULL
    BEGIN
        SET @ColumnName = ''
        SET @TableName = 
        (
            SELECT MIN(QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME))
            FROM     INFORMATION_SCHEMA.TABLES
            WHERE         TABLE_TYPE = 'BASE TABLE'
                AND    QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME) > @TableName
                AND    OBJECTPROPERTY(
                        OBJECT_ID(
                            QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME)
                             ), 'IsMSShipped'
                               ) = 0
        )

        WHILE (@TableName IS NOT NULL) AND (@ColumnName IS NOT NULL)
        BEGIN
            SET @ColumnName =
            (
                SELECT MIN(QUOTENAME(COLUMN_NAME))
                FROM     INFORMATION_SCHEMA.COLUMNS
                WHERE         TABLE_SCHEMA    = PARSENAME(@TableName, 2)
                    AND    TABLE_NAME    = PARSENAME(@TableName, 1)
                    AND    DATA_TYPE IN ('char', 'varchar', 'nchar', 'nvarchar')
                    AND    QUOTENAME(COLUMN_NAME) > @ColumnName
            )

            IF @ColumnName IS NOT NULL
            BEGIN
                INSERT INTO @results
                EXEC
                (
                    'SELECT ''' + @TableName + '.' + @ColumnName + ''', LEFT(' + @ColumnName + ', 3630) 
                    FROM ' + @TableName + ' WITH (NOLOCK) ' +
                    ' WHERE ' + @ColumnName + ' LIKE ' + @SearchStr2
                )
            END
        END    
    END

    SELECT ColumnName, ColumnValue FROM @results
END