উইন্ডোজ কমান্ড প্রম্পটে একটি নির্দিষ্ট ডিরেক্টরিতে ফাইল / সাবফোল্ডারগুলি কীভাবে মুছবেন

307

বলুন, সেখানে একটি ভেরিয়েবল বলা হয় %pathtofolder%, এটি এটি পরিষ্কার করে দেয় যে এটি কোনও ফোল্ডারের পুরো পথ।

আমি এই ডিরেক্টরিতে প্রতিটি ফাইল এবং সাবফোল্ডার মুছতে চাই, তবে ডিরেক্টরিটি নিজেই নয়।

তবে, 'এই ফাইলটি / ফোল্ডারটি ইতিমধ্যে ব্যবহারে রয়েছে' এর মতো একটি ত্রুটি থাকতে পারে ... যখন এটি ঘটে তখন এটি কেবল চালিয়ে যাওয়া উচিত এবং সেই ফাইল / ফোল্ডারটি এড়ানো উচিত।

এর জন্য কিছু আদেশ আছে?

windows  batch-file  file-io  cmd  directory 
— ডেনিজ জোয়েটম্যান
সূত্র
— রোজবার্গ
উইন্ডো ফোল্ডারগুলি মুছে ফেলা কতটা কঠিন তা পাগল ... বা একটি বিন্দু দিয়ে শুরু করা ... উইন্ডোতে বাশ সংহতকরণের জন্য godশ্বরকে ধন্যবাদ! rm -rf path\to\folderউইন্ডোজ 10 এ কাজ করে (বা গিট বাশ থেকে আসতে পারে ... যে কোনও উপায়ে যদি আপনার কাছে চেষ্টা করা হয় তবেই!)
— স্টিজন ডি উইট

উত্তর:

256

আপনি C:\Temp উত্সের মধ্যে ফোল্ডার এবং ফাইলগুলি পরিষ্কার করতে এই শেল স্ক্রিপ্টটি ব্যবহার করতে পারেন :

del /q "C:\Temp\*"
FOR /D %%p IN ("C:\Temp\*.*") DO rmdir "%%p" /s /q

উপরের কমান্ডটি সম্বলিত একটি ব্যাচ ফাইল তৈরি করুন (বলুন, মুছে দিন.ব্যাট)। ডিলিট.ব্যাট ফাইলটি যেখানে অবস্থিত সেখানে যান এবং তারপরে কমান্ডটি চালান: ডিলিট.বাট

— আয়ান
সূত্র
20
আমি চেষ্টা করেছিলাম কিন্তু দুর্ভাগ্যক্রমে এমন ফাইলগুলি যেখানে মুছে ফেলা হয় না, কেবলমাত্র সাব-ফোল্ডারগুলি মুছে ফেলা হয়। উদাহরণস্বরূপ আমার কাছে টেস্ট নামের একটি ফোল্ডার রয়েছে। এটিতে "রিপন" এবং "ওয়াসিম" নামে 2 টি ফোল্ডার রয়েছে এবং এতে "রিপোনালওয়াসিম.টেক্সট" নামে একটি ফাইল রয়েছে। সাবফোল্ডার রিপন এবং ওয়াসিম মুছে ফেলা হয়েছে তবে রিপোনালওয়াসিম.টিএসটি মোছা হয়নি।
— রিপন আল ওয়াসিম
16
একক শতাংশ চিহ্ন ব্যবহার করুন যদি আপনি কমান্ড লাইন যেমন থেকে সরাসরি চালানোর জন্য ইচ্ছুক%p
— অ্যালেক্স
2
দুঃখের বিষয় যে এটি 2 লাইন নেয়, তবে কমপক্ষে এটি কার্যকর হয়! আমি একটি কাজের "ওয়ান-লাইনার" অনুসন্ধান করতে করতে ক্লান্ত এবং এই সাথে যাব, ধন্যবাদ!
— নাইটকোডার
2
আপনি ব্যাট ফাইল ছাড়াই এক লাইনে দুটি কমান্ড কার্যকর করতে'&& 'অপারেটরটি ব্যবহার করতে পারেন (' %% 'এর পরিবর্তে একক'% 'লক্ষ্য করুন)। ডেল / এস / কিউ "মাইফোল্ডার *" এবং & ফর / ডি% পি ইন ("মাইফোল্ডার *")
— ডিএমএমডির
</ f "delims =" %% i in ('dir / b / a-d') do (ইকো ডেল "%% i" / q)> ফাইলগুলির জন্য সহায়তা করতে পারে (কেবল সেই প্রতিধ্বনি সরান)
— গ্রেনিক্স
340

rmdir কাজের জন্য আমার সর্বকালের প্রিয় কমান্ড। এটি সাবফোল্ডার সহ বিশাল ফাইল এবং ফোল্ডার মুছে ফেলার জন্য কাজ করে। একটি ব্যাকআপ তৈরি করা হয়নি, সুতরাং নিশ্চিত হয়ে নিন যে আপনি এই আদেশটি চালানোর আগে আপনার ফাইলগুলি নিরাপদে অনুলিপি করেছেন।

RMDIR "FOLDERNAME" /S /Q

এটি নিঃশব্দে ফোল্ডার এবং সমস্ত ফাইল এবং সাবফোল্ডারগুলি সরিয়ে দেয়।

— সুরেশ
সূত্র
65
এটি ওপেনটি যে প্যাথফোল্ডারটি রাখতে চাইছিল তা সরিয়ে ফেলবে বলে মনে হচ্ছে।
— ফজ ইভান্স
4
এটি নিজেই ফোল্ডারটি সরিয়ে ফেলবে, সুতরাং আপনাকে অন্য একটি কমান্ড যুক্ত করতে হবে: md FOLDERNAME(নীচে @ আরোকোকজিনের উত্তর দেখুন)।
— thordan
4
এখানে "ব্যাকআপ তৈরি হয়" বলতে কী বোঝ? আমি এমন কোনও কিছু দেখতে পাচ্ছি না যা কোনও ধরণের ব্যাকআপ তৈরি করবে ...
— পল গ্রোক
1
ডিরেক্টরি খালি নয় বার্তাটি প্রতিক্রিয়া হিসাবে এসেছিল!
— জামশেদ কামরান
10
নিজেই ফোল্ডারটি সরিয়ে না দেওয়ার জন্য, এটির আগে বর্তমান ডিরেক্টরিটি তৈরি করুন, তারপরে "ব্যবহার করুন।" FOLDERNAME হিসাবে। পরে এটি পুনরায় তৈরি করা প্রয়োজনীয়ভাবে একই নয় কারণ এসিএলগুলি হারিয়ে যেতে পারে। cd "FOLDERNAME" RD . /S /Q
— মরিটজ উভয়ই
85

