এক্সপি বা - - একটি নতুন উইন্ডোজ ইনস্টল করার পরে আমি কীভাবে উইন্ডোজ আপডেটগুলিকে "জোর" করতে পারি?
আমি এক সপ্তাহ পরে "ওল্ড" উইন্ডোজ আপডেট করতে চাই না, তাই এটি "এক ধাপে" করা যেতে পারে? এমন কোনও "জাদুকরী" কমান্ড রয়েছে যা উইন্ডোজকে আপডেটগুলি যাচাই করতে বাধ্য করে, এবং যদি কিছু থাকে তবে সেগুলি ইনস্টল করুন?
উত্তর:
আপনি কোনও স্ক্রিপ্ট ব্যবহার করে স্বয়ংক্রিয়ভাবে আপডেটগুলি পরীক্ষা করতে এবং ইনস্টল করতে পারেন। এটি এক্সপি বা উইন্ডোজ 7 এর মধ্যে কাজ করবে।
ডাউনলোডের জন্য বেশ কয়েকটি স্ক্রিপ্ট পাওয়া যায়, এটি আমার :
' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.
' This code has been placed in the public domain. It may be freely
' used, modified, and distributed. However it is provided with no
' warranty, either express or implied.
'
' Exit Codes:
' 0 = scripting failure
' 1 = error obtaining or installing updates
' 2 = installation successful, no further updates to install
' 3 = reboot needed; rerun script after reboot
'
' Note that exit code 0 has to indicate failure because that is what
' is returned if a scripting error is raised.
'
Set updateSession = CreateObject("Microsoft.Update.Session")
Set updateSearcher = updateSession.CreateUpdateSearcher()
Set updateDownloader = updateSession.CreateUpdateDownloader()
Set updateInstaller = updateSession.CreateUpdateInstaller()
Do
WScript.Echo
WScript.Echo "Searching for approved updates ..."
WScript.Echo
Set updateSearch = updateSearcher.Search("IsInstalled=0")
If updateSearch.ResultCode <> 2 Then
WScript.Echo "Search failed with result code", updateSearch.ResultCode
WScript.Quit 1
End If
If updateSearch.Updates.Count = 0 Then
WScript.Echo "There are no updates to install."
WScript.Quit 2
End If
Set updateList = updateSearch.Updates
For I = 0 to updateSearch.Updates.Count - 1
Set update = updateList.Item(I)
WScript.Echo "Update found:", update.Title
Next
WScript.Echo
updateDownloader.Updates = updateList
updateDownloader.Priority = 3
Set downloadResult = updateDownloader.Download()
If downloadResult.ResultCode <> 2 Then
WScript.Echo "Download failed with result code", downloadResult.ResultCode
WScript.Echo
WScript.Quit 1
End If
WScript.Echo "Download complete. Installing updates ..."
WScript.Echo
updateInstaller.Updates = updateList
Set installationResult = updateInstaller.Install()
If installationResult.ResultCode <> 2 Then
WScript.Echo "Installation failed with result code", installationResult.ResultCode
For I = 0 to updateList.Count - 1
Set updateInstallationResult = installationResult.GetUpdateResult(I)
WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode
Next
WScript.Quit 1
End If
If installationResult.RebootRequired Then
WScript.Echo "The system must be rebooted to complete installation."
WScript.Quit 3
End If
WScript.Echo "Installation complete."
Loop
আপনি এটি কমান্ড লাইন থেকে এটি চালান:
cscript wsusupdate.vbs
আমার স্ক্রিপ্টটি কেবলমাত্র স্বল্পমাত্রায় কার্যকর তবে এটি এখনও কার্যকর হতে পারে। আরও অনেক অতিরিক্ত বৈশিষ্ট্যযুক্ত এমন অন্যান্য স্ক্রিপ্ট রয়েছে, একটি গুগল অনুসন্ধান করুন।
<59, 3> <null>: 0x80240044। কোন ধারণা কেন এই ব্যর্থ হয়? আমি এই পদ্ধতিগুলি উল্লেখ করার পদ্ধতিগুলি অনুসন্ধান করার চেষ্টা করেছি, তবে কী ঘটছে তা আমি বুঝতে পারি না figure তুমি কি আমাকে সঠিক দিকনির্দেশনা দিবে?
উইন্ডোজ আপডেট ব্যবহারের স্বাভাবিক পদ্ধতির বাইরে আপনি একটি কমান্ড-লাইন থেকে একটি চেক জোর করতে পারেন।
প্রশাসক কমান্ড প্রম্পট খুলুন এবং চালান:
C:\> %windir%\system32\wuauclt.exe /detectnow
Wuauclt.exe উইন্ডোজ আপডেটের অটোআপেট ক্লায়েন্ট এবং মাইক্রোসফ্ট আপডেট থেকে উপলব্ধ আপডেটগুলি (এমএস উইন্ডোজ প্ল্যাটফর্মের বিভিন্ন সংস্করণের জন্য) পরীক্ষা করতে ব্যবহৃত হয়।
এটি কোনও ইনস্টল করতে বাধ্য করবে না।
আপডেটগুলি পরীক্ষা করতে, কন্ট্রোল প্যানেল, সুরক্ষা, উইন্ডোজ আপডেটে যান, তারপরে "আপডেটের জন্য চেক করুন" এ ক্লিক করুন।
আপডেটগুলির জন্য সত্যিকারের পুনর্বার জোর দেওয়ার আরেকটি উপায় হ'ল % উইন্ডির% \ উইন্ডোজ \ সফ্টওয়্যার ডিস্ট্রিবিউশন in এ সঞ্চিত সমস্ত আপডেট মুছে ফেলা স্লেটটি পরিষ্কার করে দেওয়া \ ডাউনলোড :
NET STOP wuauserv
RD /S /Q %windir%\SoftwareDistribution\Download
NET START wuauserv
তারপরে উইন্ডোজ আপডেটে যান এবং "আপডেটগুলি পরীক্ষা করুন"। এটি এক ঘন্টা সময় নিতে পারে, কারণ আপনার সিস্টেমের ভলিউমের প্রতিটি আপডেটযোগ্য ফাইল চেক করা হয়েছে (পরবর্তীকালে "আপডেটের জন্য চেকগুলি দ্রুত হবে)"। এই পদ্ধতির ত্রুটিগুলি, বোতলজাত আপডেটগুলি মুছে ফেলা হয় এবং এমএস দেখে যেমন অন্তত ইনসোফার করে ততক্ষণ একটি পরিষ্কার, আপ টু ডেট সিস্টেম দেয়।
আমি উইন্ডোস্টল নামে একটি দ্বিতীয় পক্ষের সরঞ্জাম ব্যবহার করছি তাজা উইন্ডোজ ইনস্টলেশন আপডেট করার জন্য। এর সাথে আপনি স্বয়ংক্রিয় রিবুটগুলি সহ পুরো আপডেটিং প্রক্রিয়াটি স্বয়ংক্রিয় করতে পারবেন। আমি মনে করি ব্যবহারকারীর উপস্থিতি ছাড়াই একটি নতুন উইন্ডোকে আধুনিকীকরণের দ্রুততম উপায়গুলির মধ্যে একটি।
আমি খুঁজে পেয়েছি যে উইন্ডোজ 7 এ আপনার নতুন ইনস্টলের অংশ হিসাবে আপনি আইই আপগ্রেড করেছেন বা আপনি এখনও আইই চালাচ্ছেন না এবং সূচনা প্রশ্নের উত্তর দিয়েছেন, উইন্ডোজ আপডেট আপনাকে একটি ত্রুটি দেবে। আমি জিইউআইয়ের মধ্য দিয়ে না গিয়ে মাইক্রোসফ্ট আপডেটে উইন্ডোজ আপডেট স্যুইচ করার কোনও উপায়ও পাইনি, সুতরাং আমি নিজেই আইআই আপ করি, এটি আরম্ভ করি এবং তারপরে জিইউআইয়ের মাধ্যমে উইন্ডোজ আপডেট সেটআপ করব, তাই আমি মাইক্রোসফ্ট আপডেটে স্যুইচ করতে পারি এবং এড়াতে পারি প্রাথমিক ত্রুটি আপনার মাইলেজ পরিবর্তিত হতে পারে.