সীমাবদ্ধতার সাথে কীভাবে কলামটি ড্রপ করবেন?

Question

এসকিউএল সার্ভার ২০০৮ এ ডিফল্ট সীমাবদ্ধতা রয়েছে এমন একটি কলাম কীভাবে ড্রপ করবেন?

আমার জিজ্ঞাসা হয়

alter table tbloffers
drop column checkin

আমি ত্রুটি নিচে পেয়ে যাচ্ছি

এক বা একাধিক বস্তু এই কলামটিতে অ্যাক্সেস করার কারণে টেবিলের ড্রপ কলম চেকইন ব্যর্থ হয়েছে।

বাধা দিয়ে কলামটি ড্রপ করতে কেউ কি আমার জিজ্ঞাসাটি সংশোধন করতে পারে?

Comments

অন্যান্য টেবিলগুলি থেকে এই টেবিলের জন্য কিছু রেফারেন্স থাকতে পারে যা এই ত্রুটি ঘটাচ্ছে।

— পঙ্কজ উপাধ্যায়

এতে আগত নতুন আগতদের জন্য, নীচে আমার উত্তরটি দেখুন , যদি এটি আপনার পক্ষে কাজ করে তবে এটি অন্যান্য সমাধানগুলির থেকে কিছুটা সহজ।

— BrainSlugs83

আমি আমার প্রশ্ন এবং উত্তর এখানে

— আকাশ যেল্লাপ্পা

Answer 1

প্রথমে আপনার সমস্যাটি ফেলে দেওয়া উচিত DEFAULT constraint, এর পরে আপনি কলামটি ফেলে দিতে পারেন

alter table tbloffers drop constraint [ConstraintName]
go

alter table tbloffers drop column checkin

তবে ত্রুটিটি অন্য কারণে উপস্থিত হতে পারে - উদাহরণস্বরূপ ব্যবহারকারী নির্ধারিত ফাংশন বা SCHEMABINDINGতাদের জন্য বিকল্প সেট সহ দেখুন ।

ইউপিডি: সীমাবদ্ধতার স্ক্রিপ্টটি সম্পূর্ণ স্বয়ংক্রিয়ভাবে বাদ দেওয়া:

DECLARE @sql NVARCHAR(MAX)
WHILE 1=1
BEGIN
    SELECT TOP 1 @sql = N'alter table tbloffers drop constraint ['+dc.NAME+N']'
    from sys.default_constraints dc
    JOIN sys.columns c
        ON c.default_object_id = dc.object_id
    WHERE 
        dc.parent_object_id = OBJECT_ID('tbloffers')
    AND c.name = N'checkin'
    IF @@ROWCOUNT = 0 BREAK
    EXEC (@sql)
END

Comments

স্বয়ংক্রিয় স্ক্রিপ্ট জন্য ধন্যবাদ। একটি যাদুমন্ত্র মত কাজ করে!

— কানাডিয়ানড্রি 3

আপনাকে অনেক ধন্যবাদ - আপনি আমাকে অনেক সময় বাঁচিয়েছেন। আমি যে প্রশ্নটি জিজ্ঞাসা করেছি তা এখানে যুক্ত করেছি

— আকাশ যেল্লাপ্পা

Answer 2

সীমাবদ্ধতার নামটি পাওয়ার জন্য প্রথমে পৃথক ক্যোয়ারী চালিয়ে না গিয়ে অজানা নাম নিয়ে ডিফল্ট সীমাবদ্ধতা ফেলে দেওয়ার আরও একটি উপায় এখানে রয়েছে:

DECLARE @ConstraintName nvarchar(200)
SELECT @ConstraintName = Name FROM SYS.DEFAULT_CONSTRAINTS
WHERE PARENT_OBJECT_ID = OBJECT_ID('__TableName__')
AND PARENT_COLUMN_ID = (SELECT column_id FROM sys.columns
                        WHERE NAME = N'__ColumnName__'
                        AND object_id = OBJECT_ID(N'__TableName__'))
IF @ConstraintName IS NOT NULL
EXEC('ALTER TABLE __TableName__ DROP CONSTRAINT ' + @ConstraintName)

Comments

