কমান্ড-লাইন থেকে উইন্ডোজ আপডেটগুলি ইনস্টল করা সম্ভব? গ্রাফিকাল আপডেট সরঞ্জামটি উইন্ডোজ in-তে খুব ভাল কাজ করে না বলে মনে হয় না Sometimes সুতরাং যখন এমন কোনও আপডেট থাকে যেগুলি ডিফল্টরূপে চেক না করা হয়, তখন আমি সেগুলি ইনস্টল করতে পারি না ...
সুতরাং, আমি ইনস্টল করার জন্য অন্য কোনও উপায় আছে কি?
উত্তর:
উইন্ডোজ 7 সম্পর্কে নিশ্চিত নন, তবে এক্সপি / ভিস্তার সাহায্যে আপডেটগুলি সনাক্ত করতে এবং ডাউনলোড করতে নিম্নলিখিত কমান্ডটি চালাতে পারেন:
wuauclt /detectnow /reportnow
আপনার যদি এটি কাজ করতে সমস্যা হয় তবে ডাব্লুএসইউএস উইকিটি দেখুন ।
অন্যথায় আপনার যদি চান একটি নির্দিষ্ট আপডেট থাকে তবে কেবল মাইক্রোসফ্ট ওয়েবসাইট থেকে ডাউনলোড করুন। যদি আপনাকে ইনস্টল করতে বাধা দিতে সমস্যা হয় তবে এটি সর্বাধিক সহজ উপায়, কারণ উইন্ডোজ আপডেট লগগুলি মোকাবেলা করার জন্য godশ্বরভক্ত।
আপডেটগুলি চেক করতে, ডাউনলোড করতে ও সিঙ্ক্রোনালি ইনস্টল করতে আপনি কোনও স্ক্রিপ্ট ব্যবহার করতে পারেন। আমি প্রায়শই উইন্ডোজ কোর সার্ভারগুলির ম্যানুয়াল প্যাচিংয়ের জন্য এই vbscript এর একটি পরিবর্তিত সংস্করণ ব্যবহার করি ।
Set updateSession = CreateObject("Microsoft.Update.Session")
updateSession.ClientApplicationID = "MSDN Sample Script"
Set updateSearcher = updateSession.CreateUpdateSearcher()
WScript.Echo "Searching for updates..." & vbCRLF
Set searchResult = _
updateSearcher.Search("IsInstalled=0 and Type='Software' and IsHidden=0")
WScript.Echo "List of applicable items on the machine:"
For I = 0 To searchResult.Updates.Count-1
Set update = searchResult.Updates.Item(I)
WScript.Echo I + 1 & "> " & update.Title
Next
If searchResult.Updates.Count = 0 Then
WScript.Echo "There are no applicable updates."
WScript.Quit
End If
WScript.Echo vbCRLF & "Creating collection of updates to download:"
Set updatesToDownload = CreateObject("Microsoft.Update.UpdateColl")
For I = 0 to searchResult.Updates.Count-1
Set update = searchResult.Updates.Item(I)
addThisUpdate = false
If update.InstallationBehavior.CanRequestUserInput = true Then
WScript.Echo I + 1 & "> skipping: " & update.Title & _
" because it requires user input"
Else
If update.EulaAccepted = false Then
WScript.Echo I + 1 & "> note: " & update.Title & _
" has a license agreement that must be accepted:"
WScript.Echo update.EulaText
WScript.Echo "Do you accept this license agreement? (Y/N)"
strInput = WScript.StdIn.Readline
WScript.Echo
If (strInput = "Y" or strInput = "y") Then
update.AcceptEula()
addThisUpdate = true
Else
WScript.Echo I + 1 & "> skipping: " & update.Title & _
" because the license agreement was declined"
End If
Else
addThisUpdate = true
End If
End If
If addThisUpdate = true Then
WScript.Echo I + 1 & "> adding: " & update.Title
updatesToDownload.Add(update)
End If
Next
If updatesToDownload.Count = 0 Then
WScript.Echo "All applicable updates were skipped."
WScript.Quit
End If
WScript.Echo vbCRLF & "Downloading updates..."
Set downloader = updateSession.CreateUpdateDownloader()
downloader.Updates = updatesToDownload
downloader.Download()
Set updatesToInstall = CreateObject("Microsoft.Update.UpdateColl")
rebootMayBeRequired = false
WScript.Echo vbCRLF & "Successfully downloaded updates:"
For I = 0 To searchResult.Updates.Count-1
set update = searchResult.Updates.Item(I)
If update.IsDownloaded = true Then
WScript.Echo I + 1 & "> " & update.Title
updatesToInstall.Add(update)
If update.InstallationBehavior.RebootBehavior > 0 Then
rebootMayBeRequired = true
End If
End If
Next
If updatesToInstall.Count = 0 Then
WScript.Echo "No updates were successfully downloaded."
WScript.Quit
End If
If rebootMayBeRequired = true Then
WScript.Echo vbCRLF & "These updates may require a reboot."
End If
WScript.Echo vbCRLF & "Would you like to install updates now? (Y/N)"
strInput = WScript.StdIn.Readline
WScript.Echo
If (strInput = "Y" or strInput = "y") Then
WScript.Echo "Installing updates..."
Set installer = updateSession.CreateUpdateInstaller()
installer.Updates = updatesToInstall
Set installationResult = installer.Install()
'Output results of install
WScript.Echo "Installation Result: " & _
installationResult.ResultCode
WScript.Echo "Reboot Required: " & _
installationResult.RebootRequired & vbCRLF
WScript.Echo "Listing of updates installed " & _
"and individual installation results:"
For I = 0 to updatesToInstall.Count - 1
WScript.Echo I + 1 & "> " & _
updatesToInstall.Item(i).Title & _
": " & installationResult.GetUpdateResult(i).ResultCode
Next
End If
এটি এর জন্য কবজির মতো কাজ করে বলে মনে হচ্ছে তবে আমি এটি অবশ্যই উইন্ডোজ 7 এর অধীনে পরীক্ষা করে দেখিনি। প্রয়োজনে একটি নির্দিষ্ট আপডেটকে টার্গেট করার জন্য অন্য একটি নিবন্ধের লিঙ্কও রয়েছে।
এর রয়েছে একটি PowerShell মডিউল করে একটি অনুরূপ অভিজ্ঞতা অনাবৃত।
তাত্ক্ষণিকভাবে দেখার পরে আমি এই তৃতীয় পক্ষের অ্যাপ্লিকেশনটিও পেয়েছি যা আপডেট এপিআইও ব্যবহার করে, তবে আরও কয়েকটি বিকল্পের সাথে (যদিও আপনাকে তৃতীয় পক্ষের কোডকে বিশ্বাস করা প্রয়োজন)।
কমান্ড লাইন থেকে উইন্ডোজ আপডেট:
www.sysadminsoftware.com/udc.html
সরঞ্জামটি (আপডেটগুলি ডিপোমেন্ট কমান্ডার) আপনি যা চাইছেন ঠিক তাই করতে পারে। আপনি নির্দিষ্ট প্যাচগুলি এড়াতে, নির্দিষ্ট আপডেটগুলি লক্ষ্যবস্তু করা, সমাপ্তির পরে N মিনিট পুনরায় বুট করা, সিএসভিতে প্রতিবেদন তৈরি করতে এবং আরও কিছু করতে প্যারামিটারগুলিও পাস করতে পারেন .. এটি বেশ কয়েকটি GUI ইউটিলিটি সহ আসে।
আপনি Windows অপারেটিং সিস্টেম প্যাচ থাকে, তাহলে especailly তাজা ইনস্টলসমূহ পর একটি গুরুতর কটাক্ষপাত অফলাইন আপডেটার ।
আপনার প্রস্তাবিত সমস্ত প্যাচগুলি ডাউনলোড করার জন্য এটি স্ক্রিপ্ট ব্যবহার করে (সুতরাং উইন 2000, উইন এক্সপি, উইন 2003, ভিস্তা, উইন 2003, 32 এবং 64 বিট যেখানে উপযুক্ত), বহু ভাষা, পরিষেবা প্যাকগুলি, নেট ফ্রেমওয়ার্ক এবং অফিস প্যাচগুলি (এক্সপি, 2000) , 2003, 2007)।
আপনি একবারে সেগুলি ডাউনলোড হয়ে গেলে, আপনি কেবলমাত্র প্রতিটি প্যাচ মঙ্গলবার আপডেট করেন এবং কেবলমাত্র পরিবর্তনগুলি পান। যদিও এটি অনুঘটক পেয়েছে এবং এগুলি প্রতিদিন বেশি সময় পাচ্ছে (বর্তমানে ওএস / অফিসে অনেকগুলি ম্যাগ)।
আপনার স্থানীয় মেশিনে ফাইলগুলি ডাউনলোড হয়ে গেলে সেগুলির সিডি / ডিভিডি চিত্রগুলি তৈরি করার জন্য একটি স্ক্রিপ্ট রয়েছে (এটি যদি আপনি চান তবে এখন প্রতি ওএস প্রতি ডিভিডি চিত্রের জন্য স্বয়ংক্রিয়ভাবে এটি ঘটবে)।
আমি যা করি তা হ'ল একটি 4 গিগাবাইট এসডি মেমরি কার্ড ব্যবহার করে, কোনও এসডি কার্ড পাঠক যা লেখার সুরক্ষার ট্যাবটিকে সম্মান করে। আমি 2 জিবি কার্ড ব্যবহার করতাম, তবে আমি সবেমাত্র উইন এক্সপি ফিট করতে পারি এবং অফিসের বেশিরভাগ অংশ এখন এটি তৈরি করে, তাই আমি 4 জিবি কার্ডে চলে গেলাম।
এইভাবে কোনও মেশিনের সমস্যা সমাধানের সময়, আমি এই পূর্বে লিখনযোগ্য ডিভাইসটি একটি অবিশ্বস্ত, সম্ভবত ভাইরাস সংক্রামিত মেশিনে trustোকাতে বিশ্বাস করি (যেহেতু আমি এটি সম্পর্কে কিছুই জানি না, তাই আমি এটি সংক্রামিত বলে ধরে নিই) আমার ডিভাইসটি রক্ষিত তা জেনেও।
সুতরাং আমি প্রথম পদক্ষেপ হিসাবে এটি আপ টু ডেট করতে পারেন।
আপনি যদি অটোরান ব্যবহার করেন, বা ডিভাইসে এক্সিকিউটেবল চালু করেন (কী, বাহ্যিক এইচডি, সিডি, ডিভিডি, আপনি যেখানেই লিখেছেন) এটি একটি স্ক্রিপ্ট শুরু করে যা সমস্ত আপডেট প্রয়োগ করতে স্থানীয় মেশিনে উইন্ডোজ আপডেট পরিষেবা ব্যবহার করে, তবে পরিবর্তে সেগুলি ডাউনলোড করার জন্য তারের পার হয়ে যাওয়ার জন্য এটি কেবল স্থানীয় অনুলিপি ব্যবহার করে।
এইভাবে উইনএক্সপি মেশিনটিকে সর্বশেষতম এসপি এবং প্যাচগুলিতে আপডেট করতে এখনও 1+ ঘন্টা সময় লাগতে পারে, তবে সেই পথটিতে শূন্য নেটওয়ার্ক ট্র্যাফিক রয়েছে এবং আপনি ইথারনেট কেবলটি সম্পূর্ণরূপে আনপ্লাগ করে এটি করতে পারেন।
আশ্চর্যজনকভাবে দরকারী সরঞ্জাম!
মাইক্রোসফ্টের পুরোপুরি চালানো উচিত নয়, যেমন অটোআপেটের ছেলেরা ছিল, যারা প্যাচ সিডি তৈরির আগে, সিডি চিত্র বিতরণ করেছিল। এই সরঞ্জামটি স্ক্রিপ্টগুলি আপডেট করে এবং আপনাকে আপনার লাইসেন্সযুক্ত উইন্ডোজ ওয়ার্কস্টেশনে সমস্ত প্যাচ পেতে হবে।
আমি বর্তমানে duffbeer703 দ্বারা উত্তরে একটি মন্তব্য যুক্ত করতে পারি না , তাই এখানে আলাদা উত্তর হিসাবে:
ইন্টারনেট সংরক্ষণাগারে সংরক্ষণাগার হিসাবে ডাব্লুএসইউসউইকি লিঙ্কের শেষ "ভাল" সংস্করণটি এটি । মূল উত্তরে প্রদত্ত বিকল্পগুলি এই FAQ এন্ট্রিটিতে বর্ণিত হয়েছে ।
আমি এটি বিশ্বাস করি না, উইন্ডোজ আপডেটের সঠিকভাবে কাজ করতে ইন্টারনেট এক্সপ্লোরারের সাথে কিছু অ্যাক্টিভ এক্স এবং অন্যান্য সংহতকরণ প্রয়োজন।
যেহেতু উইন্ডোজ 7 এখনও সবেমাত্র একটি মুক্তির প্রার্থী, আপনার এই ধরণের বাগগুলি আশা করা উচিত।
আপনি যদি এমএসডিএন এর সদস্য হন তবে আপনার নির্দিষ্ট ডিফল্ট বাগটি টিমে জমা দেওয়ার বিষয়ে বুদ্ধিমানের কাজ হতে পারে।