এসকিউএল সার্ভার: সমস্ত আপের কেস প্রপার কেস / শিরোনাম কেস করুন

Question 1

আমার কাছে একটি টেবিল রয়েছে যা সমস্ত UPPER CASE হিসাবে আমদানি করা হয়েছিল এবং আমি এটিকে যথাযথ ক্ষেত্রে রূপান্তর করতে চাই। আপনার কোন স্ক্রিপ্ট এটি সম্পূর্ণ করতে ব্যবহৃত হয়েছে?

Question 2

এখানে একটি ইউডিএফ রয়েছে যা কৌশলটি করবে ...

create function ProperCase(@Text as varchar(8000))
returns varchar(8000)
as
begin
  declare @Reset bit;
  declare @Ret varchar(8000);
  declare @i int;
  declare @c char(1);

  if @Text is null
    return null;

  select @Reset = 1, @i = 1, @Ret = '';

  while (@i <= len(@Text))
    select @c = substring(@Text, @i, 1),
      @Ret = @Ret + case when @Reset = 1 then UPPER(@c) else LOWER(@c) end,
      @Reset = case when @c like '[a-zA-Z]' then 0 else 1 end,
      @i = @i + 1
  return @Ret
end

আপনার ডেটা আপডেট করার জন্য আপনাকে এখনও এটি ব্যবহার করতে হবে।

Question 3

এই ফাংশন:

"যথাযথ কেস" সমস্ত "UPPER CASE" শব্দ যা শ্বেত স্থান দ্বারা সীমিত করা হয়
"লোয়ার কেস শব্দ" একা ছেড়ে দেয়
এমনকি অ-ইংরেজি বর্ণমালার জন্যও সঠিকভাবে কাজ করে
এটি বহনযোগ্য যে এটি সাম্প্রতিক এসকিউএল সার্ভার সংস্করণগুলির অভিনব বৈশিষ্ট্যগুলি ব্যবহার করে না
ইউনিকোড সমর্থনের জন্য এনসিএইচআর এবং এনভিচারচার ব্যবহার করার জন্য সহজেই পরিবর্তন করা যেতে পারে, পাশাপাশি আপনি যে কোনও প্যারামিটার দৈর্ঘ্যেরও উপযুক্ত দেখেন
সাদা স্থান সংজ্ঞা কনফিগার করা যেতে পারে

CREATE FUNCTION ToProperCase(@string VARCHAR(255)) RETURNS VARCHAR(255)
AS
BEGIN
  DECLARE @i INT           -- index
  DECLARE @l INT           -- input length
  DECLARE @c NCHAR(1)      -- current char
  DECLARE @f INT           -- first letter flag (1/0)
  DECLARE @o VARCHAR(255)  -- output string
  DECLARE @w VARCHAR(10)   -- characters considered as white space

  SET @w = '[' + CHAR(13) + CHAR(10) + CHAR(9) + CHAR(160) + ' ' + ']'
  SET @i = 1
  SET @l = LEN(@string)
  SET @f = 1
  SET @o = ''

  WHILE @i <= @l
  BEGIN
    SET @c = SUBSTRING(@string, @i, 1)
    IF @f = 1 
    BEGIN
     SET @o = @o + @c
     SET @f = 0
    END
    ELSE
    BEGIN
     SET @o = @o + LOWER(@c)
    END

    IF @c LIKE @w SET @f = 1

    SET @i = @i + 1
  END

  RETURN @o
END

ফলাফল:

dbo.ToProperCase('ALL UPPER CASE and    SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')
-----------------------------------------------------------------
All Upper Case and      Some lower Ää Öö Üü Éé Øø Cc Ææ

Question 4

UPDATE titles
  SET title =
      UPPER(LEFT(title, 1)) +
        LOWER(RIGHT(title, LEN(title) - 1))

http://sqlmag.com/t-sql/how-title-case-column-value

Question 5

আপনি যদি এসকিউএল সার্ভারে সিএলআর সক্ষম করতে পারেন (2005 বা তার পরে প্রয়োজন) তবে আপনি একটি সিএলআর ফাংশন তৈরি করতে পারেন যা টেক্সটইনফো.টোটিটেলকেস অন্তর্নির্মিত ফাংশন ব্যবহার করে যা আপনাকে কেবল কয়েকটি ক্ষেত্রে এটি করার সংস্কৃতি-সচেতন উপায় তৈরি করতে দেয় would কোড লাইন।