আমি যে সহজ সমাধানটির কথা ভাবতে পারি তা হ'ল সম্পূর্ণ ডিরেক্টরিটি মুছে ফেলা

RD /S /Q folderPath

তারপরে আবার এই ডিরেক্টরিটি তৈরি করুন:

MD folderPath
— wojciech_rak
সূত্র
5
মুছে ফেলার অনুমতি থাকলেও নতুন ফোল্ডার তৈরি না করে কি ?? আমি এর সম্ভাব্য আশা করি :)
— স্যান্ডি
13
এটি একটি খারাপ সমাধান, যেহেতু এটি ডিরেক্টরি নোডের জন্য ফাইল সিস্টেমে একটি রেসকে পরিচয় করিয়ে দেয়, ততক্ষণে দ্বিতীয় কমান্ড কার্যকর হলে তা কার্যকর হতে পারে।
— রোক স্ট্রিনিয়া
22
এছাড়াও, ডিরেক্টরিতে যদি সুনির্দিষ্ট অনুমতি থাকে তবে আপনি সবেমাত্র আহেম (ওফস) কে নষ্ট করেছেন
— অমর ব্লু
প্রতিক্রিয়াটি ত্যাগ করবেন না: 'ডিরেক্টরিটি খালি নয়' ', কেবল দু'বার কমান্ডটি জারি করুন :-)
— কাইরান রায়ান
1
আরডি এবং আরএমডিআইআর একই কমান্ড এবং যেহেতু আপনি এই উত্তরটি পোস্ট করেছেন যেহেতু কেউ একই উত্তর দেওয়ার 9 মাস পরে, লোকেরা কেন আপনাকে পয়েন্ট দিচ্ছে?
— স্যুইচ করুন
51

এটি ফোল্ডার এবং ফাইলগুলি সরিয়ে ফোল্ডারটিকে পিছনে ফেলে দেবে।

pushd "%pathtofolder%" && (rd /s /q "%pathtofolder%" 2>nul & popd)
— foxidrive
সূত্র
4
যে কেউ এই পদ্ধতির বিষয়ে নিশ্চিত নয়: এটি অবশ্যই ডিরেক্টরিটি পুনরায় তৈরি করে না। ছাড়াই 2>nul, এটি আউটপুট করে "প্রক্রিয়াটি ফাইলটি অ্যাক্সেস করতে পারে না কারণ এটি অন্য প্রক্রিয়া দ্বারা ব্যবহৃত হচ্ছে।"
— রক স্ট্রিনিয়া
6
আমি ঘৃণা করি যে উইন্ডোজ কোনও প্রোগ্রাম দ্বারা ব্যবহৃত ফাইল এবং ফোল্ডারগুলি মুছতে পারে না। এবং আমি ভালবাসি যে আপনি এই ওয়ান-লাইনারে আপনার পক্ষে এটি ব্যবহার করেছেন।
— andref
সুতরাং এই উবার-যাদুটি কীভাবে আমরা উইন্ডোজে কোনও ফোল্ডার খালি করি ?? চিত্তাকর্ষক :)
— mlvljr
3
@MLvljr কেবলমাত্র যদি আপনি পিতামাতার ফোল্ডারটি রাখতে চান তবেই। RD /?ফোল্ডার খালি করার সহজ উপায়টি আপনাকে দেখায়।
— ফক্সিড্রাইভ
1
এটি আপনার দুর্দান্ত অবস্থানে ফিরে আসার প্রয়োজন হলে এটি দুর্দান্ত, অন্যথায় কেবল CD mypath && RD /S .যথেষ্ট হবে। আমি পছন্দ করি না যে আপনাকে আপনার পথটি দু'বার পুনরাবৃত্তি করতে হবে, দীর্ঘ পথের জন্য এটি পড়া শক্ত হয়ে যায়। তাই আমি set p="mypath"শুরুতে একটি যুক্ত করব ।
— অমিত নাইডু
39 
@ECHO OFF

SET THEDIR=path-to-folder

Echo Deleting all files from %THEDIR%
DEL "%THEDIR%\*" /F /Q /A

Echo Deleting all folders from %THEDIR%
FOR /F "eol=| delims=" %%I in ('dir "%THEDIR%\*" /AD /B 2^>nul') do rd /Q /S "%THEDIR%\%%I"
@ECHO Folder deleted.

EXIT

... প্রদত্ত ডিরেক্টরিটির নীচে সমস্ত ফাইল এবং ফোল্ডারগুলি মুছে ফেলে তবে ডিরেক্টরিটি নিজেই নয়।

— thepip3r
সূত্র
4
এটি সঠিক উত্তর হওয়া উচিত .. সহজ সরল করুন .. মুছে ফোল্ডারকন্টেন্টস.ব্যাট ফাইল .. আপনার পথে পপ করুন এবং এটি একটি
— কবজির
3
DEL কমান্ড লাইন শটটি বিকল্প /Aএছাড়াও গোপন বৈশিষ্ট্য সেট দিয়ে ফাইল মুছে দিন এবং %dir%\*মত উদ্ধৃতি চিহ্ন মধ্যে লেখা হবে "%dir%\*"একটি স্থান বা এই অক্ষরের এক ধারণকারী ডিরেক্টরি জন্যও কাজ &()[]{}^=;!'+,`~। এবং ফর কমান্ড লাইনটি সংশোধন করা উচিত for /F "eol=| delims=" %%I in ('dir "%dir%\*" /AD /B 2^>nul') do rd /Q /S "%dir%\%%I"কারণ ফর লুকানো অ্যাট্রিবিউট সেট সহ ডিরেক্টরিগুলি উপেক্ষা করে। বিকল্পগুলির সাথে ডিআইআর কেবল তাদের নাম দিয়ে সমস্ত ডিরেক্টরি /AD /Bআউটপুট করে । বিটিডাব্লু: পরিবেশের পরিবর্তনশীলের পক্ষে ভাল নাম নয়। dir
— মফি
1
সাব ফোল্ডারটি মুছবে না
— আরমিরান্ডা
1
@ মিরান্ডা, আমার পরীক্ষায় এটি ওপি যেমনটি বলেছিল ঠিক তেমন করে। আপনার কি এমন কোনও মামলা রয়েছে যেখানে এটি সাবফোল্ডারগুলি মুছবে না?
— thepip3r
এই উত্তরটি কী "এই ফাইল / ফোল্ডারটি ইতিমধ্যে ব্যবহারে রয়েছে" এর মতো একটি ত্রুটি থাকতে পারে ... এর প্রয়োজনীয়তার সমাধান করে ... যখন এটি ঘটে তখন এটি কেবল চালিয়ে যাওয়া উচিত এবং সেই ফাইল / ফোল্ডারটি এড়ানো উচিত "" ?
— পিটার মর্টেনসেন
30 
CD [Your_Folder]
RMDIR /S /Q .

