আমি কীভাবে দুর্ঘটনাজনিত [ক্যাপস লক] হিটগুলি প্রতিরোধ করতে পারি, একটি দ্বিতীয় বা তারও বেশি বাধ্যতামূলক হোল্ড দেরি করে?

Question

কী এক সেকেন্ড বা তার বেশি সময় ধরে রাখার পরে কেবল ক্যাপস লককে সক্রিয় করার কোনও উপায় / উপযোগিতা রয়েছে? আমি এটি পুরোপুরি অক্ষম করতে চাই না, কেবলমাত্র এই ক্রিয়াকলাপটি দুর্ঘটনাক্রমে সক্রিয়করণকে আটকাতে চাই।

অটোহটকি এটির জন্য স্ক্রিপ্ট করা যায়?

Comments

এটি ওএস নির্ভর করবে, সুতরাং দয়া করে একটি ওএস ট্যাগ যুক্ত করুন।

— রিচার্ড

এটি একটি দুর্দান্ত বৈশিষ্ট্য হবে।

— মোয়াব

Answer 1

এটি সত্যই একটি এএইচকে টাইমার-স্ক্রিপ্টের সাহায্যে করা যেতে পারে। এই স্ক্রিপ্টটি ক্যাপস লকটি চাপলে এবং ক্যাপস্লক আপকে আটকানো হলে নিবন্ধভুক্ত হবে , কেবলমাত্র নির্দিষ্ট সংখ্যক মিলিসেকেন্ড পেরিয়ে গেলেই এটি ফায়ার করতে দেয়। ডিফল্ট সময়সীমা 0.2 সেকেন্ড, এটি সিস্টেম ট্রেতে কনফিগার করা যায়।

; AutoHotKey - Suppress CapsLock
; This is a modified version of a scrpt by Lexikos, taken from:
; http://www.autohotkey.com/board/topic/82509-software-fix-for-double-clicking-mouse/

RegRead minDelay, HKCU, Software\LongCapsLock, MinDelay
if ErrorLevel
    minDelay := 200  ; Default setting.

#NoTrayIcon  ; Hide initial icon.
Menu Tray, Icon, %A_WinDir%\System32\main.cpl  ; Set icon.
Menu Tray, Icon  ; Show icon.
Menu Tray, NoStandard
Menu Tray, Add, &Configure, TrayConfigure
Menu Tray, Add, E&xit, TrayExit
Menu Tray, Default, &Configure
Menu Tray, Click, 1  ; Single-click to configure.
Menu Tray, Tip, Long CapsLock

global _starttime
global timing := 0

CapsLock::
if (timing = 0) {
    timing := 1
    _startTime := A_TickCount
}
return

CapsLock Up::
if (timing = 1) {
    _timeDiff := A_TickCount - _startTime
    ;MsgBox  diff: %_timeDiff%
    if (_timeDiff > minDelay) {
        Send {CapsLock down} 
    }
    timing := 0
}
return

TrayConfigure:
prompt := "Enter minimum duration needed to hold Caps Lock`n"
            . "before it is toggled. The unit is milliseconds."
Loop {
    InputBox newMinDelay, Long CapsLock, %prompt%,,,,,,,, %minDelay%
    if ErrorLevel  ; Cancelled?
        return
    if (newMinDelay+0 >= 150 && newMinDelay <= 10000) ; Valid?
        break
    if (A_Index = 1)
        prompt .= "`n`nPlease enter a number between 150 and 10000."
}
minDelay := newMinDelay
if (minDelay = 200)
    RegDelete HKCU, Software\LongCapsLock
else
    RegWrite REG_DWORD, HKCU, Software\LongCapsLock, MinDelay, %minDelay%
return

TrayExit:
ExitApp

Answer 2

আমি এখানে দুটি এএইচকে স্ক্রিপ্ট পেয়েছি। আমি যদি স্ক্রিপ্টগুলিতে আমি মন্তব্য করেছি তার চেয়ে আরও ব্যাখ্যা করতে চাই, তবে নীচে একটি মন্তব্য যুক্ত করুন।

প্রথমটিটি আরও জটিল এবং সম্ভবত ব্যর্থতার ঝুঁকিপূর্ণ, তবে এটি ক্যাপসলককে এক সেকেন্ড ধরে থাকার পরে আক্ষরিক কীপ্রেস হিসাবে প্রেরণ করে।

দ্বিতীয়টি "ক্যাপস লক" এর রাজ্যে টগল করে, আপনি যে বিলম্বটি চান তা অন্য কোনও প্রোগ্রামের ক্যাপসলক হটকারির জন্য যদি হয় তবে তা কাম্য নয়।

Delayদ্বিতীয় লাইনে ভেরিয়েবল পরিবর্তন করে আপনি বিলম্বটি কনফিগার করতে পারেন ।

---