Question 6

আমি জানি এই থ্রেডে এটি দেরী পোস্ট তবে, দেখার মতো। এই ফাংশন আমার জন্য সর্বদা কাজ করে। তাই ভাগ করে নেওয়ার কথা ভেবেছি।

CREATE FUNCTION [dbo].[fnConvert_TitleCase] (@InputString VARCHAR(4000) )
RETURNS VARCHAR(4000)
AS
BEGIN
DECLARE @Index INT
DECLARE @Char CHAR(1)
DECLARE @OutputString VARCHAR(255)

SET @OutputString = LOWER(@InputString)
SET @Index = 2
SET @OutputString = STUFF(@OutputString, 1, 1,UPPER(SUBSTRING(@InputString,1,1)))

WHILE @Index <= LEN(@InputString)
BEGIN
    SET @Char = SUBSTRING(@InputString, @Index, 1)
    IF @Char IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&','''','(')
    IF @Index + 1 <= LEN(@InputString)
BEGIN
    IF @Char != ''''
    OR
    UPPER(SUBSTRING(@InputString, @Index + 1, 1)) != 'S'
    SET @OutputString =
    STUFF(@OutputString, @Index + 1, 1,UPPER(SUBSTRING(@InputString, @Index + 1, 1)))
END
    SET @Index = @Index + 1
END

RETURN ISNULL(@OutputString,'')
END

পরীক্ষা কল:

select dbo.fnConvert_TitleCase(Upper('ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')) as test
select dbo.fnConvert_TitleCase(upper('Whatever the mind of man can conceive and believe, it can achieve. – Napoleon hill')) as test

ফলাফল:

এখানে চিত্র বর্ণনা লিখুন

Question 7

আমি খেলায় কিছুটা দেরি করেছি, তবে আমি বিশ্বাস করি এটি আরও কার্যকরী এবং এটি রাশিয়ান, জার্মান, থাই, ভিয়েতনামিজ ইত্যাদি সহ যে কোনও ভাষার সাথে কাজ করে, এটি 'বা - বা' এর পরে বড় হাতের কিছু তৈরি করবে। বা (বা) বা স্পেস (স্পষ্টত :)।

CREATE FUNCTION [dbo].[fnToProperCase]( @name nvarchar(500) )
RETURNS nvarchar(500)
AS
BEGIN
declare @pos    int = 1
      , @pos2   int

if (@name <> '')--or @name = lower(@name) collate SQL_Latin1_General_CP1_CS_AS or @name = upper(@name) collate SQL_Latin1_General_CP1_CS_AS)
begin
    set @name = lower(rtrim(@name))
    while (1 = 1)
    begin
        set @name = stuff(@name, @pos, 1, upper(substring(@name, @pos, 1)))
        set @pos2 = patindex('%[- ''.)(]%', substring(@name, @pos, 500))
        set @pos += @pos2
        if (isnull(@pos2, 0) = 0 or @pos > len(@name))
            break
    end
end

return @name
END
GO

Question 8

আপনি যদি এসআইএসআইএস ডেটা আমদানিতে রয়েছেন যা কেস মিশ্রিত হয়েছে এবং যথাযথ ক্ষেত্রে একটি কলামে একটি অনুসন্ধান করার প্রয়োজন রয়েছে তবে আপনি লক্ষ্য করবেন যে উত্সটি মিশ্রিত এবং অনুসন্ধানের উত্সটি যথাযথ যেখানে অনুসন্ধান ব্যর্থ হয়েছে। এছাড়াও আপনি খেয়াল করবেন যে ডাইর এবং বাম ফাংশনগুলি ব্যবহার করতে পারবেন না ডাইরেক্ট কলামগুলির জন্য এসকিউএল সার্ভার 2008r2 এর জন্য এসএসআইএস। এখানে আমার জন্য কার্যকর একটি সমাধান রয়েছে:

UPPER(substring(input_column_name,1,1)) + LOWER(substring(input_column_name, 2, len(input_column_name)-1))

Question 9

