আমি এখানে নতুন তাই দয়া করে আমার পোস্টটি ভুল বা এর মতো কিছু আছে কিনা তা আমাকে জানান।
আমার কাছে বর্তমানে একটি ম্যাক্রো রয়েছে যা একটি এক্সেল ফাইলকে একাধিক ফাইলে বিভক্ত করে আলাদাভাবে সেভ করে। এই পদক্ষেপটির আমি একটি উত্তর পেয়েছি এবং এতে বেশ খুশি।
এই ফাইলগুলিকে পাসওয়ার্ড সুরক্ষিত রাখতে আমার প্রয়োজন তাই আমি যখন তাদের ক্লায়েন্টগুলিতে ইমেল করি তখন আমার মনে হয় সেগুলি নিরাপদে স্থানান্তরিত হচ্ছে। আমার জন্য এই কৌশলটি সম্পাদন করতে আমি কি কোনও ম্যাক্রো লিখতে / ব্যবহার করতে পারি?
আমার এক্সেল ফাইল ট্যাব 1 আমার সমস্ত ডেটা রাখে এবং বর্তমানে কলাম এ এর উপর ভিত্তি করে সমস্ত কিছু আলাদা করে দেয় its
John Test1
John Test2
John Test3
Alex Test4
Alex Test5
Frank Test6
Frank Test7আমি যে ম্যাক্রো ব্যবহার করি তা জন / অ্যালেক্স / ফ্র্যাঙ্কের জন্য পৃথক করা ফাইলগুলিতে বিভক্ত হয় যা কেবলমাত্র অন্য কোনও ব্যক্তির ডেটার সাথেই তাদের ডেটা প্রদর্শন করে না।
আমার কাছে ট্যাব 2 রয়েছে যা সমস্ত পাসওয়ার্ড রাখে:
John Pw1
Alex Pw2
Frank Pw3আমি আমার বর্তমান ম্যাক্রো প্রক্রিয়া চলাকালীন সদ্য নির্মিত নথিগুলিতে প্রয়োগ করতে ট্যাব 2-এ থাকা পাসওয়ার্ডগুলি তালিকাভুক্ত করার একটি উপায় অনুসন্ধান করছি।
এ সম্পর্কে যে কোনও সহায়তা প্রশংসিত হবে। আমি যা জিজ্ঞাসা করেছি তার কোনওটি অস্পষ্ট কিনা তা আমাকে জানান Let
রেফারেন্সের জন্য আমি ব্যবহারকারী এমটোন থেকে পাওয়া কোডটি উদ্ধৃত করব কারণ এটি বর্তমানে আমি ব্যবহার করছি এমন কোড। এই কোডটি আমার পক্ষে খুব কার্যকর হয়েছে এবং এটি পোস্ট করার জন্য এমটোনকে আমি অত্যন্ত কৃতজ্ঞ। আমি বিশ্বাস করি না আমি এমটোনকে একটি ব্যক্তিগত বার্তা প্রেরণ করতে পারি তবে আমি যদি পারতাম তবে আমি তাকে আন্তরিকভাবে ধন্যবাদ জানাতে পারি!
Public Sub SplitToFiles()
' MACRO SplitToFiles
' Last update: 2012-03-04
' Author: mtone
' Version 1.1
' Description:
' Loops through a specified column, and split each distinct values into a separate file by making a copy and deleting rows below and above
'
' Note: Values in the column should be unique or sorted.
'
' The following cells are ignored when delimiting sections:
' - blank cells, or containing spaces only
' - same value repeated
' - cells containing "total"
'
' Files are saved in a "Split" subfolder from the location of the source workbook, and named after the section name.
Dim osh As Worksheet ' Original sheet
Dim iRow As Long ' Cursors
Dim iCol As Long
Dim iFirstRow As Long ' Constant
Dim iTotalRows As Long ' Constant
Dim iStartRow As Long ' Section delimiters
Dim iStopRow As Long
Dim sSectionName As String ' Section name (and filename)
Dim rCell As Range ' current cell
Dim owb As Workbook ' Original workbook
Dim sFilePath As String ' Constant
Dim iCount As Integer ' # of documents created
iCol = Application.InputBox("Enter the column number used for splitting", "Select column", 2, , , , , 1)
iRow = Application.InputBox("Enter the starting row number (to skip header)", "Select row", 5, , , , , 1)
iFirstRow = iRow
Set osh = Application.ActiveSheet
Set owb = Application.ActiveWorkbook
iTotalRows = osh.UsedRange.Rows.Count
sFilePath = Application.ActiveWorkbook.Path
If Dir(sFilePath + "\Split", vbDirectory) = "" Then
MkDir sFilePath + "\Split"
End If
'Turn Off Screen Updating Events
Application.EnableEvents = False
Application.ScreenUpdating = False
Do
' Get cell at cursor
Set rCell = osh.Cells(iRow, iCol)
sCell = Replace(rCell.Text, " ", "")
If sCell = "" Or (rCell.Text = sSectionName And iStartRow <> 0) Or InStr(1, rCell.Text, "total", vbTextCompare) <> 0 Then
' Skip condition met
Else
' Found new section
If iStartRow = 0 Then
' StartRow delimiter not set, meaning beginning a new section
sSectionName = rCell.Text
iStartRow = iRow
Else
' StartRow delimiter set, meaning we reached the end of a section
iStopRow = iRow - 1
' Pass variables to a separate sub to create and save the new worksheet
CopySheet osh, iFirstRow, iStartRow, iStopRow, iTotalRows, sFilePath, sSectionName, owb.fileFormat
iCount = iCount + 1
' Reset section delimiters
iStartRow = 0
iStopRow = 0
' Ready to continue loop
iRow = iRow - 1
End If
End If
' Continue until last row is reached
If iRow < iTotalRows Then
iRow = iRow + 1
Else
' Finished. Save the last section
iStopRow = iRow
CopySheet osh, iFirstRow, iStartRow, iStopRow, iTotalRows, sFilePath, sSectionName, owb.fileFormat
iCount = iCount + 1
' Exit
Exit Do
End If
Loop
'Turn On Screen Updating Events
Application.ScreenUpdating = True
Application.EnableEvents = True
MsgBox Str(iCount) + " documents saved in " + sFilePath
End Sub
Public Sub DeleteRows(targetSheet As Worksheet, RowFrom As Long, RowTo As Long)
Dim rngRange As Range
Set rngRange = Range(targetSheet.Cells(RowFrom, 1), targetSheet.Cells(RowTo, 1)).EntireRow
rngRange.Select
rngRange.Delete
End Sub
Public Sub CopySheet(osh As Worksheet, iFirstRow As Long, iStartRow As Long, iStopRow As Long, iTotalRows As Long, sFilePath As String, sSectionName As String, fileFormat As XlFileFormat)
Dim ash As Worksheet ' Copied sheet
Dim awb As Workbook ' New workbook
' Copy book
osh.Copy
Set ash = Application.ActiveSheet
' Delete Rows after section
If iTotalRows > iStopRow Then
DeleteRows ash, iStopRow + 1, iTotalRows
End If
' Delete Rows before section
If iStartRow > iFirstRow Then
DeleteRows ash, iFirstRow, iStartRow - 1
End If
' Select left-topmost cell
ash.Cells(1, 1).Select
' Clean up a few characters to prevent invalid filename
sSectionName = Replace(sSectionName, "/", " ")
sSectionName = Replace(sSectionName, "\", " ")
sSectionName = Replace(sSectionName, ":", " ")
sSectionName = Replace(sSectionName, "=", " ")
sSectionName = Replace(sSectionName, "*", " ")
sSectionName = Replace(sSectionName, ".", " ")
sSectionName = Replace(sSectionName, "?", " ")
' Save in same format as original workbook
ash.SaveAs sFilePath + "\Split\" + sSectionName, fileFormat
' Close
Set awb = ash.Parent
awb.Close SaveChanges:=False
End Sub
SaveAs()ওয়ার্কবুক অবজেক্টের পদ্ধতির অতিরিক্ত পরামিতিগুলি দেখুন ।