এটি এমন একটি কাজ যা আপনি আপনার ব্যাচের অগ্রাধিকার সেট করতে অন্যের কাছ থেকে ব্যবহার করতে পারেন। আপনি যদি এটি কোনও ডিরেক্টরিতে এটি অনুলিপি করেন তবে আপনি যথারীতি যে কোনও সময় এটিকে কল করতে পারেন ইত্যাদি। টোগামকে ধন্যবাদ , এটি আমাকে লেখার সরঞ্জাম এবং পদ্ধতি দিয়েছে। পরিবর্তনশীল নিশ্চিত করে যে পিনপয়েন্টেড প্রক্রিয়াটি ঠিক আপনার প্রয়োজন এবং আপনার ব্যাচের অন্য কোনও উদাহরণ নয় (অসম্ভব, তবে সম্ভাব্য দৃশ্য)।SetMyPrio.batMyPrio.bat%PATH%UniqueString
@echo off
GOTO :EndOfReminder
<HELP>
USAGE:
From any batch file or command prompt, write
CALL MyPrio [/?|/h] [<priority>|get]
to set the priority of the caller cmd. Default for <priority> is idle.
/?, /h This help.
<priority> If you want your priority change to
idle -- no parameter, 64, idle or "idle"
below normal -- 16384 or "below normal"
normal -- 32, normal or "normal"
above normal -- 32768 or "above normal"
high priority -- 128 or "high priority"
real time -- 256, realtime or "realtime"
get Returns current priority as errorlevel
TO DO
- Parameter error control.
- Support for Unicode characters in help.
</HELP>
:EndOfReminder
setlocal
set Priority=%~1
if /I ["%Priority%"]==["/h"] ( call :PrintHelp & exit /b )
if ["%Priority%"]==["/?"] ( call :PrintHelp & exit /b )
set UniqueString=%RANDOM%-%RANDOM%-%RANDOM%-%RANDOM%-%RANDOM%
if ["%Priority%"]==["get"] for /f "usebackq tokens=2 delims==" %%a in (`wmic Process WHERE "name='cmd.exe' AND CommandLine LIKE '%%%UniqueString%%%'" Get Priority /format:LIST`) do exit /b %%a
if not defined Priority set Priority=idle
for /f "usebackq tokens=2 delims==" %%a in (`wmic Process WHERE "name='cmd.exe' AND CommandLine LIKE '%%%UniqueString%%%'" Get ParentProcessID /format:LIST`) do set myPID=%%a
wmic process where "ProcessId='%myPID%'" CALL setpriority "%Priority%" > nul 2>&1
endlocal
goto :eof
:PrintHelp
setlocal DisableDelayedExpansion
call :eln 0
set "levelerror=^%%errorlevel^%%"
for /F "delims=" %%a in ('find /v /n "" "%~f0"') do (
set "line=%%a"
REM We store errorlevel in tmpel because setlocal will set errorlevel to 0...
call set tmpel=%levelerror%
setlocal EnableDelayedExpansion
REM ... and now we restore it
REM %levelerror% was expanded to %errorlevel% before running the iteration
REM and the CALL SET allows actual errorlevel be stored in tmpel
REM Finally, we set errorlevel again
call :eln !tmpel!
set "line=!line:*]=!"
if /i "!line!"=="</HELP>" exit /b 0
if errorlevel 1 echo(!line!
if /i "!line!"=="<HELP>" call :eln 1
REM errorlevel is the only value that survives the following endlocal
endlocal
)
exit /b 1
:eln
REM Sets errorlevel to %1
exit /b %1
সম্পাদনা করুন (2018-06-12)
- নাম পরিবর্তিত MyPrio যুক্ত অপশন
/?, /hএবং get।
- বিকল্প
/?এবং /hটেক্সট আপনার মধ্যে অনুস্মারক লিখতে প্রিন্ট <HELP>এবং </HELP>। আপনার প্রয়োজন মতো অন্য কোনও ব্যাচে এই পদ্ধতিটি পুনরায় ব্যবহার করা যেতে পারে।
আপনি যদি MyPrio.batকোনও ব্যাচের শুরুতে কল করেন, যে কোনও সময় আপনি এটি শুরু করেন, কোনও কমান্ড লাইন থেকে বা উইন্ডোজ এক্সপ্লোরার থেকে ফাইলগুলি টেনে এনে ফেলে দেওয়ার বিষয়টি গুরুত্বপূর্ণ নয় (যা পরামিতি হয়ে যায়), এর প্রতিটি অংশ (এবং শিশু প্রক্রিয়াগুলি) চলবে আপনার কাঙ্ক্ষিত অগ্রাধিকার
উদাহরণ স্বরূপ:
@echo off
call MyPrio
REM Here comes a set of commands that will run with idle priority.
call MyPrio normal
REM Here may come some interactive part to request information needed to continue.
call MyPrio
REM Back to idle (or put any other priority you prefer).
call MyPrio normal
REM You may want to set the priority to normal at the end just in case you call the batch from a command line.
মন্তব্য
প্রতিটি সম্ভাব্য বিকল্প দিয়ে PrioTest.batপরীক্ষার জন্য আমি একটি ব্যাচ তৈরি করেছি MyPrio.batএবং তাদের আদেশ দিয়েছি যাতে কোনও কলই অগ্রাধিকারটিকে অন্য একটিতে পরিবর্তন করে। আমি একটি সাবরুটিন তৈরি করেছি ( :test1):
1. বর্তমান অগ্রাধিকার পায় এবং এতে সংরক্ষণ করুন myPrioBefore।
২.MyPrio পরীক্ষার প্যারামিটার সহ কল করুন ।
3. নতুন অগ্রাধিকার পায় এবং এতে সংরক্ষণ করুন myPrioAfter।
4. একটি গোপন শুরু ping -t localhost।
5. অগ্রাধিকার এবং PID, পায় pingপ্রক্রিয়া এবং তাদের সংরক্ষণ
pingPrioএবং pingPID।
6. ছাপে মান myPrioBefore, এর কল MyPrio,
myPrioAfterএবং pingPrio। The
. শুরুটি হত্যা করে ping(নিশ্চিত হওয়া যে এটি অন্যটি নয়)।
@echo off
setlocal
set UniqueString=%RANDOM%-%RANDOM%-%RANDOM%-%RANDOM%-%RANDOM%
for /f "usebackq tokens=2 delims==" %%a in (`wmic Process WHERE "name='cmd.exe' AND CommandLine LIKE '%%%UniqueString%%%'" Get ParentProcessID /format:LIST`) do set myPID=%%a
for %%a in (64 16384 32 32768 128 256 idle "below normal" none normal "idle" "normal" "above normal" realtime "high priority" "realtime") do call :test1 %%a
CALL MyPrio normal
endlocal
goto :eof
:test1
for /f "usebackq tokens=2 delims==" %%b in (`wmic Process WHERE "ProcessID='%%myPID%%'" Get Priority /format:LIST`) do set myPrioBefore=%%b
if [%1]==[none] ( call MyPrio ) else ( call MyPrio %1 )
for /f "usebackq tokens=2 delims==" %%b in (`wmic Process WHERE "ProcessID='%%myPID%%'" Get Priority /format:LIST`) do set myPrioAfter=%%b
start "" /b ping -t localhost > nul
for /f "usebackq tokens=2 delims==" %%b in (`wmic Process WHERE "name='ping.exe' AND ParentProcessID='%%myPID%%'" Get Priority /format:LIST`) do set pingPrio=%%b
for /f "usebackq tokens=2 delims==" %%b in (`wmic Process WHERE "name='ping.exe' AND ParentProcessID='%%myPID%%'" Get ProcessID /format:LIST`) do set pingPID=%%b
echo myPrioBefore==%myPrioBefore% / CALL MyPrio %1 / myPrioAfter==%myPrioAfter% / pingPrio==%pingPrio%
taskkill /f /pid %pingPID% > nul
exit /b
এটি পরীক্ষক ব্যাচের আউটপুট:
myPrioBefore==4 / CALL MyPrio 64 / myPrioAfter==4 / pingPrio==4
myPrioBefore==4 / CALL MyPrio 16384 / myPrioAfter==6 / pingPrio==6
myPrioBefore==6 / CALL MyPrio 32 / myPrioAfter==8 / pingPrio==8
myPrioBefore==8 / CALL MyPrio 32768 / myPrioAfter==10 / pingPrio==8
myPrioBefore==10 / CALL MyPrio 128 / myPrioAfter==13 / pingPrio==8
myPrioBefore==13 / CALL MyPrio 256 / myPrioAfter==13 / pingPrio==8
myPrioBefore==13 / CALL MyPrio idle / myPrioAfter==4 / pingPrio==4
myPrioBefore==4 / CALL MyPrio "below normal" / myPrioAfter==6 / pingPrio==6
myPrioBefore==6 / CALL MyPrio none / myPrioAfter==4 / pingPrio==4
myPrioBefore==4 / CALL MyPrio normal / myPrioAfter==8 / pingPrio==8
myPrioBefore==8 / CALL MyPrio "idle" / myPrioAfter==4 / pingPrio==4
myPrioBefore==4 / CALL MyPrio "normal" / myPrioAfter==8 / pingPrio==8
myPrioBefore==8 / CALL MyPrio "above normal" / myPrioAfter==10 / pingPrio==8
myPrioBefore==10 / CALL MyPrio realtime / myPrioAfter==13 / pingPrio==8
myPrioBefore==13 / CALL MyPrio "high priority" / myPrioAfter==13 / pingPrio==8
myPrioBefore==13 / CALL MyPrio "realtime" / myPrioAfter==13 / pingPrio==8
আপনি দেখতে পাচ্ছেন, myPrioAfterকলটিতে অনুরোধটির সাথে মেলে না এবং কখনও কখনও , এর অগ্রাধিকারটি pingপিতামাতার সমান হয় না cmdতাই মানগুলি আরও থাকতে হবে (পঞ্চম লাইনে দেখুন: বর্তমান অগ্রাধিকারটি 10, আপনি অনুরোধ 128, নতুন অগ্রাধিকার 13 এবং শিশু প্রক্রিয়া 8, দুঃখিত?)। এছাড়াও, realtimeমনে হয় এটি কার্যকর হয় না (অ্যাডমিন অধিকারগুলি আমি ধরে নিই)
cmd.exeপিআইডি নির্দিষ্ট করে ফোটায়। এটি প্রায় একটি উত্তর। তবে এখনই আমি এটি করার কোনও উপায় ভাবতে পারি না। আমি এই চিন্তাটি পটভূমিতে প্রেরণ করব। হয়তো কিছু ধারণা হাজির।