আমি কীভাবে কোনও স্থানীয় এসকিউএল সার্ভারের দৃষ্টান্তটিতে নিজেকে প্রশাসককে অ্যাক্সেস দিতে পারি?

Question 1

আমি আমার স্থানীয় মেশিনে এসকিউএল সার্ভার 2008 আর 2 ইনস্টল করেছি। তবে, অধিকারের (বা অভাবের) কারণে আমি একটি নতুন ডাটাবেস তৈরি করতে পারি না।

"ডেটাবেস পার্মিশন তৈরি করুন"

সুতরাং, আমি আমার বর্তমান লগইনটিতে প্রশাসকের সুবিধাগুলি বরাদ্দ করার চেষ্টা করেছি

"ব্যবহারকারীর এই ক্রিয়াটি সম্পাদন করার অনুমতি নেই" "

আমি একটি নতুন লগইন তৈরি করার চেষ্টা করেছি যাতে অ্যাডমিনের সুবিধাগুলি থাকবে তবে ভাগ্য নেই। আমি কীভাবে নিজেকে অ্যাডমিনের অধিকার দেব যাতে আমি একটি ডেটাবেস তৈরি করতে পারি? আমি আবার ইনস্টল করতে পারি, তবে আমি পছন্দ করি না।

Question 2

হ্যাঁ - এসকিউএল সার্ভার ইনস্টল করার সময় আপনি নিজেকে সিসাদমিন ভূমিকাতে যুক্ত করতে ভুলে গেছেন। আপনি যদি আপনার মেশিনে স্থানীয় প্রশাসক হন তবে এই ব্লগ পোস্টটি আপনাকে পুনরায় ইনস্টল না করেই নিজের অ্যাকাউন্টটি এসকিউএল সার্ভার সিসাদমিন গ্রুপে পেতে এসকিউএলসিএমডি ব্যবহার করতে সহায়তা করতে পারে। এটি এসকিউএল সার্ভারের কিছুটা সুরক্ষা গর্ত, যদি আপনি আমাকে জিজ্ঞাসা করেন তবে এটি আপনাকে এই ক্ষেত্রে সহায়তা করবে।

Question 3

একটি কমান্ড প্রম্পট উইন্ডো খুলুন। আপনার যদি ইতিমধ্যে এসকিউএল সার্ভারের একটি ডিফল্ট উদাহরণ রয়েছে, এসকিউএল সার্ভার পরিষেবা বন্ধ করতে কমান্ড প্রম্পটে নিম্নলিখিত কমান্ডটি চালান:

net stop mssqlserver

এখন যে ডিরেক্টরিতে এসকিউএল সার্ভার ইনস্টল করা আছে সেখানে যান। উদাহরণস্বরূপ ডিরেক্টরিটি এর মধ্যে একটি হতে পারে:

C:\Program Files\Microsoft SQL Server\MSSQL10_50.MSSQLSERVER\MSSQL\Binn
C:\Program Files\Microsoft SQL Server\MSSQL13.MSSQLSERVER\MSSQL\Binn

আপনার এমএসএসকিউএল ডিরেক্টরিটি বের করুন এবং CDএটিতে এটি নির্ধারণ করুন:

CD C:\Program Files\Microsoft SQL Server\MSSQL10_50.MSSQLSERVER\MSSQL\Binn

এখন একক ব্যবহারকারী মোডে এসকিউএল সার্ভার শুরু করতে নিম্নলিখিত কমান্ডটি চালান। যেমন SQLCMDনির্দিষ্ট করা হচ্ছে, কেবলমাত্র একটি SQLCMDসংযোগ তৈরি করা যেতে পারে (অন্য কমান্ড প্রম্পট উইন্ডো থেকে)।

sqlservr -m"SQLCMD"

এখন, উপরের একক ব্যবহারকারীর মোডে এসকিউএল সার্ভার শুরু করা হিসাবে একই ব্যবহারকারীর মতো অন্য কমান্ড প্রম্পট উইন্ডোটি খুলুন এবং এতে চালনা করুন:

sqlcmd

এবং এন্টার টিপুন। এখন আপনি একক ব্যবহারকারী মোডে চলমান এসকিউএল সার্ভারের বিপরীতে এসকিউএল বিবৃতি কার্যকর করতে পারেন:

create login [<<DOMAIN\USERNAME>>] from windows;

-- For older versions of SQL Server:
EXEC sys.sp_addsrvrolemember @loginame = N'<<DOMAIN\USERNAME>>', @rolename = N'sysadmin';

-- For newer versions of SQL Server:
ALTER SERVER ROLE [sysadmin] ADD MEMBER [<<DOMAIN\USERNAME>>];

GO

সূত্র ।

আপডেট করা পরে কোনও সেমিকোলনটি ভুলে যাবেন না ALTER SERVER ROLE [sysadmin] ADD MEMBER [<<DOMAIN\USERNAME>>];এবং অতিরিক্ত অর্ধযন্তটি যুক্ত করবেন না GOবা কমান্ড কখনই কার্যকর করে না।

Question 4

আমি একটি এসকিউএল 2012 ডাটাবেস গ্রহণ করেছি যেখানে আমি সিসাদমিন নই তবে মেশিনে প্রশাসক ছিলাম। আমি "প্রশাসক হিসাবে রান করুন" এর সাথে এসএসএমএস ব্যবহার করেছি, আমার এনটি অ্যাকাউন্টকে এসকিউএল লগইন হিসাবে যুক্ত করেছি এবং সিস্টেমিনে সার্ভারের ভূমিকা সেট করেছি। সমস্যা নেই.

Question 5

এখানে একটি স্ক্রিপ্ট রয়েছে যা এটি ঠিক করতে সক্ষম বলে দাবি করে।

এই সাধারণ স্ক্রিপ্টের সাহায্যে আপনার স্থানীয় এসকিউএল সার্ভার এক্সপ্রেসে প্রশাসকের অধিকার পান

স্ক্রিপ্টের লিঙ্কটি ডাউনলোড করুন

বর্ণনা

এই কমান্ড স্ক্রিপ্টটি আপনাকে সহজেই স্থানীয় এসকিউএল সার্ভারের উদাহরণস্বরূপ সিসাদমিন চরিত্রে নিজেকে যুক্ত করতে দেয়। আপনার অবশ্যই উইন্ডোজ স্থানীয় প্রশাসক গোষ্ঠীর সদস্য হতে হবে বা যে কোনও ব্যবহারকারীর শংসাপত্রগুলি অ্যাক্সেস করতে হবে। স্ক্রিপ্টটি এসকিউএল সার্ভার 2005 এবং তারপরে সমর্থন করে।

স্ক্রিপ্টটি সর্বাধিক কার্যকর যদি আপনি বিকাশকারী হয়ে এসকিউএল সার্ভার ২০০ এক্সপ্রেস ব্যবহার করার চেষ্টা করছেন যা অন্য কারও দ্বারা ইনস্টল করা হয়েছিল। এই পরিস্থিতিতে সাধারণত আপনার এসকিউএল সার্ভার ২০০ 2008 এক্সপ্রেস উদাহরণের প্রশাসক অধিকার থাকবে না, কারণ পূর্বনির্ধারিতভাবে কেবল এসকিউএল সার্ভার ২০০৮ ইনস্টল করা ব্যক্তিকে প্রশাসনিক সুযোগ-সুবিধা দেওয়া হয়।

যে ব্যবহারকারী এসকিউএল সার্ভার ২০০ Express এক্সপ্রেস ইনস্টল করেছেন সে আপনাকে প্রয়োজনীয় সুযোগ-সুবিধা দেওয়ার জন্য এসকিউএল সার্ভার ম্যানেজমেন্ট স্টুডিও ব্যবহার করতে পারে। তবে কী হবে যদি এসকিউএল সার্ভার ম্যানেজমেন্ট স্টুডিও ইনস্টল করা না হয়? না আরও খারাপ যদি ইনস্টলিং ব্যবহারকারীর আর পাওয়া না যায়?