এখানে এমন একটি সংস্করণ যা লুপের পরিবর্তে ক্রম বা সংখ্যা সারণী ব্যবহার করে। কোনও চরিত্রকে কখন বড় হাতের অক্ষরে রূপান্তর করা যায় তার জন্য আপনি ব্যক্তিগত বিধিগুলিকে স্যুইট করার জন্য WHERE ধারাটি সংশোধন করতে পারেন। আমি কেবল একটি সহজ সেট অন্তর্ভুক্ত করেছি যা অ্যাডাস্ট্রোফেস ব্যতীত কোনও নন-চিঠি দ্বারা চালিত যে কোনও অক্ষরের বড় হাতের অক্ষর করবে। এর অর্থ কীভাবে হয় যে 123apple এর "a" তে ম্যাচ হবে কারণ "3" কোনও চিঠি নয়। আপনি যদি কেবল সাদা-স্থান (স্থান, ট্যাব, ক্যারেজ-রিটার্ন, লাইন-ফিড) চান তবে আপনি প্যাটার্নটি এটির '[^a-z]'সাথে প্রতিস্থাপন করতে পারেন '[' + Char(32) + Char(9) + Char(13) + Char(10) + ']'।

CREATE FUNCTION String.InitCap( @string nvarchar(4000) ) RETURNS nvarchar(4000) AS
BEGIN

-- 1. Convert all letters to lower case
    DECLARE @InitCap nvarchar(4000); SET @InitCap = Lower(@string);

-- 2. Using a Sequence, replace the letters that should be upper case with their upper case version
    SELECT @InitCap = Stuff( @InitCap, n, 1, Upper( SubString( @InitCap, n, 1 ) ) )
    FROM (
        SELECT (1 + n1.n + n10.n + n100.n + n1000.n) AS n
        FROM       (SELECT 0 AS n UNION SELECT    1 UNION SELECT    2 UNION SELECT    3 UNION SELECT    4 UNION SELECT    5 UNION SELECT    6 UNION SELECT    7 UNION SELECT    8 UNION SELECT    9) AS    n1
        CROSS JOIN (SELECT 0 AS n UNION SELECT   10 UNION SELECT   20 UNION SELECT   30 UNION SELECT   40 UNION SELECT   50 UNION SELECT   60 UNION SELECT   70 UNION SELECT   80 UNION SELECT   90) AS   n10
        CROSS JOIN (SELECT 0 AS n UNION SELECT  100 UNION SELECT  200 UNION SELECT  300 UNION SELECT  400 UNION SELECT  500 UNION SELECT  600 UNION SELECT  700 UNION SELECT  800 UNION SELECT  900) AS  n100
        CROSS JOIN (SELECT 0 AS n UNION SELECT 1000 UNION SELECT 2000 UNION SELECT 3000)                                                                                                             AS n1000
        ) AS Sequence
    WHERE 
        n BETWEEN 1 AND Len( @InitCap )
    AND SubString( @InitCap, n, 1 ) LIKE '[a-z]'                 /* this character is a letter */
    AND (
        n = 1                                                    /* this character is the first `character` */
        OR SubString( @InitCap, n-1, 1 ) LIKE '[^a-z]'           /* the previous character is NOT a letter */
        )
    AND (
        n < 3                                                    /* only test the 3rd or greater characters for this exception */
        OR SubString( @InitCap, n-2, 3 ) NOT LIKE '[a-z]''[a-z]' /* exception: The pattern <letter>'<letter> should not capatolize the letter following the apostrophy */
        )

-- 3. Return the modified version of the input
    RETURN @InitCap

END

Question 10

উপরে যে লিঙ্কটি পোস্ট করেছি তা হ'ল একটি দুর্দান্ত বিকল্প যা মূল ইস্যুটিকে সম্বোধন করে: যে আমরা কখনই প্রোগ্রামিকভাবে সমস্ত ক্ষেত্রে (স্মিথ-জোন্স, ফন হাউসন, জন স্মিথ এমডি) অ্যাকাউন্ট করতে পারি না, কমপক্ষে মার্জিত উপায়ে নয়। টনি এই ক্ষেত্রে মোকাবেলা করার জন্য একটি ব্যতিক্রম / বিরতি চরিত্রের ধারণাটি প্রবর্তন করে। যাইহোক, সার্ভোর ধারণার ভিত্তিতে (স্থানের পূর্বে সমস্ত নিম্ন বর্ণগুলি উপরে) প্রতিস্থাপনের বিবৃতিগুলি পরিবর্তে পরিবর্তে একটি একক টেবিলের ভিত্তিতে প্রতিস্থাপন করা যেতে পারে। সত্যিই, কোনও নিম্ন / আপ অক্ষর সংমিশ্রণটি @ আলফায় প্রবেশ করানো যেতে পারে এবং বিবৃতিটি বদলাবে না:

declare @str    nvarchar(8000)
declare @alpha  table (low nchar(1), up nchar(1))


set @str = 'ALL UPPER CASE and    SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ'

-- stage the alpha (needs number table)
insert into @alpha
    -- A-Z / a-z
    select      nchar(n+32),
                nchar(n)
    from        dbo.Number
    where       n between 65 and 90 or
                n between 192 and 223

-- append space at start of str
set @str = lower(' ' + @str)

-- upper all lower case chars preceded by space
select  @str = replace(@str, ' ' + low, ' ' + up) 
from    @Alpha

select @str

Question 11

ভন নিউম্যানস, ম্যাককেইনস, ডিজিউজম্যানস এবং জনসন-স্মিথের যত্ন নেওয়ার ক্ষেত্রে ব্যতিক্রমগুলির অনুসন্ধানের বিষয়টি বজায় রাখা অর্থপূর্ণ হবে।

Question 12

@ রিচার্ড সায়াকানিত উত্তরে ধার এবং উন্নত। এটি একাধিক শব্দ পরিচালনা করে। তার উত্তরের মতো, এটি কোনও ইউডিএফ ব্যবহার করে না, কেবল বিল্ট-ইন ফাংশন ( STRING_SPLITএবং STRING_AGG) এবং এটি বেশ দ্রুত। STRING_AGGএসকিউএল সার্ভারের প্রয়োজন 2017 তবে আপনি সর্বদা STUFF/XMLকৌশলটি ব্যবহার করতে পারেন । প্রতিটি ব্যতিক্রম হ্যান্ডেল করবে না তবে অনেক প্রয়োজনীয়তার জন্য দুর্দান্ত কাজ করতে পারে।

SELECT StateName = 'North Carolina' 
INTO #States
UNION ALL
SELECT 'Texas'


;WITH cteData AS 
(
    SELECT 
        UPPER(LEFT(value, 1)) +
            LOWER(RIGHT(value, LEN(value) - 1)) value, op.StateName
    FROM   #States op
    CROSS APPLY STRING_SPLIT(op.StateName, ' ') AS ss
)
SELECT 
    STRING_AGG(value, ' ')
FROM cteData c 
GROUP BY StateName

Question 13

@ গ্যালুয়ানির উত্তরে একটি সামান্য পরিবর্তন - যা উদাহরণস্বরূপ St Elizabeth'sপরিণত হয় St Elizabeth'S।

এই পরিবর্তনটি অ্যাডাস্ট্রোফ-এসকে লোয়ারকেস হিসাবে রাখে যেখানে সরবরাহিত স্ট্রিংয়ের শেষে এসগুলি আসে বা তার পরে একটি স্থান (এবং কেবলমাত্র সেই পরিস্থিতিতে) থাকে।

create function properCase(@text as varchar(8000))
returns varchar(8000)
as
begin
    declare @reset int;
    declare @ret varchar(8000);
    declare @i int;
    declare @c char(1);
    declare @d char(1);

    if @text is null
    return null;

    select @reset = 1, @i = 1, @ret = '';

    while (@i <= len(@text))
    select
        @c = substring(@text, @i, 1),
        @d = substring(@text, @i+1, 1),
        @ret = @ret + case when @reset = 1 or (@reset=-1 and @c!='s') or (@reset=-1 and @c='s' and @d!=' ') then upper(@c) else lower(@c) end,
        @reset = case when @c like '[a-za-z]' then 0 when @c='''' then -1 else 1 end,
        @i = @i + 1
    return @ret
end

এটা আবর্তন করে:

st elizabeth's মধ্যে St Elizabeth's
o'keefe মধ্যে O'Keefe
o'sullivan মধ্যে O'Sullivan

অন্যদের মন্তব্য যে অ-ইংরাজী ইনপুটটির জন্য বিভিন্ন সমাধান পছন্দনীয় the

Question 14

আমি মনে করি আপনি দেখতে পাবেন যে নিম্নলিখিতগুলি আরও কার্যকর:

IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
    DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
    @str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
    SET @str = ' ' + @str
    SET @str = REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE( @str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z')
    RETURN RIGHT(@str, LEN(@str) - 1)
END
GO

প্রতিস্থাপনের বিবৃতিটি সরাসরি এসকিউএল কোয়েরিতে কাটা এবং আটকানো যায়। এটি অতি কুরুচিপূর্ণ, তবে আপনার আগ্রহী কলামটির পরিবর্তে @str এর পরিবর্তে, আপনি যেমন পোস্ট হওয়া ইউডিএফদের সাথে একটি প্রচ্ছন্ন কার্সারের জন্য কোনও মূল্য দিতে হবে না। আমি দেখতে পেয়েছি যে এমনকি আমার ইউডিএফ ব্যবহার করা এটি আরও কার্যকর।

ওহ এবং পরিবর্তে হাত দ্বারা প্রতিস্থাপন বিবৃতি উত্পন্ন করার জন্য এটি ব্যবহার করুন:

-- Code Generator for expression
DECLARE @x  INT,
    @c  CHAR(1),
    @sql    VARCHAR(8000)
SET @x = 0
SET @sql = '@str' -- actual variable/column you want to replace
WHILE @x < 26
BEGIN
    SET @c = CHAR(ASCII('a') + @x)
    SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+  ''', '' ' + UPPER(@c) + ''')'
    SET @x = @x + 1
