প্রত্যাখ্যান সভায় অপসারণ

Question

আমি Outlook 2007 চালাচ্ছি। যখন আমি 1 থেকে 1 এর জন্য একটি মিটিং আমন্ত্রণ পাঠাতে এবং সেই ব্যক্তিটি হ্রাস পেলে, আমি কীভাবে বাতিলকরণ বিজ্ঞপ্তিটি অস্বীকার করে এমন ব্যক্তি পাঠানো ছাড়া আমার মিটিং থেকে এই মিটিংটি মুছে ফেলতে পারি?

যখন আমি সাক্ষাতকারটি মুছে ফেলার চেষ্টা করি, আউটলুক বাতিলকরণ নোটিশ পাঠানোর পরামর্শ দেয়।

Answer 1

আমি আমার ক্যালেন্ডার থেকে অ্যাপয়েন্টমেন্ট মুছে ফেলার জন্য নিম্নলিখিত VBA subroutine ব্যবহার করছি।

Public Sub deleteSelectedAppointment()
    Dim obj As Object
    Dim cl As Integer
    Dim apt As AppointmentItem
    Dim aptDel As AppointmentItem
    Dim pattern As RecurrencePattern
    Dim cnt As Integer

    On Error GoTo ErrHandler

    cnt = 0
    For Each obj In ActiveExplorer.Selection
        cl = obj.Class

        Select Case cl
        Case olMail
        Case olTask
        Case olAppointment
            Set apt = obj
            Debug.Print "Appointment " & apt.subject

            If apt.IsRecurring Then
                '  find and delete the selected item in a series
                Set pattern = apt.GetRecurrencePattern()
                Set aptDel = pattern.GetOccurrence(apt.Start)
            Else
                '  non-recurring appointment
                Set aptDel = apt
            End If

            If aptDel Is Nothing Then
                Debug.Print "Nothing to delete!"
            Else
                aptDel.Delete
                cnt = cnt + 1
            End If

        Case Else
            Debug.Print "unexpected class " & cl
        End Select
    Next obj

    Debug.Print "Deleted appointments: " & cnt

    Exit Sub

ErrHandler:
    MsgBox "Cannot delete appointment" & vbCrLf & Err.Description, vbInformation
    Err.Clear
    On Error GoTo 0

End Sub

এটি কাজ এবং মেইল ​​জন্য কাজ করে। স্পষ্টতই, এই ধরনের রুটিন মুছে ফেলা হতে পারে অনেক যদি যত্নের সাথে ব্যবহার না হয় ...