আপনি একটি ত্রুটি বার্তা পাবেন, আপনাকে জানিয়েছে যে আরএমডিআইআর কমান্ড বর্তমান ফোল্ডারটি অ্যাক্সেস করতে পারে না, সুতরাং এটি এটি মুছতে পারে না।

আপডেট :

থেকে এই দরকারী মন্তব্য (ধন্যবাদ মরটিজ উভয় ), আপনি যোগ করতে পারেন &&মধ্যে, তাই RMDIRচলবে না যদি CDকমান্ড ব্যর্থ (যেমন ভুলভাবে লেখা ডিরেক্টরির নাম):

CD [Your_Folder] && RMDIR /S /Q .

থেকে উইন্ডোজ কম্যান্ড-লাইন রেফারেন্স :

/ এস: একটি ডিরেক্টরি ট্রি মুছে ফেলে (নির্দিষ্ট ডিরেক্টরি এবং সমস্ত ফাইল সহ সমস্ত উপ-ডিরেক্টরি))

/ প্রশ্ন: নিঃশব্দ মোড নির্দিষ্ট করে। ডিরেক্টরি ট্রি মুছে ফেলার সময় নিশ্চিতকরণের জন্য অনুরোধ জানায় না। (দ্রষ্টব্য যে / q কেবলমাত্র / গুলি নির্দিষ্ট থাকলে কাজ করে))

— O.Badr
সূত্র
1
এটি টেম্প খালি করার জন্য উপযুক্ত, তবে এটি cd [Your_Folder]অত্যন্ত সমালোচনামূলক - আমাকে মনে রাখতে হবে যে আমি নিজে ডিরেক্টরিটি মুছব না ...
— age
5
এটিই সঠিক সমাধান। যোগ &&লাইন বিরতি পরিবর্তে কমান্ড মধ্যে এবং আপনি একটি ব্যর্থ CD থেকে নিরাপদ।
— মরিটজ উভয়ই
এটি একটি সহজ এবং সঠিক সমাধান। এমনকি Azure কমান্ড শেল দিয়ে কাজ করে!
— ফিলিপ
বেশ খারাপ সমাধান ... উদাহরণস্বরূপ আমার একটি এসএনএন আপডেটের জন্য এই কমান্ড লাইন মুছে ফেলার প্রয়োজন - আপডেট এসএনএন করার আগে আমি সমস্ত ফাইল এবং ফোল্ডারগুলি মুছতে চাই কারণ মেশিনে যেখানে আমি এটি ব্যবহার করি সেখানে কিছু পরিবর্তন হতে পারে তবে প্রাসঙ্গিক কেবলমাত্র চেক ইন করা আইটেম। আরএমডিআইআর / এস / কিউ করছেন। এছাড়াও এসভিএন লিঙ্কটি সরিয়ে দেয় এবং ফোল্ডারটিকে আর কোনও এসএনএন ফোল্ডার তৈরি করে না
— ডোমিনিক লেম্বারগার
এটি আগের চারটি উত্তর থেকে কীভাবে আলাদা?
— পিটার মর্টেনসেন
9

আরডি মানে রিমোভ ডিরেক্টরি।

/ এস: ফোল্ডার ছাড়াও সমস্ত ফাইল এবং সাবফোল্ডার মুছুন। একটি সম্পূর্ণ ফোল্ডার গাছ মুছে ফেলতে এটি ব্যবহার করুন।

/ প্রশ্ন: শান্ত - ওয়াইএন নিশ্চিতকরণ প্রদর্শন করবেন না

উদাহরণ:

RD /S /Q C:/folder_path/here
— সিরেশ ইয়ারলগদা
সূত্র
1
কী /Sএবং এর /Qঅর্থ ব্যাখ্যা করার জন্য একমাত্র
— হ'ল উত্সাহিত
2
নং rdএর সমতুল্য rmdirএবং ডিরেক্টরি নিজেই সরিয়ে ফেলবে এবং ওপি যা চায় তা নয়।
— ওয়েস্টার্নগুন
এই উত্তরটি কী "এই ফাইল / ফোল্ডারটি ইতিমধ্যে ব্যবহারে রয়েছে" এর মতো কোনও ত্রুটি হতে পারে ... যখন এটি ঘটে তখন এটি কেবল চালিয়ে যাওয়া উচিত এবং সেই ফাইল / ফোল্ডারটি এড়ানো উচিত? " উদাহরণস্বরূপ, এটি চালিয়ে যাওয়ার পরিবর্তে কি পুরোপুরি বাতিল করা যায়?
— পিটার মর্টেনসেন
8

আমি পাওয়ারশেল ব্যবহার করি 

Remove-Item c:\scripts\* -recurse

এটি ফোল্ডারের সামগ্রীগুলি সরিয়ে ফেলবে, ফোল্ডারটি নিজেই নয়।

— rhellem
সূত্র
রিহেলিমের উত্তর সাম্প্রতিক, তবে এটি কেবলমাত্র আমার পক্ষে উত্তর দেবে answer (উইন 8.1, পছন্দ দ্বারা নয়)
— philologon
2
ব্যাচের কমান্ড লাইন থেকে:powershell -Command "Remove-Item 'PathToMyDirectory\*' -Recurse -Force"
— রোজবার্গ
নোট করুন যে "*" প্রয়োজনীয় বা এটি ফোল্ডারটি সরিয়ে ফেলবে।
— mhenry1384
7

উত্তর হিসাবে, 2018-06-01 পোস্ট কোনটিই বাদে একক কমান্ড লাইন দ্বারা পোস্ট করা foxidrive , সত্যিই সব ফাইল এবং সকল ফোল্ডার / ডিরেক্টরি মুছে ফেলা %PathToFolder%। যে হিসাবে 2018-06-01 ব্যবহার পোস্ট ভাল একটি আরো জটিল সমাধান কেন সব অন্যান্য উত্তর ব্যাখ্যা দিয়ে একটি ব্যাচ ফাইল হিসাবে হিসাবে সব ফাইল এবং একটি ফোল্ডার সাবফোল্ডার মুছে ফেলতে একটি খুব সহজ একক কমান্ড লাইন দিয়ে আরও একটি উত্তর পোস্ট করার জন্য কারণ DEL আর ফর সহ আরডি কোনও ফোল্ডার পুরোপুরি পরিষ্কার করতে ব্যর্থ হয়েছিল।