এই স্ক্রিপ্টটি কয়েকটি ক্লিকে সমস্যা সংশোধন করে!

দ্রষ্টব্য: আপনার একটি 'ইনস্ট্যান্স নেম' (সম্ভবত 'এমএসএসকিউএসএলভার হতে চলেছে - তবে এটি নাও হতে পারে) দিয়ে বিএটি ফাইল সরবরাহ করতে হবে: "মাইক্রোসফ্ট এসকিউএল সার্ভার ম্যানেজমেন্ট কনসোল-এ নিম্নলিখিতটি চালিয়ে আপনি প্রথমে মানটি পেতে পারেন ":

 SELECT @@servicename

তারপরে বিএটি ফাইলটি 'এসকিউএল উদাহরণের নাম' দেওয়ার জন্য অনুরোধ জানালে ফলাফলটি অনুলিপি করুন।

  @echo off 
    rem 
    rem **************************************************************************** 
    rem 
    rem    Copyright (c) Microsoft Corporation. All rights reserved. 
    rem    This code is licensed under the Microsoft Public License. 
    rem    THIS CODE IS PROVIDED *AS IS* WITHOUT WARRANTY OF 
    rem    ANY KIND, EITHER EXPRESS OR IMPLIED, INCLUDING ANY 
    rem    IMPLIED WARRANTIES OF FITNESS FOR A PARTICULAR 
    rem    PURPOSE, MERCHANTABILITY, OR NON-INFRINGEMENT. 
    rem 
    rem **************************************************************************** 
    rem 
    rem CMD script to add a user to the SQL Server sysadmin role 
    rem 
    rem Input:  %1 specifies the instance name to be modified. Defaults to SQLEXPRESS. 
    rem         %2 specifies the principal identity to be added (in the form "<domain>\<user>"). 
    rem            If omitted, the script will request elevation and add the current user (pre-elevation) to the sysadmin role. 
    rem            If provided explicitly, the script is assumed to be running elevated already. 
    rem 
    rem Method: 1) restart the SQL service with the '-m' option, which allows a single connection from a box admin 
    rem            (the box admin is temporarily added to the sysadmin role with this start option) 
    rem         2) connect to the SQL instance and add the user to the sysadmin role 
    rem         3) restart the SQL service for normal connections 
    rem 
    rem Output: Messages indicating success/failure. 
    rem         Note that if elevation is done by this script, a new command process window is created: the output of this 
    rem         window is not directly accessible to the caller. 
    rem 
    rem 
    setlocal 
    set sqlresult=N/A 
    if .%1 == . (set /P sqlinstance=Enter SQL instance name, or default to SQLEXPRESS: ) else (set sqlinstance=%1) 
    if .%sqlinstance% == . (set sqlinstance=SQLEXPRESS) 
    if /I %sqlinstance% == MSSQLSERVER (set sqlservice=MSSQLSERVER) else (set sqlservice=MSSQL$%sqlinstance%) 
    if .%2 == . (set sqllogin="%USERDOMAIN%\%USERNAME%") else (set sqllogin=%2) 
    rem remove enclosing quotes 
    for %%i in (%sqllogin%) do set sqllogin=%%~i 
    @echo Adding '%sqllogin%' to the 'sysadmin' role on SQL Server instance '%sqlinstance%'. 
    @echo Verify the '%sqlservice%' service exists ... 
    set srvstate=0 
    for /F "usebackq tokens=1,3" %%i in (`sc query %sqlservice%`) do if .%%i == .STATE set srvstate=%%j 
    if .%srvstate% == .0 goto existerror 
    rem 
    rem elevate if <domain/user> was defaulted 
    rem 
    if NOT .%2 == . goto continue 
    echo new ActiveXObject("Shell.Application").ShellExecute("cmd.exe", "/D /Q /C pushd \""+WScript.Arguments(0)+"\" & \""+WScript.Arguments(1)+"\" %sqlinstance% \""+WScript.Arguments(2)+"\"", "", "runas"); >"%TEMP%\addsysadmin{7FC2CAE2-2E9E-47a0-ADE5-C43582022EA8}.js" 
    call "%TEMP%\addsysadmin{7FC2CAE2-2E9E-47a0-ADE5-C43582022EA8}.js" "%cd%" %0 "%sqllogin%" 
    del "%TEMP%\addsysadmin{7FC2CAE2-2E9E-47a0-ADE5-C43582022EA8}.js" 
    goto :EOF 
    :continue 
    rem 
    rem determine if the SQL service is running 
    rem 
    set srvstarted=0 
    set srvstate=0 
    for /F "usebackq tokens=1,3" %%i in (`sc query %sqlservice%`) do if .%%i == .STATE set srvstate=%%j 
    if .%srvstate% == .0 goto queryerror 
    rem 
    rem if required, stop the SQL service 
    rem 
    if .%srvstate% == .1 goto startm 
    set srvstarted=1 
    @echo Stop the '%sqlservice%' service ... 
    net stop %sqlservice% 
    if errorlevel 1 goto stoperror 
    :startm 
    rem 
    rem start the SQL service with the '-m' option (single admin connection) and wait until its STATE is '4' (STARTED) 
    rem also use trace flags as follows: 
    rem     3659 - log all errors to errorlog 
    rem     4010 - enable shared memory only (lpc:) 
    rem     4022 - do not start autoprocs 
    rem 
    @echo Start the '%sqlservice%' service in maintenance mode ... 
    sc start %sqlservice% -m -T3659 -T4010 -T4022 >nul 
    if errorlevel 1 goto startmerror 
    :checkstate1 
    set srvstate=0 
    for /F "usebackq tokens=1,3" %%i in (`sc query %sqlservice%`) do if .%%i == .STATE set srvstate=%%j 
    if .%srvstate% == .0 goto queryerror 
    if .%srvstate% == .1 goto startmerror 
    if NOT .%srvstate% == .4 goto checkstate1 
    rem 
    rem add the specified user to the sysadmin role 
    rem access tempdb to avoid a misleading shutdown error 
    rem 
    @echo Add '%sqllogin%' to the 'sysadmin' role ... 
    for /F "usebackq tokens=1,3" %%i in (`sqlcmd -S np:\\.\pipe\SQLLocal\%sqlinstance% -E -Q "create table #foo (bar int); declare @rc int; execute @rc = sp_addsrvrolemember '$(sqllogin)', 'sysadmin'; print 'RETURN_CODE : '+CAST(@rc as char)"`) do if .%%i == .RETURN_CODE set sqlresult=%%j 
    rem 
    rem stop the SQL service 
    rem 
    @echo Stop the '%sqlservice%' service ... 
    net stop %sqlservice% 
    if errorlevel 1 goto stoperror 
    if .%srvstarted% == .0 goto exit 
    rem 
    rem start the SQL service for normal connections 
    rem 
    net start %sqlservice% 
    if errorlevel 1 goto starterror 
    goto exit 
    rem 
    rem handle unexpected errors 
    rem 
    :existerror 
    sc query %sqlservice% 
    @echo '%sqlservice%' service is invalid 
    goto exit 
    :queryerror 
    @echo 'sc query %sqlservice%' failed 
    goto exit 
    :stoperror 
    @echo 'net stop %sqlservice%' failed 
    goto exit 
    :startmerror 
    @echo 'sc start %sqlservice% -m' failed 
    goto exit 
    :starterror 
    @echo 'net start %sqlservice%' failed 
    goto exit 
    :exit 
    if .%sqlresult% == .0 (@echo '%sqllogin%' was successfully added to the 'sysadmin' role.) else (@echo '%sqllogin%' was NOT added to the 'sysadmin' role: SQL return code is %sqlresult%.) 
    endlocal 
    pause

