মাইক্রোসফ্ট ওয়ার্ডে কি নির্বাচিত মন্তব্যের ক্ষেত্রটি বাড়ানো সম্ভব? এর অর্থ হ'ল আপনি এর আগে কোনও মন্তব্য নির্দিষ্ট করেছেন তবে এখন সেই মন্তব্যের নির্বাচনটি প্রসারিত করতে চান।
কাজ করার জন্য নীচের মন্তব্যটি পেতে একটি উদাহরণ হিসাবে আমাকে মন্তব্যটি মুছে ফেলতে হয়েছিল এবং তারপরে একটি নতুন মন্তব্য যুক্ত করতে হয়েছিল। আমি বরং কেবল নির্বাচনটি প্রসারিত করতাম।
উত্তর:
আমি সাধারণত ক্লিপবোর্ডে মন্তব্য পাঠ্যটি অনুলিপি করি, মন্তব্যটি মুছুন এবং তারপরে সঠিক পাঠ্যের জন্য একটি নতুন মন্তব্য তৈরি করুন।
নিম্নলিখিত ম্যাক্রো এটি স্বয়ংক্রিয় করে তোলে:
Sub enlarge_comment()
'assumes that the current selection contains just one comment!
Dim newrange As Range
Set newrange = Selection.Range
Selection.Comments(1).Range.Copy 'copy text of old comment
Selection.Comments.Add Range:=newrange 'create new comment
Selection.Paste 'add text to new comment
newrange.Comments(1).Delete 'delete old comment
End Sub
আমি মন্তব্যটির বিন্যাস (যেমন বিভিন্ন ফন্টের মতো) হারিয়ে না যায় তা নিশ্চিত করার জন্য ক্লিপবোর্ডটি ব্যবহার করি, তবে আরও সহজ উপায় আছে কিনা তা পরীক্ষা করে দেখিনি। ফলাফল এটি:
অবশ্যই আপনি কোনওরকম ত্রুটি পরিচালনা পরিচালনা করতে চান; যদি নির্বাচিত অঞ্চলে একাধিক মন্তব্য থাকে তবে ওয়ার্ড প্রথমটি হিসাবে বিবেচনা করে যা তা গ্রহণ করবে। এছাড়াও, আপনার নতুন নির্বাচনের সম্পূর্ণরূপে পুরানো নির্বাচন থাকা দরকার; অন্যথায় Selection.Commentsখালি এবং Selection.Comments(1).Range.Copyব্যর্থ হয়।
আমি কেবল expand or shrink the selected comment area ম্যাক্রো না লিখে কীভাবে / কপি করা / মন্তব্যটি মুছে ফেলা হয়নি তা খুঁজে পেয়েছি (ওয়ার্ড 10 এ):
দেখুন খসড়ায় যান । আপনি 'হ্যান্ডলস' এর মধ্যে আপনার মন্তব্যটি দেখতে পাবেন {লাল বন্ধনীগুলি side পাশে মন্তব্য চিহ্ন সহ [বর্গাকার বন্ধনীগুলিতে]।
মন্তব্যের ক্ষেত্রটি প্রসারিত / সঙ্কুচিত করতে, হ্যান্ডলগুলি ভিতরে নতুন পাঠ্য সন্নিবেশ করুন (কাটা এবং পেস্ট করুন)।
উদাহরণ: {N.Sea} [AB1] আজ শীতল । এবার হ্যান্ডেলের ভিতরে অতিরিক্ত পাঠ্য সরান।
উদাহরণ: {N.Sea শীতকালীন} [AB1] আজ , আপনি মন্তব্যের ক্ষেত্রটি এভাবে প্রসারিত করেছেন (আপনি যদি পাঠ্যের বাইরে বের করেন তবে আপনি এটি সঙ্কুচিত করবেন)।
PS:} এর আগে স্থানটি প্রয়োজনীয়, এটি আপনাকে এটি ছাড়াই এটি করতে দেবে না।
আশা করি এটা সাহায্য করবে
উপরে আমার জোনাস হাইডেলবার্গের সমাধানের উপর ভিত্তি করে আমার মোটামুটি সম্পূর্ণ সমাধান:
Sub ChangeCommentSpan()
'
'If the current selection range is larger than the comment its spans, this macro expands the document-scope
'range of the comment to encompass the entire current selection's range. Alternatively, if the current
'selection range is smaller than the comment spanned by it, this macro reduces the document-scope range of
'the comment to encompass only the current selection's range.
'
'AUTHOR: Peter Straton
'
'CREDIT: Derived from Jonas Heidelberg's solution at:
' https://superuser.com/questions/159765/expand-comment-select-in-microsoft-word
'
'*************************************************************************************************************
Const ExpandUnits As Integer = wdWord 'Alternatively, could use wdCharacter
Dim CheckRng
Dim DocTextSelRng As Range
Dim EndBackward As Boolean
Dim EndForward As Boolean
Dim Forward As Boolean
Dim OrigCmnt As Comment
Dim MovedEndUnits As Long
Dim MovedStartUnits As Long
'First check whether the selection includes (overlaps onto) one and only one comment.
With Selection
If .Comments.Count > 1 Then
MsgBox "The selected range includes more than one Word comment. Unable to determine which " & _
"comment is to be expanded.", vbOKOnly + vbCritical, "SELECTION ERROR"
Exit Sub
End If
Set DocTextSelRng = .Range.Duplicate 'Capture the current Selection range (the document-text range)
'because the Selection object's range will change to be the new
'comment's (internal) Text range when the new comment is added.
End With
'Sometimes the user fails to span the current-comment's scope range (or span the whole comment) with their
'manual selection, resulting in the targeted comment being undetectable using the Selection object's range.
'So check for that case using a copy of the selected range and, if necessary, progressively expand it one
'character at a time, alternating left and then right, until at least one overlapping comment is found.
Set CheckRng = DocTextSelRng.Duplicate
With CheckRng
While .Comments.Count = 0
If Forward Then
If Not EndForward Then
MovedEndUnits = .MoveEnd(ExpandUnits, 1)
EndForward = (MovedEndUnits = 0)
End If
Forward = EndBackward
Else
If Not EndBackward Then
MovedStartUnits = .MoveStart(ExpandUnits, -1)
EndBackward = (MovedStartUnits = 0)
End If
Forward = Not EndForward
End If
If EndForward And EndBackward Then
'The range was expanded to include the whole document text and no comment was found.
MsgBox "The active document includes no Comments.", vbOKOnly + vbCritical, "NO COMMENTS FOUND"
Exit Sub
End If
Wend
Set OrigCmnt = .Comments(1)
'Found the nearest Comment so check whether it overlaps the originally selected range.
'IMPORANT: Start and End values are insertion-point locations, not character positions. So the Start
'property of a Comment object's Scope range may be the same value as the End value of the character
'immediately to its left and the End property of a Comment Scope range may be the same value as the
'Start value of the character immediately to its right. Therefore, the following conditional test
'must use "<=" and ">=", respectively, not just "<" and ">":
If (DocTextSelRng.End <= OrigCmnt.Scope.Start) Or (DocTextSelRng.Start >= OrigCmnt.Scope.End) Then
'The found Comment does not overlap onto the original selected range, so inform user and exit.
MsgBox "The selected range includes no Comments.", vbOKOnly + vbCritical, "SELECTION ERROR"
Exit Sub
End If
End With
'Expand (or reduce) the comment to include all of (or only) the selected range.
OrigCmnt.Range.Copy 'Copy the (internal) text of the existing comment
DocTextSelRng.Comments.Add Range:=DocTextSelRng 'Create a new comment that spans the selected document scope
'Paste the original Comment's (internal) text and its formatting as the new Comment's (internal) text
Selection.Paste 'NOTE: This is the now-current Selection which is the new Comment's (internal) text
'range (not the Comment's scope range, which spans the document-text it applies to).
OrigCmnt.Delete 'Delete the original comment
'Finally, close the Comments pane that was automatically opened by the Comments.Add method call, above.
If WordBasic.ViewAnnotations = -1 Then
WordBasic.ViewAnnotations 0
End If
End Sub