17

ব্যাচের ফাইলে আমাকে তারিখ কমান্ড থেকে এক মাস, দিন, বছর বের করতে হবে। সুতরাং আমি নিম্নলিখিতটি ব্যবহার করলাম, যা ডায়াল্ট কমান্ডকে তার সাব স্ট্রিংগুলিকে ভেরিয়েবলের সাথে বের করার জন্য প্রয়োজনীয়ভাবে পার্স করে:

set Day=%Date:~3,2%
set Mth=%Date:~0,2%
set Yr=%Date:~6,4%

এটি সর্বোত্তম, তবে আমি যদি এই ব্যাচ ফাইলটি কোনও ভিন্ন আঞ্চলিক / দেশের সেটিংস সহ কোনও মেশিনে স্থাপন করি তবে এটি ব্যর্থ হয় কারণ মাস, দিন এবং বছর বিভিন্ন স্থানে থাকে।

তারিখের বিন্যাস নির্বিশেষে আমি কীভাবে মাস, দিন এবং বছর বের করতে পারি?

— AngryHacker
সূত্র

1

আপনি কি পুরোপুরি ব্যাচে সীমাবদ্ধ? ভিবিএস স্ক্রিপ্ট / ডাব্লুএসএইচ এবং / বা পাওয়ারশেল এ জাতীয় জিনিসটি আরও সহজ ...

— অ্যাড্রিয়েন

@ অ্যাড্রিন, হ্যাঁ ব্যাচে সীমাবদ্ধ - এটি ভিএস ২০০৮ পোস্ট-বিল্ড পদক্ষেপের অংশ।

— ক্রুদ্ধহ্যাকার

% তারিখ% কে% তারিখ দ্বারা প্রতিস্থাপন করা হচ্ছে: ~ 6,4% -% তারিখ: ~ 3,2% -% তারিখ

— :, 0,2

14

সূত্র: http://ss64.com/nt/syntax-getdate.html

পদ্ধতি 2 (একক সেমিডি)

_GetDate.cmd

@Echo off
:: Check WMIC is available
WMIC.EXE Alias /? >NUL 2>&1 || GOTO s_error

:: Use WMIC to retrieve date and time
FOR /F "skip=1 tokens=1-6" %%G IN ('WMIC Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
   IF "%%~L"=="" goto s_done
      Set _yyyy=%%L
      Set _mm=00%%J
      Set _dd=00%%G
      Set _hour=00%%H
      SET _minute=00%%I
)
:s_done

:: Pad digits with leading zeros
      Set _mm=%_mm:~-2%
      Set _dd=%_dd:~-2%
      Set _hour=%_hour:~-2%
      Set _minute=%_minute:~-2%

:: Display the date/time in ISO 8601 format:
Set _isodate=%_yyyy%-%_mm%-%_dd% %_hour%:%_minute%
Echo %_isodate%
pause

পদ্ধতি 1 (সেন্টিমিটার + ভিবি)

_GetDate.cmd

@Echo off
For /f %%G in ('cscript /nologo getdate.vbs') do set _dtm=%%G
Set _yyyy=%_dtm:~0,4%
Set _mm=%_dtm:~4,2%
Set _dd=%_dtm:~6,2%
Set _hh=%_dtm:~8,2%
Set _nn=%_dtm:~10,2%
Echo %_yyyy%-%_mm%-%_dd%T%_hh%:%_nn%

_getdate.vbs

Dim dt
dt=now
'output format: yyyymmddHHnn
wscript.echo ((year(dt)*100 + month(dt))*100 + day(dt))*10000 + hour(dt)*100 + minute(dt)

— টেক্স হেক্স
সূত্র

1

আহ হা, লোকালের তারিখের ক্রম সন্ধানের খুব ঝরঝরে উপায়। ss64 এর একটি নিফটি সম্প্রদায় রয়েছে cmd.exe ব্যবহারকারীদের।

— নিকলি

আমি আপনার উত্স লিঙ্ক থেকে উভয় স্ক্রিপ্ট অন্তর্ভুক্ত। আশা করি এটি আপনার জন্য ঠিক আছে

— নিক্সদা

@nixda কোনও সমস্যা নেই, ব্যবহারকারী যাই হোক না কেন সাহায্য করে।

— টেক্স হেক্স