Question 6

মাইক্রোসফ্ট এই সমস্যা সম্পর্কে একটি নিবন্ধ আছে। এটি প্রতিটি ধাপে ধাপে এটি দিয়ে যায়।

https://docs.microsoft.com/en-us/sql/datedia-engine/configure-windows/connect-to-sql-server-wn- সিস্টেম-অ্যাডমিনিস্ট্রেটর-are- লকড- আউট

সংক্ষেপে এটি -mঅন্যান্য সমস্ত উত্তরগুলির মতোই স্ক্যালসার্ভারের উদাহরণটি শুরু করে । তবে মাইক্রোসফ্ট আরও কিছু বিস্তারিত নির্দেশাবলী সরবরাহ করে।

প্রারম্ভিক পৃষ্ঠা থেকে, এসকিউএল সার্ভার ম্যানেজমেন্ট স্টুডিও শুরু করুন। ভিউ মেনুতে, নিবন্ধিত সার্ভারগুলি নির্বাচন করুন। (যদি আপনার সার্ভারটি ইতিমধ্যে নিবন্ধভুক্ত না থাকে, স্থানীয় সার্ভার গ্রুপগুলিতে ডান ক্লিক করুন, কার্যগুলিতে নির্দেশ করুন এবং তারপরে স্থানীয় সার্ভারগুলি নিবন্ধিত করুন ক্লিক করুন)

