ব্যাটারি স্তর পরিবর্তনের উপর ভিত্তি করে আমাকে টাস্ক শিডিয়ুলারে একটি টাস্ক তৈরি করতে হবে
উইন্ডোজ ইভেন্ট হিসাবে এই ধরণের বিবরণ লগ না। তবে আপনি নীচের ব্যাচ ফাইলের মতো কিছু ব্যবহার করতে পারেন এবং একটি কাস্টম ইভেন্ট তৈরি করতে পারেন।
Battery.cmd
এই ব্যাচ ফাইলটি বর্তমান ব্যাটারি শতাংশের চার্জ পর্যবেক্ষণ করে এবং ব্যবহারকারী নির্ধারিত প্রান্তিক মানের নীচে চার্জটি নামলে ব্যবহারকারী নির্ধারিত ইভেন্ট তৈরি করে।
@echo off
setlocal EnableDelayedExpansion
rem set threshold value
set _threshold=82
:start
rem get the battery charge
rem use findstr to strip blank lines from wmic output
for /f "usebackq skip=1 tokens=1" %%i in (`wmic Path Win32_Battery Get EstimatedChargeRemaining ^| findstr /r /v "^$"`) do (
set _charge=%%i
echo !_charge!
if !_charge! lss !_threshold! (
echo threshold reached
rem create a custom event in the application event log
rem requires administrator privileges
eventcreate /l APPLICATION /t WARNING /ID 999 /D "Battery charge has dropped"
goto :done
) else (
rem wait for 10 minutes then try again
timeout /t 600 /nobreak
goto :start
)
)
:done
endlocal
মন্তব্য:
Eventcreateএবং সহ উইন্ডোজ 10 পর্যন্ত Windows XP তে কমান্ড কাজ, এটা কাজ প্রশাসকের প্রাধিকার প্রয়োজন_thresholdপ্রয়োজনীয় হিসাবে সেট করুন- ব্যাটারি যদি এই মানের নীচে পড়ে তবে আইডি সহ একটি ইভেন্ট
999বর্ণনার সাথে অ্যাপ্লিকেশন ইভেন্ট লগে উত্পন্ন হবেBattery charge has dropped
eventcreateআপনার পরিস্থিতির জন্য প্রয়োজনীয় কমান্ডটি পরিবর্তন করুন ।timeoutআপনার পরিস্থিতির জন্য প্রয়োজনীয় হিসাবে বিলম্ব পরিবর্তন করুন ।
উদাহরণ আউটপুট:
আমার ব্যাটারির বর্তমানে চার্জ রয়েছে 81%। আমি প্রান্তিকতা সেট 82। আমি দৌড়ানোর সময় যা ঘটে তা এখানে Battery.cmd:
> battery
81
threshold reached
SUCCESS: An event of type 'WARNING' was created in the 'APPLICATION' log with 'EventCreate' as the source.
এবং ইভেন্ট লগতে এখানে নতুন এন্ট্রি রয়েছে:
ইভেন্টক্রিট সিনট্যাক্স
EVENTCREATE [/S system [/U username [/P [password]]]] /ID eventid
[/L logname] [/SO srcname] /T type /D description
Description:
This command line tool enables an administrator to create
a custom event ID and message in a specified event log.
Parameter List:
/S system Specifies the remote system to connect to.
/U [domain\]user Specifies the user context under which
the command should execute.
/P [password] Specifies the password for the given
user context. Prompts for input if omitted.
/L logname Specifies the event log to create
an event in.
/T type Specifies the type of event to create.
Valid types: SUCCESS, ERROR, WARNING, INFORMATION.
/SO source Specifies the source to use for the
event (if not specified, source will default
to 'eventcreate'). A valid source can be any
string and should represent the application
or component that is generating the event.
/ID id Specifies the event ID for the event. A
valid custom message ID is in the range
of 1 - 1000.
/D description Specifies the description text for the new event.
/? Displays this help message.
Examples:
EVENTCREATE /T ERROR /ID 1000
/L APPLICATION /D "My custom error event for the application log"
EVENTCREATE /T ERROR /ID 999 /L APPLICATION
/SO WinWord /D "Winword event 999 happened due to low diskspace"
EVENTCREATE /S system /T ERROR /ID 100
/L APPLICATION /D "Custom job failed to install"
EVENTCREATE /S system /U user /P password /ID 1 /T ERROR
/L APPLICATION /D "User access failed due to invalid user credentials"
আরও পড়া