END
PRINT @sql

যাইহোক এটি সারি সংখ্যার উপর নির্ভর করে। আমি আশা করি আপনি কেবল এস / \ বি ([এজেড]) / ইউসি $ 1 / করতে পারতেন তবে ওহ ভাল আমরা আমাদের সরঞ্জামগুলি নিয়ে কাজ করি।

দ্রষ্টব্য যেহেতু আপনাকে এটি ব্যবহার করতে হবে তেমনটি আপনাকে .... যেমন dbo.ProperCase (LOWER (কলাম)) নির্বাচন করুন যেহেতু কলামটি বড় হাতের অক্ষরে রয়েছে। এটি আমার 5000 টি এন্ট্রি (এমনকি এক সেকেন্ডও নয়) এমনকি নীচের সাথে আমার টেবিলে বেশ দ্রুত কাজ করে।

আন্তর্জাতিকীকরণ সম্পর্কিত মন্তব্যগুলির উদ্রেকের প্রতিক্রিয়ায় আমি নিম্নলিখিত প্রয়োগটি উপস্থাপন করি যা কেবলমাত্র এসকিউএল সার্ভারের উপরের এবং নিম্নের প্রয়োগের উপর নির্ভর করে প্রতিটি আসকি চরিত্র পরিচালনা করে। মনে রাখবেন, আমরা এখানে যে ভেরিয়েবলগুলি ব্যবহার করছি তা হ'ল ভ্রচার (যার অর্থ তারা কেবলমাত্র ASCII মান রাখতে পারে)। আরও আন্তর্জাতিক বর্ণমালা ব্যবহার করতে, আপনাকে এনভিচারার ব্যবহার করতে হবে। যুক্তিটি একই রকম হতে পারে তবে আপনাকে ASCII এবং CHAR এর জায়গায় ইউনিকোড এবং এনসিএইচআর ব্যবহার করতে হবে এবং প্রতিস্থাপনের বিবৃতিটি আরও অনেক বিশাল হবে ....

-- Code Generator for expression
DECLARE @x  INT,
    @c  CHAR(1),
    @sql    VARCHAR(8000),
    @count  INT
SEt @x = 0
SET @count = 0
SET @sql = '@str' -- actual variable you want to replace
WHILE @x < 256
BEGIN
    SET @c = CHAR(@x)
    -- Only generate replacement expression for characters where upper and lowercase differ
    IF @x = ASCII(LOWER(@c)) AND @x != ASCII(UPPER(@c))
    BEGIN
        SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+  ''', '' ' + UPPER(@c) + ''')'
        SET @count = @count + 1
    END
    SET @x = @x + 1
END
PRINT @sql
PRINT 'Total characters substituted: ' + CONVERT(VARCHAR(255), @count)

মূলত আমার পদ্ধতির ভিত্তি দক্ষতার জন্য প্রাক-কম্পিউটিং ট্রেড করছে। সম্পূর্ণ ASCII বাস্তবায়ন নিম্নরূপ:

IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
    DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
    @str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
    SET @str = ' ' + @str