একটি দুর্দান্ত উত্তর, আপনাকে ধন্যবাদ। আমি উপরের উত্তরটিও উচ্চতর করেছিলাম, যদিও, কেবল সেলেক্টিং এবং ড্রপ করার সিদ্ধান্ত নেওয়ার আগে প্রথমে পরিদর্শন করার পুরানো অভ্যাসের বাইরে।

— নগরব

সত্যিই দুর্দান্ত উত্তর। সুবিধার্থে / ভবিষ্যতের ব্যবহারের জন্য আমি এটির বাইরে একটি সঞ্চিত প্রক্রিয়া তৈরি করেছি: পেস্টবিন.

— com

যখন একটি কলামে একাধিক প্রতিবন্ধকতা বাঁধা আছে তখন দুর্দান্ত উত্তর তবে এখনও অ্যাক্সেসটি অনুপস্থিত। অন্তর্ভুক্ত লুপ সহ @ ডিগসের পোস্টের অনুরূপ কিছু সঞ্চিত সংগ্রহ 5 টি তারকা উত্তর হতে পারে

— YeinCM-Qva

Answer 3

আপনি স্বতন্ত্রভাবে পরিবর্তে একক বিবৃতিতে কলাম এবং এর সীমাবদ্ধতাগুলি ফেলে দিতে পারেন।

CREATE TABLE #T
  (
     Col1 INT CONSTRAINT UQ UNIQUE CONSTRAINT CK CHECK (Col1 > 5),
     Col2 INT
  )

ALTER TABLE #T DROP CONSTRAINT UQ , 
                    CONSTRAINT CK, 
                    COLUMN Col1


DROP TABLE #T 

কিছু গতিশীল এসকিউএল যা নির্ভরযোগ্য চেক সীমাবদ্ধতা এবং ডিফল্ট সীমাবদ্ধতার নামগুলি সন্ধান করবে এবং কলাম সহ সেগুলি বাদ দিবে নীচে রয়েছে

(তবে অন্যান্য সম্ভাব্য কলাম নির্ভরতা যেমন বিদেশী কী, অনন্য এবং প্রাথমিক কী বাধা, গণিত কলাম, সূচীগুলি নয়)

CREATE TABLE [dbo].[TestTable]
(
A INT DEFAULT '1' CHECK (A=1),
B INT,
CHECK (A > B)
)

GO

DECLARE @TwoPartTableNameQuoted nvarchar(500) = '[dbo].[TestTable]',
        @ColumnNameUnQuoted sysname = 'A',
        @DynSQL NVARCHAR(MAX);

SELECT @DynSQL =
     'ALTER TABLE ' + @TwoPartTableNameQuoted + ' DROP' + 
      ISNULL(' CONSTRAINT ' + QUOTENAME(OBJECT_NAME(c.default_object_id)) + ',','') + 
      ISNULL(check_constraints,'') + 
      '  COLUMN ' + QUOTENAME(@ColumnNameUnQuoted)
FROM   sys.columns c
       CROSS APPLY (SELECT ' CONSTRAINT ' + QUOTENAME(OBJECT_NAME(referencing_id)) + ','
                    FROM   sys.sql_expression_dependencies
                    WHERE  referenced_id = c.object_id
                           AND referenced_minor_id = c.column_id
                           AND OBJECTPROPERTYEX(referencing_id, 'BaseType') = 'C'
                    FOR XML PATH('')) ck(check_constraints)
WHERE  c.object_id = object_id(@TwoPartTableNameQuoted)
       AND c.name = @ColumnNameUnQuoted;

PRINT @DynSQL;
EXEC (@DynSQL); 

Comments

যদিও আপনার এই সীমাবদ্ধতার নামটি জানা উচিত। টেবিল তৈরির সময় যদি তাদের নাম না দেওয়া হয় তবে তারা একটি স্বয়ংক্রিয়ভাবে উত্পন্ন নাম পায়।

— জয়ে 10

@ জোয় - নাম না জেনে বাধা পড়ার কোনও বাক্য গঠন নেই। DROP CONSTRAINT ব্যাকরণটি দেখার জন্য এটি একটি প্রয়োজনীয় যুক্তি you তবে এটি খুঁজে পেয়ে আপনি একই সময়ে সীমাবদ্ধতা এবং কলামটি ছাড়তে পারেন।