সাধারণ একক কমান্ড লাইন সমাধান যা অবশ্যই একটি ব্যাচ ফাইলে ব্যবহার করা যেতে পারে:

pushd "%PathToFolder%" 2>nul && ( rd /Q /S "%PathToFolder%" 2>nul & popd )

এই কমান্ড লাইনে একের পর এক কার্যকর করা তিনটি কমান্ড রয়েছে।

প্রথম কমান্ড PUSHD স্ট্যাক এবং পরবর্তী মেকগুলিতে বর্তমান ডিরেক্টরি পাথটি চাপায়%PathToFolder% কমান্ড প্রক্রিয়া চালানোর জন্য বর্তমান ডিরেক্টরিকে তৈরি করে।

এটি ইউএনসি পাথগুলির জন্য ডিফল্টরূপেও কাজ করে কারণ কমান্ড এক্সটেনশনগুলি ডিফল্টরূপে সক্ষম হয় এবং এই ক্ষেত্রে PUSHD একটি অস্থায়ী ড্রাইভ লেটার তৈরি করে যা সেই নির্দিষ্ট নেটওয়ার্ক সংস্থানকে নির্দেশ করে এবং তারপরে নতুন ড্রাইভ অক্ষর ব্যবহার করে বর্তমান ড্রাইভ এবং ডিরেক্টরি পরিবর্তন করে।

PUSHD হ্যান্ডেল ত্রুটির বার্তা এই আউটপুট stderr নির্দিষ্ট ডিরেক্টরি এ সব অস্তিত্ব নেই যদি:

সিস্টেম নির্দিষ্ট পথ খুঁজে পাচ্ছি না.

এই ত্রুটি বার্তাটি NUL2>nul ডিভাইসে পুনর্নির্দেশের মাধ্যমে চাপা দেওয়া হয়েছে ।

পরবর্তী কমান্ড আরডি কেবল তখনই কার্যকর করা হয় যখন বর্তমান কমান্ড প্রসেসের জন্য নির্দিষ্ট ডিরেক্টরিতে বর্তমান ডিরেক্টরি পরিবর্তন করা সফল হয়েছিল, অর্থাৎ নির্দিষ্ট ডিরেক্টরিটি উপস্থিত রয়েছে।

কমান্ড আরডি বিকল্প সহ /Qএবং /Sএকটি ডিরেক্টরি সরিয়ে ফেলা শান্তভাবে সব সাবডিরেক্টরি এমনকি যদি নির্দিষ্ট ডিরেক্টরি গোপন বৈশিষ্ট্য সহ বা শুধুমাত্র পাঠযোগ্য বৈশিষ্ট্য সেট দিয়ে ফাইল বা ফোল্ডার রয়েছে। সিস্টেম অ্যাট্রিবিউট কখনও কোনও ফাইল বা ফোল্ডার মোছা প্রতিরোধ করে না।

মুছে ফেলা হয় না:

  1. যে কোনও চলমান প্রক্রিয়াটির জন্য ফোল্ডারগুলি বর্তমান ডিরেক্টরি হিসাবে ব্যবহৃত হয়। কোনও চলমান প্রক্রিয়ার জন্য যদি কোনও ফোল্ডারটিকে বর্তমান ডিরেক্টরি হিসাবে ব্যবহার করা হয় তবে এই জাতীয় ফোল্ডারের পুরো ফোল্ডার ট্রিটিকে মুছা যাবে না।

  2. চলমান অ্যাপ্লিকেশন / প্রক্রিয়া দ্বারা খোলার সময় ফাইলটি মুছে ফেলা রোধ করতে ফাইলগুলিতে অ্যাক্সেস অনুমতি সেট সহ ফাইলগুলির অ্যাক্সেস অনুমতি সহ যে কোনও চলমান প্রক্রিয়া দ্বারা খোলার সময় ফাইলগুলি। এই জাতীয় একটি খোলা ফাইল খোলা ফাইলটিতে পুরো ফোল্ডার ট্রি মুছতেও বাধা দেয়।

  3. যে ফাইলগুলি / ফোল্ডারগুলিতে বর্তমান ব্যবহারকারীর ফাইল / ফোল্ডার মুছতে প্রয়োজনীয় (এনটিএফএস) অনুমতি নেই সেগুলি এই ফাইল / ফোল্ডারে ফোল্ডার ট্রি মুছতে বাধা দেয়।

কোনও ফোল্ডার মোছা না যাওয়ার প্রথম কারণটি এই কমান্ড লাইন দ্বারা নির্দিষ্ট ফোল্ডারের সমস্ত ফাইল এবং সাবফোল্ডার মুছতে ব্যবহৃত হয়, তবে ফোল্ডারটি নিজেই নয়। কমান্ড প্রক্রিয়া চলমান জন্য ফোল্ডারটি অস্থায়ীভাবে বর্তমান ডিরেক্টরি তৈরি করা হয় যা ফোল্ডারটি নিজেই মুছতে বাধা দেয়। অবশ্যই এর ফলে আরডি কমান্ড দ্বারা একটি ত্রুটি বার্তা আউটপুট আসে :

প্রক্রিয়াটি ফাইলটি অ্যাক্সেস করতে পারে না কারণ এটি অন্য প্রক্রিয়া দ্বারা ব্যবহৃত হচ্ছে।

ফাইলটি এখানে ভুল শব্দ যা বাস্তবে ফোল্ডারটি অন্য একটি প্রক্রিয়া দ্বারা ব্যবহৃত হচ্ছে, বর্তমান কমান্ড প্রক্রিয়া যা কমান্ড আরডি চালায় । ভাল, বাস্তবে একটি ফোল্ডার ফাইল সিস্টেমের জন্য একটি বিশেষ ফাইল যা ফাইল বৈশিষ্ট্য ডিরেক্টরি যা এই ত্রুটি বার্তাকে ব্যাখ্যা করে। তবে আমি ফাইল সিস্টেম পরিচালনার খুব গভীর দিকে যেতে চাই না।

এই ত্রুটি বার্তাটি, অন্য সব ত্রুটি বার্তা, যা কারণ উপরে লিখিত তিন কারণের ঘটতে পারে মত, সঙ্গে এটি পুনঃনির্দেশিত দ্বারা দমন করা হয় 2>nulহাতলের থেকে stderr ডিভাইসে NUL ।

তৃতীয় কমান্ড, পিওপিডি , কমান্ড আরডি- র প্রস্থান মূল্য থেকে স্বাধীনভাবে কার্যকর করা হয় ।

