কমান্ড লাইন থেকে ইন্টারনেট এক্সপ্লোরারকে ডিফল্ট ব্রাউজার হিসাবে সেট করুন

Question

কমান্ড লাইন থেকে আরম্ভ করার জন্য কি ইন্টারনেট এক্সপ্লোরারকে ডিফল্ট ব্রাউজার হিসাবে সেট করা সম্ভব?

আমার কাছে একটি ওয়েব অ্যাপ্লিকেশন রয়েছে যা কেবলমাত্র ইন্টারনেট এক্সপ্লোরারের অধীনে চলে Firef তবে যদি ফায়ারফক্সটি ডিফল্ট ব্রাউজার হয় তবে এটি কার্যকর হয় না। ব্যবহারকারীরা একটি ডোমেন পরিবেশে আছেন এবং যদিও আমি এইভাবে কোনও ব্যাচ থেকে আমাদের অ্যাপ্লিকেশনটি চালু করার চেষ্টা করি:

start "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

আমি ব্রাউজারটি ম্যানুয়ালি পরিবর্তন না করে অ্যাপ্লিকেশন আরম্ভ হবে না।

Comments

আমি মনে করি "অ্যাপটি ঠিক করুন যাতে এটি প্রতিটি শালীন ব্রাউজারের নীচে ভেঙে ফেলার পরিবর্তে যথাযথ এইচটিএমএলকে সম্মান দেয়" কোনও বিকল্প নয়?

— শাদুর

@ শাদুর এমন কিছু ক্ষেত্র রয়েছে যেখানে সমস্যাগুলি বৈশিষ্ট্য হিসাবে দেখা হয় ..

— জোসেফ হানসেন

একক ব্রাউজারে নির্দিষ্ট ভাঙ্গা আচরণের উপর নির্ভর করা কোনও বৈশিষ্ট্য নয় বা কমপক্ষে কখনই হওয়া উচিত নয়।

— শাদুর

@ techie007 আমি নিজেই এটি পরীক্ষা করি নি তবে আপনি এখানে এবং এখানে পরীক্ষা করে দেখতে পারেন ।

— avirk

আইই ডিফল্ট ব্রাউজার তৈরি করা একটি খারাপ ধারণা।

— জেট

Answer 1

এই কমান্ডটি আইই কে ডিফল্ট ব্রাউজার হিসাবে সেট করবে:

shmgrate.exe OcinstallreinstallIE

এই নীতিটি ডিফল্ট ব্রাউজার নির্ধারণ করা লোকদের থামাতে হবে।

Comments

কোন প্রব। এটা আপনার জন্য কাজ করে খুশি।

— slotishtype

নীতিটির জন্যও +1।

— এমডিটি গাই

উইন্ডোজ ভিস্টায় রেজিস্ট্রেশন স্কিমটি পুনরুদ্ধার করা হয়েছিল। shmgrateসরঞ্জামটি কেবল উইন্ডোজ 2000 / এক্সপি এবং উইন্ডোজ সার্ভার 2003 এ উপলব্ধ। এছাড়াও, এই নীতিটি ইন্টারনেট এক্সপ্লোরারটিকে এটি ডিফল্ট ব্রাউজার হিসাবে সেট করা আছে কিনা তা পরীক্ষা করতে বাধা দেবে।

— 31415

Answer 2

আপনি এটি চেষ্টা করতে পারেন, এটি কাজ করবে

start "" "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

আপনার কমান্ডে ত্রুটিটি হ'ল startপ্রথম উদ্ধৃত স্ট্রিংটিকে অ্যাপ্লিকেশনটির শিরোনাম বলে প্রত্যাশা করে, এই ক্ষেত্রে আপনি খালি রাখতে পারেন leave

iexplorer.exeসিস্টেমের ডিফল্ট ওয়েব ব্রাউজার হিসাবে সেট করার জন্য , আপনি ব্যবহার করতে assocএবং ftypeআদেশগুলি ব্যবহার করতে পারেন , যা ফাইল প্রকারের সাথে এক্সটেনশনগুলি এবং এক্সিকিউটেবল ফাইলের সাথে ফাইলের প্রকারগুলি সংযুক্ত করে:

assoc .html=htmlfile
ftype htmlfile="C:\Program Files\Internet Explorer\iexplore.exe" %1

%1 এখানে যুক্তিটি হ'ল - এটি URL বা ফাইল যা আপনি প্রোগ্রামটিকে একটি ইনপুট হিসাবে প্রেরণ করতে পারেন

Comments

(জাস্ট) আইএমএল দ্বারা খোলার জন্য এইচটিএমএল ফাইল ধরণের সংযুক্তি এটি ওএসের ডিফল্ট ব্রাউজার হিসাবে সেট করার মতো নয়।

— ʜιᴇcʜιᴇ007

iexplore.exe, iexplorer.exe নয়

— ইন্টারলিঙ্কড

Answer 3

উইন্ডোজ ভিস্তা এবং পরে, আই 7+

