কোনও স্ক্রোল হুইল ট্র্যাকবলের প্রতিকার?

30

আমি একটি ট্র্যাকবল কেনার চিন্তা করছি এবং আমার বিকল্পটি লজিটেক ট্র্যাকম্যান মার্বেল। তবে আমি দেখতে পেলাম যে কোনও স্ক্রোল হুইল নেই। আপনি কিভাবে এটি মোকাবেলা করবেন? আমি কি অবশ্যই স্ক্রোল হুইল সহ একটি ট্র্যাকবল কিনতে চাই? আমি ফেসবুক ব্যবহার করে অনেক স্ক্রোল করি।

আমি আমার সূচি এবং মাঝারি আঙ্গুল দিয়ে ক্লিক করতে চাই না, তাই কিছু ট্র্যাকবল ইঁদুর আমার পক্ষে ট্র্যাকম্যান হুইলের মতো কাজ করবে না।

windows-7  scroll-wheel  trackball 
— lamwaiman1988
সূত্র
লজিটেক দ্বারা ট্র্যাকম্যান হুইল চেষ্টা করুন। অফারটি তারযুক্ত বা ওয়্যারলেস মডেল।
— মোয়াব
আমি আমার সূচি এবং মাঝারি আঙ্গুল দিয়ে ক্লিক করতে চাই না, এ কারণেই আমি কেন্দ্রে বল সহ একটি ট্র্যাকবল চাই। ধন্যবাদ।
— lamwaiman1988
আপনি সাধারণত আপনার মাউস সফ্টওয়্যার দিয়ে জিনিসগুলি সেট আপ করতে পারেন। সেখান থেকে আপনি বিভিন্ন জিনিস করতে পারেন (ট্র্যাকবল ইত্যাদি সরানোর সময় ডান-ক্লিক বোতামটি ধরে রাখুন ...) আমি ধরে নিচ্ছি যে আপনি সম্ভবত আপনার সমস্যাটি ইতিমধ্যে ইতিমধ্যে ঠিক করেছেন, কারণ আপনি এটি এক বছর আগে পোস্ট করেছিলেন । যদি না হয় তবে তোমার শুভকামনা রইল।
— হেল্পিংহ্যান্ড
@ হেল্পিংহ্যান্ড নোপ আমি এখনও একটি কার্যকর সমাধান খুঁজে পাইনি। এখন আমি স্ক্রোলিংয়ের জন্য পেজআপ এবং পেজডাউন ব্যবহার করছি।
— lamwaiman1988

উত্তর:

13

আপনি যদি উইন্ডোতে থাকেন তবে আমি অটোহটকি চেষ্টা করার পরামর্শ দিই, অন্য ব্যবহারকারীরা ইতিমধ্যে মার্বেল মাউসটি দিয়ে স্ক্রোলিংটি মোকাবেলা করেছেন (আমি স্ক্রিপ্টটি নীচে ব্যবহার করেছি):

http://www.autohotkey.com/board/topic/4677-wheel-button-emulation-script/

লজিটেকের সমাধান যা তাদের ড্রাইভারদের সাথে আসে তা অদ্ভুত: আপনি 4 টি উপায় স্ক্রোলিং সক্ষম করতে একবার ক্লিক করুন এবং এটি অক্ষম করতে আবার ক্লিক করুন। আপনি ধরে রাখতে এবং স্ক্রোল করতে পারবেন না যা আমি পরে ছিলাম। আমি তাদের সফ্টওয়্যার আনইনস্টল করে দিয়েছি wound

— user1146719
সূত্র
এই সমাধানটি কাজ করে তবে কেবল ট্র্যাকবলের ছোট বাম বোতামটি সমর্থন করে যাতে এটি ওয়েব পৃষ্ঠার জন্য এটির ডিফল্ট 'পিছনে' ফাংশনটি অক্ষম করে। যাইহোক, আমি এই উত্তরটি কয়েক দিন চেষ্টা করার পরে গ্রহণ করতে পারি।
— lamwaiman1988
দ্রষ্টব্য: এএইচকে স্ক্রিপ্টটি কেবল এক্স-বোতাম, বা 4+ বোতাম ট্র্যাকবলগুলির সাথে ট্র্যাকবলগুলির জন্য কাজ করে।
— মাইকেল পাউলুকোনিস
ভিন্ন বোতামটি ব্যবহার করতে স্ক্রিপ্টটি আপডেট করা খুব সহজ। শীর্ষের কাছাকাছি একটি ভেরিয়েবল অ্যাসাইনমেন্টের উপরে একটি মন্তব্য রয়েছে - পরিবর্তে সেই বোতামটি ব্যবহার করতে "XButton1" কে অন্য মানতে পরিবর্তন করুন। "কীগুলি, মাউস বোতামগুলির তালিকা এবং জয়স্টিক নিয়ন্ত্রণের তালিকা" এর অধীনে এএইচকে সহায়তা ফাইলে (কেবল স্টার্ট মেনু থেকে এএইচকে চালান) বিশেষ কীগুলির একটি তালিকা রয়েছে, যেখানে আপনি সংশোধক হিসাবে কাজ করতে কোনও কী / বোতাম বেছে নিতে পারেন।
— জেমস বি
9