POPD স্ট্যাক থেকে PUSHD দ্বারা চালিত ডিরেক্টরি পথটি পপ করে এবং কমান্ড প্রক্রিয়াটি এই ডিরেক্টরিতে চালিত করার জন্য বর্তমান ডিরেক্টরিকে পরিবর্তিত করে, অর্থাৎ প্রাথমিক বর্তমান ডিরেক্টরিটি পুনরুদ্ধার করে। ইউএনসি ফোল্ডার পাথের ক্ষেত্রে পিওপিডি পুশডের তৈরি অস্থায়ী ড্রাইভ লেটারটি মুছে দেয় ।

দ্রষ্টব্য: পিওপিডি নিঃশব্দে প্রাথমিক বর্তমান ডিরেক্টরিটি পুনরুদ্ধার করতে ব্যর্থ হতে পারে প্রাথমিক বর্তমান ডিরেক্টরি যদি ডিরেক্টরি থাকে না তা পরিষ্কার করার জন্য ডিরেক্টরিটির একটি উপ-ডিরেক্টরি ছিল। এই বিশেষ ক্ষেত্রে %PathToFolder%বর্তমান ডিরেক্টরি রয়ে গেছে। সুতরাং এটির উপরের কমান্ড লাইনটি কোনও সাব-ডিরেক্টরি থেকে না চালানোর পরামর্শ দেওয়া হচ্ছে%PathToFolder% ।

আরও একটি আকর্ষণীয় বিষয়: আমি কমান্ড লাইন স্থানীয় ডিরেক্টরি ভাগ করে একটি ইউএনসি পাথ ব্যবহার করার চেষ্টা C:\Tempভাগ নাম দিয়ে Tempএবং ইউএনসি পাথ ব্যবহার \\%COMPUTERNAME%\Temp\CleanTestএনভায়রনমেন্ট ভেরিয়েবল নির্ধারিত PathToFolderউইন্ডোজ 7 তাহলে কমান্ড লাইন চলমান বর্তমান ডিরেক্টরির একটি ভাগ স্থানীয় একটি সাব হয় ইউএনসি পাথ, অর্থাত দিয়ে অ্যাক্সেস করা ফোল্ডার C:\Temp\CleanTest\Subfolder1, Subfolder1দ্বারা মুছে ফেলা হয় আরডি এবং পরবর্তী POPD তৈরীর চুপটি ব্যর্থ C:\Temp\CleanTest\Subfolder1আবার বর্তমান ডিরেক্টরী ফলেZ:\CleanTest চলমান কমান্ড প্রক্রিয়ার জন্য বর্তমান ডিরেক্টরী হিসাবে অবশিষ্ট আছে। সুতরাং এটি খুব খুব বিশেষ ক্ষেত্রে অস্থায়ী ড্রাইভ লেটারটি বর্তমান ডিরেক্টরিটি পরিবর্তিত না হওয়া অবধি অবধি উদাহরণস্বরূপ থাকেcd /D %SystemRoot%একটি স্থানীয় ডিরেক্টরি সত্যিই বিদ্যমান। দুর্ভাগ্যক্রমে পিওপিডি টির0 এর বেশি মানের সাথে প্রস্থান হয় না যদি এটি প্রাথমিক বর্তমান ডিরেক্টরিটি পুনরুদ্ধার করতে ব্যর্থ হয় তবে কেবলমাত্র পিওপিডি- র প্রস্থান কোডটি ব্যবহার করে খুব বিশেষ ত্রুটির শর্তটি সনাক্ত করা অসম্ভব হয়ে পড়ে । তবে, ধারণা করা যেতে পারে যে ইউএনসির পাথগুলি সাধারণত স্থানীয় ফাইল এবং ফোল্ডার অ্যাক্সেসের জন্য ব্যবহার করা হয় না বলে কেউ এই খুব বিশেষ ত্রুটির ক্ষেত্রে কখনও যায় না।

ব্যবহৃত কমান্ডগুলি আরও ভালভাবে বোঝার জন্য, একটি কমান্ড প্রম্পট উইন্ডোটি খুলুন, নিম্নলিখিত কমান্ডগুলি সম্পাদন করুন এবং প্রতিটি কমান্ডের জন্য প্রদর্শিত সহায়তাটি খুব যত্ন সহকারে পড়ুন।

  • pushd /?
  • popd /?
  • rd /?

উইন্ডোজ ব্যাচ ফাইল ব্যবহার করে একাধিক কমান্ডের সাথে একক লাইন অপারেটরদের ব্যাখ্যা করে &&এবং &এখানে ব্যবহৃত।

পরবর্তী আমাদের ব্যাচ ফাইল সমাধান কমান্ড ব্যবহার করে দেখা যাক DEL ফাইল মুছে ফেলতে %PathToFolder%এবং জন্য এবং আরডি মধ্যে সাবফোল্ডার মুছে ফেলতে %PathToFolder%।

@echo off
setlocal EnableExtensions DisableDelayedExpansion

rem Clean the folder for temporary files if environment variable
rem PathToFolder is not defined already outside this batch file.
if not defined PathToFolder set "PathToFolder=%TEMP%"

rem Remove all double quotes from folder path.
set "PathToFolder=%PathToFolder:"=%"

rem Consisted the folder path only of double quotes?
if not defined PathToFolder goto EndCleanFolder

rem Remove a backslash at end of folder path.
if "%PathToFolder:~-1%" == "\" set "PathToFolder=%PathToFolder:~0,-1%"

rem Consisted folder path only of a backslash (with one or more double quotes)?
if not defined PathToFolder goto EndCleanFolder

rem Delete all files in specified folder including files with hidden
rem or read-only attribute set, except the files currently opened by
rem a running process which prevents deletion of the file while being
rem opened by the application, or on which the current user has not
rem the required permissions to delete the file.
del /A /F /Q "%PathToFolder%\*" >nul 2>nul

rem Delete all subfolders in specified folder including those with hidden
rem attribute set recursive with all files and subfolders, except folders
rem being the current directory of any running process which prevents the
rem deletion of the folder and all folders above, folders containing a file
rem opened by the application which prevents deletion of the file and the
rem entire folder structure to this file, or on which the current user has
rem not the required permissions to delete a folder or file in folder tree
rem to delete.
for /F "eol=| delims=" %%I in ('dir "%PathToFolder%\*" /AD /B 2^>nul') do rd /Q /S "%PathToFolder%\%%I" 2>nul

:EndCleanFolder
endlocal

