কোনও সারণীর প্রতিটি সারিটির জন্য কীভাবে কোনও সঞ্চিত প্রক্রিয়া কল করতে পারে, যেখানে কোনও সারির কলামগুলি কোনও কার্সার ব্যবহার না করেই এসপিতে ইনপুট পরামিতি হয় ?
কোনও সারণীর প্রতিটি সারিটির জন্য কীভাবে কোনও সঞ্চিত প্রক্রিয়া কল করতে পারে, যেখানে কোনও সারির কলামগুলি কোনও কার্সার ব্যবহার না করেই এসপিতে ইনপুট পরামিতি হয় ?
উত্তর:
সাধারণভাবে বলতে গেলে আমি সর্বদা একটি সেট ভিত্তিক পদ্ধতির সন্ধান করি (কখনও কখনও স্কিমা পরিবর্তন করার ব্যয়ে)।
যাইহোক, এই স্নিপেট এর নিজস্ব জায়গা আছে ..
-- Declare & init (2008 syntax)
DECLARE @CustomerID INT = 0
-- Iterate over all customers
WHILE (1 = 1)
BEGIN
-- Get next customerId
SELECT TOP 1 @CustomerID = CustomerID
FROM Sales.Customer
WHERE CustomerID > @CustomerId
ORDER BY CustomerID
-- Exit loop if no more customers
IF @@ROWCOUNT = 0 BREAK;
-- call your sproc
EXEC dbo.YOURSPROC @CustomerId
END
আপনি এর মতো কিছু করতে পারেন: যেমন আপনার টেবিলটি অর্ডার করুন গ্রাহকআইডি (অ্যাডভেঞ্চার ওয়ার্কস Sales.Customer
নমুনা টেবিল ব্যবহার করে ), এবং WHIP লুপ ব্যবহার করে সেই গ্রাহকদের উপর পুনরাবৃত্তি করুন:
-- define the last customer ID handled
DECLARE @LastCustomerID INT
SET @LastCustomerID = 0
-- define the customer ID to be handled now
DECLARE @CustomerIDToHandle INT
-- select the next customer to handle
SELECT TOP 1 @CustomerIDToHandle = CustomerID
FROM Sales.Customer
WHERE CustomerID > @LastCustomerID
ORDER BY CustomerID
-- as long as we have customers......
WHILE @CustomerIDToHandle IS NOT NULL
BEGIN
-- call your sproc
-- set the last customer handled to the one we just handled
SET @LastCustomerID = @CustomerIDToHandle
SET @CustomerIDToHandle = NULL
-- select the next customer to handle
SELECT TOP 1 @CustomerIDToHandle = CustomerID
FROM Sales.Customer
WHERE CustomerID > @LastCustomerID
ORDER BY CustomerID
END
এটি যে কোনও টেবিলে কাজ করা উচিত যতক্ষণ না আপনি ORDER BY
কোনও কলামে কোনও ধরণের সংজ্ঞা দিতে পারেন ।
DECLARE @SQL varchar(max)=''
-- MyTable has fields fld1 & fld2
Select @SQL = @SQL + 'exec myproc ' + convert(varchar(10),fld1) + ','
+ convert(varchar(10),fld2) + ';'
From MyTable
EXEC (@SQL)
ঠিক আছে, তাই আমি কখনও এই জাতীয় কোড উত্পাদন করতে না, কিন্তু এটি আপনার প্রয়োজনীয়তা পূরণ করে।
মার্কের উত্তরটি ভাল (আমি কীভাবে এটি করতে পারি তা যদি আমি এটিতে মন্তব্য করব!)
কেবল ভেবেছিলাম আমি উল্লেখ করতে পারি যে লুপটি পরিবর্তন করা ভাল তবে SELECT
কেবলমাত্র একবারেই উপস্থিত রয়েছে (সত্যিকারের ক্ষেত্রে যেখানে আমার দরকার ছিল এটি করুন, এটি SELECT
বেশ জটিল ছিল এবং এটি দু'বার লেখা একটি ঝুঁকিপূর্ণ রক্ষণাবেক্ষণের সমস্যা ছিল)।
-- define the last customer ID handled
DECLARE @LastCustomerID INT
SET @LastCustomerID = 0
-- define the customer ID to be handled now
DECLARE @CustomerIDToHandle INT
SET @CustomerIDToHandle = 1
-- as long as we have customers......
WHILE @LastCustomerID <> @CustomerIDToHandle
BEGIN
SET @LastCustomerId = @CustomerIDToHandle
-- select the next customer to handle
SELECT TOP 1 @CustomerIDToHandle = CustomerID
FROM Sales.Customer
WHERE CustomerID > @LastCustomerId
ORDER BY CustomerID
IF @CustomerIDToHandle <> @LastCustomerID
BEGIN
-- call your sproc
END
END
আপনি যদি সঞ্চিত পদ্ধতিটিকে কোনও ফাংশনে পরিণত করতে পারেন যা কোনও টেবিল ফেরত দেয় তবে আপনি ক্রস-প্রয়োগ ব্যবহার করতে পারেন।
উদাহরণস্বরূপ, বলুন যে আপনার কাছে গ্রাহকদের একটি টেবিল রয়েছে এবং আপনি তাদের অর্ডারের যোগফলটি গণনা করতে চান, আপনি একটি ফাংশন তৈরি করবেন যা গ্রাহকআইডি গ্রহণ করে এবং যোগফলটি ফেরত দেয়।
এবং আপনি এটি করতে পারেন:
SELECT CustomerID, CustomerSum.Total
FROM Customers
CROSS APPLY ufn_ComputeCustomerTotal(Customers.CustomerID) AS CustomerSum
যেখানে ফাংশনটি দেখতে হবে:
CREATE FUNCTION ComputeCustomerTotal
(
@CustomerID INT
)
RETURNS TABLE
AS
RETURN
(
SELECT SUM(CustomerOrder.Amount) AS Total FROM CustomerOrder WHERE CustomerID = @CustomerID
)
স্পষ্টতই, উপরের উদাহরণটি একটি একক ক্যোয়ারিতে কোনও ব্যবহারকারী সংজ্ঞায়িত ফাংশন ছাড়াই করা যেতে পারে।
ত্রুটিটি হ'ল ফাংশনগুলি খুব সীমাবদ্ধ - একটি সঞ্চিত পদ্ধতির অনেকগুলি বৈশিষ্ট্য কোনও ব্যবহারকারী-সংজ্ঞায়িত ফাংশনে পাওয়া যায় না এবং সঞ্চিত পদ্ধতিটিকে কোনও ফাংশনে রূপান্তর করা সবসময় কাজ করে না।
আমি স্বীকৃত উত্তরটি ব্যবহার করব, তবে অন্য সম্ভাবনাটি হ'ল একটি টেবিল ভেরিয়েবল ব্যবহার করে মানগুলির একটি সংখ্যক সেট ধরে রাখতে (এই ক্ষেত্রে কেবল কোনও টেবিলের আইডি ক্ষেত্র) এবং টেবিলের সাথে একটি JOIN সহ র নাম্বার দ্বারা লুপ করুন লুপের মধ্যে ক্রিয়াটির জন্য আপনার যা প্রয়োজন তা পুনরুদ্ধার করুন।
DECLARE @RowCnt int; SET @RowCnt = 0 -- Loop Counter
-- Use a table variable to hold numbered rows containg MyTable's ID values
DECLARE @tblLoop TABLE (RowNum int IDENTITY (1, 1) Primary key NOT NULL,
ID INT )
INSERT INTO @tblLoop (ID) SELECT ID FROM MyTable
-- Vars to use within the loop
DECLARE @Code NVarChar(10); DECLARE @Name NVarChar(100);
WHILE @RowCnt < (SELECT COUNT(RowNum) FROM @tblLoop)
BEGIN
SET @RowCnt = @RowCnt + 1
-- Do what you want here with the data stored in tblLoop for the given RowNum
SELECT @Code=Code, @Name=LongName
FROM MyTable INNER JOIN @tblLoop tL on MyTable.ID=tL.ID
WHERE tl.RowNum=@RowCnt
PRINT Convert(NVarChar(10),@RowCnt) +' '+ @Code +' '+ @Name
END
এসকিউএল সার্ভার 2005 এর পরে, আপনি ক্রস প্রয়োগ এবং একটি টেবিল-মূল্যবান ফাংশন দিয়ে এটি করতে পারেন।
কেবল স্পষ্টতার জন্য, আমি সেই সব ক্ষেত্রে উল্লেখ করছি যেখানে সঞ্চিত পদ্ধতিটি একটি টেবিলের মূল্যবান ফাংশনে রূপান্তর করা যায়।
এটি উপরে n3rds সমাধানের একটি প্রকরণ। অর্ডার বাই ব্যবহার করে কোনও বাছাইয়ের দরকার নেই, যেমনটি এমআইএন () ব্যবহৃত হয়।
মনে রাখবেন গ্রাহকআইডিএইড (বা আপনি অগ্রগতির জন্য অন্যান্য যে কোনও সংখ্যাসূচক কলামটি ব্যবহার করেন) এর অবশ্যই একটি অনন্য বাধা থাকতে হবে। তদ্ব্যতীত, এটিকে যত তাড়াতাড়ি সম্ভব করার জন্য গ্রাহকআইডিকে সূচিযুক্ত করতে হবে।
-- Declare & init
DECLARE @CustomerID INT = (SELECT MIN(CustomerID) FROM Sales.Customer); -- First ID
DECLARE @Data1 VARCHAR(200);
DECLARE @Data2 VARCHAR(200);
-- Iterate over all customers
WHILE @CustomerID IS NOT NULL
BEGIN
-- Get data based on ID
SELECT @Data1 = Data1, @Data2 = Data2
FROM Sales.Customer
WHERE [ID] = @CustomerID ;
-- call your sproc
EXEC dbo.YOURSPROC @Data1, @Data2
-- Get next customerId
SELECT @CustomerID = MIN(CustomerID)
FROM Sales.Customer
WHERE CustomerID > @CustomerId
END
আমি এই আইডিটি কিছু ভ্যাচারগুলিতে ব্যবহার করি যা আমাকে প্রথমে একটি অস্থায়ী টেবিলের মধ্যে রেখে তাদের আইডি দেওয়ার জন্য সন্ধান করা উচিত।
এটি ইতিমধ্যে সরবরাহ করা জবাবগুলির মধ্যে একটি প্রকরণ, তবে এটি আরও ভাল করে সম্পাদন করা উচিত কারণ এর জন্য অর্ডার, COUNT বা MIN / MAX প্রয়োজন হয় না। এই পদ্ধতির সাথে একমাত্র অসুবিধা হ'ল আপনাকে সমস্ত আইডি ধরে রাখতে একটি টেম্প টেবিল তৈরি করতে হবে (ধারণাটি হ'ল গ্রাহক আইডিগুলির তালিকায় আপনার ফাঁক রয়েছে)।
এটি বলেছিল, আমি @ মারক পাওেলের সাথে একমত, যদিও সাধারণভাবে বলা যায়, একটি সেট ভিত্তিক পদ্ধতিটি আরও ভাল হওয়া উচিত।
DECLARE @tmp table (Id INT IDENTITY(1,1) PRIMARY KEY NOT NULL, CustomerID INT NOT NULL)
DECLARE @CustomerId INT
DECLARE @Id INT = 0
INSERT INTO @tmp SELECT CustomerId FROM Sales.Customer
WHILE (1=1)
BEGIN
SELECT @CustomerId = CustomerId, @Id = Id
FROM @tmp
WHERE Id = @Id + 1
IF @@rowcount = 0 BREAK;
-- call your sproc
EXEC dbo.YOURSPROC @CustomerId;
END
বেশ কয়েকটি সারি যখন আমি সাধারণত এটি করি তখন:
(বৃহত্তর ডেটাসেটে আমি উপরে উল্লিখিত সমাধানগুলির মধ্যে একটি ব্যবহার করব)।
DELIMITER //
CREATE PROCEDURE setFakeUsers (OUT output VARCHAR(100))
BEGIN
-- define the last customer ID handled
DECLARE LastGameID INT;
DECLARE CurrentGameID INT;
DECLARE userID INT;
SET @LastGameID = 0;
-- define the customer ID to be handled now
SET @userID = 0;
-- select the next game to handle
SELECT @CurrentGameID = id
FROM online_games
WHERE id > LastGameID
ORDER BY id LIMIT 0,1;
-- as long as we have customers......
WHILE (@CurrentGameID IS NOT NULL)
DO
-- call your sproc
-- set the last customer handled to the one we just handled
SET @LastGameID = @CurrentGameID;
SET @CurrentGameID = NULL;
-- select the random bot
SELECT @userID = userID
FROM users
WHERE FIND_IN_SET('bot',baseInfo)
ORDER BY RAND() LIMIT 0,1;
-- update the game
UPDATE online_games SET userID = @userID WHERE id = @CurrentGameID;
-- select the next game to handle
SELECT @CurrentGameID = id
FROM online_games
WHERE id > LastGameID
ORDER BY id LIMIT 0,1;
END WHILE;
SET output = "done";
END;//
CALL setFakeUsers(@status);
SELECT @status;
এর আরও ভাল সমাধান হ'ল
- সঞ্চিত প্রক্রিয়াটির অনুলিপি / অতীত কোড
- আপনি যে টেবিলটি আবার এটি চালাতে চান তার সাথে সেই কোডটিতে যোগ দিন (প্রতিটি সারির জন্য)
এটি আপনি একটি পরিষ্কার টেবিল-ফর্ম্যাট আউটপুট পান। আপনি যদি প্রতিটি সারির জন্য এসপি চালান, আপনি প্রতিটি পুনরাবৃত্তির জন্য একটি পৃথক ক্যোয়ারী ফলাফল পাবেন যা কুৎসিত।
যদি আদেশটি গুরুত্বপূর্ণ হয়
--declare counter
DECLARE @CurrentRowNum BIGINT = 0;
--Iterate over all rows in [DataTable]
WHILE (1 = 1)
BEGIN
--Get next row by number of row
SELECT TOP 1 @CurrentRowNum = extendedData.RowNum
--here also you can store another values
--for following usage
--@MyVariable = extendedData.Value
FROM (
SELECT
data.*
,ROW_NUMBER() OVER(ORDER BY (SELECT 0)) RowNum
FROM [DataTable] data
) extendedData
WHERE extendedData.RowNum > @CurrentRowNum
ORDER BY extendedData.RowNum
--Exit loop if no more rows
IF @@ROWCOUNT = 0 BREAK;
--call your sproc
--EXEC dbo.YOURSPROC @MyVariable
END
আমার কাছে এমন কিছু প্রোডাকশন কোড ছিল যা একবারে কেবলমাত্র 20 জন কর্মচারী পরিচালনা করতে পারে, নীচের কোডটির কাঠামোটি। আমি সবেমাত্র প্রোডাকশন কোডটি অনুলিপি করেছি এবং নীচে জিনিসগুলি সরিয়েছি।
ALTER procedure GetEmployees
@ClientId varchar(50)
as
begin
declare @EEList table (employeeId varchar(50));
declare @EE20 table (employeeId varchar(50));
insert into @EEList select employeeId from Employee where (ClientId = @ClientId);
-- Do 20 at a time
while (select count(*) from @EEList) > 0
BEGIN
insert into @EE20 select top 20 employeeId from @EEList;
-- Call sp here
delete @EEList where employeeId in (select employeeId from @EE20)
delete @EE20;
END;
RETURN
end
আমি এর অনুরূপ কিছু করতে চাই (যদিও এটি এখনও কার্সার ব্যবহারের সাথে খুব মিল)
[কোড]
-- Table variable to hold list of things that need looping
DECLARE @holdStuff TABLE (
id INT IDENTITY(1,1) ,
isIterated BIT DEFAULT 0 ,
someInt INT ,
someBool BIT ,
otherStuff VARCHAR(200)
)
-- Populate your @holdStuff with... stuff
INSERT INTO @holdStuff (
someInt ,
someBool ,
otherStuff
)
SELECT
1 , -- someInt - int
1 , -- someBool - bit
'I like turtles' -- otherStuff - varchar(200)
UNION ALL
SELECT
42 , -- someInt - int
0 , -- someBool - bit
'something profound' -- otherStuff - varchar(200)
-- Loop tracking variables
DECLARE @tableCount INT
SET @tableCount = (SELECT COUNT(1) FROM [@holdStuff])
DECLARE @loopCount INT
SET @loopCount = 1
-- While loop variables
DECLARE @id INT
DECLARE @someInt INT
DECLARE @someBool BIT
DECLARE @otherStuff VARCHAR(200)
-- Loop through item in @holdStuff
WHILE (@loopCount <= @tableCount)
BEGIN
-- Increment the loopCount variable
SET @loopCount = @loopCount + 1
-- Grab the top unprocessed record
SELECT TOP 1
@id = id ,
@someInt = someInt ,
@someBool = someBool ,
@otherStuff = otherStuff
FROM @holdStuff
WHERE isIterated = 0
-- Update the grabbed record to be iterated
UPDATE @holdAccounts
SET isIterated = 1
WHERE id = @id
-- Execute your stored procedure
EXEC someRandomSp @someInt, @someBool, @otherStuff
END
[/ কোড]
মনে রাখবেন যে আপনার টেম্প / ভেরিয়েবল টেবিলটিতে আপনার পরিচয় বা আইট্রেটেড কলামের প্রয়োজন নেই , আমি কেবল এটি করা পছন্দ করি যাতে লুপের মাধ্যমে পুনরাবৃত্তি হওয়ার সাথে আমার সংগ্রহ থেকে শীর্ষ রেকর্ডটি মুছতে হবে না।