সিএমডি প্রশাসক হিসাবে চালিত হচ্ছে / কীভাবে উন্নতি সুবিধা পেয়েছে তা কীভাবে সনাক্ত করবেন?

Question 1

ব্যাচ ফাইলের অভ্যন্তর থেকে, আমি পরীক্ষা করতে চাই যে আমি প্রশাসক / উন্নত সুবিধাগুলির সাথে চলছি কিনা।

"প্রশাসক হিসাবে চালান" নির্বাচন করা হলে ব্যবহারকারীর নাম পরিবর্তন হয় না, যাতে এটি কাজ করে না।

যদি সর্বজনীনভাবে উপলব্ধ কমান্ড থাকে, যার কোনও প্রভাব নেই, তবে প্রশাসনিক সুযোগ-সুবিধার প্রয়োজন হয়, তবে আমি এটি চালাতে পারি এবং অধিকারগুলির জন্য পরীক্ষা করার জন্য একটি ত্রুটি কোড পরীক্ষা করতে পারি। এখনও পর্যন্ত, আমি এই জাতীয় আদেশ খুঁজে পাইনি। আমি যে কমান্ডগুলি পেয়েছি সেগুলি একটি একক, অ-নির্দিষ্ট ত্রুটি কোডটি প্রত্যাবর্তন করবে বলে মনে হচ্ছে যা কোনও কিছুই নির্দেশ করতে পারে এবং বিভিন্ন কারণে তারা ব্যর্থতার ঝুঁকিতে রয়েছে।

আমি কেবল উইন্ডোজ about এর বিষয়ে যত্নশীল, যদিও পূর্ববর্তী অপারেটিং সিস্টেমগুলির সমর্থনটি দুর্দান্ত।

Question 2

যোগ করুন : উইন্ডোজ 8 এর জন্য এটি কাজ করবে না; পরিবর্তে এই দুর্দান্ত উত্তর দেখুন ।

এখানে এই সমাধানটি খুঁজে পেয়েছেন: http://www.robvenderwoude.com/clevertricks.php

AT > NUL
IF %ERRORLEVEL% EQU 0 (
    ECHO you are Administrator
) ELSE (
    ECHO you are NOT Administrator. Exiting...
    PING 127.0.0.1 > NUL 2>&1
    EXIT /B 1
)

ধরে নেওয়া যায় না যে এটি কার্যকর নয় এবং যেহেতু আমরা উইন 7 এর সাথে কথা বলছি আপনি যদি উপযুক্ত হন তবে নিম্নলিখিতগুলি পাওয়ারশেলটিতে ব্যবহার করতে পারবেন:

$principal = new-object System.Security.Principal.WindowsPrincipal([System.Security.Principal.WindowsIdentity]::GetCurrent())
$principal.IsInRole([System.Security.Principal.WindowsBuiltInRole]::Administrator)

যদি না হয় (এবং সম্ভবত নাও, যেহেতু আপনি স্পষ্টভাবে ব্যাচ ফাইলগুলি প্রস্তাব করেছিলেন) তবে আপনি উপরেরটি .NET লিখতে এবং আপনার ব্যাচ ফাইলটি ব্যবহারের ফলাফলের উপর ভিত্তি করে একটি এক্সি থেকে একটি প্রস্থান কোড ফেরত দিতে পারেন।

Question 3

এই কৌশলটির জন্য কেবল একটি কমান্ড প্রয়োজন: net sessionকমান্ড প্রম্পটে টাইপ করুন ।

আপনি যদি প্রশাসক না হন তবে আপনি একটি অ্যাক্সেস পান না বলে বার্তা বঞ্চিত হন।

System error 5 has occurred.

Access is denied.

আপনি যদি প্রশাসক হন তবে আপনি একটি পৃথক বার্তা পাবেন যা সর্বাধিক সাধারণ:

There are no entries in the list.

এমএস টেকনেট থেকে :

পরামিতি ছাড়াই ব্যবহৃত, নেট সেশন স্থানীয় কম্পিউটারের সাথে সমস্ত সেশন সম্পর্কিত তথ্য প্রদর্শন করে।

Question 4

আমি এটি ব্যবহারের জন্য রুশির পরামর্শ পছন্দ করি তবে এটি অন্য একটি বিকল্প:

whoami /groups | findstr /b BUILTIN\Administrators | findstr /c:"Enabled group" && goto :isadministrator

এই পদ্ধতির সাহায্যে আপনাকে নন-অ্যাডমিনিস্ট্রেটর এবং অ-উন্নত প্রশাসকের মধ্যে পার্থক্য করতে দেয় যদি আপনি চান। অ-উন্নত প্রশাসকদের এখনও গ্রুপ তালিকায় বিল্টিন \ প্রশাসক রয়েছে তবে এটি সক্ষম নয়।

তবে এটি কিছু অ-ইংরাজী ভাষা সিস্টেমে কাজ করবে না। পরিবর্তে, চেষ্টা করুন

whoami /groups | findstr /c:" S-1-5-32-544 " | findstr /c:" Enabled group" && goto :isadministrator

(এটি উইন্ডোজ on এ কাজ করা উচিত তবে আমি পূর্ববর্তী সংস্করণগুলি সম্পর্কে নিশ্চিত নই))

Question 5

অন্যরা যা রেখেছিল তা অনেক সুন্দর, তবে ব্যাচ কমান্ডের শুরুতে রাখা যেতে পারে এমন একটি লাইনার হিসাবে। (ভাল, সাধারণত @ ইকো অফ করার পরে।)

net.exe session 1>NUL 2>NUL || (Echo This script requires elevated rights. & Exit /b 1)

Question 6

ভিস্তা, উইন 7 এবং তারপরে এটি করার সহজতম উপায় হ'ল টোকেন গ্রুপগুলি গণনা করা এবং বর্তমান অখণ্ডতা স্তরের সন্ধান করা (বা প্রশাসকদের পক্ষ থেকে, যদি কেবল গ্রুপের সদস্যপদ গুরুত্বপূর্ণ হয়):

আমরা উন্নতভাবে চলছি কিনা তা পরীক্ষা করুন:

whoami /groups | find "S-1-16-12288" && Echo I am running elevated, so I must be an admin anyway ;-)

আমরা স্থানীয় প্রশাসকদের অন্তর্ভুক্ত কিনা তা পরীক্ষা করুন:

whoami /groups | find "S-1-5-32-544" && Echo I am a local admin

আমরা ডোমেন প্রশাসকদের অন্তর্ভুক্ত কিনা তা পরীক্ষা করুন:

whoami /groups | find "-512 " && Echo I am a domain admin

নীচের নিবন্ধটি এসআইডি উইন্ডোজগুলির ব্যবহারের জন্য অখণ্ডতা স্তরের তালিকাবদ্ধ করেছে: http ://msdn.mic Microsoft.com/en-us/library/bb625963.aspx

Question 7

এখানে হ্যারি এর উত্তরে সামান্য পরিবর্তন হয়েছে যা উন্নত স্থিতিতে ফোকাস করে; আমি এটি ইনস্টল.বাট ফাইলের শুরুতে ব্যবহার করছি:

set IS_ELEVATED=0
whoami /groups | findstr /b /c:"Mandatory Label\High Mandatory Level" | findstr /c:"Enabled group" > nul: && set IS_ELEVATED=1
if %IS_ELEVATED%==0 (
    echo You must run the command prompt as administrator to install.
    exit /b 1
)

এটি অবশ্যই আমার পক্ষে কাজ করেছে এবং নীতিটি যথাযথ বলে মনে হচ্ছে; থেকে MSFT ক্রিস জ্যাকসন :

আপনি যখন উন্নত অবস্থায় চলেছেন, আপনার টোকেনে একটি এসিই রয়েছে যা বাধ্যতামূলক লেবেল \ উচ্চ বাধ্যতামূলক স্তর called

Question 8

সমাধান:

at >nul
if %ErrorLevel% equ 0 ( echo Administrator ) else ( echo NOT Administrator )

উইন্ডোজ 10 এর অধীনে কাজ করে না

উইন্ডোজের সমস্ত সংস্করণের জন্য এটি করা যেতে পারে:

openfiles >nul 2>&1
if %ErrorLevel% equ 0 ( echo Administrator ) else ( echo NOT Administrator )

Question 9