— মার্টিন স্মিথ

ভাল কোড, আমার একবারে বহুবিধ প্রতিবন্ধকতাগুলি ড্রপ করা দরকার, তবে কলামটি নয়। আপনার পরিবর্তনটি কৌশলটি করেছে। ধন্যবাদ !!

— htm11h

Answer 4

এই প্রশ্নের সাথে এখানে ডিফল্ট সীমাবদ্ধতা সন্ধান করুন:

SELECT
    df.name 'Constraint Name' ,
    t.name 'Table Name',
    c.NAME 'Column Name'
FROM sys.default_constraints df
INNER JOIN sys.tables t ON df.parent_object_id = t.object_id
INNER JOIN sys.columns c ON df.parent_object_id = c.object_id AND df.parent_column_id = c.column_id

এটি আপনাকে ডিফল্ট সীমাবদ্ধতার নাম, পাশাপাশি সারণী এবং কলামের নাম দেয়।

আপনার যখন সেই তথ্য থাকে তখন আপনাকে প্রথমে ডিফল্ট সীমাবদ্ধতা ফেলে দিতে হবে:

ALTER TABLE dbo.YourTable
DROP CONSTRAINT name-of-the-default-constraint-here

এবং তারপরে আপনি কলামটি ড্রপ করতে পারেন

ALTER TABLE dbo.YourTable DROP COLUMN YourColumn

Comments

এটি ক্রমানুসারে করা হবে না। আপনি উভয় একই সময়ে করতে পারেন।

— মার্টিন স্মিথ

@ মার্টিনস্মিত: ঠিক আছে, দুর্দান্ত - ভাগ করে নেওয়ার জন্য ধন্যবাদ! আমি এই সম্ভাবনা সম্পর্কে সচেতন ছিলাম না - আপনি প্রতিদিন নতুন কিছু শিখুন! :-)

— marc_s

কেউ এই দুটি বিবৃতি একত্রিত করতে দয়া করে একটি উদাহরণ প্রদান করতে পারেন। আমার মতো কিছুটা দরকার: ALTER TABLE table DROP CONSTRAINT DF_XY DROP COLUMN XYদুর্ভাগ্যক্রমে এই বিবৃতিটির বাক্য গঠনটি সঠিক নয়

— My-Name-Is

@ মাই-নেম-ইজ: আপনি যদি মার্টিনের উত্তরটি পরীক্ষা করে DROP

— দেখেন তবে

Answer 5

নিম্নলিখিতটি আমার জন্য এসকিউএল অ্যাজুরি ব্যাকেন্ডের (এসকিউএল সার্ভার ম্যানেজমেন্ট স্টুডিও ব্যবহার করে) বিপরীতে কাজ করেছে, তাই ওয়াইএমএমভি, তবে এটি যদি আপনার পক্ষে কাজ করে তবে অন্যান্য সমাধানের চেয়ে এটি আরও সহজ।

ALTER TABLE MyTable
    DROP CONSTRAINT FK_MyColumn
    CONSTRAINT DK_MyColumn
    -- etc...
    COLUMN MyColumn
GO

Answer 6

আমি একই পেয়েছি:

অল্টার টেবিল ড্রপ কলাম ব্যর্থ হয়েছে কারণ এক বা একাধিক বস্তু এই কলাম বার্তায় অ্যাক্সেস করে ।

আমার কলামে একটি সূচি ছিল যা প্রথমে মুছতে হবে। Sys.indexes ব্যবহার করে কৌতুকটি করেছেন:

DECLARE @sql VARCHAR(max)

SELECT @sql = 'DROP INDEX ' + idx.NAME + ' ON tblName'
FROM sys.indexes idx
INNER JOIN sys.tables tbl ON idx.object_id = tbl.object_id
INNER JOIN sys.index_columns idxCol ON idx.index_id = idxCol.index_id
INNER JOIN sys.columns col ON idxCol.column_id = col.column_id
WHERE idx.type <> 0
    AND tbl.NAME = 'tblName'
    AND col.NAME = 'colName'