আমার একই ট্র্যাকবল রয়েছে এবং সমাধানটি খুব মার্জিত: আপনি যখন একটি বাছাই করা বোতামটি ক্লিক করেন, তখন বলটি নিজেই একটি স্ক্রোলিং চাকা হয়ে যায়। আমি ছোট আঙুলের সাহায্যে টিপুন যে ডান বোতাম।

এটি খুব সুবিধাজনক এবং এটি ব্যবহার করতে কয়েক দিন সময় লাগে।

আপনি তাড়াতাড়ি বিবেচনা করবেন যে কোনও স্ক্রোলওহিল (একটি মাউস বা একটি ট্র্যাকবলের উপর) অযোগ্য কিছু something আমাকে বিশ্বাস করুন, এটি মূল্যবান ;-)

সুবিধাদি:

  • 1D এর পরিবর্তে 2D স্ক্রোলিং
  • চাকার চেয়ে দ্রুত এবং আরও সুনির্দিষ্ট স্ক্রোলিং
  • দীর্ঘ স্ক্রোল জন্য আরও আরামদায়ক (বল জড়তা ধন্যবাদ)। আপনার ফেসবুক উদাহরণের জন্য উপযুক্ত।

আমি এ ছাড়া আর বাঁচতে পারি না।

যে কোনও লিনাক্স ওএসের অধীনে এটি কনফিগার করা শক্ত নয়। এটির জন্য আপনাকে কেবল একটি /etc/X11/xorg.conf ফাইল তৈরি করতে হবে (আমার কনফিগারেশনটি এখানে দেখুন: লিনাক্সের অধীনে একটি ট্র্যাকবল কনফিগার করুন Xorg.conf সম্পাদনা না করে )

আরও বিশদ এখানে পাওয়া যাবে: https://help.ubuntu.com/commune/Logitech_Marblemouse_USB

উইন্ডোজটিতে আমার কোনও অভিজ্ঞতা নেই তবে আমি মনে করি ট্র্যাকবলের সাথে একটি কনফিগারেশন সরঞ্জাম সরবরাহ করা হয়েছে।

— ploum
সূত্র
2
আমার কাজের পরিবেশটি বেশিরভাগ উইন্ডোজ তাই এটি আমার পক্ষে একটি কার্যকর বিকল্প নয় এবং কীভাবে এটি উইন্ডোতে পোর্ট করা যায় সে সম্পর্কে আমার কোনও ধারণা নেই।
— lamwaiman1988
8

আপনি মার্বেল মাউস স্ক্রোল হুইল চেষ্টা করতে পারেন, বিশেষত সেই মাউসের জন্য বিকাশ করা:

মার্বেল মাউস স্ক্রোল হুইল বা কেবল মার্বেল স্ক্রোল, একটি ছোট প্রোগ্রাম যা কোনও ট্র্যাকবল বা মাউস ছাড়াই কোনও স্ক্রল হুইল সিমুলেট করার জন্য ডিজাইন করা হয়েছে। এটি বিশেষত লজিটেক মার্বেল মাউসের জন্য ডিজাইন করা হয়েছিল তবে কোনও মানক মাউস বা ট্র্যাকবলের সাথে কাজ করতে পারে। এটি উইন্ডোজ 2000 এবং তার জন্য ডিজাইন করা হয়েছে।

মার্বেল স্ক্রোলটি লজিটকের অটস্ক্রোল এবং ইউনিভার্সাল স্ক্রোল ফাংশনগুলির জন্য প্রতিস্থাপন; উভয়ই যথাযথভাবে একটি সত্যিকারের স্ক্রোল চাকা অনুকরণ করুন এবং উভয়েরই সীমাবদ্ধতা এবং ত্রুটি রয়েছে।

মার্বেল স্ক্রোল যে কোনও মাউস বা ট্র্যাকবলের সাথে কাজ করে এবং লগিটেকের সেটপয়েন্ট বা মাউসওয়্যার ড্রাইভারগুলি ইনস্টল করার প্রয়োজন হয় না।

