কীভাবে আউটলুক 2013 এ ভাগ করা মেলবক্সে ম্যাক্রো চালানো যায়

Question

আমি আমার নিজস্ব মেলবক্স, তবে একটি শেয়ার্ড মেলবক্সের সাথেও কাজ করছি। আমার প্রাপ্ত ইমেলগুলিতে স্বয়ংক্রিয়ভাবে সংযুক্তিগুলি সংরক্ষণ করার জন্য আমার কাছে একটি ম্যাক্রো রয়েছে তবে এটি কেবল আমার নিজের মেইলবক্সের জন্য কাজ করে, ভাগ করা মেলবক্সের জন্য নয়। আমি কীভাবে এটি করতে পারি তা দয়া করে বলতে পারেন?

আমার এ পর্যন্ত যা আছে:

Private Declare Function ShellExecute Lib "shell32.dll" Alias _
  "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, _
  ByVal lpFile As String, ByVal lpParameters As String, _
  ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long

Private WithEvents Items As Outlook.Items

Private Sub Application_Startup()
  Dim Ns As Outlook.NameSpace
  Dim Folder As Outlook.MAPIFolder

  Set Ns = Application.GetNamespace("MAPI")
  Set Folder = Ns.GetDefaultFolder(olFolderInbox)
  Set Items = Folder.Items
End Sub

Private Sub Items_ItemAdd(ByVal Item As Object)
  If TypeOf Item Is Outlook.MailItem Then
    PrintAttachments Item
  End If
End Sub

Private Sub PrintAttachments(oMail As Outlook.MailItem)
  On Error Resume Next
  Dim colAtts As Outlook.Attachments
  Dim oAtt As Outlook.Attachment
  Dim sFile As String
  Dim sDirectory As String
  Dim sFileType As String

  sDirectory = "I:\Finance_Administration\MMR\Attachments\"

  Set colAtts = oMail.Attachments

  If colAtts.Count Then
    For Each oAtt In colAtts

' This code looks at the last 4 characters in a filename
      sFileType = LCase$(Right$(oAtt.FileName, 4))

      Select Case sFileType

' Add additional file types below
      Case ".xls", ".doc", "docx", ".pdf"

         sFile = sDirectory & oAtt.FileName
         oAtt.SaveAsFile sFile
        'ShellExecute 0, "print", sFile, vbNullString, vbNullString, 0
      End Select
    Next
    End If
End Sub

Comments

এখানে একবার দেখুন । আমি শেয়ার করা বিনিময় অ্যাকাউন্টগুলি ঘৃণা করি। ডাউনলোড ম্যাক্রো ট্রিগার করতে কোনও নিয়ম ব্যবহার করা সম্ভবত এটি সহজ।

— রায়স্টাফেরিয়ান

Answer 1

এটি শেয়ার ইনবক্সে চালানোর জন্য, আপনার ভিবিএ কোডটি সংশোধন করার চেষ্টা করুন

উদাহরণ

Private Sub Application_Startup()
  Dim Ns As Outlook.NameSpace
  Dim Folder As Outlook.Folder
  Dim olShareName As Outlook.Recipient


  Set Ns = Application.GetNamespace("MAPI")
  Set olShareName = Ns.CreateRecipient("[e-mail]") '// Owner's email address
  Set Folder = Ns.GetSharedDefaultFolder(olShareName, olFolderInbox) '// Inbox
  Set Items = Folder.Items
End Sub