যদি আপনার উপরের "পদ্ধতি 2" এ সেকেন্ড ধরে রাখতে হয় তবে অন্যদের মতো শীর্ষস্থানীয় শূন্যগুলি Set _second=00%%Kথেকে এক্সট্রাক্ট করার সময় যোগ করুন wmicএবং প্যাড করুন।

— টিম পেরেন্তি

13

উইন্ডোজ এক্সপি এবং তারপরে

_getDate.cmd

@echo off
for /f "tokens=2 delims==" %%G in ('wmic os get localdatetime /value') do set datetime=%%G

set year=%datetime:~0,4%
set month=%datetime:~4,2%
set day=%datetime:~6,2%

echo %year%/%month%/%day%

_{আউটপুট}

— and31415
সূত্র

সর্বাধিক সংক্ষিপ্ত উত্তরের জন্য +1। আমি ECHO %year%-%month%-%day%আইএসও এবং ফাইল সিস্টেমের সামঞ্জস্যপূর্ণ ফর্ম্যাটটি দিয়ে শেষ করার পরামর্শ দিই (বছর-দিন-দিন স্বয়ংক্রিয়ভাবে সাজানোর কথা উল্লেখ না করা)। :-)।

— জাফান শ্রয়েডার

3

আমি জানি আপনি ঠিক যা চেয়েছিলেন তা নয়, তবে আমি dateব্যাচ ফাইলের অভ্যন্তরে একটি কমান্ড থেকে লিনাক্স অ্যাপ্লিকেশনটির উইন্ডোজ পোর্টটি ব্যবহার করি এবং তারপরে ফলাফলটি একটি ভেরিয়েবলের কাছে বরাদ্দ করি।

কেবলমাত্র ব্যাচের কমান্ড ব্যবহার করে নির্ভরযোগ্যভাবে তারিখটি পাওয়ার জন্য আমার এখনও কোনও উপায় খুঁজে পাওয়া যায়নি।

— Hydaral
সূত্র

2

YYYY-MM-DD ফর্ম্যাটের জন্য এই ব্যাচ ফাইলটি ব্যবহার করুন। এটি একটি উইন্ডো উপকরণ সরঞ্জাম ব্যবহার করে যা আঞ্চলিক সেটিংস থেকে পৃথক একটি ডেটটাইম স্ট্রিং পেতে সমস্ত সাম্প্রতিক উইন্ডোজ সংস্করণগুলিতে উপস্থিত হওয়া উচিত।

পাথের মধ্যে একটি ব্যাচ ফাইলে সংরক্ষণ করুন (যেমন) সি: \ উইন্ডোজ d rdate.bat এর পরে ভেরিয়েবল (গুলি) সেট করতে একটি কল RDATE.BAT দিয়ে অ্যাক্সেস করুন। অন্যথায়, কোডটি আপনার ব্যাচের ফাইলে অনুলিপি করুন।

এই তারিখের ফর্ম্যাটটি ফাইলের নাম এবং লগিংয়ের জন্য উপযুক্ত। এটি সঠিকভাবে সাজান। লগটাইম ভেরিয়েবলটি দ্বিতীয় যথার্থতায় লগিং ব্যাচ ফাইল ক্রিয়াকলাপের জন্য উপযুক্ত YYYY-MM-DD-HHMMSS হিসাবে একটি তারিখ + সময় পরিবর্তনশীল যুক্ত করে।

আপনার ইচ্ছামতো তারিখ (এবং সময়) ফর্ম্যাটগুলি সামঞ্জস্য করুন। উত্পাদনে পর্দার প্রতিধ্বনি রিম করুন। প্রতিটি পাঠ্য নির্বাচনের দুটি সংখ্যা হ'ল শূন্য-ভিত্তিক প্রারম্ভের অক্ষর সূচক এবং অনুলিপি করার জন্য অক্ষরের সংখ্যা, যেমন,% ডেটটাইম: ~ 0,4% 0 অবস্থান থেকে শুরু করে একটি 4 টি অক্ষরের স্ট্রিং নেয়।

echo off
rem First, get the locality-invariant datetime
for /f "tokens=2 delims==" %%I in ('wmic os get localdatetime /format:list') do set datetime=%%I
rem echo %datetime%

rem Build the reverse date string YYYY-MM-DD
set rdate=%datetime:~0,4%-%datetime:~4,2%-%datetime:~6,2%
echo rdate=%rdate%

rem Built a datetime string YYYY-MM-DD-hhmmss
set logtime=%rdate%-%datetime:~8,6% 
echo logtime=%logtime%

