সিএমেক ও সিটিস্ট: পরীক্ষা করুন পরীক্ষা তৈরি করে না

Question 1

make testলক্ষ্য ব্যবহার করে আমার কয়েকটি পরীক্ষা স্বয়ংক্রিয়ভাবে চালানোর জন্য আমি সিএমকেটে সিটিস্টেস্ট চেষ্টা করছি । সমস্যাটি হ'ল সিএমকে "বুঝতে" পারছেন না যে আমি যে পরীক্ষাটি চালাতে চাইছি তা নির্মাণ করা উচিত কারণ এটি প্রকল্পের অংশ।

সুতরাং আমি এই নির্ভরতা স্পষ্টভাবে নির্দিষ্ট করার জন্য একটি উপায় খুঁজছি।

Question 2

এটা তর্কসাপেক্ষে একটি CMake মধ্যে বাগ (আগের ট্র্যাক এখানে ) যে এই বাক্সের বাইরে কাজ করে না। একটি কার্যপ্রণালী নিম্নলিখিত করা হয়:

add_test(TestName ExeName)
add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND}
                  DEPENDS ExeName)

তারপরে আপনি চালাতে পারবেন make checkএবং এটি পরীক্ষাটি সংকলন ও চালনা করবে। আপনার যদি বেশ কয়েকটি পরীক্ষা করে থাকে তবে আপনাকে DEPENDS exe1 exe2 exe3 ...উপরের লাইনে ব্যবহার করতে হবে ।

Question 3

আসলে ব্যবহারের একটি উপায় আছে make test। আপনাকে পরীক্ষার এক হিসাবে নির্বাহযোগ্য পরীক্ষার বিল্ডটি সংজ্ঞায়িত করতে হবে এবং তারপরে পরীক্ষাগুলির মধ্যে নির্ভরতা যুক্ত করতে হবে। এটাই:

ADD_TEST(ctest_build_test_code
         "${CMAKE_COMMAND}" --build ${CMAKE_BINARY_DIR} --target test_code)
ADD_TEST(ctest_run_test_code test_code)
SET_TESTS_PROPERTIES(ctest_run_test_code
                     PROPERTIES DEPENDS ctest_build_test_code)

Question 4

আমি রিচকের উত্তরের বৈকল্পিক ব্যবহার করি। শীর্ষ-স্তরে CMakeLists.txt, আমি build_and_testসমস্ত পরীক্ষার বিল্ডিং এবং চালনার জন্য একটি কাস্টম লক্ষ্য যুক্ত করি :

find_package(GTest)
if (GTEST_FOUND)
    enable_testing()
    add_custom_target(build_and_test ${CMAKE_CTEST_COMMAND} -V)
    add_subdirectory(test)
endif()

এর CMakeLists.txtঅধীনে থাকা বিভিন্ন সাব-প্রজেক্ট ফাইলগুলিতে test/আমি প্রতিটি পরীক্ষার নির্বাহযোগ্য হিসাবে নির্ভরযোগ্য হিসাবে যুক্ত করি build_and_test:

include_directories(${CMAKE_SOURCE_DIR}/src/proj1)
include_directories(${GTEST_INCLUDE_DIRS})
add_executable(proj1_test proj1_test.cpp)
target_link_libraries(proj1_test ${GTEST_BOTH_LIBRARIES} pthread)
add_test(proj1_test proj1_test)
add_dependencies(build_and_test proj1_test)

এই পদ্ধতির সাথে, আমার কেবল (বা ) make build_and_testপরিবর্তে প্রয়োজন , এবং এটির জন্য কেবলমাত্র বিল্ডিং টেস্ট কোড (এবং এর নির্ভরতা) এর সুবিধা রয়েছে। এটি লজ্জার বিষয় আমি টার্গেটের নামটি ব্যবহার করতে পারি না । আমার ক্ষেত্রে এটি এতটা খারাপ নয় কারণ আমার কাছে একটি শীর্ষ স্তরের স্ক্রিপ্ট রয়েছে যা গাছের বাইরে ডিবেগ করে এবং রিলিজ করে (এবং ক্রস-সংকলিত) কল করে এবং তারপরে এটি অনুবাদ করে ।make testmake all testtestcmakemaketestbuild_and_test

স্পষ্টতই, জিস্টেস্ট স্টাফগুলির প্রয়োজন নেই। আমি গুগল টেস্টের মতো / ব্যবহার করার মতোই হয়েছি এবং সিএমকে / সিটেষ্টের সাথে এটি ব্যবহারের একটি সম্পূর্ণ উদাহরণ ভাগ করতে চেয়েছি। আইএমএইচও, এই পদ্ধতির আমাকে ব্যবহার করার অনুমতি দেওয়ার সুবিধাও রয়েছে ctest -V, যা পরীক্ষাগুলি চলাকালীন গুগল টেস্ট আউটপুট দেখায়:

1: Running main() from gtest_main.cc
1: [==========] Running 1 test from 1 test case.
1: [----------] Global test environment set-up.
1: [----------] 1 test from proj1
1: [ RUN      ] proj1.dummy
1: [       OK ] proj1.dummy (0 ms)
1: [----------] 1 test from proj1 (1 ms total)
1:
1: [----------] Global test environment tear-down
1: [==========] 1 test from 1 test case ran. (1 ms total)
1: [  PASSED  ] 1 test.
1/2 Test #1: proj1_test .......................   Passed    0.03 sec

Question 5

আপনি যদি অনুকরণ করার চেষ্টা করছেন make check, আপনি এই উইকি এন্ট্রি দরকারী পুরোপুরি দেখতে পাবেন:

http://www.cmake.org/Wiki/CMakeEmulateMakeCheck