SET @str =     REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(@str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z'), ' š', ' Š'), ' œ', ' Œ'), ' ž', ' Ž'), ' à', ' À'), ' á', ' Á'), ' â', ' Â'), ' ã', ' Ã'), ' ä', ' Ä'), ' å', ' Å'), ' æ', ' Æ'), ' ç', ' Ç'), ' è', ' È'), ' é', ' É'), ' ê', ' Ê'), ' ë', ' Ë'), ' ì', ' Ì'), ' í', ' Í'), ' î', ' Î'), ' ï', ' Ï'), ' ð', ' Ð'), ' ñ', ' Ñ'), ' ò', ' Ò'), ' ó', ' Ó'), ' ô', ' Ô'), ' õ', ' Õ'), ' ö', ' Ö'), ' ø', ' Ø'), ' ù', ' Ù'), ' ú', ' Ú'), ' û', ' Û'), ' ü', ' Ü'), ' ý', ' Ý'), ' þ', ' Þ'), ' ÿ', ' Ÿ')
    RETURN RIGHT(@str, LEN(@str) - 1)
END
GO

Question 15

ফিরে গিয়ে অবহেলিত ডেটা পেতে কি খুব দেরি হচ্ছে?

আপনার ক্লায়েন্ট বেসের ভন নিউম্যান্স, ম্যাককেইনস, ডিজিউজম্যানস এবং জনসন-স্মিথ আপনার প্রসেসিংয়ের ফলাফল পছন্দ করতে পারে না ...

এছাড়াও, আমি অনুমান করছি যে এটি ডেটাগুলির এক-সময়ের আপগ্রেড হওয়ার উদ্দেশ্যে? ডিবিতে সংশোধিত নামগুলি রফতানি, ফিল্টার / সংশোধন এবং পুনরায় আমদানি করা আরও সহজ হতে পারে এবং তারপরে আপনি নাম ফিক্সিংয়ের জন্য নন- এসকিউএল পদ্ধতি ব্যবহার করতে পারেন ...

Question 16

এসকিউএলটিম.কম ফোরামে @ http://www.sqlteam.com/forums/topic.asp?TOPIC_ID=47718 এ আমি খুঁজে পেয়েছি এমন আরও একটি পরিবর্তন এখানে রয়েছে

create FUNCTION PROPERCASE
(
--The string to be converted to proper case
@input varchar(8000)
)
--This function returns the proper case string of varchar type
RETURNS varchar(8000)
AS
BEGIN
IF @input IS NULL
BEGIN
--Just return NULL if input string is NULL
RETURN NULL
END

--Character variable declarations
DECLARE @output varchar(8000)
--Integer variable declarations
DECLARE @ctr int, @len int, @found_at int
--Constant declarations
DECLARE @LOWER_CASE_a int, @LOWER_CASE_z int, @Delimiter char(3), @UPPER_CASE_A int, @UPPER_CASE_Z int

--Variable/Constant initializations
SET @ctr = 1
SET @len = LEN(@input)
SET @output = ''
SET @LOWER_CASE_a = 97
SET @LOWER_CASE_z = 122
SET @Delimiter = ' ,-'
SET @UPPER_CASE_A = 65
SET @UPPER_CASE_Z = 90

WHILE @ctr <= @len
BEGIN
--This loop will take care of reccuring white spaces
WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) > 0
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
SET @ctr = @ctr + 1
END

IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @LOWER_CASE_a AND @LOWER_CASE_z
BEGIN
--Converting the first character to upper case
SET @output = @output + UPPER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END

SET @ctr = @ctr + 1

WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) = 0 AND (@ctr <= @len)
BEGIN
IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @UPPER_CASE_A AND @UPPER_CASE_Z
BEGIN
SET @output = @output + LOWER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END
SET @ctr = @ctr + 1
END

END
RETURN @output
END



GO
SET QUOTED_IDENTIFIER OFF
GO
SET ANSI_NULLS ON
GO

Question 17

আমি জানি শয়তানটি বিস্তারিতভাবে রয়েছে (বিশেষত যেখানে লোকদের ব্যক্তিগত ডেটা সম্পর্কিত), এবং এটি সঠিকভাবে মূলধনীকরণ করা খুব ভাল লাগবে তবে উপরের ধরণের ঝামেলা হ'ল আমাদের মধ্যে বাস্তববাদী, সময়-সচেতন নীচের ব্যবহারগুলি কেন :

