কীভাবে আমি Word 2007/2010 এর বিষয়বস্তুটি আমার স্বাক্ষর দ্বারা ইমেল করতে পারি?

Question

ব্যবহারকারীদের একটি ইমেলের শরীরের (নকল হিসাবে নয়) শব্দ শব্দের পাঠাতে এবং সমস্ত ইমেল চিঠিপত্রের স্বাক্ষর অন্তর্ভুক্ত করার প্রয়োজন আছে।

ব্যবহারকারী বর্তমানে ব্যবহার করছেন Send to Mail Recipient, যা একটি ইমেলের দস্তাবেজে দস্তাবেজ সন্নিবেশ করায়, তবে তারা স্বয়ংক্রিয়ভাবে তাদের স্বাক্ষর যোগ করতে অক্ষম হয় এবং নিজে নিজে প্রতিটি ইমেলের সাথে এটি যুক্ত করতে হবে। আমার বোঝার থেকে, কারণ Word এ এমবেড করা মেল টুকরা Outlook এর সম্পূর্ণ সংস্করণের মতো নয়।

নিয়মিত E-Mail ওয়ার্ডের কমান্ড তাদের স্বাক্ষর সহ একটি নতুন ইমেল বার্তা আনবে, তবে নথির পরিবর্তে ইমেলের শরীরের একটি সংযুক্তি রয়েছে।

একটি ইমেলের শরীরের মধ্যে এটির সামগ্রী পাঠাতে এবং ব্যবহারকারীর স্বাক্ষর স্বয়ংক্রিয়ভাবে সন্নিবেশ করার উপায় আছে কি?

আমি একটি সমাধান খুঁজছেন যা Office 2007 এবং 2010 উভয় ক্ষেত্রে কাজ করবে এবং ম্যাক্রোর ঠিক আছে।

Answer 1

HowTo-Outlook.com এ এই কার্যকারিতা সক্ষম করতে আমি একটি শব্দ ম্যাক্রো খুঁজে পেয়েছি, " ইমেল হিসাবে শব্দ নথি পাঠান ":

Sub SendDocAsMail()

Dim oOutlookApp As Outlook.Application
Dim oItem As Outlook.MailItem

On Error Resume Next

'Start Outlook if it isn't running
Set oOutlookApp = GetObject(, "Outlook.Application")
If Err <> 0 Then
    Set oOutlookApp = CreateObject("Outlook.Application")
End If

'Create a new message
Set oItem = oOutlookApp.CreateItem(olMailItem)

'Allow the user to write a short intro and put it at the top of the body
Dim msgIntro As String
msgIntro = InputBox("Write a short intro to put above your default " & _
            "signature and current document." & vbCrLf & vbCrLf & _
            "Press Cancel to create the mail without intro and " & _
            "signature.", "Intro")

'Copy the open document
Selection.WholeStory
Selection.Copy
Selection.End = True

'Set the WordEditor
Dim objInsp As Outlook.Inspector
Dim wdEditor As Word.Document
Set objInsp = oItem.GetInspector
Set wdEditor = objInsp.WordEditor

'Write the intro if specified
Dim i As Integer
If msgIntro = IsNothing Then
    i = 1
    'Comment the next line to leave your default signature below the document
    wdEditor.Content.Delete
Else
    'Write the intro above the signature
    wdEditor.Characters(1).InsertBefore (msgIntro)
    i = wdEditor.Characters.Count
    wdEditor.Characters(i).InlineShapes.AddHorizontalLineStandard
    wdEditor.Characters(i + 1).InsertParagraph
    i = i + 2
End If

'Place the current document under the intro and signature
wdEditor.Characters(i).PasteAndFormat (wdFormatOriginalFormatting)

'Display the message
oItem.Display

'Clean up
Set oItem = Nothing
Set oOutlookApp = Nothing
Set objInsp = Nothing
Set wdEditor = Nothing

End Sub

যদি আপনি ম্যাক্রোকে Word তে ধাপে ধাপে সাহায্যের প্রয়োজন হয় তবে প্রকৃত (উপরে) লিঙ্কটিতে ছবি সহ রয়েছে।