আমি এটি যাচাই করেছি যা এটি সাফল্যের সাথে যা বলেছে তা করে (সিএমকে ২.৮.১০)।

Question 6

নিজেকে মাথা ব্যথা বাঁচাও:

make all test

আমার জন্য বাক্সের বাইরে কাজ করে এবং পরীক্ষা চালানোর আগে নির্ভরতা তৈরি করে। এটি কতটা সহজ, এটি দেওয়া প্রায়ক্ষেত্রে দেশীয় make testকার্যকারিতাটি সুবিধাজনক করে তোলে কারণ এটি আপনাকে কোড বিচ্ছিন্ন হয়ে গেলেও শেষ সংকলন পরীক্ষা চালানোর বিকল্প দেয়।

Question 7

আপনি যদি সিএমকে> = 3.7 ব্যবহার করছেন তবে প্রস্তাবিত পদ্ধতিরটি ফিক্সচারগুলি ব্যবহার করা :

add_executable(test test.cpp)
add_test(test_build
  "${CMAKE_COMMAND}"
  --build "${CMAKE_BINARY_DIR}"
  --config "$<CONFIG>"
  --target test
)
set_tests_properties(test_build PROPERTIES FIXTURES_SETUP    test_fixture)
add_test(test test)
set_tests_properties(test       PROPERTIES FIXTURES_REQUIRED test_fixture)

এটি নিম্নলিখিতগুলি করে:

এর testথেকে নির্মিত একটি নির্বাহযোগ্য লক্ষ্য যুক্ত করেtest.cpp
একটি test_build"পরীক্ষা" যুক্ত করে যা লক্ষ্য তৈরি করতে কুমেক চালায়test
মার্কস test_buildপরীক্ষা চোকান একটি সেটআপ টাস্ক হতেtest_fixture
একটি testপরীক্ষা যোগ করুন যা কেবলমাত্র testএক্সিকিউটেবল চালায়
দৃ testxture়তা প্রয়োজন পরীক্ষা চিহ্নিত test_fixture।

সুতরাং, প্রতিবার পরীক্ষা testচালাতে হয়, এটি প্রথমে পরীক্ষা চালায় test_buildযা প্রয়োজনীয় নির্বাহযোগ্য করে তোলে।

Question 8

এটিই আমি হাতছাড়া করেছিলাম এবং ব্যবহার করে যাচ্ছি:

set(${PROJECT_NAME}_TESTS a b c)

enable_testing()
add_custom_target(all_tests)
foreach(test ${${PROJECT_NAME}_TESTS})
        add_executable(${test} EXCLUDE_FROM_ALL ${test}.cc)
        add_test(NAME ${test} COMMAND $<TARGET_FILE:${test}>)
        add_dependencies(all_tests ${test})
endforeach(test)

build_command(CTEST_CUSTOM_PRE_TEST TARGET all_tests)
string(CONFIGURE \"@CTEST_CUSTOM_PRE_TEST@\" CTEST_CUSTOM_PRE_TEST_QUOTED ESCAPE_QUOTES)
file(WRITE "${CMAKE_BINARY_DIR}/CTestCustom.cmake" "set(CTEST_CUSTOM_PRE_TEST ${CTEST_CUSTOM_PRE_TEST_QUOTED})" "\n")

ওয়াইএমএমভি

Question 9

ডেরিকের উত্তর, সরল ও মন্তব্য করা হয়েছে:

# It is impossible to make target "test" depend on "all":
# https://gitlab.kitware.com/cmake/cmake/-/issues/8774
# Set a magic variable in a magic file that tells ctest
# to invoke the generator once before running the tests:
file(WRITE "${CMAKE_BINARY_DIR}/CTestCustom.cmake"
    "set(CTEST_CUSTOM_PRE_TEST ${CMAKE_MAKE_PROGRAM})\n"
)

এটি পুরোপুরি সঠিক নয়, যেহেতু এটি চলমান একযোগে সমস্যা সমাধান করে না ninja all test, যদি কেউ তা করে। বিপরীতে, কারণ এখন, আপনার দুটি নিনজা প্রক্রিয়া রয়েছে।

(এফটিআর, আমি এই সমাধানটি এখানেও ভাগ করে নিয়েছি ))

Question 10

উপরের সমস্ত উত্তর নির্ভুল। তবে আসলে সিএমকে সিটিস্টকে এর পরীক্ষার সরঞ্জাম হিসাবে ব্যবহার করে, সুতরাং মিশনটি করার জন্য আদর্শ পদ্ধতি (আমার মনে হয় এটি):

enable_testing ()
add_test (TestName TestCommand)
add_test (TestName2 AnotherTestCommand)

তারপরে cmake চালান এবং লক্ষ্যগুলি তৈরি করতে তৈরি করুন। এর পরে, আপনি হয় মেক টেস্ট চালাতে পারেন , বা কেবল চালাতে পারেন

ctest

আপনি ফলাফল পাবেন। এটি সিএমকে ২.৮ এর অধীনে পরীক্ষা করা হয়।

এখানে বিশদটি পরীক্ষা করুন: http://cmake.org/Wiki/CMake/Testing_With_CTest# সিম্পল_স্টেস্টিং

Question 11

সমস্ত উত্তরগুলি ভাল, তবে তারা আদেশ দিয়ে একটি পরীক্ষা চালানোর জন্য traditionতিহ্য লঙ্ঘন করে make test। আমি এই কৌশলটি করেছি:

add_test(NAME <mytest>
WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
COMMAND sh -c "make <mytarget>; $<TARGET_FILE:<mytarget>>")

এর অর্থ হল পরীক্ষার মধ্যে বিল্ডিং (allyচ্ছিকভাবে) এবং এক্সিকিউটেবল টার্গেট চালানো থাকে।