এক্সেলের অন্য একটি কক্ষের ডেটার ভিত্তিতে সংশ্লিষ্ট কলাম এবং সারি ডেটা সন্ধান করুন

1

ঠিক আছে, তাই আমার কাছে ইমেজটির মতো কয়েকটি টেবিল এবং নীচের লিঙ্কে একটি এক্সেল ফাইল রয়েছে।

https://www.dropbox.com/s/967glpkyfjfb6iy/Test.xlsx?dl=0

আমি যা করার চেষ্টা করছি তা ডি 2: এন 21 সীমার মধ্যে একটি মান প্রবেশ করতে সক্ষম হবে এবং এটি কলাম B & D এর একটি ঘরের অনুরূপ মান এবং সারি 1 থেকে তারিখটি ফিরিয়ে আনতে এবং সেগুলি B26 , C26 কোষে প্রদর্শিত করতে সক্ষম করবে & D26 যথাক্রমে।

আমি আইএনডিএক্স ম্যাচের সূত্রগুলি ব্যবহার করার চেষ্টা করেছি কিন্তু এটি কাজ করে বলে মনে হচ্ছে না। আমি ধরে নিচ্ছি যে আমি কিছু মিস করছি। কোন সাহায্যের ব্যাপকভাবে প্রশংসা হবে।

microsoft-excel

— SeanM_NB
সূত্র

যদি ডি 2: এন 21 এ সদৃশ থাকে তবে এর কোন মূল্য বিবেচনা করা উচিত?

— patkim

2

এটি কোনও ভিবিএ ব্যবহার না করেই করা যেতে পারে। তবে এর জন্য কেবল চেহারা / রেফারেন্স ফাংশনগুলির চেয়ে বেশি প্রয়োজন কারণ সেগুলি কেবলমাত্র এক মাত্রায় কাজ করে (অন্যান্য ফাংশনগুলির মতো)।

SUMPRODUCT() একটি ফাংশন যা দ্বিমাত্রিক অ্যারে (যা কেবলমাত্র একটি সাধারণ তুলনা ব্যবহার করে উত্পন্ন করা যেতে পারে) নিয়ে কাজ করে।

সমাধানের জন্য নিম্নলিখিত দুটি সূত্র প্রয়োজন:

সূত্র 1 প্রবেশ করানো হয়েছে B26এবং এতে ctrl- প্রবেশ / পূরণ / অনুলিপি করা হয়েছে B26:C26:

=IF(ISERROR($D26),NA(),INDEX(B:B,SUMPRODUCT(MAX(($D$2:$N$21=$A26)*(ROW($D$2:$N$21))))))

সূত্র 2 প্রবেশ করানো হয়েছে D26:

=INDEX($1:$1,COLUMN($D$2:$N$21)-1+MATCH($A26,INDEX($D$2:$N$21,MAX(1,SUMPRODUCT(MAX(($D$2:$N$21=A26)*(ROW($D$2:$N$21))))-ROW($D$2:$N$21)+1),1):INDEX($D$2:$N$21,MAX(1,SUMPRODUCT(MAX(($D$2:$N$21=A26)*(ROW($D$2:$N$21))))-ROW($D$2:$N$21)+1),COLUMNS($D$2:$N$21)),0))

সূত্র 2 এর পূর্বনির্ধারিত সংস্করণটি হ'ল:

=
INDEX(
  ($1:$1),
  COLUMN($D$2:$N$21)-1
  +MATCH(
    $A26,
    INDEX(
      $D$2:$N$21,
      MAX(1,SUMPRODUCT(MAX(($D$2:$N$21=A26)*(ROW($D$2:$N$21))))-ROW($D$2:$N$21)+1),
      1
    )
    :INDEX(
      $D$2:$N$21,
      MAX(1,SUMPRODUCT(MAX(($D$2:$N$21=A26)*(ROW($D$2:$N$21))))-ROW($D$2:$N$21)+1),
      COLUMNS($D$2:$N$21)
    ),
    0
  )
)

দ্রষ্টব্য যে টেবিলের ডলারের পরিমাণগুলি অনন্য ছিল, একটি কম জটিল সূত্র ব্যবহার করা যেতে পারে। যেহেতু সদৃশগুলি পাওয়া গেলে আপনি কী করতে চান তা আপনি নির্দিষ্ট করেননি, তাই আমি সবচেয়ে সহজ সূত্রটি লিখেছি যা এখনও সন্ধান পেলে কার্যকর হয়।

এই সূত্রটি ঠিক তখনই নীচের সর্বাধিক সারিতে একটি মিল থাকা বাম-সর্বাধিক মানটি বের করার জন্য ঘটে। এটি নির্দিষ্ট কিছু নির্দিষ্ট মান প্রদান করতে পরিবর্তন করা যেতে পারে।