নিম্নলিখিত ব্যাচ স্ক্রিপ্টটি ডিফল্ট প্রোগ্রামগুলি নিয়ন্ত্রণ প্যানেল অ্যাপলেট থেকে এই প্রোগ্রামগুলিকে ডিফল্ট হিসাবে সেট করুন ক্লিক করে অনুকরণ করে । ভিস্তা / 7 এবং আইই 7 / আইই 11 দিয়ে পরীক্ষিত।

@echo off
setlocal enabledelayedexpansion

REM -- check XHTML support (IE 9+)
set xhtml=0
for /f %%G in ('"reg query "HKCR\IE.AssocFile.XHT" /ve 2>&1 | findstr /c:".XHT" "') do set xhtml=1

REM -- reset file extensions
set exts=HTM,HTML
if %xhtml% == 1 (set exts=%exts%,XHT,XHTML)

for %%G in (%exts%) do (
set ext=%%G
set ext=!ext:~0,3!
reg add "HKCU\Software\Classes\.%%G" /ve /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)

set exts=%exts%,MHT,MHTML,URL
set acl=%temp%\acl_%random%%random%.txt

for %%G in (%exts%) do (
set key=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%G\UserChoice
echo !key! [1 7 17]>"%acl%"
regini "%acl%" >nul
set ext=%%G
set ext=!ext:~0,3!
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)
del "%acl%" 2>nul

REM -- reset MIME associations
for %%G in (message/rfc822,text/html) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\MIMEAssociations\%%G\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%G" /f >nul
)

REM -- reset URL protocols
for %%A in (FTP,HTTP,HTTPS) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\%%A\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%A" /f >nul
for %%B in (DefaultIcon,shell) do (
set key=HKCU\Software\Classes\%%A
reg delete "!key!\%%B" /f >nul 2>&1
reg copy "HKCR\IE.%%A\%%B" "!key!\%%B" /s /f >nul
reg add "!key!" /v "EditFlags" /t REG_DWORD /d 2 /f >nul
reg add "!key!" /v "URL Protocol" /t REG_SZ /d "" /f >nul
))

REM -- reset the start menu Internet link (Vista and earlier)
reg add "HKCU\Software\Clients\StartMenuInternet" /ve /t REG_SZ /d "IEXPLORE.EXE" /f

REM -- reset cached icons
if %xhtml% == 1 (
ie4uinit -cleariconcache
) else (
taskkill /im explorer.exe /f >nul
start explorer
)

pause
exit /b

মন্তব্য

যে কোনও ওয়েব ব্রাউজার অ্যাপ্লিকেশন স্টার্ট মেনুতে ইন্টারনেট ক্লায়েন্ট হিসাবে উপস্থিত হতে নিবন্ধন করতে পারে। কোনও অ্যাপ্লিকেশন ফাইল এবং প্রোটোকলের জন্য যথাযথ নিবন্ধকরণের সাথে এই দৃশ্যমানতা ধরণের একটি অ্যাপ্লিকেশনকে ডিফল্ট ব্রাউজারের স্থিতি দেয়। ডিফল্ট ওয়েব ব্রাউজারটি সিস্টেমের যে কোনও জায়গা থেকে স্বেচ্ছাসেবী URL গুলি চালু করতে ব্যবহৃত হয়।

দ্রষ্টব্য বিদ্যমান [শুরু মেনু লিঙ্ক] নিবন্ধগুলি উইন্ডোজ later এবং তারপরে উপেক্ষা করা হবে। এই নিবন্ধটি উইন্ডোজ 7 হিসাবে অবচয় করা হয়েছে।

_{উত্স: উইন্ডোজ স্টার্ট মেনু দিয়ে কীভাবে কোনও ইন্টারনেট ব্রাউজার বা ইমেল ক্লায়েন্ট নিবন্ধিত করতে হয়}

­­

ফাইল এবং প্রোটোকল অ্যাসোসিয়েশনের জন্য শ্রেণিবদ্ধ রেজিস্ট্রি কাঠামো মেশিন-স্তরের খেলাপিগুলির চেয়ে ব্যবহারকারী-প্রতি ডিফল্টকে প্রাধান্য দেয়।

_{সূত্র: ডিফল্ট প্রোগ্রামসমূহ}

Comments

