আমি কীভাবে ভিবিএ ব্যবহার না করে এক্সেলে বিপরীত স্ট্রিং অনুসন্ধান করতে পারি?

Question

আমার কাছে স্ট্রালের একটি তালিকা সহ একটি এক্সেল স্প্রেডশিট রয়েছে। প্রতিটি স্ট্রিং বেশ কয়েকটি শব্দের সমন্বয়ে গঠিত, তবে প্রতিটি স্ট্রিংয়ের শব্দের সংখ্যা পৃথক।

এক্সেল ফাংশনগুলি (কোনও ভিবিএ নেই) ব্যবহার করে, প্রতিটি স্ট্রিংয়ে শেষ শব্দটি আলাদা করার কোনও উপায় আছে?

উদাহরণ:

  আপনি কি মানব হিসাবে শ্রেণিবদ্ধ? -> মানব?
নেতিবাচক, আমি একটি মাংসের পপসিকল -> পপসিকল
                  আজিজ! আলো! -> আলো!

Comments

আমি ভাবছি কেন আপনার কাছে কৃত্রিম কোনও ভিবিএ বাধা নেই?

— ইবিগ্রিন

আমি খুব সহজেই এটি ভিবিএর মাধ্যমে সমাধান করতে পারি, তবে আমি যদি কৌতূহলী আছি যে কোনও ভিবিএবিহীন সমাধান থাকে। ভিবিএ বড় ডেটা সেটগুলির জন্য পারফরম্যান্স পেনাল্টি রাখে।

— জেমস

যথারীতি, দুটি উত্তর সত্যিই আলাদা হয়ে গেছে এবং সঠিক উত্তর হিসাবে কোনটি নির্বাচন করতে হবে তা সিদ্ধান্ত নেওয়ার জন্য আমার অনেক সময় হয়েছে। এই ক্ষেত্রে, জোন এবং ব্র্যাডসি উভয়ই (ব্র্যাডের সহায়তায়) সঠিক, কার্যনির্বাহী সমাধান নিয়ে এসেছেন।

— জেমস

আমি ব্র্যাডসির সমাধানটি বেছে নিয়েছি কারণ এটি দুটির চেয়ে আরও মার্জিত বলে মনে হচ্ছে এবং তিনি ফাংশনটির একটি সহজ ব্যাখ্যা প্রদান করেছেন।

— জেমস

আপনার প্রশ্নের সঠিকভাবে উত্তর দেওয়া যদি আপনি ভিবিএকে অনুপযুক্ত করে তোলে তা নির্দেশ না করেন (যেহেতু আপনি নিজের ম্যাক্রো এবং ভিবিএতে ফাংশন লিখতে পারেন, এটি বিল্ট-ইন ফাংশনগুলির সমতুল্য করে)।

— dkretz

Answer 1

এইটি পরীক্ষা করা হয়েছে এবং কাজ করে (ব্র্যাডের মূল পোস্টের ভিত্তিতে):

=RIGHT(A1,LEN(A1)-FIND("|",SUBSTITUTE(A1," ","|",
     LEN(A1)-LEN(SUBSTITUTE(A1," ","")))))

যদি আপনার মূল স্ট্রিংগুলিতে একটি পাইপ "" "থাকতে পারে চরিত্রটি, তারপরে উপরের উভয়টিকে অন্য কোনও চরিত্রের সাথে প্রতিস্থাপন করুন যা আপনার উত্সে প্রদর্শিত হবে না। (আমার বিশ্বাস ব্র্যাডের মূলটি নষ্ট হয়ে গেছে কারণ অনুবাদে একটি ছাপানো অক্ষর মুছে ফেলা হয়েছে)।

বোনাস: এটি কীভাবে কাজ করে (ডান থেকে বামে):

LEN(A1)-LEN(SUBSTITUTE(A1," ",""))- মূল স্ট্রিংয়ের
SUBSTITUTE(A1," ","|", ... )ফাঁকের সংখ্যা - একটি দিয়ে কেবলমাত্র চূড়ান্ত স্থানকে প্রতিস্থাপন করে - প্রতিস্থাপিতের |
FIND("|", ... )পরম অবস্থানটি খুঁজে পায় |(এটিই ছিল চূড়ান্ত স্থান)
Right(A1,LEN(A1) - ... ))- এর পরে সমস্ত অক্ষর ফিরে আসে|

