আইআইএস 7-এ ডিফল্ট ওয়েব সাইটে ভার্চুয়াল ডিরেক্টরি তৈরি করতে অ্যাপসিএমডি

Question

আমি আইআইএস 7 ব্যবহার করে "ডিফল্ট ওয়েব সাইট" এর অধীনে একটি ভার্চুয়াল ডিরেক্টরি তৈরি করার চেষ্টা করি AppCmd।

তবে প্রথমে আমি দেখতে চাই যে ইতিমধ্যে একটি বিদ্যমান কিনা। আমি AppCmd"ডিফল্ট ওয়েব সাইট" এর অধীনে ভার্চুয়াল ডিরেক্টরি তৈরি করতে কীভাবে ব্যবহার করতে পারি এবং আমি কীভাবে একটি বিবৃতি দিতে পারি?

Answer 1

এটা চেষ্টা কর:

@ECHO OFF
REM --------------------------------------------------------------------------------
REM Check for and create VDir under Default Web Site
REM
REM %1 is the VDIR to create
REM %2 is the Physical path to the VDIR 
REM --------------------------------------------------------------------------------

IF "%1"=="" GOTO Syntax
IF "%2"=="" GOTO Syntax

ECHO Running...
ECHO   AppCmd.exe list vdir "Default Web Site/%1/"
ECHO.
AppCmd.exe list vdir "Default Web Site/%1/"
IF %errorlevel%==1 GOTO Exists

ECHO.
ECHO Running...
ECHO   AppCmd.exe ADD vdir /app.name:"Default Web Site/" /path:/%1 /physicalPath:%2
ECHO.
AppCmd.exe ADD vdir /app.name:"Default Web Site/" /path:/%1 /physicalPath:%2

GOTO End

:Exists
ECHO.
ECHO VDir already exists
ECHO.
GOTO End

:SYNTAX
ECHO.
ECHO VDir Name and Physical Path Required
ECHO.
ECHO CreateVDir.CMD ^<VDirName^> C:\PhysPath
ECHO.

:END

Comments

শান্ত! আমার যা করা দরকার এটি এটিই! ধন্যবাদ! দেখে মনে হচ্ছে সার্ভারফল্ট SO এর মতোই ভাল হতে পারে!

— রিরি

এটি আমার জন্য অস্তিত্বহীন ভার্চুয়াল ডিরেক্টরিতে 1 এর একটি প্রস্থান কোড ট্রিগার করবে বলে মনে হয় না। আইআইএস 7.5 ব্যবহার করে।

— jpmc26

Answer 2

এটা চেষ্টা কর. বেশিরভাগ ক্ষেত্রে ক্রিস্টোফার_জি_ লুইস দেওয়া উত্তর হিসাবে একই, তবে ত্রুটি কোডের পরিবর্তে তালিকার আউটপুটটির বিশ্লেষণের উপর নির্ভর করে যা আমি পাই না।

এছাড়াও cmd.exe শেল কনস্ট্রাক্ট এ ব্যবহার করে || বি (যদি একটি ব্যর্থ হয় তবে খ করুন)

@ECHO OFF
REM --------------------------------------------------------------------------------
REM Check for and create VDir under Default Web Site
REM
REM %1 is the VDIR to create
REM %2 is the Physical path to the VDIR 
REM --------------------------------------------------------------------------------

IF "%1"=="" GOTO Syntax
IF "%2"=="" GOTO Syntax

AppCmd.exe list vdir "Default Web Site/%1/" | findstr /I "Default Web Site/%1/" || AppCmd.exe add vdir /app.name:"Default Web Site/" /path:/%1 /physicalPath:%2

goto :eof