আমি প্রতিক্রিয়াগুলির অনেকগুলি (সর্বাধিক?) পড়েছি, তারপরে একটি ব্যাট ফাইল তৈরি করেছে যা উইন 8.1 এ আমার জন্য কাজ করে। ভেবেছিলাম ভাগ করে নিই।

setlocal
set runState=user
whoami /groups | findstr /b /c:"Mandatory Label\High Mandatory Level" > nul && set runState=admin
whoami /groups | findstr /b /c:"Mandatory Label\System Mandatory Level" > nul && set runState=system
echo Running in state: "%runState%"
if not "%runState%"=="user" goto notUser
  echo Do user stuff...
  goto end
:notUser
if not "%runState%"=="admin" goto notAdmin
  echo Do admin stuff...
  goto end
:notAdmin
if not "%runState%"=="system" goto notSystem
  echo Do admin stuff...
  goto end
:notSystem
echo Do common stuff...
:end

আশা করি কেউ এটি দরকারী খুঁজে পেয়েছেন :)

Question 10

Https://stackoverflow.com/a/38856823/2193477 এর একটি "নো-অ-ওয়ান-লাইনার" সংস্করণ

@echo off
net.exe session 1>NUL 2>NUL || goto :not_admin
echo SUCCESS
goto :eof

:not_admin
echo ERROR: Please run as a local administrator.
exit /b 1

Question 11

আমি জানি আমি এই পার্টিতে সত্যিই দেরি করেছি, তবে অ্যাডমিন-হুড নির্ধারণের জন্য আমার এক লাইনার এখানে।

এটি ত্রুটি স্তরের উপর নির্ভর করে না, কেবলমাত্র systeminfo:

for /f "tokens=1-6" %%a in ('"net user "%username%" | find /i "Local Group Memberships""') do (set admin=yes & if not "%%d" == "*Administrators" (set admin=no) & echo %admin%)

এটি হ্যাঁ বা না, ব্যবহারকারী প্রশাসকের স্থিতির উপর নির্ভর করে ফিরে আসে ...

এটি ভেরিয়েবলের "অ্যাডমিন" এর মানও হ্যাঁ বা না অনুসারে নির্ধারণ করে।

Question 12

আপনি যদি প্রশাসকের অধিকার নিয়ে ব্যবহারকারী হিসাবে চলমান থাকেন তবে পরিবেশ পরিবর্তনশীল সেশননাম সংজ্ঞায়িত হবে না এবং ব্যাচ ফাইল চালানোর সময় আপনার প্রশাসকের অধিকার নেই।

প্রশাসকের অধিকার যাচাই করতে আপনার "নেট সেশন" কমান্ডটি ব্যবহার করা উচিত এবং "0" এর ত্রুটি রিটার্ন কোডের সন্ধান করা উচিত।

উদাহরণ; - প্রথম প্রতিধ্বনি বিবৃতিটি বেল চরিত্রটি net session >nul 2>&1 if not %errorlevel%==0 (echo echo You need to start over and right-click on this file, echo then select "Run as administrator" to be successfull. echo.&pause&exit)

Question 13

উইন্ডোজ ১০-এর মাধ্যমে আমি উইন্ডোজ on-তে ব্যবহার করার জন্য একটি সহজ পদ্ধতিটি এখানে মূলত, আমি উইন্ডোজ \ সিস্টেম 32 \ ডাব্লুআইডিআই \ লগফায়ার ফোল্ডারটি পরীক্ষা করার জন্য কেবল "IF উপস্থিত" কমান্ডটি ব্যবহার করি। কমপক্ষে from থেকে উইন্ডোজের প্রতিটি ইনস্টল-এ ডাব্লুআইডিআই ফোল্ডারটি বিদ্যমান এবং এর অ্যাক্সেসের জন্য প্রশাসকের অধিকার প্রয়োজন privile ডাব্লুআইডিআই ফোল্ডারের সর্বদা এর ভিতরে একটি লগফিলস ফোল্ডার থাকে। সুতরাং, ডাব্লুআইডিআই \ লগ ফাইলে ফোল্ডারে "যদি উপস্থিত থাকে" চালানো অ্যাডমিন হিসাবে চালিত হয় তবে সত্য এবং অ্যাডমিন হিসাবে চালানো না হলে এটি মিথ্যা হয়ে যায়। এটি কোনও ব্যাচ ফাইলে সুবিধাগুলির স্তর যাচাই করতে এবং সেই ফলাফলের উপর ভিত্তি করে আপনার যে কোনও আদেশের ইচ্ছা তা শাখায় ব্যবহার করা যেতে পারে।