SELECT UPPER('Put YoUR O'So oddLy casED McWeird-nAme von rightHERE here')

আমার অভিজ্ঞতায় লোকেরা তাদের নামটি দেখে ... ঠিক আছে যদিও এমনকি এটি বাক্যটির অর্ধেক পথ।

দেখুন: রাশিয়ানরা একটি পেন্সিল ব্যবহার করেছিল!

Question 18

সবেমাত্র শিখেছি InitCap()।

এখানে কিছু নমুনা কোড রয়েছে:

SELECT ID
      ,InitCap(LastName ||', '|| FirstName ||' '|| Nvl(MiddleName,'')) AS RecipientName
FROM SomeTable

Question 19

এটি এসএসএমএসে কাজ করেছে:

Select Jobtitle,
concat(Upper(LEFT(jobtitle,1)), SUBSTRING(jobtitle,2,LEN(jobtitle))) as Propercase
From [HumanResources].[Employee]

Question 20

আপনি যদি সমস্ত ডেটা জানেন তবে এটি কেবল একটি শব্দ here প্রথমে কলামটি সমস্ত নিম্নে আপডেট করুন এবং তারপরে নিম্নলিখিতটি চালান

    update tableName set columnName = 
    upper(SUBSTRING(columnName, 1, 1)) + substring(columnName, 2, len(columnName)) from tableName

Question 21

সম্প্রতি এটিকে মোকাবেলা করতে হয়েছিল এবং আমি যা চাইছিলাম তার কিছুই হিট না করার পরে নিম্নলিখিতগুলি নিয়ে এসেছিল। এটি একটি সম্পূর্ণ বাক্য করবে, বিশেষ শব্দ পরিচালনার ক্ষেত্রে। আমাদের একক চরিত্রের 'শব্দ' নিয়েও সমস্যা ছিল যা অনেকগুলি সহজ পদ্ধতি হ্যান্ডেল করে দেয় তবে আরও জটিল পদ্ধতি নয়। একক রিটার্ন ভেরিয়েবল, কোনও লুপ বা কার্সার নেই।

CREATE FUNCTION ProperCase(@Text AS NVARCHAR(MAX))
RETURNS NVARCHAR(MAX)
AS BEGIN

    DECLARE @return NVARCHAR(MAX)

    SELECT @return = COALESCE(@return + ' ', '') + Word FROM (
         SELECT CASE
            WHEN LOWER(value) = 'llc' THEN UPPER(value)
            WHEN LOWER(value) = 'lp' THEN UPPER(value) --Add as many new special cases as needed
            ELSE
               CASE WHEN LEN(value) = 1
               THEN UPPER(value)
               ELSE UPPER(LEFT(value, 1)) + (LOWER(RIGHT(value, LEN(value) - 1)))
              END
            END AS Word
         FROM STRING_SPLIT(@Text, ' ')
     ) tmp

     RETURN @return
END

Question 22

আপনার ডেটা এমএস ওয়ার্ডে অনুলিপি করুন এবং আটকান এবং "প্রতিটি শব্দকে বড় করে তোলার জন্য" পাঠ্য-রূপান্তরকরণে অন্তর্নির্মিত ব্যবহার করুন। ব্যতিক্রমগুলি সম্বোধন করতে আপনার মূল ডেটার সাথে তুলনা করুন। "ম্যাকডোনাল্ড" এবং "আইবিএম" টাইপ ব্যতিক্রমের পক্ষে ম্যানুয়ালি পাশের কোনও উপায়ে দেখতে পাচ্ছি না তবে এইভাবেই আমি এফডাব্লুআইডাব্লু করে ফেললাম।

Question 23

সার্ভার সার্ভার 2016 এবং আরও নতুনতে আপনি STRING_SPLIT ব্যবহার করতে পারেন


with t as (
    select 'GOOFYEAR Tire and Rubber Company' as n
    union all
    select 'THE HAPPY BEAR' as n
    union all
    select 'MONK HOUSE SALES' as n
    union all
    select 'FORUM COMMUNICATIONS' as n
)
select
    n,
    (
        select ' ' + (
            upper(left(value, 1))
            + lower(substring(value, 2, 999))
        )
        from (
            select value
            from string_split(t.n, ' ')
        ) as sq
        for xml path ('')
    ) as title_cased
from t