উইন্ডোজ 8.1 এ আমার জন্য ডিফল্ট হিসাবে IE রিসেট করে না। :(

— 5cʜιᴇ007

@ techie007 কন্ট্রোল প্যানেলে ডিফল্ট প্রোগ্রাম সেটিংস সম্পর্কে কী? সেখানে কি কিছু পরিবর্তন হয়েছে? ব্যাচের স্ক্রিপ্টটি কার্যকর করার সময় আপনি কোনও ত্রুটি পেয়েছেন?

— 31415

উইন্ডোজ ((প্রো, -৪-বিট) এর অধীনে কাজ করার মতো মনে হচ্ছে, তবে উইন্ডোজ ৮ এর অধীনে (প্রো 32-বিট) এটি কেবলমাত্র (একই / সাধারণ) আউটপুটটি দেখায় "অপারেশন সফলভাবে সম্পন্ন হয়েছে।" -- "চালু রাখবার জন্য যেকোনো বোতাম চাপুন . . ." কিন্তু আসলে আইই ডিফল্ট হিসাবে সেট করে না।

— ʜιᴇcʜιᴇ007

আমার অন্যান্য উইন্ডোজ 8 মেশিনের অধীনে এটি কিছুটা ভাল কাজ করেছে। আমি এটি চালাচ্ছি, এবং এরপরের সময় আমি একটি লিঙ্ক লিঙ্ক খুলি, এটি আমাকে জিজ্ঞাসা করে যে আমি কোন ব্রাউজারটি ব্যবহার করতে চাই। এটি আমার দ্বারা যথেষ্ট ভাল, যেমন অন্যান্য বিট এবং টুকরো টুকরো টুকরো মনে হয় (এএএএফসিটি) এটি করার পরে আইই ডিফল্ট হিসাবে নিবন্ধিত হয়েছে। সুতরাং আমার অনুগ্রহ আছে। :)

— 5cʜιᴇ007

@ techie007 আমি সম্পূর্ণরূপে ভুলে গেছি যে মাইক্রোসফ্ট নিয়ম পরিবর্তন করেছে এবং এখন those রেজিস্ট্রি কীগুলির বেশিরভাগের জন্য একটি প্রতিরোধ বিরোধী সুরক্ষা রয়েছে। আপনি যদি এটি পরীক্ষা করতে ইচ্ছুক হন তবে আমি আপনাকে স্ক্রিপ্টটির একটি আপডেট সংস্করণ পাঠাতে পারি যা উইন্ডোজ 8 এর সংযুক্তি পরিষ্কার করবে এবং পরবর্তী সময়ে আপনি যখন কোনও লিঙ্ক বা এইচটিএমএল ফাইল খুলবেন তখন উইন্ডোজ আপনাকে কোনটি বেছে নিতে দেবে ব্রাউজার ব্যবহার করতে। এটি সম্ভবত আপনি স্বয়ংক্রিয় পদ্ধতিতে সেরা অর্জন করতে পারেন কারণ (কিছু) ব্যবহারকারীর ইন্টারঅ্যাকশন যেভাবেই প্রয়োজন হবে।

— 31415

Answer 4

আপনি একটি ব্যাট ফাইলে দুটি লাইনের নীচে যুক্ত করতে পারেন

reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /f /v "Check_Associations" /d "yes" /t REG_SZ

reg add "HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\http\UserChoice" /f /v "ProgId" /d "IE.HTTP" /t REG_SZ

ব্যাট চালানোর পরে, পুনরায় বুট করুন / লগ অফ করুন এবং লগ ব্যাক করুন যেহেতু উপরের দুটি কমান্ড লাইন রেজিস্ট্রি মান পরিবর্তন করতে বোঝায় ..

অ্যাডিটিনাল বিশদ এখানে পাওয়া যাবে

(স্থির) -ক্যান্ট ইন্টারনেট এক্সপ্লোরারকে ডিফল্ট ব্রাউজার হিসাবে সেট করুন! http://www.windowstechinfo.com/2016/03/fixed-cant-set-internet-explorer-as-the-default-browser.html

Answer 5

কমান্ড লাইন থেকে ডিফল্ট ব্রাউজার সেট করা সম্পর্কে আমি জানি না, তবে আপনি গোষ্ঠী নীতি দ্বারা ডোমেনের জন্য সেট এবং প্রয়োগ করতে পারেন।

আপনাকে শুরু করার জন্য এখানে কিছু:

http://technet.microsoft.com/en-us/library/hh147307%28WS.10%29.aspx

Answer 6

startকমান্ড বা ব্যাচ ফাইলটি কাজ করতে পেতে কেবল ড্রপ করুন ।

"C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

Comments

আমরা (ঠিক আছে আমি যাইহোক) কমান্ড-লাইন থেকে ডিফল্ট ব্রাউজার সেট করার বিষয়ে সমাধানগুলি সন্ধান করছি, কেবল ওপিতে উদাহরণ সমস্যা / কারণ সমাধান করার জন্য নয়।

— ʜιᴇcʜιᴇ007

Answer 7

উইন্ডোজ 8 (IE 10+) এর জন্য এটি সহজ ভিবিএস স্ক্রিপ্ট:

Dim URL 
Dim IE 
Set IE = CreateObject("internetexplorer.application")
URL = "res://ieframe.dll/defaultbrowser.htm" 
IE.Visible = True
IE.Navigate URL


 Do While IE.Busy
    WScript.Sleep 100
 Loop

IE.Document.getElementById("changeDefaultButton").Click

এটি আইই ডিফল্ট হিসাবে আইই পরিবর্তন করার জন্য আই পৃষ্ঠা শুরু করবে এবং গ্রহণের জন্য বোতামে সিমুলেট করুন।