EXEC sp_executeSql @sql
GO

ALTER TABLE tblName
DROP COLUMN colName

Answer 7

আমি আমার এসকিউএল সার্ভার সংস্করণে একটু স্ক্রিপ্ট আপডেট করেছি

DECLARE @sql nvarchar(max)

SELECT @sql = 'ALTER TABLE `table_name` DROP CONSTRAINT ' + df.NAME 
FROM sys.default_constraints df
  INNER JOIN sys.tables t ON df.parent_object_id = t.object_id
  INNER JOIN sys.columns c ON df.parent_object_id = c.object_id AND df.parent_column_id = c.column_id
where t.name = 'table_name' and c.name = 'column_name'

EXEC sp_executeSql @sql
GO

ALTER TABLE table_name
  DROP COLUMN column_name;

Answer 8

এটি সর্বদা কেবল একটি ডিফল্ট সীমাবদ্ধতা নয় যা কলাম ছাড়তে বাধা দেয় এবং কখনও কখনও সূচিগুলিও আপনাকে সীমাবদ্ধতা ছাড়তে বাধা দিতে পারে। সুতরাং আমি একটি পদ্ধতি লিখেছিলাম যা কোনও কলামে কোনও সূচক বা সীমাবদ্ধতা এবং কলামটি শেষে এটি নিজেই ফেলে দেয়।

IF OBJECT_ID ('ADM_delete_column', 'P') IS NOT NULL
   DROP procedure ADM_delete_column;
GO

CREATE procedure ADM_delete_column
    @table_name_in  nvarchar(300)
,   @column_name_in nvarchar(300)
AS 
BEGIN
    /*  Author: Matthis ([e-mail] at 2019.07.20)
        License CC BY (creativecommons.org)
        Desc:   Administrative procedure that drops columns at MS SQL Server
                - if there is an index or constraint on the column 
                    that will be dropped in advice
                => input parameters are TABLE NAME and COLUMN NAME as STRING
    */
    SET NOCOUNT ON

    --drop index if exist (search first if there is a index on the column)
    declare @idx_name VARCHAR(100)
    SELECT  top 1 @idx_name = i.name
    from    sys.tables t
    join    sys.columns c
    on      t.object_id = c.object_id
    join    sys.index_columns ic
    on      c.object_id = ic.object_id
    and     c.column_id = ic.column_id
    join    sys.indexes i
    on      i.object_id = ic.object_id
    and     i.index_id = ic.index_id
    where   t.name like @table_name_in
    and     c.name like @column_name_in
    if      @idx_name is not null
    begin 
        print concat('DROP INDEX ', @idx_name, ' ON ', @table_name_in)
        exec ('DROP INDEX ' + @idx_name + ' ON ' + @table_name_in)
    end

    --drop fk constraint if exist (search first if there is a constraint on the column)
    declare @fk_name VARCHAR(100)
    SELECT  top 1 @fk_name = CONSTRAINT_NAME 
    from    INFORMATION_SCHEMA.CONSTRAINT_COLUMN_USAGE
    where   TABLE_NAME like @table_name_in
    and     COLUMN_NAME like @column_name_in
    if      @fk_name is not null
    begin 
        print concat('ALTER TABLE ', @table_name_in, ' DROP CONSTRAINT ', @fk_name)
        exec ('ALTER TABLE ' + @table_name_in + ' DROP CONSTRAINT ' + @fk_name)
    end

    --drop column if exist
    declare @column_name VARCHAR(100)
    SELECT  top 1 @column_name = COLUMN_NAME 
    FROM    INFORMATION_SCHEMA.COLUMNS 
    WHERE   COLUMN_NAME like concat('%',@column_name_in,'%')
    if  @column_name is not null
    begin 
        print concat('ALTER TABLE ', @table_name_in, ' DROP COLUMN ', @column_name)
        exec ('ALTER TABLE ' + @table_name_in + ' DROP COLUMN ' + @column_name)
    end
end;
GO


--to run the procedure use this execute and fill the parameters 
execute ADM_delete_column 
    @table_name_in  = ''
,   @column_name_in = ''
    ;