নিম্নলিখিত স্ক্রিপ্টটি ব্যবহার করে অটোহটকি যাদুতে এটি করা যেতে পারে , যা .ahkকার্যকর করার জন্য কোনও ফাইলে সংরক্ষণ করা উচিত । স্ক্রিপ্টটি শুরু করতে ফাইলটিতে ডাবল-ক্লিক করুন, সবুজ "এইচ" আইকনে ট্রেবারে ডান-ক্লিক করে এটি বন্ধ করুন এবং প্রস্থান নির্বাচন করুন।
স্ক্রিপ্টটি দুটি উইন্ডোর সমন্বিত স্ক্রোলিংয়ের জন্য রচিত। আপনাকে একে একে একে যুক্ত করে স্ক্রোল করতে প্রথমে উইন্ডো নির্বাচন করতে হবে। স্ক্রিপ্ট সমন্বিত স্ক্রোলিংয়ের জন্য নিম্নলিখিত কীগুলি সদৃশ করে: হুইল আপ, হুইল ডাউন, পেজ আপ, পৃষ্ঠা ডাউন।
স্ক্রিপ্টটি আরম্ভের জন্য কিছু হটকি ব্যবহার করে। আপনি কিছু অন্যান্য হটকি ব্যবহার করতে বা অনির্বাণিতগুলিকে সরাতে এটি সম্পাদনা করতে পারেন। আমি যেগুলি বেছে নিয়েছি সেগুলি নীচে বর্ণিত।
F1 : Starts a new group of windows
F2 : Includes the currently active window in the group
F3 : Shows the windows in the group even if minimized
F4 : Closes all windows in the group
এখানে স্ক্রিপ্ট। এটি আমার পরীক্ষায় কাজ করেছিল।
#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
#SingleInstance Force
SendMode Input ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir% ; Ensures a consistent starting directory.
Process, Priority, , High
SetWinDelay 0
g = 1 ; Used to generate unique group names
; Reload script to reinitialize all variables, since there is no delete group
f1::
Reload
return
; Add currently active window to the group
f2::
WinGet, active_id, ID, A
GroupAdd, grpname, ahk_id %active_id%
return
; Restore all windows in the group to be visible
f3::WinRestore, ahk_group grpname
return
; Close all windows in the group
f4::GroupClose, grpname , A
Reload
return
; This intercepts scroll keys on the active window and duplicates them on the other window
#IfWinActive ahk_group grpname
WheelUp::
WheelDown::
PgUp::
PgDn::
MouseGetPos, mX, mY ; remember mouse position in current window
Send {%A_ThisHotKey%}
GroupActivate grpname ; activate the next window of this group
If (A_ThisHotKey = "WheelUp" || A_ThisHotKey = "WheelDown")
MouseMove, 200, 200, 0 ; move the mouse over the currently active window
Send {%A_ThisHotKey%}
GroupActivate grpname ; Activate previous window
MouseMove, mX, mY, 0 ; Restore its mouse position
return