সম্পাদনা করুন: উত্স পাঠ্যে কোনও স্থান নেই এমন ক্ষেত্রে অ্যাকাউন্টের জন্য সূত্রের শুরুতে নিম্নলিখিতটি যুক্ত করুন:

=IF(ISERROR(FIND(" ",A1)),A1, ... )

এখন পুরো সূত্র তৈরি:

=IF(ISERROR(FIND(" ",A1)),A1, RIGHT(A1,LEN(A1) - FIND("|",
    SUBSTITUTE(A1," ","|",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))))

অথবা আপনি =IF(COUNTIF(A1,"* *")অন্যান্য সংস্করণের বাক্য গঠন ব্যবহার করতে পারেন ।

যখন আসল স্ট্রিংটিতে শেষ পজিশনে কোনও স্থান থাকতে পারে তখন সমস্ত শূন্যস্থান গণনা করার সময় একটি ট্রিম ফাংশন যুক্ত করতে পারে: ফাংশনটিকে নিম্নলিখিতটি করা:

=IF(ISERROR(FIND(" ",B2)),B2, RIGHT(B2,LEN(B2) - FIND("|",
    SUBSTITUTE(B2," ","|",LEN(TRIM(B2))-LEN(SUBSTITUTE(B2," ",""))))))

Comments

আপনাকে যথেষ্ট ধন্যবাদ দিতে পারে না। বাকী স্ট্রিংও খুব দরকার, তাই কেবল = ডান থেকে = বামে পরিবর্তন এবং এলইএন (এ 1) অপসারণ - আমাকে বিশ্রামটি পাওয়ার অনুমতি দিয়েছে। তবে প্রাথমিক স্তরের সমস্ত কাজ করার জন্য আপনাকে ধন্যবাদ :)

— লুক ডুড্রিজ

+1: একটি চরিত্রের উদাহরণের সংখ্যা পাওয়ার জন্য আমাকে "লেন (এ 1)-এলইএন (সাবস্টিটিউট (এ 1," "," ")) কৌশল মনে করতে হবে

— আনসচাউং

দুর্দান্ত সমাধান! একমাত্র সমস্যা হ'ল এক্সেল ফাংশন নামগুলি স্থানীয়করণ করে, তাই আপনাকে অ-ইংলিশ অ্যাক্সেলের জন্য সূত্রটি আবার লিখতে হবে। এখানে রাশিয়ানটির জন্য পুনরায় লিখিত রূপটি রয়েছে: = ПРАВСИМВ (এ 1; ДЛСТР (এ 1) -ПОИСК ("|"; ПОДСТАВИТЬ (এ 1; ""; "|"; ДЛСТР (এ 1) -ДЛСТР (ПОДСТАВИТЬ (এ 1; ""; ""))))))

— মাইকেল প্লিসকিন

এই উত্তরটি ধারাবাহিক ফাঁকা স্থানযুক্ত স্ট্রিংগুলিতে বিরতি।

— কিছুটা

আমি সূত্রগুলি অস্থায়ী কলামগুলিতে বিভক্ত করার সুপারিশ করব (আপনি সেগুলি পরে লুকিয়ে রাখতে পারেন)। এটি বিশেষ ক্ষেত্রে ডিবাগ করার জন্য খুব দরকারী useful

— উইসবাকী

Answer 2

এই কৌশলটি আমি দুর্দান্ত সাফল্যের সাথে ব্যবহার করেছি:

=TRIM(RIGHT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

স্ট্রিংয়ে প্রথম শব্দটি পেতে, শুধু ডানদিকে থেকে বাম দিকে পরিবর্তন করুন

=TRIM(LEFT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

এছাড়াও, পাঠ্যটি ধারণ করে ঘর দ্বারা A1 প্রতিস্থাপন করুন।

Comments

আমার জন্য কাজ করে - সবে প্রথমটি " "আমার ডিলিমিটারের সাথে প্রতিস্থাপন করে । দু'জন 100মনে হয় এটি 100 টি অক্ষরের স্ট্রিংয়ের মধ্যে সীমাবদ্ধ

— রাখবে

আমরা যদি অন্য কোনও ডিলিমিটার ব্যবহার করি তবে শেষের =TRIM(SUBSTITUTE(RIGHT(SUBSTITUTE(A1, ".", REPT(".", 100)), 100), ".", ""))

— দিকেও এটি ছাঁটাই

খুব চতুর পদ্ধতি। এটি যা করে তা হ'ল প্রতিটি স্পেসকে 100 স্পেসের সাথে প্রতিস্থাপন করা হবে, তারপরে শীর্ষস্থানীয় / পিছনে স্থান ছাড়াই শেষ 100 টি অক্ষর ফিরিয়ে দিন।

— জেনাডিক্স

@ বেঞ্জিনার আমার ধারণা এটি 100 টি অক্ষরের চেয়ে বেশি দীর্ঘ স্ট্রিংয়ের জন্য কাজ করে। 100 টি অক্ষর একক শব্দের আকার সীমাবদ্ধ করে। আপনি ডান (বা বাম) একশ অক্ষর নিচ্ছেন ..... যদি 101 টি অক্ষরের একটি শব্দ দীর্ঘায়িত হয় তবে আপনার সমস্যা হতে পারে, তবে যদি 100 টি বর্ণের একটি স্ট্রিং 3 স্পেস সহ ... প্রায় 400 টি চরিত্রের স্ট্রিং প্যাডড এবং এখনও কাজ করে। জেরি বউকেয়ারকে - খুব মার্জিত, ধন্যবাদ।

— টিন বাম

Answer 3

জেরির উত্তরের আরও শক্তিশালী সংস্করণ:

=TRIM(RIGHT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(TRIM(A1))))

এটি স্ট্রিংয়ের দৈর্ঘ্য, অগ্রণী বা পিছনের স্থানগুলি বা অন্য যে কোনও কিছু নির্বিশেষে কাজ করে এবং এটি এখনও বেশ ছোট এবং সহজ।

Comments

এটি একটি দুর্দান্ত সূত্র। আমি =TRIM(RIGHT(SUBSTITUTE(TRIM(A1), ".", REPT(" ", LEN(TRIM(A1)))), LEN(TRIM(A1))))ফাইল এক্সটেনশন পেতে সূত্রটি পরিবর্তন করেছি ।

— আদর্শ মাদ্রেচা

আরও একটি SUBSTITUTEএটি কেবল ফাঁকা স্থান নয়, কোনও চরিত্রের জন্য কাজ করতে দেয়। =TRIM(SUBSTITUTE(RIGHT(SUBSTITUTE(TRIM(A1),"/",REPT("/",LEN(TRIM(A1)))),LEN(TRIM(A1))),"/","")), যেখানে "/" সীমাবদ্ধ চরিত্র।

— পিপি্রোটিয়াস

@ জোফিংল, এটি একটি অত্যন্ত সংক্ষিপ্ত এবং স্মার্ট সমাধান। এটি বেশ ভাল কাজ করে, ঠিক যে যদি বিভেদক একটি স্ট্রিং এটা সব ক্ষেত্রে ভাল কাজ করে না উল্লেখ করতে, এখানে বিভেদক জন্য একটি উদাহরণ: " ; "(ক সেমিকোলন শূণ্যস্থান দ্বারা বেষ্টিত) ইনপুট মান সঙ্গে "Technology Sprint 24 ; Sprint 4"এটা ফেরৎ: "; Sprint 4"। আমি যোগ করা সমাধানটি ব্যবহার করছি: @ পিপ্রোটেস।

— ডেভিড লিয়াল

যদি ডিলিমিটারটি একটি স্ট্রিং হয় তবে কোনও বিশেষ চরিত্র দ্বারা এর আগে এটি প্রতিস্থাপন করা সম্ভব হবে, উদাহরণস্বরূপ @ পিপ্রোটিয়াস সূত্রে প্রতিস্থাপন TRIM(A1)দ্বারা: TRIM(SUBSTITUTE(A1, "strDelimeter", ";"))সমস্ত জায়গায়, একটি নতুন চরিত্রের ডেলিমিটার থাকতে: ";"বা আরও ভাল char()ফাংশন ব্যবহার করে সন্ধানের জন্য কিছু সত্যিই অপ্রত্যাশিত চরিত্র।

— ডেভিড লিয়াল

@ প্রোটিউস সাধারণ ক্ষেত্রে একক অক্ষর সমাধানের জন্য TRIMদ্বিতীয় যোগ করার পরে আপনার ফাংশনটির দরকার নেই SUBSTITUTE। সূত্রটি এই অংশটি =SUBSTITUTE(RIGHT(SUBSTITUTE(TRIM(A1),";",REPT(";",LEN(TRIM(A1)))),LEN(TRIM(A1))),";","")

— ডেভিড লিয়াল

Answer 4

আমি দেখেছি এই Google এ এক্সেল 2003 পরীক্ষিত ও এটা আমার জন্য কাজ করে:

=IF(COUNTIF(A1,"* *"),RIGHT(A1,LEN(A1)-LOOKUP(LEN(A1),FIND(" ",A1,ROW(INDEX($A:$A,1,1):INDEX($A:$A,LEN(A1),1))))),A1)

[সম্পাদনা] আমার কাছে মন্তব্য করার মতো যথেষ্ট পরিমাণে সংবাদ নেই, তাই এটি সবচেয়ে ভাল জায়গা বলে মনে হচ্ছে ... ব্র্যাডসির উত্তরও স্থানের ফাঁকা জায়গা বা খালি কোষ নিয়ে কাজ করে না ...
[২ য় সম্পাদনা] আসলে, এটির জন্য কাজ করে না একক শব্দ হয় ...

Comments

নিকটতম সমাধানটি এখনও, তবে আমি একটি ছাঁটাই ফেলব () যেহেতু পেছনের স্থানটি এটি ভেঙে দেবে।

— ইবিগ্রিন

সত্য, অন্তর্বর্তী কক্ষে ট্রিম () ছাঁটাই করা সম্ভবত সবচেয়ে সহজ এবং তারপরে মধ্যবর্তী কক্ষে উপরের সূত্রটি প্রয়োগ করুন। এছাড়াও, সেলটি শূন্য হয়ে থাকলে 0 কেটে ফেলা হয়, তাই ইসব্ল্যাঙ্ক () দিয়েও জড়িয়ে দেওয়া যেতে পারে

— জন

Answer 5

=RIGHT(TRIM(A1),LEN(TRIM(A1))-FIND(CHAR(7),SUBSTITUTE(" "&TRIM(A1)," ",CHAR(7),
LEN(TRIM(A1))-LEN(SUBSTITUTE(" "&TRIM(A1)," ",""))+1))+1)

এটি অত্যন্ত দৃ is় - এটি কোনও ফাঁকা স্থান নয়, শীর্ষস্থানীয় / অনুসরণযোগ্য স্থান, একাধিক স্পেস, একাধিক শীর্ষস্থানীয় / অনুবর্তনকারী স্পেস ... এবং আমি উল্লম্ব বারের পরিবর্তে ডিলিমিটারের জন্য চর (7) ব্যবহার করেছি "|" কেবলমাত্র যদি এটি একটি পছন্দসই পাঠ্য আইটেম হয়।

Comments

এক্সেল 2010 সালে আমার জন্য কাজ করে। ধন্যবাদ

— রুডিগার ওল্ফ

Answer 6

এটি খুব পরিষ্কার এবং কমপ্যাক্ট, এবং ভাল কাজ করে।

{=RIGHT(A1,LEN(A1)-MAX(IF(MID(A1,ROW(1:999),1)=" ",ROW(1:999),0)))}

এটি কোনও ফাঁকা স্থান বা একটি শব্দের জন্য ফাঁদে ত্রুটি দেয় না, তবে এটি যুক্ত করা সহজ।

সম্পাদনা করুন:
এটি স্থানের স্থান, একক শব্দ এবং খালি ঘর পরিস্থিতি পরিচালনা করে। আমি এটি ভাঙার কোনও উপায় খুঁজে পাই না।

{=RIGHT(TRIM(A1),LEN(TRIM(A1))-MAX(IF(MID(TRIM(A1),ROW($1:$999),1)=" ",ROW($1:$999),0)))}

Comments

কুল। এটি অ্যারে ফাংশনগুলির একটি সত্যই আকর্ষণীয় ব্যবহার! এত দিন পরে আর উত্তর পাওয়ার আশা করিনি। ভাগ করার জন্য আপনাকে ধন্যবাদ।

— জেমস

Answer 7

=RIGHT(A1,LEN(A1)-FIND("`*`",SUBSTITUTE(A1," ","`*`",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))) 

Comments

আপনি এটি পরীক্ষা করেছেন? "আপনি কি মানুষ হিসাবে শ্রেণিবদ্ধ হয়েছেন?" দিয়ে আমার পক্ষে কাজ করে না?

— এড গুইনিস

না, এটি কাজ করে না। যদিও কিছু আকর্ষণীয় উপাদান রয়েছে। লেন (এ 1) -লাইন (সাবস্টিটিউট (এ 1, "", "") আপনাকে স্ট্রিংয়ের

— ফাঁকের ফাঁকে

এটি একটি আকর্ষণীয় ফাংশন। খুব খারাপ এটি কাজ করে না। আমি জায়গাগুলির সংখ্যা গণনা করতে সক্ষম হওয়ার কৌশলটি পছন্দ করি।

— জেমস 18

@ ব্র্যাড: আমি * টি অক্ষর প্রদর্শন করতে আপনার পোস্ট সম্পাদনা করেছি। আসলগুলি সেগুলি সঠিকভাবে মুদ্রণ করে নি। এগুলি জায়গায়, এটি কাজ করে। +1

— জেমস

Answer 8

জেরি এবং জো এর উত্তরগুলিতে যুক্ত করার জন্য, আপনি যদি শেষ শব্দটি ব্যবহার করতে পারেন তার আগে এই পাঠ্যটি সন্ধান করতে চান:

=TRIM(LEFT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))))-LEN(TRIM(A1))))