বৈশিষ্ট্য

  • দুটিরও বেশি বোতাম সহ যে কোনও মাউসে স্ক্রোল হুইল যুক্ত করুন
  • বেশিরভাগ অ্যাপ্লিকেশনগুলির সাথে সামঞ্জস্যতা যা কোনও স্ক্রল চাকা সমর্থন করে (কোনও ধরণের ইনপুট জন্য)
  • সামঞ্জস্যযোগ্য ত্বরণ
  • সামঞ্জস্যযোগ্য স্ক্রোলিং দূরত্ব (প্রতি "পদক্ষেপ" - নীচে দেখুন)
  • একটি বাস্তব মাউস চাকা অনুকরণ করতে স্ক্রোলিং পদক্ষেপ
  • দ্রুত বাম / ডানদিকে মোড সুইচার
  • ট্রে আইকনে ক্লিক করে দ্রুত সক্ষম / অক্ষম করুন
  • সিস্টেম রিসোর্সের উপর ছোট এবং হালকা

পণ্যের ওয়েবসাইটটি বর্তমানে নিচে বলে মনে হচ্ছে, তবে এখানে সংরক্ষণাগার.অর্গ সাইটে সাইটের পাঠ্যের একটি অনুলিপি রয়েছে ।

একটি ডাউনলোড লিঙ্ক এখানে ।