সন্নিবেশ করা মানটির জন্য সারণীতে নকল উপস্থিত রয়েছে কিনা তা সনাক্ত করতে নিম্নলিখিত সূত্রটি ব্যবহার করা যেতে পারে A26, যদি কিছু বিজ্ঞপ্তি / ক্রিয়া প্রয়োজন হয়:

=SUMPRODUCT(MAX((D2:N21=A26)*(ROW(D2:N21))))<>SUMPRODUCT(SUM((D2:N21=A26)*(ROW(D2:N21))))

অনন্য মানগুলির ক্ষেত্রে, MAX()সূত্র 1- এ ফাংশনটির আর প্রয়োজন হবে না, অবশ্যই সরলীকৃত সূত্র 2:

=INDEX($1:$1,IFERROR(1/(1/(SUMPRODUCT(($D$2:$N$21=A26)*(COLUMN($D$2:$N$21))))),NA()))

নোট:

পূর্বনির্ধারিত সূত্রটি প্রবেশ করানো হলে আসলে কাজ করে।
($1:$1)পূর্বনির্ধারিত সংস্করণে চারপাশে বন্ধনীগুলি $1:$1নিজের লাইনে থাকতে বাধ্য করতে বাধ্য হয় ।
যদিও আমি #N/Aপ্রবেশ করানো ডলারের পরিমাণটি খুঁজে না পাওয়া গেলে ত্রুটিটি প্রদর্শন করতে বেছে নিয়েছি , এটি অন্য কোনও কিছুর পরিবর্তে হতে পারে।

— robinCTS
সূত্র

-1

আমি মনে করি সমস্ত অনুসন্ধান / রেফারেন্স ফাংশন কলাম বা সারিগুলিতে অনুসন্ধান করে। আমি "কাস্টম ফাংশন" ব্যবহার করব যা ভিডিএ ফাংশন যা মডিউলটিতে চলে। আপনার B26, C26 এবং D26 এর জন্য 3, একটি প্রয়োজন হবে। এখানে ডি 26 (তারিখ) এর জন্য একটি। ডি 26 এ আপনার "= zDate (A26)" থাকবে। মডিউল:

Option Explicit

Function zDate$(param$)
  Dim icol&, searchRange As Range, cellRange As Range
  Set searchRange = Range("D2:N21")
  Set cellRange = searchRange.Find(param, , xlValues, xlWhole)
  icol = cellRange.Column ' column of found cell
  zDate = Cells(1, icol) ' returns date
End Function

সম্পাদনা: @robinCTS থেকে কি আশ্চর্যজনক উত্তর। আমি সহ বইটি কিনতে যাচ্ছি। আমি তৈরি করতে সরানো হয়েছিল

=INDEX(A1:N21,1,MAX(SUMPRODUCT((D2:N21=A26)*(COLUMN(D2:N21)) )))

তবে এটি ডুপগুলি পরীক্ষা করে না এবং আমি "$ bbbnn.nn" ফর্ম্যাটটি বুঝতে পারি না। আমার মধ্যে, এ 26 কে "$" এবং স্পেসগুলি অন্তর্ভুক্ত করতে হবে। ধন্যবাদ

— dcromley
সূত্র

দেখে মনে হচ্ছে আপনি সহজ সূত্রটি বেশ ভালভাবে খুঁজে পেয়েছেন। এটির সাথে একমাত্র সমস্যাটি সেই ক্ষেত্রে যেখানে মানটির সন্ধান A26করা যায় না। আপনার সূত্রটি কলামে তারিখটি ফেরত দেয় D, অন্য সূত্রগুলিকে একটি বিজ্ঞপ্তি সংক্রান্ত রেফারেন্স সতর্কতা (বা না, যদি পুনরাবৃত্ত গণনার অনুমতি দেওয়া হয়) ট্রিগার করে এবং B26:C26তাদের পূর্ববর্তী অনুসন্ধান মানগুলি বজায় রাখে। এবং, অবশ্যই, এটি ডুপসের জন্য ভুল / মেলানো ফলাফলগুলি ফিরিয়ে দেবে, যেমনটি আপনি বলেছিলেন। আপনার সূত্রটি প্রকৃতপক্ষে স্পেস এবং স্পেসগুলিতে প্রবেশ না করেই কাজ করে$ , কারণ ডেটা সেলগুলির জন্য ব্যবহৃত অ্যাকাউন্টিং নম্বর ফর্ম্যাটটির কারণে সেগুলি কেবল সেখানে।

— রবিন্টিসট