ব্যাচ ফাইলটি প্রথমে নিশ্চিত করে যে পরিবেশের পরিবর্তনশীলটি PathToFolderডাবল কোট ছাড়াই এবং শেষে ব্যাকস্ল্যাশ ছাড়াই একটি ফোল্ডার পাথ দিয়ে সত্যই সংজ্ঞায়িত। ব্যাকস্ল্যাশটি শেষে কোনও সমস্যা হবে না তবে ফোল্ডারের পথে ডাবল উদ্ধৃতিগুলি সমস্যাযুক্ত হতে পারে কারণ PathToFolderব্যাচের ফাইল এক্সিকিউশন চলাকালীন অন্যান্য স্ট্রিংগুলির সাথে মানটির সাথে মিল রয়েছে।

দুটি লাইন গুরুত্বপূর্ণ:

del /A /F /Q "%PathToFolder%\*" >nul 2>nul
for /F "eol=| delims=" %%I in ('dir "%PathToFolder%\*" /AD /B 2^>nul') do rd /Q /S "%PathToFolder%\%%I" 2>nul

কমান্ড ডিল কমান্ডটি নির্দিষ্ট ডিরেক্টরিতে সমস্ত ফাইল মুছতে ব্যবহৃত হয়।

  • বিকল্পটি /Aহ'ল গুপ্ত বৈশিষ্ট্যযুক্ত ফাইল সহ সমস্ত ফাইল প্রক্রিয়া করার জন্য অপশনটি প্রয়োজনীয় যা ডিলেট বিকল্পটি ব্যবহার না করে উপেক্ষা করবে /A।
  • /Fকেবলমাত্র পঠনযোগ্য অ্যাট্রিবিউট সেট দিয়ে ফাইলগুলি মুছে ফেলার জন্য বিকল্পটি প্রয়োজনীয়।
  • /Qএকাধিক ফাইল সত্যিকার অর্থে মুছে ফেলা উচিত যদি ব্যবহারকারীকে অনুরোধ না করে একাধিক ফাইলের নিঃশব্দ মুছে ফেলার জন্য বিকল্পটি প্রয়োজনীয়।
  • >nulSTDOUT কে হ্যান্ডল করতে লিখিত ফাইল নামের আউটপুট পুনঃনির্দেশ করা প্রয়োজন ডিভাইসটিতে NUL এর মধ্যে মুছে ফেলা যায় না কারণ একটি ফাইল বর্তমানে খোলা আছে বা ব্যবহারকারীর ফাইল মুছার অনুমতি নেই।
  • 2>nulপ্রতিটি ফাইল যা হ্যান্ডেল থেকে মুছে ফেলা যাবে না জন্য ত্রুটির বার্তা আউটপুট পুনর্নির্দেশ করা প্রয়োজন stderr ডিভাইসে NUL ।

নির্দিষ্ট ডিরেক্টরিতে সমস্ত উপ-ডিরেক্টরি মুছে ফেলার জন্য ফর এবং আরডি কমান্ডগুলি ব্যবহৃত হয়। কিন্তু for /Dকারণ ব্যবহার করা হয় না জন্য গোপন বৈশিষ্ট্য সেট দিয়ে এই ক্ষেত্রে সাবডিরেক্টরি মধ্যে উপেক্ষা করা হয়। এই কারণে for /Fব্যাকগ্রাউন্ডে পৃথক কমান্ড প্রক্রিয়া শুরু করে নিম্নলিখিত কমান্ড লাইনটি চালানোর জন্য ব্যবহৃত হয় %ComSpec% /c:

dir "%PathToFolder%\*" /AD /B 2>nul

ডিআর আউটপুটগুলি খালি ফর্ম্যাটে কারণ /Bঅ্যাট্রিবিউটের সাথে ডিরেক্টরি এন্ট্রি D, অর্থাত্ নির্দিষ্ট ডিরেক্টরিতে থাকা সমস্ত উপ-ডিরেক্টরিগুলির নাম যেমন কোনও পাথ ছাড়াই লুকানো অ্যাট্রিবিউটের মতো আলাদা বৈশিষ্ট্যগুলিতে স্বাধীন। 2>nulদ্বারা ত্রুটির বার্তা আউটপুট পুনর্নির্দেশ করতে ব্যবহৃত হয় থেকে DIR কোনো সংগ্রহ নেই হাতল থেকে পাওয়া উপর stderr ডিভাইসে NUL ।

ফেরৎ অপারেটর >ক্যারেট অক্ষর দিয়ে পালিয়ে করা আবশ্যক, ^, উপর জন্য কমান্ড লাইন একটি আক্ষরিক চরিত্র যখন উইন্ডোজ কমান্ড অনুবাদক কমান্ড নির্বাহ করার আগে এই কমান্ড লাইন প্রক্রিয়া হিসেবে ব্যাখ্যা করা জন্য যা এমবেডেড executes dirএকটি পৃথক কমান্ড প্রক্রিয়ায় কমান্ড লাইন শুরু পটভূমিতে.

জন্য প্রসেস বন্দী আউটপুট হ্যান্ডেল লেখা stdout- এ একটি শুরু কমান্ড প্রক্রিয়া যার পথ ছাড়া সাবডিরেক্টরি নাম এবং উদ্ধৃতি চিহ্ন মধ্যে লেখা কখনোই হয়।

জন্য বিকল্প /Fখালি লাইন যা এখানে ঘটবে না উপেক্ষা করে থেকে DIR বিকল্প /Bনা আউটপুট খালি লাইন আছে।

জন্য একটি সেমিকোলন যা লাইন চরিত্র ডিফল্ট শেষ দিয়ে শুরু লাইন উপেক্ষা করবে। একটি ডিরেক্টরি নাম একটি সেমিকোলন দিয়ে শুরু করতে পারেন। এই কারণেই eol=|উল্লম্ব বার অক্ষরকে শেষ-পংক্তির অক্ষর হিসাবে সংজ্ঞায়িত করতে ব্যবহৃত হয় যা কোনও ডিরেক্টরি বা ফাইলের নামে থাকতে পারে না।

জন্য স্থান এবং অনুভূমিক ট্যাবটি ডিলিমিটার হিসাবে লাইনটি সাবস্ট্রিংগুলিতে বিভক্ত করবে এবং নির্দিষ্ট লুপ ভেরিয়েবলের জন্য কেবল প্রথম স্থান / ট্যাব সীমিত স্ট্রিং সরবরাহ করবে I। এই বিভাজনমূলক আচরণটি এখানে চাওয়া হয়নি কারণ একটি ডিরেক্টরি নামে এক বা একাধিক স্পেস থাকতে পারে। সুতরাং delims=লাইন বিভাজন আচরণ অক্ষম করতে লুপ ভেরিয়েবল I, সর্বদা সম্পূর্ণ ডিরেক্টরি নাম হিসাবে নির্ধারিত করার জন্য সীমান্তকারীদের একটি খালি তালিকা সংজ্ঞায়িত করতে ব্যবহৃত হয় ।

