ওয়ার্কশিটগুলির মধ্যে এক্সেলের মধ্যে একটি মান সন্ধান করা, যদি অন্য কলাম থেকে ফেরত মান পাওয়া যায়

Question

আমার একটি কার্যপত্রিকা রয়েছে যাতে দুটি ওয়ার্কশিট রয়েছে। আমার একটি ফাংশন দরকার যা ওয়ার্কশিট_1 এর কলাম এ থেকে একটি মান নেবে এবং এটিকে ওয়ার্কশিট_2 এর কলাম ডি'র সাথে তুলনা করবে। ওয়ার্কশিট ৩-তে কলাম ডি-এর মধ্যে যদি মানটি পাওয়া যায়, তবে কার্যপত্রকটিতে কলাম ক এর বিষয়বস্তু প্রদর্শন করুন। যদি পাওয়া না যায় তবে "পাওয়া যায় না" প্রদর্শন করুন।

কার্যপত্রক_1 এ, আমার কাছে নিম্নলিখিত ডেটাসেট রয়েছে:

     A
1. ABC123
2. DEF234
3. GHI567
4. JKLM123
5. OPQ456
6. RSTU789

কার্যপত্রকটিতে আমার কাছে নিম্নলিখিত ডেটাসেট রয়েছে:

    A       D                             
1.  RED     ER4654F- RSTU789 - 54DF56GH
2.  BLUE    132DF- ABC123 - SDFG1665
3.  GREEN   456FD-OPQ456-D564G
4.  PURPLE  7987-DEF234-165416
5.  ORANGE  SDF86- JKLM123 -5DFG6H

ওয়ার্কশিট_1 এর মানগুলি ওয়ার্কশিট_2 এর কলাম ডি-তে উপস্থিত থাকলে এবং কলাম এ থেকে মানগুলি প্রদর্শিত হলে সঠিকভাবে সন্ধান করার জন্য আমি কীভাবে ফাংশনটি গঠন করব?

আপনার সাহায্যের জন্য আগাম ধন্যবাদ!

Comments

ঠিক আছে ... এই অনুরোধটির জন্য এখানে একটি নতুন কুঁচকে। আমি কীভাবে বেশ কয়েকটি কলামের মতো ম্যাচ সন্ধান করতে ম্যাচ ফাংশনটি ব্যবহার করতে পারি যেমন কলাম ডি যদিও জেড এবং যদি কোনও মিল খুঁজে পাওয়া যায়, তবে এটি কলামটির ফলাফলটি ফিরে পেয়েছিল?

— নওলিন্স

Answer 1

আপনি শীট 1 এর কলাম A এ আইটেমটির জন্য পত্রক 2 এ কলাম ডি অনুসন্ধান করতে ম্যাচ ফাংশনটি ব্যবহার করতে পারেন। উদাহরণস্বরূপ শীট 1 এর সেল বি 1 এ আপনি প্রবেশ করতে পারেন:

=MATCH("*"&$A1&"*",Sheet2!$D:$D,0)

এটি শীট 2 কলাম ডি-তে লাইন নম্বরটি ফিরে আসবে যেখানে A1 এর বিষয়বস্তু পাওয়া যায়, বা কোনও মিল না পাওয়া গেলে # N / A। অনুসন্ধান শব্দটির আগে এবং পরে "*" হ'ল ওয়াইল্ড কার্ড।

আপনি শিট 2 কলাম এ বিষয়বস্তুগুলি পেতে আইএনডেক্স ফাংশনটি ব্যবহার করতে পারেন সেল বি 1 তে পরিবর্তন করুন:

=INDEX(Sheet2!$A:$A,MATCH("*"&$A1&"*",Sheet2!$D:$D,0)) 

এটি শীট 2 কলাম ক এর মানটি ফিরিয়ে দেবে যা শিট 2 কলাম ডি-তে পাওয়া আইটেমের সাথে মিলেছে বা কোনও মিল না পাওয়া গেলে # এন / এ।

কোনও মিল নেই যখন আপনি "পাওয়া যায়নি" দেখানোর জন্য আপনি আইফেরআরআর ফাংশনটি ব্যবহার করতে পারেন। বি 1 সেলটি পরিবর্তন করুন

=IFERROR(INDEX(Sheet2!$A:$A,MATCH("*"&$A1&"*",Sheet2!$D:$D,0)),"Not Found")

কেবলমাত্র অবশিষ্ট সমস্যাটি হ'ল ওয়াইল্ডকার্ড ব্যবহারের অর্থ আপনি কলাম ডি-তে শব্দের কিছু অংশের সাথে মিল পেতে পারেন (উদাহরণস্বরূপ "বিসি 12" সারি 2 তে পাওয়া যাবে)। যদি আপনি যা চান তা যদি না হয় তবে আমি কলাম ডি পরিবর্তন করার পরামর্শ দিচ্ছি যাতে স্পেসগুলি সরিয়ে দেওয়া হয় এবং প্রতিটি আইটেমের শুরু এবং শেষে একটি "-" যুক্ত করা যায়, সুতরাং সারি 1 হবে:

'-ER4654F-RSTU789-54DF56GH-

(অ্যাস্টোস্ট্রোফ এক্সেলকে এটিকে গণনা হিসাবে বিবেচনা না করার জন্য বলে)। কলাম ডি-তে আপনি "-" এর মধ্যে কেবলমাত্র জিনিসগুলি মেলে কিনা তা নিশ্চিত করতে এখন আপনি অনুসন্ধানের শব্দটির আগে এবং পরে যুক্ত করতে পারেন B সেল বি 1 এর চূড়ান্ত সূত্রটি হ'ল:

=IFERROR(INDEX(Sheet2!$A:$A,MATCH("*-"&$A1&"-*",Sheet2!$D:$D,0)),"Not Found")

এই সূত্রটি শীট 1 কলাম বিতে অন্য কক্ষে অনুলিপি করুন

Comments

আমাকে এটি মারধর। খুব ভাল উত্তর।

— ব্যান্ডারসনচ

আপনার সহায়তার জন্য আপনাকে অনেক ধন্যবাদ। এটি একটি স্বপ্নের মতো কাজ করেছে এবং আমি এটিকে আরও অনেক স্প্রেডশিটে ব্যবহার করতে সক্ষম হয়েছি। এটি আমাকে অনেক উপায়ে সহায়তা করেছে। আবারও, ধন্যবাদ!

— নওলিন্স