সুতরাং… আমি একটি সামান্য ভিবিএস স্ক্রিপ্ট নিয়ে কাজ করছি যা করতে পারে:
- অবিরাম ভিএসএস স্ন্যাপশট নিন
- এগুলি একটি ফোল্ডারে মাউন্ট করুন (যেখান থেকে আপনি ফাইলগুলি ব্যাকআপ করতে পারেন)
- ভিএসএস স্ন্যাপশটগুলি আনমাউন্ট করুন
এটি মাইক্রোসফ্ট থেকে উপলব্ধ হিসাবে ভলিউম শ্যাডো কপি সার্ভিস এসডিকে .2.২ অংশ vshadow.exe( ডকুমেন্টেশন ) এর উপর নির্ভর করে । আমি এই সংস্করণটির সাথে কাজ করছি: " ভিএসএডএড.ও.এক্স.ই. ২.২ - ভলিউম শেডো কপির নমুনা ক্লায়েন্ট, কপিরাইট (সি) 2005 মাইক্রোসফ্ট কর্পোরেশন। "
মূলত, এই চারটি ভ্যাশডো কমান্ডের চারপাশে এটি একটি ঝরঝরে ছোট্ট মোড়ক:
vshadow.exe -q - সিস্টেমে সমস্ত ছায়া অনুলিপি তালিকাবদ্ধ করুন
vshadow.exe -p {ভলিউম তালিকা} - অবিচ্ছিন্ন ছায়া অনুলিপি পরিচালনা করে
vshadow.exe -el = {SnapID}, dir - ছায়ার অনুলিপিটিকে মাউন্ট পয়েন্ট হিসাবে প্রকাশ করুন
vshadow.exe -ds = {SnapID} - এই ছায়া অনুলিপি মুছে ফেলে
এখানে তার সহায়তা পর্দা:
ভিএসএস স্ন্যাপশট তৈরি / মাউন্ট সরঞ্জাম
ব্যবহার:
cscript / nologo VssSnapshot.vbs / লক্ষ্য: পথ {/ আয়তন: এক্স | / আনমাউন্ট} [/ ডিবাগ]
/ ভলিউম - স্ন্যাপশটে ভলিউমের ড্রাইভ লেটার
/ টার্গেট - স্ন্যাপশটটি মাউন্ট করার পাথ (পরম বা আপেক্ষিক)
/ ডিবাগ - ডিবাগ আউটপুট উপর সুইচ
উদাহরণ:
cscript / nologo VssSnapshot.vbs / টার্গেট: সি: \ ব্যাকআপ \ ড্রাইভডি / ভলিউম: ডি
cscript / nologo VssSnapshot.vbs / লক্ষ্য: সি: \ ব্যাকআপ \ ড্রাইভডি / আনমাউন্ট
ইঙ্গিত: নতুন স্ন্যাপশট নেওয়ার আগে আনমাউন্ট করার দরকার নেই।
এখানে কিছু নমুনা আউটপুট:
সি: \ ভেসস্ন্যাপশট> সিএসক্রিপ্ট / নোলোগো ভেসস্পট্যাপট.ভিবিএস / লক্ষ্য: মাউন্টপয়েন্টস \ ই / ভলিউম: ই
05/03/2010 17:13:04 ভিএসএস মাউন্ট পয়েন্ট প্রস্তুত ...
05/03/2010 17:13:04 মাউন্ট পয়েন্ট এখানে প্রস্তুত: সি: \ ভেসস্পটনা \ মাউন্টপয়েন্টস \ ই
05/03/2010 17:13:04 ভলিউমের জন্য ভিএসএস স্ন্যাপশট তৈরি করা: ই
05/03/2010 17:13:08 আইডি সহ স্ন্যাপশট তৈরি করা হয়েছে: ed 4ed3a907-c66f-4b20-bda0-9dcda3b667ec}
05/03/2010 17:13:08 ভিএসএস স্ন্যাপশটটি সফলভাবে মাউন্ট করা হয়েছে
05/03/2010 17:13:08 শেষ হয়েছে
সি: \ ভেসস্ন্যাপশট> সিএসক্রিপ্ট / নোলোগো ভেসস্পট্যাপট.ভিবিএস / লক্ষ্য: মাউন্টপয়েন্টস \ ই / আনমাউন্ট
05/03/2010 17:13:35 ভিএসএস মাউন্ট পয়েন্ট প্রস্তুত ...
05/03/2010 17:13:36 আর কিছুই করার নেই
05/03/2010 17:13:36 শেষ হয়েছে
এবং এখানে লিপি নিজেই। সাধারণ অস্বীকৃতি প্রযোজ্য: সফ্টওয়্যারটি যেমনটি সরবরাহ করা হয়, তেমন কোনও ওয়্যারেন্টি দিচ্ছি না, নিজের ঝুঁকিতে ব্যবহার করি, যদি কোনও কিছু দোষ দেওয়ার জন্য কেবলমাত্র ব্রেক করে তবে তা নিজেই। আমি এটি পুরোপুরি পরীক্ষা করেছি, যদিও এটি আমার পক্ষে ভাল কাজ করে। নীচের মন্তব্যগুলির মাধ্যমে আমাকে কোনও বাগ সম্পর্কে অবহিত করুন।
''# VssSnapshot.vbs
''# http://serverfault.com/questions/119120/how-to-use-a-volume-shadow-copy-to-make-backups/119592#119592
Option Explicit
Dim fso: Set fso = CreateObject("Scripting.FileSystemObject")
''# -- MAIN SCRIPT -------------------------------------------
Dim args, snapshotId, targetPath, success
Set args = WScript.Arguments.Named
CheckEnvironment
Log "preparing VSS mount point..."
targetPath = PrepareVssMountPoint(args("target"))
If args.Exists("unmount") Then
Log "nothing else to do"
ElseIf targetPath <> vbEmpty Then
Log "mount point prepared at: " & targetPath
Log "creating VSS snapshot for volume: " & args("volume")
snapshotId = CreateVssSnapshot(args("volume"))
If snapshotId <> vbEmpty Then
Log "snapshot created with ID: " & snapshotId
success = MountVssSnapshot(snapshotId, targetPath)
If success Then
Log "VSS snapshot mounted sucessfully"
Else
Die "failed to mount snapshot"
End If
Else
Die "failed to create snapshot"
End If
Else
Die "failed to prepare mount point"
End If
Log "finished"
''# -- FUNCTIONS ---------------------------------------------
Function PrepareVssMountPoint(target) ''# As String
Dim cmd, result, outArray
Dim path, snapshot, snapshotId
Dim re, matches, match
PrepareVssMountPoint = VbEmpty
target = fso.GetAbsolutePathName(target)
If Not fso.FolderExists(fso.GetParentFolderName(target)) Then
Die "Invalid mount point: " & target
End If
''# create or unmount (=delete existing snapshot) mountpoint
If Not fso.FolderExists(target) Then
If Not args.Exists("unmount") Then fso.CreateFolder target
Else
Set re = New RegExp
re.MultiLine = False
re.Pattern = "- Exposed locally as: ([^\r\n]*)"
cmd = "vshadow -q"
result = RunCommand(cmd, false)
outarray = Split(result, "*")
For Each snapshot In outArray
snapshotId = ParseSnapshotId(snapshot)
If snapshotId <> vbEmpty Then
Set matches = re.Execute(snapshot)
If matches.Count = 1 Then
path = Trim(matches(0).SubMatches(0))
If fso.GetAbsolutePathName(path) = target Then
cmd = "vshadow -ds=" & snapshotId
RunCommand cmd, true
Exit For
End If
End If
End If
Next
If args.Exists("unmount") Then fso.DeleteFolder target
End If
PrepareVssMountPoint = target
End Function
Function CreateVssSnapshot(volume) ''# As String
Dim cmd, result
If Not fso.DriveExists(volume) Then
Die "Drive " & volume & " does not exist."
End If
cmd = "vshadow -p " & Replace(UCase(volume), ":", "") & ":"
result = RunCommand(cmd, false)
CreateVssSnapshot = ParseSnapshotId(result)
End Function
Function MountVssSnapshot(snapshotId, target) ''# As Boolean
Dim cmd, result
If fso.FolderExists(targetPath) Then
cmd = "vshadow -el=" & snapshotId & "," & targetPath
result = RunCommand(cmd, true)
Else
Die "Mountpoint does not exist: " & target
End If
MountVssSnapshot = (result = "0")
End Function
Function ParseSnapshotId(output) ''# As String
Dim re, matches, match
Set re = New RegExp
re.Pattern = "SNAPSHOT ID = (\{[^}]{36}\})"
Set matches = re.Execute(output)
If matches.Count = 1 Then
ParseSnapshotId = matches(0).SubMatches(0)
Else
ParseSnapshotId = vbEmpty
End If
End Function
Function RunCommand(cmd, exitCodeOnly) ''# As String
Dim shell, process, output
Dbg "Running: " & cmd
Set shell = CreateObject("WScript.Shell")
On Error Resume Next
Set process = Shell.Exec(cmd)
If Err.Number <> 0 Then
Die Hex(Err.Number) & " - " & Err.Description
End If
On Error GoTo 0
Do While process.Status = 0
WScript.Sleep 100
Loop
output = Process.StdOut.ReadAll
If process.ExitCode = 0 Then
Dbg "OK"
Dbg output
Else
Dbg "Failed with ERRORLEVEL " & process.ExitCode
Dbg output
If Not process.StdErr.AtEndOfStream Then
Dbg process.StdErr.ReadAll
End If
End If
If exitCodeOnly Then
Runcommand = process.ExitCode
Else
RunCommand = output
End If
End Function
Sub CheckEnvironment
Dim argsOk
If LCase(fso.GetFileName(WScript.FullName)) <> "cscript.exe" Then
Say "Please execute me on the command line via cscript.exe!"
Die ""
End If
argsOk = args.Exists("target")
argsOk = argsOk And (args.Exists("volume") Or args.Exists("unmount"))
If Not argsOk Then
Say "VSS Snapshot Create/Mount Tool" & vbNewLine & _
vbNewLine & _
"Usage: " & vbNewLine & _
"cscript /nologo " & fso.GetFileName(WScript.ScriptFullName) & _
" /target:path { /volume:X | /unmount } [/debug]" & _
vbNewLine & vbNewLine & _
"/volume - drive letter of the volume to snapshot" & _
vbNewLine & _
"/target - the path (absolute or relative) to mount the snapshot to" & _
vbNewLine & _
"/debug - swich on debug output" & _
vbNewLine & vbNewLine & _
"Examples: " & vbNewLine & _
"cscript /nologo " & fso.GetFileName(WScript.ScriptFullName) & _
" /target:C:\Backup\DriveD /volume:D" & vbNewLine & _
"cscript /nologo " & fso.GetFileName(WScript.ScriptFullName) & _
" /target:C:\Backup\DriveD /unmount" & _
vbNewLine & vbNewLine & _
"Hint: No need to unmount before taking a new snapshot." & vbNewLine
Die ""
End If
End Sub
Sub Say(message)
If message <> "" Then WScript.Echo message
End Sub
Sub Log(message)
Say FormatDateTime(Now()) & " " & message
End Sub
Sub Dbg(message)
If args.Exists("debug") Then
Say String(75, "-")
Say "DEBUG: " & message
End If
End Sub
Sub Die(message)
If message <> "" Then Say "FATAL ERROR: " & message
WScript.Quit 1
End Sub
আমি এই কারো সাহায্য করে আশা করি। সিসি বাই সা ব্যবহার করে নির্দ্বিধায় এটি ব্যবহার করুন । আমি কেবল আপনাকে জিজ্ঞাসা করি যে আপনি এখানে লিঙ্কটি অক্ষত রেখেছেন back