কমান্ড ফর কমান্ড আরডি কমান্ডটি প্রতিটি ডিরেক্টরি নামের জন্য কোনও পাথ ছাড়াই চালিত করে যে কারণটি আরডি কমান্ড লাইনে ফোল্ডারটির পথটি আবার অবশ্যই নির্দিষ্ট করতে হবে যা সাবফোল্ডার নামের সাথে সংযুক্ত হয়।

ব্যবহৃত কমান্ডগুলি বোঝার জন্য এবং তারা কীভাবে কাজ করে তা জানতে একটি কমান্ড প্রম্পট উইন্ডোটি খুলুন, নিম্নলিখিত কমান্ডগুলি সম্পাদন করুন এবং প্রতিটি কমান্ডের জন্য প্রদর্শিত সমস্ত সহায়তা পৃষ্ঠাগুলি খুব মনোযোগ সহকারে পড়ুন।

  • del /?
  • dir /?
  • echo /?
  • endlocal /?
  • for /?
  • goto /?
  • if /?
  • rd /?
  • rem /?
  • set /?
  • setlocal /?
— Mofi
সূত্র
5

একটি পাঠ্য নথি তৈরি করতে এবং এটি অনুলিপি / আটকানোর জন্য নোটপ্যাড ব্যবহার করুন :

rmdir /s/q "%temp%"
mkdir "%temp%"

ফাইল হিসাবে নাম সংরক্ষণ করুন :

delete_temp.bat

প্রকার হিসাবে সংরক্ষণ করুন: সমস্ত ফাইল এবং Saveবোতামটি ক্লিক করুন ।

এটি যে কোনও ধরণের অ্যাকাউন্টে (প্রশাসক বা একটি মানক ব্যবহারকারী) কাজ করে। শুধু এটি চালান!

আমি এই উদাহরণে একটি অস্থায়ী পরিবর্তনশীল ব্যবহার করি তবে আপনি অন্য কোনও ব্যবহার করতে পারেন! PS: শুধুমাত্র উইন্ডোজ ওএসের জন্য!

— ফিলিপ গোজর্জেভিক্জ
সূত্র
একটি বেশ সহজ এবং পরিষ্কার সমাধান
— কার্লোস লিউ
4

ফাইল মুছতে:

del PATH_TO_FILE

এতে সমস্ত ফাইল সহ ফোল্ডার মুছতে:

rmdir /s /q PATH_TO_FOLDER

নির্দিষ্ট ফোল্ডার থেকে সমস্ত ফাইল মুছতে (ফোল্ডারটি নিজেই মোছা নয়) কিছুটা জটিল। del /s *.*ফোল্ডারগুলি মুছতে পারে না, তবে সমস্ত সাবফোল্ডার থেকে ফাইলগুলি সরিয়ে দেয়। সুতরাং দুটি কমান্ডের প্রয়োজন:

del /q PATH_TO_FOLDER\*.*
for /d %i in (PATH_TO_FOLDER\*.*) do @rmdir /s /q "%i"
— ম্যাক্সিম সুস্লোভ
সূত্র
হ্যাঁ এটি সঠিক। অবশ্যই দুটি ধাপ হতে হবে। এটি আরও উত্সাহের দাবিদার, কারণ এটি উপরোক্ত আরও বেশি ভোট প্রাপ্ত উত্তরের সাথে তুলনা করে কেন তা ব্যাখ্যা করে।
— ওয়েস্টার্নগুন
DEL কমান্ড লাইন শটটি বিকল্প /Aমুছে লুকানো বৈশিষ্ট্য সেট এবং বিকল্প ফাইল /Fএছাড়াও মুছে ফেলতে শুধুমাত্র পাঠযোগ্য বৈশিষ্ট্য সেট এবং গত যুক্তি প্রায় ডবল কোট সঙ্গে ফাইল। তাই del /A /F /Q "PATH_TO_FOLDER\*"আরও ভাল হবে। এবং ফর কমান্ড লাইনটি সংশোধন করা উচিত for /F "eol=| delims=" %%I in ('dir "PATH_TO_FOLDER\*" /AD /B 2^>nul') do rd /Q /S "PATH_TO_FOLDER\%%I"কারণ ফর লুকানো অ্যাট্রিবিউট সেট সহ ডিরেক্টরিগুলি উপেক্ষা করে। বিকল্পগুলির সাথে ডিআইআর কেবল তাদের নাম দিয়ে সমস্ত ডিরেক্টরি /AD /Bআউটপুট করে । PATH_TO_FOLDER
— মফি
এটি পূর্বের উত্তরগুলির (কিছু) থেকে কীভাবে আলাদা?
— পিটার মর্টেনসেন
4

সমস্ত কন্টেন্ট এবং প্যারেন্ট ফোল্ডার নিজেই মুছতে নিম্নলিখিত কমান্ডটি ব্যবহার করে আপনি এটি করতে পারেন: 

RMDIR [/S] [/Q] [drive:]path
— রিপন আল ওয়াসিম
সূত্র
এটি আগের দুটি উত্তর থেকে কীভাবে আলাদা?
— পিটার মর্টেনসেন
এই উত্তরটি কী "এই ফাইল / ফোল্ডারটি ইতিমধ্যে ব্যবহারে রয়েছে" এর মতো একটি ত্রুটি থাকতে পারে ... এর প্রয়োজনীয়তার সমাধান করে ... যখন এটি ঘটে তখন এটি কেবল চালিয়ে যাওয়া উচিত এবং সেই ফাইল / ফোল্ডারটি এড়ানো উচিত "" ?
— পিটার মর্টেনসেন
1

আমি এই পদ্ধতির বেশ কয়েকটি চেষ্টা করেছিলাম, তবে কেউই সঠিকভাবে কাজ করেনি।

আমি উইন্ডোজ কমান্ড লাইন সাইটে এই দ্বি-পদক্ষেপের পদ্ধতিটি পেয়েছি :

forfiles /P %pathtofolder% /M * /C "cmd /c if @isdir==FALSE del @file"

forfiles /P %pathtofolder%  /M * /C "cmd /c if @isdir==TRUE rmdir /S /Q @file"

এটি আমার যেমন প্রয়োজন তেমনই ওপি দ্বারা নির্দিষ্ট হিসাবে কাজ করেছিল।

