ব্যাচ ফাইলের সাথে সমাধান করার জন্য প্রায়শই আপেক্ষিক তারিখ / সময় সম্পর্কিত প্রশ্ন থাকে। কিন্তু কমান্ড লাইন ইন্টারপ্রেটার cmd.exe তারিখ / সময় গণনার জন্য কোনও কার্যকারিতা নেই। স্ট্যাক ওভারফ্লো এর অন্যান্য পৃষ্ঠাগুলিতে এবং অন্যান্য ওয়েবসাইটগুলিতে অতিরিক্ত কনসোল অ্যাপ্লিকেশন বা স্ক্রিপ্টগুলি ব্যবহার করে প্রচুর ভাল কাজের সমাধান ইতিমধ্যে এখানে পোস্ট করা হয়েছে।
তারিখ / সময় ভিত্তিক ক্রিয়াকলাপগুলির জন্য সাধারণ একটি নির্ধারিত দিন থেকে তারিখ / সময় স্ট্রিংটিকে সেকেন্ডে রূপান্তর করা প্রয়োজন। খুব সাধারণ 1970-01-01 00:00:00 ইউটিসি। তবে পরবর্তী কোনও দিন কোনও নির্দিষ্ট কাজের জন্য সমর্থন করার জন্য প্রয়োজনীয় তারিখের সীমার উপর নির্ভর করেও ব্যবহৃত হতে পারে।
জে কমান্ড লাইন ইন্টারপ্রেটার cmd.exe এর জন্য একটি দ্রুত "ডেট টু সেকেন্ড" সমাধানযুক্ত 7daysclean.cmd পোস্ট করেছেন । তবে এটি লিপ বছর সঠিকভাবে বিবেচনা করে না। জেআর চলতি বছরে লিপ দিবসকে বিবেচনায় নেওয়ার জন্য একটি অ্যাড-অন পোস্ট করেছে , তবে বেস বছর থেকে অর্থাত্ ১৯ 1970০ সাল থেকে অন্যান্য লিপ বছরকে উপেক্ষা করে।
আমি সি / সি ++ তে লিখিত আমার অ্যাপ্লিকেশনগুলিতে তারিখ / সময় রূপান্তর ফাংশনগুলিতে 1970-01-01 থেকে লিপ দিবস সহ দিনগুলির সংখ্যা দ্রুত পেতে একটি ছোট সি ফাংশন দিয়ে একবার তৈরি 20 বছরের স্ট্যাটিক টেবিলগুলি (অ্যারেগুলি) ব্যবহার করি।
এই খুব দ্রুত টেবিল পদ্ধতিটি ফর কমান্ড ব্যবহার করে ব্যাচ কোডেও ব্যবহার করা যেতে পারে । সুতরাং আমি ব্যাচ সাবরুটিন কোড করার সিদ্ধান্ত নিয়েছি GetSecondsযা 1970-01-01 00:00:00 ইউটিসি থেকে এই তারিখের / সময় স্ট্রিংয়ের জন্য এই রুটিনে পাসের জন্য সেকেন্ডের সংখ্যা গণনা করে।
দ্রষ্টব্য: উইন্ডোজ ফাইল সিস্টেমগুলিও লিপ সেকেন্ডকে সমর্থন করে না বলে লিপ সেকেন্ডগুলিকে বিবেচনায় নেওয়া হয় না।
প্রথমত, টেবিলগুলি:
1970-01-01 00:00:00 সাল থেকে প্রতিটি বছর লিপের দিনগুলি সহ ইউটিসি।
1970 - 1979: 0 365 730 1096 1461 1826 2191 2557 2922 3287
1980 - 1989: 3652 4018 4383 4748 5113 5479 5844 6209 6574 6940
1990 - 1999: 7305 7670 8035 8401 8766 9131 9496 9862 10227 10592
2000 - 2009: 10957 11323 11688 12053 12418 12784 13149 13514 13879 14245
2010 - 2019: 14610 14975 15340 15706 16071 16436 16801 17167 17532 17897
2020 - 2029: 18262 18628 18993 19358 19723 20089 20454 20819 21184 21550
2030 - 2039: 21915 22280 22645 23011 23376 23741 24106 24472 24837 25202
2040 - 2049: 25567 25933 26298 26663 27028 27394 27759 28124 28489 28855
2050 - 2059: 29220 29585 29950 30316 30681 31046 31411 31777 32142 32507
2060 - 2069: 32872 33238 33603 33968 34333 34699 35064 35429 35794 36160
2070 - 2079: 36525 36890 37255 37621 37986 38351 38716 39082 39447 39812
2080 - 2089: 40177 40543 40908 41273 41638 42004 42369 42734 43099 43465
2090 - 2099: 43830 44195 44560 44926 45291 45656 46021 46387 46752 47117
2100 - 2106: 47482 47847 48212 48577 48942 49308 49673
১৯৯০-০১-০১-এর শুরুতে ২০৩৯ থেকে ২১০6 সাল পর্যন্ত সেকেন্ড গণনা করা কেবল সি / সি ++ এ স্বাক্ষরবিহীন ৩২-বিট ভেরিয়েবল, অর্থাৎ স্বাক্ষরযুক্ত দীর্ঘ (বা স্বাক্ষরবিহীন কোনও) ব্যবহার করেই সম্ভব।
তবে গাণিতিক প্রকাশের জন্য cmd.exe ব্যবহার একটি স্বাক্ষরিত 32-বিট ভেরিয়েবল। সুতরাং সর্বাধিক মান 2147483647 (0x7FFFFFFF) যা 2038-01-19 03:14:07।
১৯ 1970০ থেকে 2106 বছরের জন্য লিপ ইয়ারের তথ্য (না / হ্যাঁ)।
1970 - 1989: N N Y N N N Y N N N Y N N N Y N N N Y N
1990 - 2009: N N Y N N N Y N N N Y N N N Y N N N Y N
2010 - 2029: N N Y N N N Y N N N Y N N N Y N N N Y N
2030 - 2049: N N Y N N N Y N N N Y N N N Y N N N Y N
2050 - 2069: N N Y N N N Y N N N Y N N N Y N N N Y N
2070 - 2089: N N Y N N N Y N N N Y N N N Y N N N Y N
2090 - 2106: N N Y N N N Y N N N N N N N Y N N
^ year 2100
চলতি বছরে প্রতি মাসের প্রথম দিন থেকে শুরু করে দিনের সংখ্যা।
Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec
Year with 365 days: 0 31 59 90 120 151 181 212 243 273 304 334
Year with 366 days: 0 31 60 91 121 152 182 213 244 274 305 335
1970-01-01 সাল থেকে একটি তারিখকে সেকেন্ডের সংখ্যায় রূপান্তর করা সেই টেবিলগুলি ব্যবহার করা বেশ সহজ।
দৃষ্টি আকর্ষন করা!
তারিখ এবং সময়ের স্ট্রিংগুলির ফর্ম্যাটটি উইন্ডোজ অঞ্চল এবং ভাষা সেটিংসের উপর নির্ভর করে। বিভেদক ও বিভিন্ন পরিবেশের নির্ধারিত টোকেন ক্রম Day, Monthএবং Yearপ্রথম জন্য লুপ GetSecondsপ্রয়োজনে স্থানীয় তারিখ / সময় ফর্ম্যাট অভিযোজিত করা আবশ্যক।
এটা তোলে পরিবেশ ভেরিয়েবলের তারিখের স্ট্রিংকে মানিয়ে যদি এনভায়রনমেন্ট ভেরিয়েবল মধ্যে তারিখ বিন্যাস প্রয়োজনীয় DATE তারিখে কমান্ড দ্বারা ব্যবহৃত তারিখ বিন্যাসে ভিন্ন জন্য উপর %%~tF।
উদাহরণস্বরূপ যখন যখন %DATE%প্রসারিত হয় Sun 02/08/2015যখন নীচের %%~tFকোডটিতে প্রসারিত হয় তখন 02/08/2015 07:38 PMলাইন 4 থেকে সংশোধন করে ব্যবহার করা যেতে পারে:
call :GetSeconds "%DATE:~4% %TIME%"
এর ফলে কেবলমাত্র সাবরুটিনে যেতে হবে 02/08/2015- সপ্তাহের দিনের সংক্ষিপ্ততার 3 টি অক্ষর এবং পৃথক স্থানের অক্ষর ব্যতীত তারিখের স্ট্রিং।
বিকল্পভাবে সঠিক ফর্ম্যাটে বর্তমান তারিখটি পাস করার জন্য নিম্নলিখিত ব্যবহার করা যেতে পারে:
call :GetSeconds "%DATE:~-10% %TIME%"
এখন তারিখের স্ট্রিংকে থেকে গত 10 অক্ষর ফাংশন গৃহীত হয় GetSecondsএবং সেইজন্য এটা না ব্যাপার পরিবেশ ভেরিয়েবলের তারিখের স্ট্রিংকে করলে DATE তারিখে সহ বা কাজের দিন ছাড়া হয় দীর্ঘ দিন এবং মাস হিসেবে প্রত্যাশিত অনুক্রমে 2 সংখ্যা, অর্থাত বিন্যাসে সাথে সবসময় হিসাবে dd/mm/yyyy বা dd.mm.yyyy।
এখানে মন্তব্য যা শুধু আউটপুট যা ফাইল মুছে দিন এবং যা ফাইলে রাখা ব্যাখ্যা দিয়ে ব্যাচ কোড C:\Tempফোল্ডারের গাছ, প্রথম কোড দেখতে জন্য লুপ।
@echo off
setlocal EnableExtensions EnableDelayedExpansion
rem Get seconds since 1970-01-01 for current date and time.
call :GetSeconds "%DATE% %TIME%"
rem Subtract seconds for 7 days from seconds value.
set /A "LastWeek=Seconds-7*86400"
rem For each file in each subdirectory of C:\Temp get last modification date
rem (without seconds -> append second 0) and determine the number of seconds
rem since 1970-01-01 for this date/time. The file can be deleted if seconds
rem value is lower than the value calculated above.
for /F "delims=" %%F in ('dir /A-D-H-S /B /S "C:\Temp"') do (
call :GetSeconds "%%~tF:0"
rem if !Seconds! LSS %LastWeek% del /F "%%~fF"
if !Seconds! LEQ %LastWeek% (
echo Delete "%%~fF"
) else (
echo Keep "%%~fF"
)
)
endlocal
goto :EOF
rem No validation is made for best performance. So make sure that date
rem and hour in string is in a format supported by the code below like
rem MM/DD/YYYY hh:mm:ss or M/D/YYYY h:m:s for English US date/time.
:GetSeconds
rem If there is " AM" or " PM" in time string because of using 12 hour
rem time format, remove those 2 strings and in case of " PM" remember
rem that 12 hours must be added to the hour depending on hour value.
set "DateTime=%~1"
set "Add12Hours=0"
if "%DateTime: AM=%" NEQ "%DateTime%" (
set "DateTime=%DateTime: AM=%"
) else if "%DateTime: PM=%" NEQ "%DateTime%" (
set "DateTime=%DateTime: PM=%"
set "Add12Hours=1"
)
rem Get year, month, day, hour, minute and second from first parameter.
for /F "tokens=1-6 delims=,-./: " %%A in ("%DateTime%") do (
rem For English US date MM/DD/YYYY or M/D/YYYY
set "Day=%%B" & set "Month=%%A" & set "Year=%%C"
rem For German date DD.MM.YYYY or English UK date DD/MM/YYYY
rem set "Day=%%A" & set "Month=%%B" & set "Year=%%C"
set "Hour=%%D" & set "Minute=%%E" & set "Second=%%F"
)
rem echo Date/time is: %Year%-%Month%-%Day% %Hour%:%Minute%:%Second%
rem Remove leading zeros from the date/time values or calculation could be wrong.
if "%Month:~0,1%" EQU "0" ( if "%Month:~1%" NEQ "" set "Month=%Month:~1%" )
if "%Day:~0,1%" EQU "0" ( if "%Day:~1%" NEQ "" set "Day=%Day:~1%" )
if "%Hour:~0,1%" EQU "0" ( if "%Hour:~1%" NEQ "" set "Hour=%Hour:~1%" )
if "%Minute:~0,1%" EQU "0" ( if "%Minute:~1%" NEQ "" set "Minute=%Minute:~1%" )
if "%Second:~0,1%" EQU "0" ( if "%Second:~1%" NEQ "" set "Second=%Second:~1%" )
rem Add 12 hours for time range 01:00:00 PM to 11:59:59 PM,
rem but keep the hour as is for 12:00:00 PM to 12:59:59 PM.
if "%Add12Hours%" == "1" (
if %Hour% LSS 12 set /A Hour+=12
)
set "DateTime="
set "Add12Hours="
rem Must use 2 arrays as more than 31 tokens are not supported
rem by command line interpreter cmd.exe respectively command FOR.
set /A "Index1=Year-1979"
set /A "Index2=Index1-30"
if %Index1% LEQ 30 (
rem Get number of days to year for the years 1980 to 2009.
for /F "tokens=%Index1% delims= " %%Y in ("3652 4018 4383 4748 5113 5479 5844 6209 6574 6940 7305 7670 8035 8401 8766 9131 9496 9862 10227 10592 10957 11323 11688 12053 12418 12784 13149 13514 13879 14245") do set "Days=%%Y"
for /F "tokens=%Index1% delims= " %%L in ("Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N") do set "LeapYear=%%L"
) else (
rem Get number of days to year for the years 2010 to 2038.
for /F "tokens=%Index2% delims= " %%Y in ("14610 14975 15340 15706 16071 16436 16801 17167 17532 17897 18262 18628 18993 19358 19723 20089 20454 20819 21184 21550 21915 22280 22645 23011 23376 23741 24106 24472 24837") do set "Days=%%Y"
for /F "tokens=%Index2% delims= " %%L in ("N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N") do set "LeapYear=%%L"
)
rem Add the days to month in year.
if "%LeapYear%" == "N" (
for /F "tokens=%Month% delims= " %%M in ("0 31 59 90 120 151 181 212 243 273 304 334") do set /A "Days+=%%M"
) else (
for /F "tokens=%Month% delims= " %%M in ("0 31 60 91 121 152 182 213 244 274 305 335") do set /A "Days+=%%M"
)
rem Add the complete days in month of year.
set /A "Days+=Day-1"
rem Calculate the seconds which is easy now.
set /A "Seconds=Days*86400+Hour*3600+Minute*60+Second"
rem Exit this subroutine
goto :EOF
অনুকূল পারফরম্যান্সের জন্য সমস্ত মন্তব্য মুছে ফেলা ভাল, অর্থাত্ ০-৪ নেতৃস্থানীয় স্পেসের পরে রিম দিয়ে শুরু হওয়া সমস্ত লাইন ।
এবং অ্যারেগুলি আরও ছোট করা যেতে পারে, যেমন 1980-01-01 00:00:00 থেকে 2038-01-19 03:14:07 হিসাবে বর্তমানে ব্যাচ কোড দ্বারা সমর্থিত উদাহরণস্বরূপ 2015-01 নীচের কোড হিসাবে -01 থেকে 2019-12-31 ব্যবহার করে যা C:\Tempফোল্ডার ট্রিতে 7 দিনের বেশি পুরানো ফাইলগুলি মুছে দেয় ।
আরও নীচে ব্যাচ কোড 24 ঘন্টা সময় বিন্যাস জন্য অনুকূলিত করা হয়।
@echo off
setlocal EnableDelayedExpansion
call :GetSeconds "%DATE:~-10% %TIME%"
set /A "LastWeek=Seconds-7*86400"
for /F "delims=" %%F in ('dir /A-D-H-S /B /S "C:\Temp"') do (
call :GetSeconds "%%~tF:0"
if !Seconds! LSS %LastWeek% del /F "%%~fF"
)
endlocal
goto :EOF
:GetSeconds
for /F "tokens=1-6 delims=,-./: " %%A in ("%~1") do (
set "Day=%%B" & set "Month=%%A" & set "Year=%%C"
set "Hour=%%D" & set "Minute=%%E" & set "Second=%%F"
)
if "%Month:~0,1%" EQU "0" ( if "%Month:~1%" NEQ "" set "Month=%Month:~1%" )
if "%Day:~0,1%" EQU "0" ( if "%Day:~1%" NEQ "" set "Day=%Day:~1%" )
if "%Hour:~0,1%" EQU "0" ( if "%Hour:~1%" NEQ "" set "Hour=%Hour:~1%" )
if "%Minute:~0,1%" EQU "0" ( if "%Minute:~1%" NEQ "" set "Minute=%Minute:~1%" )
if "%Second:~0,1%" EQU "0" ( if "%Second:~1%" NEQ "" set "Second=%Second:~1%" )
set /A "Index=Year-2014"
for /F "tokens=%Index% delims= " %%Y in ("16436 16801 17167 17532 17897") do set "Days=%%Y"
for /F "tokens=%Index% delims= " %%L in ("N Y N N N") do set "LeapYear=%%L"
if "%LeapYear%" == "N" (
for /F "tokens=%Month% delims= " %%M in ("0 31 59 90 120 151 181 212 243 273 304 334") do set /A "Days+=%%M"
) else (
for /F "tokens=%Month% delims= " %%M in ("0 31 60 91 121 152 182 213 244 274 305 335") do set /A "Days+=%%M"
)
set /A "Days+=Day-1"
set /A "Seconds=Days*86400+Hour*3600+Minute*60+Second"
goto :EOF
উইন্ডোতে তারিখ এবং সময় ফর্ম্যাট এবং ফাইল সময়ের তুলনা সম্পর্কে আরও তথ্যের জন্য ফাইলের টাইম সম্পর্কিত অতিরিক্ত তথ্য সহ ব্যাচ ফাইলে ফাইলটি 4 ঘন্টা এর চেয়ে বেশি বয়সী কিনা তা সন্ধান করুন আমার উত্তরটি দেখুন ।