উদাহরণ কোডের একটি সংক্ষিপ্ত স্নিপেট এখানে:

IF EXIST %SYSTEMROOT%\SYSTEM32\WDI\LOGFILES GOTO GOTADMIN
(Commands for running with normal privileges)

:GOTADMIN
(Commands for running with admin privileges)

মনে রাখবেন যে এই পদ্ধতিটি ধরে নিয়েছে যে ডাব্লুআইডিআই ফোল্ডারে ডিফল্ট সুরক্ষা অনুমতিগুলি সংশোধন করা হয়নি (যা বেশিরভাগ পরিস্থিতিতে হওয়ার সম্ভাবনা নেই, তবে দয়া করে নীচে # 2 দেখুন)। এমনকি সেক্ষেত্রে অ্যাডমিন অ্যাক্সেসের প্রয়োজন হয় এমন একটি সাধারণ সাধারণ ফাইল / ফোল্ডার যাচাই করার জন্য কোডটি সংশোধন করার বিষয়টি কেবলমাত্র (সিস্টেম 32 \ কনফিগারেশন \ এসএএম ভাল বিকল্প প্রার্থী হতে পারে), অথবা এমনকি আপনি তার জন্য বিশেষত নিজের তৈরি করতে পারেন উদ্দেশ্য।

এই পদ্ধতি সম্পর্কে দুটি সতর্কতা রয়েছে যদিও:

ইউএসি অক্ষম করার ফলে সম্ভবত এটিকে অ্যাডমিন হিসাবে চালানো হবে এমন সাধারণ সত্যটি হয়ে যায়।
উইন্ডোজ এক্সপ্লোরারে ডাব্লুআইডিআই ফোল্ডারটি খোলার চেষ্টা করা হচ্ছে এবং তারপরে "চালিয়ে যাও" ক্লিক করলে অনুরোধ করা সেই ব্যবহারকারীর অ্যাকাউন্টের স্থায়ী অ্যাক্সেসের অধিকার যুক্ত করবে, এইভাবে আমার পদ্ধতিটি ভেঙে দেওয়া। যদি এটি ঘটে থাকে তবে ডাব্লুআইডিআই ফোল্ডার সুরক্ষা অনুমতিগুলি থেকে ব্যবহারকারী অ্যাকাউন্টটি সরিয়ে এটি ঠিক করা যেতে পারে। যদি কোনও কারণে ব্যবহারকারী উইন্ডোজ এক্সপ্লোরারের সাথে ডাব্লুআইডিআই ফোল্ডারটি অ্যাক্সেস করতে সক্ষম হন তবে আপনাকে আলাদা ফোল্ডারটি পরীক্ষা করতে কোডটি সংশোধন করতে হবে (উপরে উল্লিখিত যেমন এই উদ্দেশ্যে বিশেষভাবে নিজের তৈরি করা ভাল পছন্দ হতে পারে) ।

সুতরাং, স্বীকার করা যে আমার পদ্ধতিটি একেবারে ভেঙে যেতে পারে নিখুঁত নয়, তবে এটি তুলনামূলক দ্রুত পদ্ধতি যা কার্যকর করা সহজ, উইন্ডোজ 7, 8 এবং 10 এর সমস্ত সংস্করণের সাথে সমানভাবে সামঞ্জস্যপূর্ণ, এবং আমি প্রদত্ত ক্যাভ্যাটগুলির প্রতি আমি সচেতন থাকি আমার জন্য 100% কার্যকর ছিল।

Question 14

উইন 7 এন্টারপ্রাইজ এবং উইন 10 এন্টারপ্রাইজের পক্ষে কাজ করে

@if DEFINED SESSIONNAME (
    @echo.
    @echo You must right click to "Run as administrator"
    @echo Try again
    @echo.
    @pause
    @goto :EOF
)