এ 1-এ 'আমার ছোট বিড়াল' দিয়ে 'আমার ছোট' (যেখানে জো ও জেরির 'বিড়াল' দেবে)

জেরি এবং জো শেষ শব্দটি যেভাবে বিচ্ছিন্ন করে দেয়, ঠিক তেমনভাবে তার বাম দিকে সমস্ত কিছু পাওয়া যায় (তারপরে এটি ছাঁটাই করে)

Answer 9

স্ট্রিংটি বিপরীত হতে পারে তা কল্পনা করুন। তাহলে এটা সত্যিই সহজ। স্ট্রিংয়ে কাজ করার পরিবর্তে:

"My little cat" (1)

আপনি কাজ

"tac elttil yM" (2)

সঙ্গে =LEFT(A1;FIND(" ";A1)-1)A2 এর আপনি পেতে "My"দিয়ে (1) এবং "tac", (2) সঙ্গে বিপরীত হয় যা"cat" , (1) গত শব্দ।

একটি স্ট্রিং বিপরীতে প্রায় কয়েকটি ভিবিএ রয়েছে। আমি পাবলিক ভিবিএ ফাংশন পছন্দ করি ReverseString।

উপরে বর্ণিত হিসাবে ইনস্টল করুন। তারপরে আপনার A1 তে স্ট্রিং সহ, উদাহরণস্বরূপ, "My little cat"এবং A2 এ এই ফাংশন:

=ReverseString(LEFT(ReverseString(A1);IF(ISERROR(FIND(" ";A1));
  LEN(A1);(FIND(" ";ReverseString(A1))-1))))

আপনি "cat"এ 2 এ দেখতে পাবেন ।

উপরের পদ্ধতিটি ধরে নিয়েছে যে শব্দগুলি ফাঁকা দিয়ে আলাদা করা হয়। IFদফা একক শব্দ = কক্ষে কোন ঐ খালি ধারণকারী কোষ জন্য। দ্রষ্টব্য: TRIMএবং CLEANমূল স্ট্রিংটিও কার্যকর। নীতিগতভাবে এটি A1 থেকে পুরো স্ট্রিংটি বিপরীত করে এবং বিপরীত স্ট্রিংয়ের মধ্যে প্রথম ফাঁকাটি সন্ধান করে যা শেষ (বিপরীত) শব্দের (অর্থাৎ, "tac ") পাশের । LEFTএই শব্দটি বাছাই করে এবং অন্য একটি স্ট্রিং বিপর্যয় শব্দের ( " cat") এর মূল ক্রমটিকে পুনর্গঠন করে । -1শেষেFIND বিবৃতি ফাঁকা সরিয়ে ফেলা হয়।

ধারণাটি হ'ল প্রথম খালিটি দিয়ে LEFTএবং স্ট্রিংয়ে প্রথম (!) শব্দটি বের করা সহজ FIND। তবে, সর্বশেষ (!) শব্দের জন্য RIGHTফাংশনটি ভুল পছন্দ হ'ল আপনি যখন এটি করার চেষ্টা করছেন কারণ দুর্ভাগ্যবশত আপনি যে স্ট্রিংটি বিশ্লেষণ করতে চান তার জন্য পতাকা খুঁজে পেতে পারে না not