— harrymc
সূত্র
উইন্ডোজ 8 এ এটি ভালভাবে কাজ করে।
— জাস্টিনাস ডডানাস
এটি এখনও উইন 7 এবং 8 এ দুর্দান্ত কাজ করে my আমার মাউসের পিছনের বোতামটি ধরে রাখা আমাকে ট্র্যাকবল ব্যবহার করে স্ক্রোল করতে দেয়। তবুও আমি এখনও পিছনের বোতামটি ব্যাক বোতাম হিসাবে ব্যবহার করতে পারি। মূলত এটি কিছু না নিয়েই কার্যকারিতা যুক্ত করেছে। সবচেয়ে ভাল সমাধান।
— জাপাজোন
1
উইন্ডোজ 10 :( উপর নির্ভরযোগ্যভাবে কাজ বলে মনে হচ্ছে না
— askvictor
1
লিঙ্কযুক্ত ডাউনলোডের আয়নাটি ম্যালওয়্যার হিসাবে দেখায় - এটি কোনও মিথ্যা ইতিবাচক কিনা তা নিশ্চিত নয় তবে আপাতত তা না করে।
— জেমস বি
1
আমি এটি বছরের পর বছর ধরে ব্যবহার করেছি এবং এটি উইন্ডোজ 8 পর্যন্ত কার্যকর হয়, এটি এটি অবিশ্বস্ত হয়ে ওঠে। উইন ১০ এ এটি চেষ্টা করে দেখেনি I তিনি আমাকে যে বক্তব্যটি দিয়েছেন তা হ'ল এই অন্য উত্তরটি যা করেছে: superuser.com/a/782571/127024
— জোহান
8

একটি সাধারণ 100 লাইন সি ++ বিকল্প রয়েছে যা অটোহটকি সমাধানগুলির সাথে বেশ মিল

  • এক্স-বাটনগুলির একটি ধরে রাখার সময় ট্র্যাকবলকে সরিয়ে দিয়ে উল্লম্ব / অনুভূমিক স্ক্রোল হুইল ইভেন্ট প্রেরণ
  • ট্র্যাকবলটি সরানো ছাড়াই একটি এক্স-বোতাম টিপুন এবং ছেড়ে দেওয়ার সময় মিডল ক্লিক করুন।

https://github.com/Seelge/TrackballScroll

সম্পাদনা করুন: নতুন সংস্করণগুলি সিস্ট্রয়-আইকন সরবরাহ করে, উইন্ডোজ 10 এ কাজ করে এবং সি # এর উপর ভিত্তি করে।

— Silpion
সূত্র
এই সমাধানটি আমি চেষ্টা করেছি এমন যে কোনও অটোহটকি স্ক্রিপ্টগুলির চেয়ে উচ্চতর, যা প্রত্যেকে একটি বিরক্তিকর "কার্সার জিগল" ভুগছে, সময়চালিত ইভেন্টের কারণে যা "মাউসটিকে তার মূল অবস্থানে ফিরিয়ে নিয়ে যায়" যখন প্রতিটি মিলি সেকেন্ডে থাকে। স্ক্রলিং। এই সাধারণ ট্র্যাকবলসক্রোল নির্বাহযোগ্য এ জাতীয় কোনও সীমাবদ্ধতা ভোগ করে না এবং খুব ভালভাবে কাজ করে। একমাত্র সতর্কতাটি হ'ল
— বেন জনসন
আমি এটি বছরের পর বছর ধরে ব্যবহার করেছিলাম এবং এটি পছন্দ করেছিলাম (এক বছর আগেও আমি এই উত্তরটি +1 করেছি) তবে গত সপ্তাহে উইন্ডোজ 10 এ স্যুইচ করার পরে আমি উল্লেখ করতে চাই যে অন্য মন্তব্যে উল্লিখিত বাগটি এখনও অবরুদ্ধ নয় ' টি স্থির করা হয়েছে, এবং অবিশ্বাস্যতা এটিকে অনুশীলনে আমার পক্ষে সম্পূর্ণ অকেজো করে তুলেছে।
— mtraceur
4

আমি যে অটোহটকি স্ক্রিপ্টটি ব্যবহার করি তা এখানে। আপনি বাম ছোট ছোট বোতামটি ধরে রেখে এবং বলটি উপরে / নিচে রোল করে স্ক্রোল করুন। তবে বাম ছোট ছোট বোতামটি ক্লিক করা এখনও ব্যাক করে। এটি বাম / ডানদিকেও স্ক্রোল করতে পারে তবে এটি আমার পক্ষে খুব সংবেদনশীল ছিল তাই এটি এখানে মন্তব্য করা হয়েছে (যে ব্লকটি শুরু হয় ;timesX := Abs(movedx) / 4)।

আমি মূল সংস্করণটি http://www.autohotkey.com/board/topic/30816-simulate-scrol-wheel-wil-using-right-mouse-button/ এ পেয়েছি । আমি আমার ভার্সনটি সেখানে আরেকজন 8923 হিসাবে পোস্ট করেছি।

$*XButton1::
Hotkey, $*XButton1 Up, XButton1up, off
;KeyWait, XButton1, T0.4
;If ErrorLevel = 1
;{
   Hotkey, $*XButton1 Up, XButton1up, on
   MouseGetPos, ox, oy
   SetTimer, WatchTheMouse, 5
   movedx := 0
   movedy := 0
   pixelsMoved := 0
;   TrayTip, Scrolling started, Emulating scroll wheel
;}
;Else
;   Send {XButton1}
return

XButton1up:
Hotkey, $*XButton1 Up, XButton1up, off
SetTimer, WatchTheMouse, off
;TrayTip
If (pixelsMoved = 0)
{
    ;The mouse was not moved, send the click event
    ; (May want to make it PGUP or something)
    Send {XButton1}
    Send {XButton1Up}
}
return

WatchTheMouse:
MouseGetPos, nx, ny
movedx := movedx+nx-ox
movedy := movedy+ny-oy

pixelsMoved := pixelsMoved + Abs(nx-ox) + Abs(ny-oy)

;timesX := Abs(movedx) / 4
;ControlGetFocus, control, A
;Loop, %timesX%
;{
;    If (movedx > 0)
;    {
;        SendMessage, 0x114, 1, 0, %control%, A ; 0x114 is WM_HSCROLL
;        movedx := movedx - 4
;    }
;    Else
;    {
;        SendMessage, 0x114, 0, 0, %control%, A ; 0x114 is WM_HSCROLL
;        movedx := movedx + 4
;    }
;}

timesY := Abs(movedy) / 4
Loop, %timesY%
{
    If (movedy > 0)
    {
        Click WheelDown
        movedy := movedy - 4
    }
    Else
    {
        Click WheelUp
        movedy := movedy + 4
    }
}   

MouseMove ox, oy
return
— user318097
সূত্র
আপনি যদি ডান-ক্লিকটি ব্যবহার করতে চান তবে "XButton1" "RButton" দিয়ে প্রতিস্থাপন করুন।
— ম্যাট ওওলক
এটি আমার জন্য নিখুঁতভাবে কাজ করছে, তবে স্ক্রোলিং ক্রিয়াটি মসৃণ করার কোনও উপায় আছে কি? উল্লম্ব স্ক্রোলিংয়ের জন্য আমি সেন্ডম্যাসেজ এবং হুইলআপ / ডাউন উভয় পদ্ধতিই চেষ্টা করেছি এবং তারা দু'জনেই 'লাফ'
— জিজ্ঞাসাবাদক
3

এটি এত লজ্জাজনক যে লজিটেক কোনও স্ক্রল হুইল সিমুলেশন বাস্তবায়ন করেনি। তাদের ড্রাইভার একটি বৈশিষ্ট্যটি এটি করার প্রতিশ্রুতি দিয়েছে, তবে এটি সমস্ত প্রয়োগের জন্য কার্যকর হয় না, এটিকে একেবারেই অকেজো করে। তারা নিখুঁত মাউস তৈরি করতে এত কাছাকাছি ছিল! : S

আমি খুঁজে পাওয়া একমাত্র কার্যকারিতা হ'ল এটির জন্য একটি অটোহটকি স্ক্রিপ্ট ব্যবহার করা। এটির সাহায্যে আপনি ছোট বাম / ডান বোতামগুলি উপরে এবং নীচে স্ক্রোল করতে পারেন। এটি নিখুঁতভাবে কাজ করে তবে এটিটি কনফিগার করাটি আসল ঝামেলা: আপনাকে প্রথমে অটোহটকি বুনিয়াদি শিখতে হবে। যদি আপনি এটি করার সিদ্ধান্ত নেন তবে এখানে আমার অটোহটকি স্ক্রিপ্ট। এটি জের্বোর মূল স্ক্রিপ্টের একটি রূপান্তর । একটি একক ক্লিক একটি সাধারণ গতিতে স্ক্রোলিং শুরু করবে, তবে ডাবল বা ট্রিপল ক্লিকটি দ্রুত স্ক্রোলিং শুরু করবে।

; This script remaps the two small buttons on a Logitech Trackman® Marble® Mouse
; to act as scroll up and scroll down

global lastXButton1ClickTime := 0
global nrSubsequentXButton1Clicks := 0

ScrollTheWheel(direction, scrollKey)
{
    now := A_TickCount
    timeSinceLastClick := now - lastXButton1ClickTime 
    lastXButton1ClickTime := now
    if (timeSinceLastClick < 300)
    {
        nrSubsequentXButton1Clicks := nrSubsequentXButton1Clicks + 1
    }
    else
    {
        nrSubsequentXButton1Clicks := 1
    }        

    sleepingFraction := 5

    if (nrSubsequentXButton1Clicks <= 1)
        scrollSpeed := 30
    if (nrSubsequentXButton1Clicks == 2)
        scrollSpeed := 15
    if (nrSubsequentXButton1Clicks >= 3)
        scrollSpeed := 5

    timeSlept := scrollSpeed

    loop 
    {
        if (direction == 1) ; Scroll down
        {
            static downKeyState
            if (scrollKey == 0) 
                GetKeyState, downKeyState, XButton1, P
            else
                GetKeyState, downKeyState, PgDn, P

            if downKeyState = U ; The key has been released, so break out of the loop
               break

            if (timeSlept >= scrollSpeed)
            {
                Send {WheelDown}
                timeSlept = 0                
            }
        }
        else ; Scroll up
        {
            static upKeyState
            if (scrollKey == 0)
                GetKeyState, upKeyState, XButton2, P
            else
                GetKeyState, upKeyState, PgUp, P

            if upKeyState = U ; The key has been released, so break out of the loop
               break            

            if (timeSlept >= scrollSpeed)
            {
                Send {WheelUp}
                timeSlept = 0                
            }
        }   

        Sleep, sleepingFraction
        timeSlept := timeSlept + sleepingFraction
    }    
}

XButton2::
    ScrollTheWheel(0, 0)
    return
XButton1::
    ScrollTheWheel(1, 0)
    return
!PgUp::
    ScrollTheWheel(0, 1)
    return
!PgDn::
    ScrollTheWheel(1, 1)
    return
— দিমিত্রি সি।
সূত্র
আমি পাশাপাশি
— পেজআপ
2

আমি সবেমাত্র একটি লজিটেক মার্বেল মাউস পেয়েছি এবং স্ক্রোলিংয়ের সমস্যাও ছিল। সুতরাং আমি এই স্ক্রিপ্টটি অটোহটকিতে তৈরি করেছি। বাম Xbutton স্ক্রলিং সক্ষম করে, যার অর্থ নীচে থাকাকালীন আপনি বলের সাহায্যে অনুভূমিক এবং অনুভূমিকভাবে স্ক্রোল করতে পারেন এবং ব্রাউজারে বাম এবং ডান বোতামগুলির সাহায্যে সামনে এবং পিছনে সরে যেতে পারেন। ডান এক্সবটনের মাঝের বোতামের মতোই ক্রিয়া রয়েছে।

আমি উইন্ডোজ 7 এ।

#SINGLEINSTANCE FORCE  
GLOBAL status := "basic"
GLOBAL cnt_x
GLOBAL cnt_y

XButton2::MButton

$*XButton1::
    status := "scroll"
    cnt_x := 0
    cnt_y := 0
    MOUSEGETPOS, st_x, st_y
    SETTIMER, _scroll, 30
RETURN

$*XButton1 UP::
    status := "basic"
    SETTIMER, _scroll, OFF
RETURN

_scroll:
    MOUSEGETPOS, cur_x, cur_y
    MOUSEMOVE, st_x, st_y

IF(abs(cur_x-st_x) > abs(cur_y-st_y)) {
    cnt_x := cnt_x + (cur_x-st_x)
    ControlGetFocus, control, A 
    IF (cnt_x > 7) {
        cnt := floor(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 0, 0, %control%, A
        }
        cnt_x := cnt_x - 8*floor(cnt_x / 8)
    } ELSE IF (cnt_x < -7) {
        cnt := -ceil(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 1, 0, %control%, A
        }
        cnt_x := cnt_x - 8*ceil(cnt_x / 8)
    }
} ELSE {
    IF (cur_y >= st_y) {
        cnt_y := cnt_y + (cur_y-st_y)**1.2
    } ELSE {
        cnt_y := cnt_y -(st_y-cur_y)**1.2
    }   
    IF (cnt_y > 7) {
        cnt := floor(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelUp
        }
        cnt_y := cnt_y - 8*floor(cnt_y / 8)
    } ELSE IF (cnt_y < -7) {
        cnt := -ceil(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelDown
        }
        cnt_y := cnt_y - 8*ceil(cnt_y / 8)
    }
}   
RETURN

$*LButton::
    IF (status = "basic") {
        CLICK DOWN Left
    } ELSE IF (status = "scroll") {
        SEND {Browser_Back}
    }
RETURN

$*LButton UP::
    IF (status = "basic") {
        CLICK UP Left
    }
RETURN

$*RButton::
    IF (status = "basic") {
        CLICK DOWN Right
    } ELSE IF (status = "scroll") {
        SEND {Browser_Forward}
    }
RETURN

$*RButton UP::
    IF (status = "basic") {
        CLICK UP Right
    }
RETURN
— Amiral_JCDG
সূত্র
আমি কীবোর্ডগুলিতে আপ এবং ডাউন কীগুলি ছেড়ে দিয়েছিলাম এবং ব্যবহার করেছিলাম। পৃষ্ঠাটি উপরে এবং নীচে সরানোর জন্য আমি স্ক্রোল বারের খালি জায়গায় টিপতাম।
— লামওয়াইমান 1988
1

আপনার ওএসের উপর নির্ভর করে আপনি যখন ধরে তখন পয়েন্টারটি সরিয়ে দিয়ে স্ক্রোলিং সক্ষম করতে বোতামগুলির মধ্যে একটিটি কনফিগার করতে সক্ষম হতে পারেন। যেমন নীচের স্ক্রিপ্টটি আমার মাউসের 10 টি বোতামে (লজিটেক এমএক্স 310 এর "শীর্ষ মধ্যম" বোতামটি সক্ষম করে):

#!/bin/sh
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 290 10
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 286 1
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 287 6 7 4 5
— Ignacio Vazquez-Abram
সূত্র
1

এমন মার্বেল মাউস (ইঁদুর) রয়েছে যার মধ্যে একটি স্ক্রোল হুইল রয়েছে। অন্যথায়, দেখে মনে হচ্ছে কোনও অ্যাপ্লিকেশন বা কিছু স্ক্রিপ্টের জন্য একটি চাকাবিহীন মাউসের পাশাপাশি একটি স্ক্রোল ফাংশন জড়িত করার জন্য বোতামগুলির একটির ব্যবহার করতে হবে (এটি আপনি গ্রহণযোগ্য সমাধান হিসাবে নয়, অন্য উত্তরের মন্তব্যে উল্লেখ করেছেন)।

সুতরাং "চাকা পুনরায় উদ্বেগ কেন?" এই ক্ষেত্রে একটি ভাল প্রবাদ।

এই উদাহরণগুলিতে, উপাদানটি শারীরিকভাবে ইনস্টল করা আছে এবং সেগুলি থেকে বেছে নেওয়া অনেক ধরণের রয়েছে। নীচে দুটি উদাহরণ এবং শৈলী রয়েছে।

wh1

বা এর মতো কিছু: অ্যাডেসো

wh2

— কার্ল বি
সূত্র
1

দুটি অপ্রচলিত বিকল্প

  • ট্র্যাকবলের পাশাপাশি একটি অ্যাপল ম্যাজিক ট্র্যাকপ্যাড ব্যবহার করুন। (এটি আমার বর্তমান সমাধান) http://www.apple.com/magictrackpad/

  • একটি লিপমোশন কন্ট্রোলার কিনুন এবং ট্র্যাকবল ছাড়াও এটি ব্যবহার করুন। উপরে এবং নীচে স্ক্রোল করতে ডিভাইসের সামনে আপনার হাতটি ত্যাগ করুন। https://www.leapmotion.com/product

এখানে চিত্র বর্ণনা লিখুন

চিত্র ক্রেডিট http://www5.pcmag.com/media/images/393268-leap-motion-controller.jpg

— spuder
সূত্র
1

একটি সরল (এবং ইরগোনোমিক সাহস আমি বলি) সমাধান হ'ল আপনার বামহাতে স্ক্রোলিংয়ের ক্রিয়াটি রাখা।

আপনার বাম হাতের সাথে মাউস ব্যবহার করে / তার বাম প্রান্তে একটি বিল্ট-ইন স্ক্রোল হুইল সহ একটি কীবোর্ড ব্যবহার করে / মিকে ( HTTP: //) এর মতো একটি প্রোগ্রাম সহ প্রোগ্রামযোগ্য কেপ্যাডের কীগুলিতে স্ক্রোলিং ফাংশনগুলি বরাদ্দ করে এটি অর্জন করা যেতে পারে www.seriosoft.org/en/index.php )।

আমি কেন এটিকে আরও অর্গনোমিক বলে মনে করি - কারণ এই পদ্ধতিটি উভয় হাতে সমানভাবে টান সরবরাহ করে। (এটি সম্পর্কে আরও: http://capsoff.org/checklist )।

— drabsv
সূত্র
1

আমি উইন্ডোজ 7 এ আছি এবং স্ক্রলিং না করে কেনসিংটন অরবিট অপটিকাল ট্র্যাকবল ব্যবহার করছি - এটি এএইচকে স্ক্রিপ্ট এবং অ্যাপ্লিকেশনগুলির দ্বারা প্রয়োজনীয় অন্যান্য এক্স-বাটনগুলি ছাড়া অন্য দুটি দ্বারা নির্দেশিত দুটি বোতামের ট্র্যাকবল।

তবে মাউসআইম্প আমার জন্য উইন্ডোজ 7 এ কাজ করছে। আইটি কনফিগারযোগ্য তবে আমার right-click + rollস্ক্রোলিংয়ের স্ক্রিন পেতে এটি আমার জন্য সেট আপ রয়েছে । এটি আরও বেশি টেনে আনার মতো, সুতরাং পয়েন্টারটি সরে যায় এবং আপনি একবারে কেবল একটি পর্দা পেয়েছেন [আপডেট: স্ক্রোল হারটি কনফিগারযোগ্য, তাই এটি "এক পৃষ্ঠার" চেয়ে বেশি হতে পারে]]।

একই সময়ে, কেনসিংটনের ট্র্যাকবল ওয়ার্কস আমাকে একটি পৃষ্ঠা-ডাউন স্ক্রোল চালু করার জন্য কনফিগার করা হয়েছে left-click + right-click। দুর্ভাগ্যক্রমে এটি তখন একবারে কোনও পৃষ্ঠা ব্যাক আপ করতে পারে না (এক বা অন্যটি)।

এটি কোনও পণ্য প্লাগ নয় - এটি এই মডেল / ধরণের ট্র্যাকবলের সাথে কাজ করতে পেরেছি ।

ক্যাভেট: আপনি ক্রমাগত ডান এবং বাম ক্লিক করেন এবং এর ফলে বিভ্রান্তি ঘটে এবং লিঙ্কগুলি অনুসরণ করা / জেএস-সক্রিয় করা হয় যখন আপনি কেবল স্ক্রোলিং বন্ধ করতে চান । :::দীর্ঘশ্বাস:::

— মাইকেল পাউলুকোনিস
সূত্র
1

আমি সবেমাত্র ক্যানসিংটনের একটি কক্ষপথ ওয়্যারলেস ট্র্যাকবল পেয়েছি, এটি অত্যন্ত আশ্চর্যজনক। আপনার বল রয়েছে, আপনার প্রতিটি পাশেই দুটি বোতাম রয়েছে এবং আপনার ট্র্যাকবলের বাইরে এক ধরণের বৃত্ত রয়েছে যা পৃষ্ঠার উপরে বা নীচে স্ক্রোল করা সম্ভব করে। এটি সত্যই কার্যকর হয় এবং আমি উইন্ডোজ এবং ম্যাক ওএসএক্স-এ ব্যবহার করছি।

— andremartins
সূত্র
1

আমি অটোহটকি ব্যবহার করে কিছুক্ষণ আগে এর জন্য কিছু তৈরি করেছি এবং অনুভব করেছি যে আমি এটি এখানে ভাগ করে নেব: মাউস হুইল এমুলেটর

বাম এবং ডান মাউস বোতামগুলি ধরে রাখার সময় মাউসটিকে প্রায় ঘুরে by

আপনি একই সময়ে বাম এবং ডান মাউস বোতামে ক্লিক করে একটি মধ্যম ক্লিক অনুকরণ করতে পারেন।

— blah238
সূত্র
1

উইন্ডোজ for এর জন্য অন্য একটি সমাধান যা ইন্টারনেট এক্সপ্লোরার সহ সমস্ত অ্যাপ্লিকেশনগুলিতে স্ক্রোল করার অনুমতি দেয়:

  1. অটোহটকি ইনস্টল করুন ।
  2. ডেস্কটপ হিসাবে এই স্ক্রিপ্ট সংরক্ষণ করুন scroll.ahk।
  3. ডান ক্লিক করুন scroll.ahk।
  4. রান স্ক্রিপ্ট নির্বাচন করুন ।
  5. নিশ্চিত করুন, যদি অনুরোধ করা হয়।

ট্র্যাকবলটি সরানোর সময় এটি ছোট ডান বোতামটি উল্লম্বভাবে স্ক্রোলকে ধারণ করবে। ছোট বাম বোতামটি হ'ল পিছনের বোতাম।

এরিক এলমোর কোডের লিঙ্কটি অদৃশ্য হয়ে যাওয়ার পরে, তা এখানে:

;;
;; Emulate_Scrolling_Middle_Button.ahk
;; Author: Erik Elmore <erik@ironsavior.net>
;; Version: 1.1 (Aug 16, 2005)
;;
;; Enables you to use any key with cursor movement
;; to emulate a scrolling middle button.  While
;; the TriggerKey is held down, you may move the
;; mouse cursor up and down to send scroll wheel
;; events.  If the cursor does not move by the
;; time the TriggerKey is released, then a middle
;; button click is generated.  I wrote this for my
;; 4-button Logitech Marble Mouse (trackball),  
;; which has no middle button or scroll wheel.
;;

;; Configuration

;#NoTrayIcon

;; Higher numbers mean less sensitivity
esmb_Threshold = 7

;; This key/Button activates scrolling
esmb_TriggerKey = XButton2

;; End of configuration

#Persistent
CoordMode, Mouse, Screen
Hotkey, %esmb_TriggerKey%, esmb_TriggerKeyDown
HotKey, %esmb_TriggerKey% Up, esmb_TriggerKeyUp
esmb_KeyDown = n
SetTimer, esmb_CheckForScrollEventAndExecute, 10
return

esmb_TriggerKeyDown:
  esmb_Moved = n
  esmb_FirstIteration = y
  esmb_KeyDown = y
  MouseGetPos, esmb_OrigX, esmb_OrigY
  esmb_AccumulatedDistance = 0
return

esmb_TriggerKeyUp:
  esmb_KeyDown = n
  ;; Send a middle-click if we did not scroll
  if esmb_Moved = n
    MouseClick, Middle
return

esmb_CheckForScrollEventAndExecute:
  if esmb_KeyDown = n
    return

  MouseGetPos,, esmb_NewY
  esmb_Distance := esmb_NewY - esmb_OrigY
  if esmb_Distance
    esmb_Moved = y

  esmb_AccumulatedDistance := (esmb_AccumulatedDistance + esmb_Distance)
  esmb_Ticks := (esmb_AccumulatedDistance // esmb_Threshold) ; floor divide
  esmb_AccumulatedDistance := (esmb_AccumulatedDistance - (esmb_Ticks * esmb_Threshold))
  esmb_WheelDirection := "WheelDown"
  if (esmb_Ticks < 0) {
    esmb_WheelDirection := "WheelUp"
    esmb_Ticks := (-1 * esmb_Ticks)
  }

  ;; Do not send clicks on the first iteration
  if esmb_FirstIteration = y
    esmb_FirstIteration = n
  else {
    Loop % esmb_Ticks {
      MouseClick, %esmb_WheelDirection%
    }
  }

  MouseMove,esmb_OrigX,esmb_OrigY,0
return
— ডেভ জার্ভিস
সূত্র
এই জন্য আপনাকে ধন্যবাদ! আমি এই স্ক্রিপ্টের দুটি ছোট পরিবর্তন করেছেন: পরিবর্তিত XButton2করতে XButton1হিসাবে আমি বাম বাটন পছন্দ করা, এবং একটি যোগ *সামনে %esmb_TriggerKey%দুটি লাইন #Persistentতাই তারা শুরু, অধ্যায় Hotkey, *%esmb_TriggerKey%। পরেরটি এটিকে সংশোধক কীগুলির দ্বারা নির্বিঘ্নে কাজ করে, সুতরাং যেমন Ctrl + স্ক্রোল কাজ করে।
— সিনকোডেনদা
0

অন্য ট্র্যাকম্যান মার্বেল ব্যবহারকারী।

আমি স্ক্রোল অনুকরণের জন্য এক্স-মাউস বোতাম নিয়ন্ত্রণ ব্যবহার করছি । এই বৈশিষ্ট্যটির প্রয়োগটি সেখানে (এখনও?) নিখুঁত নয় তবে এটি তাদের নিজস্ব সেটপয়েন্ট ™ সফ্টওয়্যারটিতে লজিটেক প্রয়োগের চেয়ে অনেক বেশি ব্যবহারযোগ্য।

আমি অটোহটকির সাথে জগাখিচু করতে না চাওয়া এবং স্রেফ কাজ করে এমন কিছু খুঁজছেন এমন কাউকে আমি এক্সএমবিসির পরামর্শ দিচ্ছি।

— Killy.MXI
সূত্র
আমাদের সাইট ব্যবহার করে, আপনি স্বীকার করেছেন যে আপনি আমাদের কুকি নীতি এবং গোপনীয়তা নীতিটি পড়েছেন এবং বুঝতে পেরেছেন ।
Licensed under cc by-sa 3.0 with attribution required.