সুতরাং আপনি একটি "যেখানে আমার নাম টু, বা সিসি ক্ষেত্রগুলিতে নেই" সন্ধান করছেন তবে উইজার্ডে তাদের একটাই নিয়ম নেই। আমি আশা করি আমার সে অধিকার আছে
আমি এই জাতীয় কোনও অ্যাডিন্স সম্পর্কে জানি না, তবে এটি নিজের নিজস্ব রোল করা সম্ভব। এই এমএসডিএন নিবন্ধটি দেখায় যে কীভাবে আউটলুক 2007 অ্যাক্সেস করতে হবে এবং একটি অ্যাডইন তৈরি করা যায়।
অথবা আপনি ভিবিএ ম্যাক্রোগুলিতে এটি করতে পারেন, আসলে ... এখানে এই আমি লিখেছি এটি আপনার যা করতে চান তা করবে, কেবল আপনার পছন্দ অনুযায়ী ধ্রুবকগুলি কনফিগার করুন। আউটলুকে ম্যাক্রো সম্পাদক (Alt + F11) টিপুন এবং এটিটি আউটলুকসেশন মডিউলটিতে আটকান। আপনি যদি আগে সেখানে ম্যাক্রোগুলি যোগ না করেন তবে খালি থাকা উচিত।
আপনাকে ম্যাক্রোগুলি সক্ষম করতে হবে , যদি না ইতিমধ্যে মেনু সরঞ্জামগুলির মাধ্যমে -> ম্যাক্রোস -> সুরক্ষা। যদি 'সমস্ত ম্যাক্রোগুলির জন্য সতর্কতা' সেট করা থাকে তবে প্রতিবার আপনি আউটলুক খুললে আপনাকে অনুরোধ জানানো হবে, যা ঠিক। ম্যাক্রো সংরক্ষণ করার পরে পুনরায় খুলুন আউটলুক।
'# [Outlook VBA custom mail mover by keyboardMonkey]
'# Checks new email if YOUR_NAME does not appear in the TO or CC list.
'# moves the message to DESTINATION_FOLDER.
'# Note: DESTINATION_FOLDER must be a child of the Inbox node, not a sibling.
Const YOUR_NAME As String = "Wesley"
Const DESTINATION_FOLDER As String = "testfolder"
'// hook into the outlook items events
Public WithEvents myOlItems As Outlook.Items
Public Sub Application_Startup()
' get the inbox item collection
Set myOlItems = Outlook.Session.GetDefaultFolder(olFolderInbox).Items
End Sub
'// called on mail item add
Private Sub myOlItems_ItemAdd(ByVal Item As Object)
If TypeName(Item) = "MailItem" Then
' get strongly typed object
Dim mymail As MailItem
Set mymail = Item
' flags if our name appears in each of the fields
Dim name_in_to As Boolean
Dim name_in_cc As Boolean
name_in_to = InStrB(1, mymail.To, YOUR_NAME) > 0
name_in_cc = InStrB(1, mymail.CC, YOUR_NAME) > 0
'#Uncomment below to show mail item details
' MsgBox (mymail.Subject + " has me in TO: " + Str(name_in_to) + " and CC: " + Str(name_in_cc))
' are we mentioned in the header?
If (Not name_in_to And Not name_in_cc) Then
' start with each main mapi folder
Dim idx As Integer
For idx = 1 To Outlook.Session.Folders.Count - 1
' recurse into subfolders
Dim dest As Outlook.MAPIFolder
Set dest = GetFolder(Outlook.Session.Folders.Item(idx), DESTINATION_FOLDER)
' we found our destination!
If Not (dest Is Nothing) Then
mymail.Move dest
Exit For
End If
Next
End If
' house cleaning
Set mymail = Nothing
End If
End Sub
'// to iterate is human. to recurse, divine
Private Function GetFolder(parent As Folder, name As String) As Outlook.MAPIFolder
Dim idx As Integer
Dim res As Object
For idx = 1 To parent.Folders.Count
Set res = GetFolder(parent.Folders.Item(idx), name)
If Not res Is Nothing Then
Set GetFolder = res
Exit For
End If
Next
If (parent.name = name) Then
Set GetFolder = parent
End If
End Function