নিবন্ধিত সার্ভার অঞ্চলগুলিতে, আপনার সার্ভারকে ডান ক্লিক করুন এবং তারপরে এসকিউএল সার্ভার কনফিগারেশন পরিচালককে ক্লিক করুন। এটি প্রশাসক হিসাবে চালনার অনুমতি চাইতে হবে এবং তারপরে কনফিগারেশন ম্যানেজার প্রোগ্রামটি খুলতে হবে।

ম্যানেজমেন্ট স্টুডিও বন্ধ করুন

এসকিউএল সার্ভার কনফিগারেশন পরিচালক, বাম ফলকে, এসকিউএল সার্ভার পরিষেবাদি নির্বাচন করুন select ডান-প্যানেলে আপনার এসকিউএল সার্ভারের উদাহরণটি সন্ধান করুন। (এসকিউএল সার্ভারের ডিফল্ট উদাহরণটিতে কম্পিউটার নামের পরে (এমএসএসকিউএলএসভার) অন্তর্ভুক্ত রয়েছে Name নামকরণের উদাহরণগুলি নিবন্ধিত সার্ভারে থাকা একই নামের সাথে উপরের ক্ষেত্রে উপস্থিত হয়)) এসকিউএল সার্ভারের উদাহরণটি ডান ক্লিক করুন, এবং তারপরে বৈশিষ্ট্যগুলি ক্লিক করুন।

স্টার্টআপ প্যারামিটার ট্যাবে, একটি প্রারম্ভিক পরামিতি বাক্স নির্দিষ্ট করুন, -ম টাইপ করুন এবং তারপরে অ্যাড ক্লিক করুন। (এটি একটি ড্যাশ তারপর ছোট ছোট অক্ষর মি।)

বিঃদ্রঃ

এসকিউএল সার্ভারের পূর্ববর্তী কয়েকটি সংস্করণের জন্য কোনও প্রারম্ভিক পরামিতি ট্যাব নেই। সেক্ষেত্রে উন্নত ট্যাবে স্টার্টআপ পরামিতিগুলিতে ডাবল ক্লিক করুন। প্যারামিটারগুলি খুব ছোট উইন্ডোতে খোলে। বিদ্যমান প্যারামিটারগুলির কোনও পরিবর্তন না করার বিষয়ে সতর্কতা অবলম্বন করুন। একেবারে শেষে, একটি নতুন পরামিতি যুক্ত করুন; -ম এবং তারপরে ওকে ক্লিক করুন। (এটি একটি আধা-কোলন তারপর ড্যাশ তারপর লোয়ার কেস লেটার মি।)