— জিম বার্চ
সূত্র

1

And31415 এর উত্তর হিসাবে প্রায় একই । উভয় স্ক্রিপ্ট ব্যবহার করুনwmic os get localdatetime

— নিক্সদা

1

আপনি ঠিক বলেছেন যে ভিএস ২০০৮ একটি ব্যাচফিল আউটপুট দেয়, আপনি পাওয়ারশেল স্ক্রিপ্টস এবং অন্যান্য প্রোগ্রাম সহ আপনি যে কোনও প্রোগ্রাম চালাতে পারেন।

সম্পাদনা:

এখানে কিছু অনুরূপ প্রশ্ন:

/programming/1051845/visual-studio-2008- প্রোফেশনাল- বিল্ড- প্রসেস /programming/

মূলত, আমি এটি এসও-তে স্থানান্তরিত হব। । ।

— surfasb
সূত্র

0

আপনি কি NET TIME \\%ComputerName%পরিবর্তে ব্যবহার করার চেষ্টা করেছেন DATE? আমি মনে করি যে NET TIMEলোকেল নির্বিশেষে একটি সুসংগত বিন্যাসে ডেটা সরবরাহ করার কথা।

— গির্জা
সূত্র

না, না।

— ক্রুদ্ধহ্যাকার

আকর্ষণীয়, আমি এটি চেষ্টা করেছি, এও এবং মার্কিন ফর্ম্যাটগুলির মধ্যে স্যুইচিং এবং net timeসর্বদা এম / ডি / ইয়ি ফর্ম্যাটে আউটপুট। @ অংগ্রিহ্যাকার, কোন সেটিংস দিয়ে এটি আপনার পক্ষে কাজ করে নি?

— হায়দরাল

1

আমি ফ্রেঞ্চ (বেলজিয়াম) পরিবর্তন করেছি এবং এটি আমাকে 2011-07-27 দিয়েছে। মার্কিন

— 07/27/2011 দিন

0

শেখরের পোস্টের জন্য ধন্যবাদ এটি প্রয়োজন হিসাবে কাজ করে এবং সেই সময়ের শূন্য প্যাডিং।

@Echo Off

for /f "tokens=1-5 delims=:" %%d in ("%time%") do set var=%date:~10,4%%date:~4,2%%date:~7,2%-%%d%%e

set datetimestr=%var: =0%

set logfile=LogFile-%datetimestr%.txt

echo %logfile%

আউটপুট: লগফিল-20151113-0901.txt

— Trifused
সূত্র

-1

এটি কিছুটা প্রসঙ্গ ছাড়তে পারে তবে এখানে একটি .bat ফাইল যা আমি আমার নিজস্ব নির্ধারিত ব্যাকআপের জন্য লিখেছিলাম এবং ভিজ্যুয়াল স্টুডিওতে পোস্ট বিল্ড ক্রিয়াকলাপ থেকে কল করি। আমি আশা করি কেউ কেউ এটির কাজে লাগবে।

নিম্নলিখিতটি একটি .bat ফাইলে সংরক্ষণ করুন

--------------------------------------------------
**:: The following is Copyright &copy; 2012 ShopNetNuke Corp.  All rights reserved.
::  and released under the GNU General Public License (GPLv3)**

:: The following section retrieves the current date and time and formats it into the '%var%' variable
:: This format always ensures that the Date and Time are fixed length to avoid the situation of
:: having a value of '12/ 1/2012 rather than '12/01/2012'
echo off
for /f "tokens=1-5 delims=:" %%d in ("%time%") do set var=%date:~10,4%-%date:~4,2%-%date:~7,2%-%%d-%%e
set var=%var: =0%
echo Beginning my valuable Backup Set:  Backup--%var%

:: If you wanted to request the user input a filename prefix, 
:: then we would use something similar to this
:: set /p nameprefix= Enter the file name prefix?
:: Get the Current Date and Time
::for /f "tokens=1-5 delims=:" %%d in ("%time%") do set var=%date:~10,4%-%date:~4,2%-%date:~7,2%-%%d-%%e
:: set var=%var: =0%
:: echo Beginning my valuable Backup Set:  Backup--%var%_%nameprefix%

Pause

