উইন্ডোজ এক্সপ্লোরার শর্টকাট পরবর্তী ভাইবোন ফোল্ডারে যেতে চান?

Question

আমি উইন্ডোজ 10-তে একটি মূল শর্টকাট সন্ধান করছি যা আমাকে ফোল্ডার এ থেকে ফোল্ডার বি এর ভিতরে ফোল্ডার এ থেকে নেভিগেট করতে দেয়:

- Top Folder
-- A (I am here)
-- B

শর্টকাট, তারপরে:

- Top Folder
-- A 
-- B (now I am here)

এর জন্য নেটিভ শর্টকাট সম্পর্কে তথ্য খুঁজে পাওয়া যায়নি।

পিএস: একটি এএইচকে স্ক্রিপ্টও সহায়ক হবে।

Answer 1

এটি দুর্দান্ত অটোহোটকি স্ক্রিপ্টের সাথে এটির কাজ করেছে?

; navigate to next sibling folder from Windows Explorer
#If WinActive("ahk_class CabinetWClass") || WinActive("ahk_class ExploreWClass")
^PgUp::
^PgDn:: NavigateToSiblingDir( InStr(A_ThisHotkey, "Up") )

NavigateToSiblingDir(UpDown)  {
   oShell := ComObjCreate("Shell.Application")
   WinGet, hWnd,, A
   for oWin in oShell.Windows  {
      if (hWnd = oWin.hwnd)  {
         oFolder := oWin.Document.Folder
         startDirPath  := oFolder.Self.Path
         parentDirPath := oFolder.ParentFolder.Self.Path
         break
      }
   }

   for item in oShell.Namespace(parentDirPath).Items  {
      if !item.IsFolder
         continue
      if (found && nextSiblingPath := item.Path)
         break
      if (item.Path = startDirPath && found := true)
         prevSiblingPath := prev
      prev := item.Path
   }

   if (UpDown && prevSiblingPath)
      oWin.Navigate(prevSiblingPath)
   if (!UpDown && nextSiblingPath)
      oWin.Navigate(nextSiblingPath)
}

গিথুব: এক্সপ্লোরার-নেভিগেট-সিলিং-ফোল্ডার.হেক

আমার আন্তরিক কৃতজ্ঞতা এবং ক্রেডিট টিড্রিংকার এবং জিজউইউজিএএইচকে (এএইচকে) যায় ।