সুতরাং পুরো স্ট্রিং সহজভাবে বিপরীত হয়। LEFTএবং FINDস্বাভাবিক হিসাবে কাজ করে তবে উত্তোলিত স্ট্রিংটি বিপরীত হয়। আপনি কীভাবে কোনও স্ট্রিংকে বিপরীত করতে পারবেন তা জানার পরে তার কোনও বড় বিষয় নয়। ReverseStringসূত্রের প্রথম বিবৃতি এই কাজটি করে।

Comments

এটি এখানে অন্যান্য সমস্ত অপশনগুলির তুলনায় অনেক সহজ, ধন্যবাদ অনেক ধন্যবাদ !! কেন অনুসন্ধানের বিপরীত সন্ধান বা বিকল্প থাকতে পারে না - বিপরীত অনুসন্ধান করতে নেতিবাচক সংখ্যা ব্যবহার করে কিছু করার মনে হয়েছে বলে মনে হচ্ছে, তবে স্পষ্টভাবে ভিবা নয় ....

— ক্রেগ ল্যাম্বি

ওপি কোনও ভিবিএ চেয়েছিল না।

— ট্রিপ কাইনেটিকস

পাগলও হয়! আপনি যদি ভিবিএ ব্যবহার করতে যান তবে ঠিক তত সহজেই একটি বিপরীত সন্ধান পেতে পারে

— ডেনজিল নিউম্যান

Answer 10

=LEFT(A1,FIND(IF(
 ISERROR(
  FIND("_",A1)
 ),A1,RIGHT(A1,
  LEN(A1)-FIND("~",
   SUBSTITUTE(A1,"_","~",
    LEN(A1)-LEN(SUBSTITUTE(A1,"_",""))
   )
  )
 )
),A1,1)-2)

Answer 11

একটি কলামে অনুলিপি করুন, সেই কলামটি নির্বাচন করুন এবং হোম> সম্পাদনা> সন্ধান করুন এবং নির্বাচন করুন, প্রতিস্থাপন করুন:

Replace All।

নক্ষত্রের পরে একটি স্থান আছে।

Comments

নোট করুন যে এক্সেল অনুসন্ধানে * একটি (লোভী) ওয়াইল্ডকার্ড, তাই এটি শেষ স্থানের সাথে সমস্ত কিছু মেলে এবং এটিকে কিছু না দিয়ে প্রতিস্থাপন করে

— সুপারফ্লাই জন

Answer 12

আমি পিটি-বিআর তে অনুবাদ করেছি, আমারও এটির যেমন প্রয়োজন ছিল।

(দয়া করে নোট করুন যে আমি স্থানটি পরিবর্তন করেছি \কারণ আমার কেবলমাত্র পাতার স্ট্রিংয়ের ফাইল নাম প্রয়োজন needed)

=SE(ÉERRO(PROCURAR("\",A1)),A1,DIREITA(A1,NÚM.CARACT(A1)-PROCURAR("|", SUBSTITUIR(A1,"\","|",NÚM.CARACT(A1)-NÚM.CARACT(SUBSTITUIR(A1,"\",""))))))

Comments

পর্তুগিজ ভাষায় এক্সেল কীভাবে পড়তে হয় তা আমি জানি না, তাই এর জন্য আমাকে আপনার শব্দটি গ্রহণ করতে হবে :)

— জেমস

Answer 13

এটি অর্জনের আর একটি উপায় নীচে রয়েছে

=IF(ISERROR(TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14))))),TRIM(D14),TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14)))))

Answer 14

আমারও এ জাতীয় কাজ ছিল এবং আমি যখন কাজটি করতাম, উপরের পদ্ধতিটি ব্যবহার করে আমার কাছে একটি নতুন পদ্ধতি ঘটেছিল: আপনি কেন এটি করবেন না:

1. স্ট্রিংটি বিপরীত করুন ("স্ট্রিং ওয়ান" "এনো গ্নার্টস" হয়ে যায়)।
2. ভাল পুরানো ফাইন্ড (যা বাম থেকে ডানদিকে হার্ডকডযুক্ত) ব্যবহার করুন।
3. এটিকে আবার পঠনযোগ্য স্ট্রিংয়ে বিপরীত করুন।

কেমন লাগছে এই শব্দ?

Comments

অবশ্যই। তবে আপনি কীভাবে এক্সেলের স্ট্রিংটি বিপরীত করবেন?

— জেমস