— পল হান
সূত্র
দুটি কমান্ড লাইনকে একটি কমান্ড লাইনে একত্রিত করা যেতে পারে: হাইড অ্যাট্রিবিউট সেট সহ ফাইলগুলি মুছে ফেলার জন্য forfiles /P "%pathtofolder%" /M * /C "%SystemRoot%\System32\cmd.exe /C if @isdir==FALSE (del /A /F @file) else rd /Q /S @file" ডেল বিকল্প /Aযুক্ত করা হয় অন্যথায় ডেল এতে প্রতিটি লুকানো ফাইলের জন্য খুঁজে পাওয়া যায় না এমন ত্রুটি বার্তা আউটপুট দেয় %pathtofolder%। কেবলমাত্র পঠনযোগ্য বৈশিষ্ট্যযুক্ত ফাইলগুলিও মুছে ফেলার জন্য ডেল বিকল্প /Fযুক্ত করা হয়েছে %pathtofolder%কারণ অন্যথায় ডেল কোনও অ্যাক্সেস প্রত্যাখ্যান ত্রুটি বার্তাকে আউটপুট দেয়।
— মফি
cmd.exeপ্রতিটি ফাইল এবং প্রতিটি ডিরেক্টরি এর জন্য উদাহরণ শুরু করার কারণে এই সমাধানটি এখানে পোস্ট করা সমস্ত অসম্পূর্ণ সমাধানগুলির চেয়ে ধীরতম %pathtofolder%। সুবিধা হল FORFILES গোপন বৈশিষ্ট্য সেট হিসাবে সঙ্গে ডিরেক্টরি উপেক্ষা না করার জন্য নয়।
— মফি
পুনরায় "এটি আমার যেমন প্রয়োজন ঠিক তেমনই কাজ করেছে এবং ওপি দ্বারা নির্দিষ্ট করেছে" " : আপনি কি "এই ফাইলটি / ফোল্ডারটি ইতিমধ্যে ব্যবহারে রয়েছে" এর মতো একটি ত্রুটি হতে পারে ... প্রয়োজনীয়তার জন্য পরীক্ষা করেছিলেন ... যখন এটি ঘটে তখন এটি কেবল চালিয়ে যাওয়া উচিত এবং সেই ফাইল / ফোল্ডারটি এড়ানো উচিত "" ?
— পিটার মর্টেনসেন
0 
@ECHO OFF
rem next line removes all files in temp folder
DEL /A /F /Q /S "%temp%\*.*"
rem next line cleans up the folder's content
FOR /D %%p IN ("%temp%\*.*") DO RD "%%p" /S /Q
— Robie
সূত্র
২ য় লাইন উইন্ডো টেম্প ডিরেক্টরিতে সমস্ত ফোল্ডার থেকে প্রতিটি ফাইলের ফাইলগুলি সরিয়ে দেবে এবং তৃতীয় লাইনটি এর বিষয়বস্তু সহ ডিরেক্টরিগুলি মুছে ফেলবে।
— রবি
কমান্ড লাইনটির জন্য সংশোধন করা উচিত for /F "eol=| delims=" %%I in ('dir "%TEMP%\*" /AD /B 2^>nul') do rd /Q /S "%TEMP%\%%I"কারণ ফর লুকানো অ্যাট্রিবিউট সেট সহ ডিরেক্টরিগুলি উপেক্ষা করে। বিকল্পগুলির সাথে ডিআইআর সমস্ত ডিরেক্টরিকে /AD /Bআউটপুট করে%TEMP% কেবল তাদের নাম দিয়ে ।
— মফি
ডিলের জন্য ডকুমেন্টেশন । আমি মনে করি আপনি / এফ দিয়ে সঠিক পথে
— পিটার মর্টেনসেন
-10

ব্যবহার করুন:

del %pathtofolder%\*.*   /s /f  /q

এটি %pathtofolder%কেবলমাত্র পঠনযোগ্য ফাইলগুলি সহ সমস্ত ফাইল এবং সাবফোল্ডারগুলি মুছে দেয় এবং নিশ্চিতকরণের জন্য অনুরোধ করে না।

— alôn
সূত্র
9
আমার শত্রু এটি% প্যাথফোল্ডার% এ খালি সাবফোল্ডারগুলি ফেলে leaves
— ডিএইচ
35
এটি% টি প্যাথফোল্ডার% এ সাবফোল্ডারগুলি মুছে না। এত খারাপ যে এই মিথ্যা উত্তরটি দিয়ে আমার ভোট দেওয়ার মতো কোনও খ্যাতি নেই
— ভিটালি কোর্সাকভ
1
ভাইটালি কর্সাকভের নির্দেশ অনুসারে, এটি সাব-ডাইরেক্টরিগুলি থেকে সমস্ত ফাইল এবং ফাইলগুলি মুছে ফেলে তবে ওপেন ডিরেক্টরিটিকে সেই জায়গায় রেখে দেয় যা ওপি কীভাবে অপসারণ করতে চেয়েছিল।
— ফজ ইভান্স
6
যদিও এই কমান্ডটি খালি ফোল্ডারগুলি ছেড়ে দেয়, এটি গৃহীত উত্তরের চেয়ে অনুরোধ করা হয়েছিল, তার থেকে অনেক বেশি কাছাকাছি। অবশ্যই এই পরিস্থিতিতে অবনতি। আমার ক্ষেত্রে, রুট ডিরেক্টরিতে থাকা ফাইলের চেয়ে আমার খালি ফোল্ডার থাকতে হবে।
— মার্কাসুএএ
কিন্তু অন্যান্য ক্লায়েন্ট মেশিনের সেই ফোল্ডারে লেখার অ্যাক্সেস থাকা শেয়ার ড্রাইভটি খুললে নেটওয়ার্ক শেয়ারে খোলা ফোল্ডার এবং সাব-ফোল্ডারটি কীভাবে আমরা মুছতে পারি .. PSfile এবং নেট ফাইল কমান্ড ফাইল সেশনটি বন্ধ করে দেবে তবে কয়েক সেকেন্ড পরে এটি তৈরি হবে স্বয়ংক্রিয়ভাবে সার্ভারে সেই ব্যবহারকারীর জন্য অন্য একটি অধিবেশন ...
— 1954762
আমাদের সাইট ব্যবহার করে, আপনি স্বীকার করেছেন যে আপনি আমাদের কুকি নীতি এবং গোপনীয়তা নীতিটি পড়েছেন এবং বুঝতে পেরেছেন ।
Licensed under cc by-sa 3.0 with attribution required.