ওকে ক্লিক করুন, এবং বার্তাটি পুনঃসূচনা করার পরে, আপনার সার্ভারের নামটিতে ডান ক্লিক করুন এবং তারপরে পুনঃসূচনা ক্লিক করুন।

এসকিউএল সার্ভার পুনরায় চালু করার পরে আপনার সার্ভারটি একক ব্যবহারকারী মোডে থাকবে। নিশ্চিত করুন যে এসকিউএল সার্ভার এজেন্ট চলছে না। যদি শুরু হয় তবে এটি আপনার একমাত্র সংযোগ গ্রহণ করবে।

উইন্ডোজ 8 প্রারম্ভের স্ক্রিনে, ম্যানেজমেন্ট স্টুডিওর আইকনটিতে ডান ক্লিক করুন। স্ক্রিনের নীচে, প্রশাসক হিসাবে চালান নির্বাচন করুন। (এটি আপনার প্রশাসকের শংসাপত্রগুলি এসএসএমএসের কাছে প্রেরণ করবে)

বিঃদ্রঃ

উইন্ডোজের পূর্ববর্তী সংস্করণগুলির জন্য প্রশাসক হিসাবে চালান বিকল্পটি একটি সাব-মেনু হিসাবে উপস্থিত হবে।

কিছু কনফিগারেশনে, এসএসএমএস বেশ কয়েকটি সংযোগ করার চেষ্টা করবে। একাধিক সংযোগ ব্যর্থ হবে কারণ এসকিউএল সার্ভার একক-ব্যবহারকারী মোডে রয়েছে। সম্পাদন করতে আপনি নীচের একটি ক্রিয়া নির্বাচন করতে পারেন। এখান থেকে যে কোন একটি করুন.

ক) উইন্ডোজ প্রমাণীকরণ (যা আপনার প্রশাসকের শংসাপত্রগুলি অন্তর্ভুক্ত) ব্যবহার করে অবজেক্ট এক্সপ্লোরারের সাথে সংযুক্ত হন। সুরক্ষা প্রসারিত করুন, লগইনগুলি প্রসারিত করুন এবং আপনার নিজস্ব লগইনে ডাবল ক্লিক করুন। সার্ভার রোলস পৃষ্ঠায়, সিসাদমিন নির্বাচন করুন এবং তারপরে ওকে ক্লিক করুন।

খ) অবজেক্ট এক্সপ্লোরারের সাথে সংযোগ স্থাপনের পরিবর্তে উইন্ডোজ প্রমাণীকরণ (যাতে আপনার প্রশাসকের শংসাপত্রগুলি অন্তর্ভুক্ত) ব্যবহার করে একটি অনুসন্ধান উইন্ডোর সাথে সংযুক্ত করুন। (আপনি যদি কেবল অবজেক্ট এক্সপ্লোরারের সাথে সংযুক্ত না হন তবে আপনি কেবল এইভাবেই সংযোগ স্থাপন করতে পারেন)) নতুন উইন্ডোজ প্রমাণীকরণ লগইন যুক্ত করতে নিম্নলিখিত কোডগুলি কার্যকর করুন যা সিসাদমিন স্থির সার্ভার রোলের সদস্য। নিম্নলিখিত উদাহরণটি CONTOSO \ PatK নামে একটি ডোমেন ব্যবহারকারী যুক্ত করেছে।
CREATE LOGIN [CONTOSO\PatK] FROM WINDOWS;   ALTER SERVER ROLE
sysadmin ADD MEMBER [CONTOSO\PatK];   
গ) যদি আপনার এসকিউএল সার্ভার মিশ্রিত প্রমাণীকরণ মোডে চলমান থাকে তবে উইন্ডোজ প্রমাণীকরণ (যাতে আপনার প্রশাসকের শংসাপত্রগুলি অন্তর্ভুক্ত) ব্যবহার করে একটি অনুসন্ধান উইন্ডোটির সাথে সংযুক্ত হন। একটি নতুন এসকিউএল সার্ভার প্রমাণীকরণ লগইন তৈরি করতে নিম্নলিখিত কোডগুলি কার্যকর করুন যা সিসাদমিন স্থির সার্ভার রোলের সদস্য।
CREATE LOGIN TempLogin WITH PASSWORD = '************';   ALTER
SERVER ROLE sysadmin ADD MEMBER TempLogin;   
সতর্কতা:

শক্তিশালী পাসওয়ার্ড দিয়ে ************ প্রতিস্থাপন করুন।

d) যদি আপনার এসকিউএল সার্ভারটি মিশ্র প্রমাণীকরণ মোডে চলমান থাকে এবং আপনি সা অ্যাকাউন্টের পাসওয়ার্ডটি পুনরায় সেট করতে চান তবে উইন্ডোজ প্রমাণীকরণ (যাতে আপনার প্রশাসকের শংসাপত্রগুলি অন্তর্ভুক্ত) ব্যবহার করে একটি উইন্ডোটির সাথে সংযোগ করুন। নিম্নলিখিত সিনট্যাক্স সহ সা অ্যাকাউন্টের পাসওয়ার্ড পরিবর্তন করুন।
ALTER LOGIN sa WITH PASSWORD = '************';   Warning
শক্তিশালী পাসওয়ার্ড দিয়ে ************ প্রতিস্থাপন করুন।

নিম্নলিখিত পদক্ষেপগুলি এখন এসকিউএল সার্ভারকে মাল্টি-ব্যবহারকারী মোডে ফিরিয়ে দেয়। এসএসএমএস বন্ধ

এসকিউএল সার্ভার কনফিগারেশন পরিচালক, বাম ফলকে, এসকিউএল সার্ভার পরিষেবাদি নির্বাচন করুন। ডান-ফলকে, এসকিউএল সার্ভারের উদাহরণটি ডান ক্লিক করুন এবং তারপরে বৈশিষ্ট্যগুলি ক্লিক করুন।

স্টার্টআপ পরামিতি ট্যাবে, বিদ্যমান পরামিতি বাক্সে, -m নির্বাচন করুন এবং তারপরে সরান ক্লিক করুন।

বিঃদ্রঃ

এসকিউএল সার্ভারের পূর্ববর্তী কয়েকটি সংস্করণের জন্য কোনও প্রারম্ভিক পরামিতি ট্যাব নেই। সেক্ষেত্রে উন্নত ট্যাবে স্টার্টআপ পরামিতিগুলিতে ডাবল ক্লিক করুন। প্যারামিটারগুলি খুব ছোট উইন্ডোতে খোলে। আপনি আগে যোগ করেছেন; -m মুছে ফেলুন এবং তারপরে ওকে ক্লিক করুন।

আপনার সার্ভারের নামটিতে ডান ক্লিক করুন এবং তারপরে পুনরায় চালু করুন ক্লিক করুন।

এখন আপনার একাউন্টের সাথে সাধারণত সংযোগ করতে সক্ষম হওয়া উচিত যা এখন সিসাদমিন ফিক্সড সার্ভার রোলের সদস্য।

Question 7

এটি আসলে এসকিএল সার্ভার কনফিগারেশন ম্যানেজারে স্টার্টআপ প্যারামিটারগুলিতে এম-যোগ করার জন্য যথেষ্ট, পরিষেবাটি পুনরায় চালু করুন, আপনার অ্যাকাউন্টে এসএমএসে একটি অ্যাড চেকবক্স সিসাদমিন যান, তারপরে পুনরায় আরম্ভ করুন এবং যথারীতি ব্যবহার করুন।

ডাটাবেস ইঞ্জিন পরিষেবা শুরুর বিকল্প

-m একক ব্যবহারকারী মোডে এসকিউএল সার্ভারের একটি উদাহরণ শুরু করে।