echo Starting SQL Server Database Backup Job...
:: The following line initiates the Backup job within SqlServer Agent.
:: Change 'MyBackupNameInSqlAgent' to the name of the job you want executed
:: Change the directory paths to those relevant to your current system installation directories
:: SqlAgent will not return a value if the backup action succeed, 
:: however, in the event an error is encountered, it will be echoed onto the screen
"C:\Program Files\Microsoft SQL Server\100\Tools\Binn\sqlcmd.exe" -S SQLSERVERNAME\INSTANCENAME -Q "execute msdb.dbo.sp_start_job @job_name = 'MyBackupNameInSqlAgent'"
:: An error will be returned if the Backup job is not found or has already been triggered by another process

echo Starting My Valuable Source Code Directory Backup...

echo ...backing up files and folders in "C:\Source\MyPreciousProjectDirectory\"...
:: The following line will execute the 7zip command to create a .7z file of the directory named in 'MyPreciousProjectDirectory'
:: and tells it to put the archive in the 'MyPreciousBackupDirectory'.  The compression level will be defined by the 7zip default settings
:: The -p flag tells 7zip to password protect the archive, in this case, I've used the Date/Time portion of the filename as the password
:: remove the '-p%var%' section to remove password protection from the archive
"C:\Program Files\7-Zip\7z.exe" a -t7z C:\MyPreciousBackupDirectory\%var%\MyPreciousProject--%var%.7z -p%var% -mhe C:\Source\MyPreciousProjectDirectory\* 

echo Source Code Directory Backups complete.

echo Archiving Database Backups now...
:: The following line will execute the 7zip command to archive the Database backup.
:: The '*' could be replaced by the actual backup name.
:: The '*' indicates all files of type '.bak'
:: The -p flag tells 7zip to password protect the archive, in this case, again, I've used the Date/Time portion of the filename as the password
:: remove the '-p%var%' section to remove password protection from the archive
"C:\Program Files\7-Zip\7z.exe" a -t7z  C:\MyPreciousBackupDirectory\%var%\MyPreciousProject-Database-%var%.7z -p%var% -mhe "C:\Program Files\Microsoft SQL Server\MSSQL10.SQLDEV08\MSSQL\Backup\*.bak"

echo Database Backup Archival process complete.

:: If you wanted to place both the previous backups into one single combination archive,
:: you could do something like the following
"C:\Program Files\7-Zip\7z.exe" a -t7z C:\MyPreciousBackupDirectoryForSourceAndDatabase\%var%\MyPreciousProjectBackupSourceAndDatabase--%var%.7z -p%var% -mhe C:\Source\MyPreciousProjectDirectory\* 


echo Now attempting to copy archives to Network Server...
:: The following line will use xcopy to copy the arechives to the server backup directory and place them in a directory named by the DateTime variable %var%
xcopy /S /I /J /Y C:\MyPreciousBackupDirectory\%var% \\MyPreciousBackupServerName\SourceCode\MyPreciousServerBackupDirectory\%var%
:: Or if the combination above was used then copy that...
xcopy /S /I /J /Y C:\MyPreciousBackupDirectoryForSourceAndDatabase\%var% \\MyPreciousBackupServerName\SourceCode\MyPreciousServerBackupDirectory\%var%


echo 7z Archive files transferred to MyPreciousBackupServerName successfully
echo  ||
echo \||/
echo  \/
echo ---------------------------------------------------
echo ----- BACKUP SET "%var%" COMPLETE ------
echo ---------------------------------------------------
pause

— জেসি
সূত্র

1

tl; dr, আপনি স্ক্রিপ্টটি কী করে তার একটি ব্যাখ্যা যুক্ত করতে পারেন। কারণ এটি এখনই সমাধান হিসাবে আসে না। এটি আরও কার্যকর হতে পারে, যদি আপনি কোডের প্রাসঙ্গিক বিটগুলি সরিয়ে ফেলতে পারেন

— শেখর

1

পুরো ব্যাচের স্ক্রিপ্টটি %date%ও %time%ভেরিয়েবলগুলির উপর নির্ভর করে যা স্থানীয়ভাবে সচেতন এবং ওপি যেমনটি বলেছিল তেমন অনুমানযোগ্য উপায়ে পার্স করা যায় না।

— 31415

একটি প্রাক্কলনযোগ্য ফর্ম্যাটে ব্যাচ ফাইলে কীভাবে তারিখ পাবেন?

সূত্র: http://ss64.com/nt/syntax-getdate.html

পদ্ধতি 2 (একক সেমিডি)

পদ্ধতি 1 (সেন্টিমিটার + ভিবি)

উইন্ডোজ এক্সপি এবং তারপরে