একটি আক্ষরিক "CapsLock" কিপ্রেস প্রেরণ করে

; Time to wait in milliseconds
Delay = 1000

; Variable used to ignore key repeats
; (Windows sends them when a key is held down)...
CapsLockHeld = 0

; This starts the timer on key *down*.
; Time is measured in milliseconds.
; Timer resolution should be approximately 20 ms.
; The negative time means run only once.
; It will reset the timer if it is already running.
CapsLock::CapsLockDown()

; This stops the timer on key *up*.
CapsLock Up::CapsLockUp()

; This sends a CapsLock keypress when the timer runs out.
SendCapsLock:
    SetTimer, SendCapsLock, Off
    HotKey, CapsLock, Off
    HotKey, CapsLock Up, Off
    SendInput, {CapsLock}
    HotKey, CapsLock Up, On
    HotKey, CapsLock, On
Return

; Using functions because otherwise global variables die
CapsLockDown() {
    global CapsLockHeld
    global Delay
    If (CapsLockHeld == 1) {
        Return
    }
    CapsLockHeld = 1
    SetTimer, SendCapsLock, %Delay%
    Return
}

CapsLockUp() {
    global CapsLockHeld
    CapsLockHeld = 0
    SetTimer, SendCapsLock, Off
    Return
}

---

"ক্যাপস লক" রাষ্ট্রটি টগল করুন:

; Time to wait in milliseconds
Delay = 1000

; Variable used to ignore key repeats
; (Windows sends them when a key is held down)...
CapsLockHeld = 0

; This starts the timer on key *down*.
; Time is measured in milliseconds.
; Timer resolution should be approximately 20 ms.
; The negative time means run only once.
; It will reset the timer if it is already running.
CapsLock::CapsLockDown()

; This stops the timer on key *up*.
CapsLock Up::CapsLockUp()

; This sends a CapsLock keypress when the timer runs out.
SendCapsLock:
    SetTimer, SendCapsLock, Off
    If (GetKeyState("CapsLock", "T"))
        SetCapsLockState, Off
    Else
        SetCapsLockState, On
Return

; Using functions because otherwise global variables die
CapsLockDown() {
    global CapsLockHeld
    global Delay
    If (CapsLockHeld == 1) {
        Return
    }
    CapsLockHeld = 1
    SetTimer, SendCapsLock, %Delay%
    Return
}

CapsLockUp() {
    global CapsLockHeld
    CapsLockHeld = 0
    SetTimer, SendCapsLock, Off
    Return
}

Comments

দ্বিতীয় লিপি বিজ্ঞাপন হিসাবে ঠিক কাজ করে। আমি প্রেসটি ডাউন টাইম 3 সেকেন্ডে বাড়ানোর জন্য "বিলম্ব" ভেরিয়েবলটি 3000 এ পরিবর্তন করেছি।

— মজুর গিক

Answer 3

একটি গুগল অনুসন্ধান আমাকে এই লিঙ্কটি http://chuchuva.com/software/capslockdelay/ এ দিয়েছে । তিন ডাউনলোড লিংক প্রথম এখনো কাজ করে।

আমি অটোহটকি স্ক্রিপ্ট সম্পর্কে জানি না। অটোহটকি এবং ক্যাপলক বিলম্বের জন্য গুগল হতে পারে।

Comments

-1 "দুর্দান্ত" নয়। বর্তমান উত্তরটি হ'ল "লিঙ্ক" হিসাবে চিহ্নিত একটি লিঙ্ক, এবং দ্বিতীয় অংশটি "আমি জানি না, গুগল ব্যবহার করে দেখুন"।

— এই ব্রাজিলিয়ান গাই

Answer 4

আমি একটি পুরানো ইউটিলিটি (এটি ভি 1.0, জানুয়ারী 2001 এর তারিখ) আমার জন্য সবচেয়ে ভাল কাজ করে, যদিও এটি মাঝে মাঝে উইন্ডোজ 10 এর অধীনে অক্ষম হয়ে যায় বলে মনে হয়, এটি আমাকে একটি স্মার্টশিফ্ট ফাংশন সহ ক্যাপসলকটিতে বিলম্ব যোগ করতে সক্ষম করে শিফট-কী এবং একটি চিঠি টিপে থাকলে ক্যাপসলকটি আনসেট করুন। এটিতে আরও অনেকগুলি ক্ষমতা রয়েছে যা আমি ব্যবহার করি না।

সম্পাদকের দ্রষ্টব্য: দেখে মনে হচ্ছে এটি বিকাশকারী, অ্যাস্টাস সফটওয়্যারটির কাছাকাছি থাকতে পারে না এবং 2001 থেকে এই সফ্টওয়্যারটি আপডেট হয়েছে বলে মনে হয় না However তবে এটি এখনও ডাউনলোডডাউনলোড http://download.cnet.com/Toggler এ রয়েছে /3000-2072_4-10054498.html